Initial Commit

code/datums/spells/area_teleport.dm

@@ -0,0 +1,82 @@
+/obj/effect/proc_holder/spell/targeted/area_teleport
+	name = "Area teleport"
+	desc = "This spell teleports you to a type of area of your selection."
+
+	var/randomise_selection = 0 //if it lets the usr choose the teleport loc or picks it from the list
+	var/invocation_area = 1 //if the invocation appends the selected area
+
+/obj/effect/proc_holder/spell/targeted/area_teleport/perform(list/targets, recharge = 1)
+	var/thearea = before_cast(targets)
+	if(!thearea || !cast_check(1))
+		revert_cast()
+		return
+	invocation(thearea)
+	spawn(0)
+		if(charge_type == "recharge" && recharge)
+			start_recharge()
+	cast(targets,thearea)
+	after_cast(targets)
+
+/obj/effect/proc_holder/spell/targeted/area_teleport/before_cast(list/targets)
+	var/A = null
+
+	if(!randomise_selection)
+		A = input("Area to teleport to", "Teleport", A) in teleportlocs
+	else
+		A = pick(teleportlocs)
+
+	var/area/thearea = teleportlocs[A]
+
+	return thearea
+
+/obj/effect/proc_holder/spell/targeted/area_teleport/cast(list/targets,area/thearea)
+	for(var/mob/living/target in targets)
+		var/list/L = list()
+		for(var/turf/T in get_area_turfs(thearea.type))
+			if(!T.density)
+				var/clear = 1
+				for(var/obj/O in T)
+					if(O.density)
+						clear = 0
+						break
+				if(clear)
+					L+=T
+
+		if(!L.len)
+			usr <<"The spell matrix was unable to locate a suitable teleport destination for an unknown reason. Sorry."
+			return
+
+		if(target && target.buckled)
+			target.buckled.unbuckle()
+
+		var/list/tempL = L
+		var/attempt = null
+		var/success = 0
+		while(tempL.len)
+			attempt = pick(tempL)
+			success = target.Move(attempt)
+			if(!success)
+				tempL.Remove(attempt)
+			else
+				break
+
+		if(!success)
+			target.loc = pick(L)
+
+	return
+
+/obj/effect/proc_holder/spell/targeted/area_teleport/invocation(area/chosenarea = null)
+	if(!invocation_area || !chosenarea)
+		..()
+	else
+		switch(invocation_type)
+			if("shout")
+				usr.say("[invocation] [uppertext(chosenarea.name)]")
+				if(usr.gender==MALE)
+					playsound(usr.loc, pick('sound/misc/null.ogg','sound/misc/null.ogg'), 100, 1)
+				else
+					playsound(usr.loc, pick('sound/misc/null.ogg','sound/misc/null.ogg'), 100, 1)
+			if("whisper")
+				usr.whisper("[invocation] [uppertext(chosenarea.name)]")
+
+	return

code/datums/spells/conjure.dm

@@ -0,0 +1,87 @@
+/obj/effect/proc_holder/spell/aoe_turf/conjure
+	name = "Conjure"
+	desc = "This spell conjures objs of the specified types in range."
+
+	var/list/summon_type = list() //determines what exactly will be summoned
+	//should be text, like list("/obj/machinery/bot/ed209")
+
+	var/summon_lifespan = 0 // 0=permanent, any other time in deciseconds
+	var/summon_amt = 1 //amount of objects summoned
+	var/summon_ignore_density = 0 //if set to 1, adds dense tiles to possible spawn places
+	var/summon_ignore_prev_spawn_points = 0 //if set to 1, each new object is summoned on a new spawn point
+
+	var/list/newVars = list() //vars of the summoned objects will be replaced with those where they meet
+	//should have format of list("emagged" = 1,"name" = "Wizard's Justicebot"), for example
+	var/delay = 1//Go Go Gadget Inheritance
+
+/obj/effect/proc_holder/spell/aoe_turf/conjure/cast(list/targets)
+
+	for(var/turf/T in targets)
+		if(T.density && !summon_ignore_density)
+			targets -= T
+	playsound(src.loc, 'sound/items/welder.ogg', 50, 1)
+
+	if(do_after(usr,delay))
+		for(var/i=0,i<summon_amt,i++)
+			if(!targets.len)
+				break
+			var/summoned_object_type = pick(summon_type)
+			var/spawn_place = pick(targets)
+			if(summon_ignore_prev_spawn_points)
+				targets -= spawn_place
+			if(ispath(summoned_object_type,/turf))
+				var/turf/O = spawn_place
+				var/turf/N = summoned_object_type
+				O.ChangeTurf(N)
+			else
+				var/atom/summoned_object = new summoned_object_type(spawn_place)
+
+				for(var/varName in newVars)
+					if(varName in summoned_object.vars)
+						summoned_object.vars[varName] = newVars[varName]
+
+				if(summon_lifespan)
+					spawn(summon_lifespan)
+						if(summoned_object)
+							del(summoned_object)
+	else
+		switch(charge_type)
+			if("recharge")
+				charge_counter = charge_max - 5//So you don't lose charge for a failed spell(Also prevents most over-fill)
+			if("charges")
+				charge_counter++//Ditto, just for different spell types
+
+
+	return
+
+/obj/effect/proc_holder/spell/aoe_turf/conjure/summonEdSwarm //test purposes
+	name = "Dispense Wizard Justice"
+	desc = "This spell dispenses wizard justice."
+
+	summon_type = list(/obj/machinery/bot/ed209)
+	summon_amt = 10
+	range = 3
+	newVars = list("emagged" = 1,"name" = "Wizard's Justicebot")
+
+
+//This was previously left in the old wizard code, not being included.
+//Wasn't sure if I should transfer it here, or to code/datums/spells.dm
+//But I decided because it is a conjuration related object it would fit better here
+//Feel free to change this, I don't know.
+/obj/effect/forcefield
+	desc = "A space wizard's magic wall."
+	name = "FORCEWALL"
+	icon = 'icons/effects/effects.dmi'
+	icon_state = "m_shield"
+	anchored = 1.0
+	opacity = 0
+	density = 1
+	unacidable = 1
+
+
+	bullet_act(var/obj/item/projectile/Proj, var/def_zone)
+		var/turf/T = get_turf(src.loc)
+		if(T)
+			for(var/mob/M in T)
+				Proj.on_hit(M,M.bullet_act(Proj, def_zone))
+		return

code/datums/spells/dumbfire.dm

@@ -0,0 +1,86 @@
+/obj/effect/proc_holder/spell/dumbfire
+
+	var/projectile_type = ""
+	var/activate_on_collision = 1
+
+	var/proj_icon = 'icons/obj/projectiles.dmi'
+	var/proj_icon_state = "spell"
+	var/proj_name = "a spell projectile"
+
+	var/proj_trail = 0 //if it leaves a trail
+	var/proj_trail_lifespan = 0 //deciseconds
+	var/proj_trail_icon = 'icons/obj/wizard.dmi'
+	var/proj_trail_icon_state = "trail"
+
+	var/proj_type = "/obj/effect/proc_holder/spell" //IMPORTANT use only subtypes of this
+
+	var/proj_insubstantial = 0 //if it can pass through dense objects or not
+	var/proj_trigger_range = 1 //the range from target at which the projectile triggers cast(target)
+
+	var/proj_lifespan = 100 //in deciseconds * proj_step_delay
+	var/proj_step_delay = 1 //lower = faster
+
+/obj/effect/proc_holder/spell/dumbfire/choose_targets(mob/user = usr)
+
+	var/turf/T = get_turf(usr)
+	for(var/i = 1; i < range; i++)
+		var/turf/new_turf = get_step(T, usr.dir)
+		if(new_turf.density)
+			break
+		T = new_turf
+	perform(list(T))
+
+/obj/effect/proc_holder/spell/dumbfire/cast(list/targets, mob/user = usr)
+
+	for(var/turf/target in targets)
+		spawn(0)
+			var/obj/effect/proc_holder/spell/targeted/projectile
+			if(istext(proj_type))
+				var/projectile_type = text2path(proj_type)
+				projectile = new projectile_type(user)
+			if(istype(proj_type,/obj/effect/proc_holder/spell))
+				projectile = new /obj/effect/proc_holder/spell/targeted/trigger(user)
+				projectile:linked_spells += proj_type
+			projectile.icon = proj_icon
+			projectile.icon_state = proj_icon_state
+			projectile.dir = get_dir(projectile, target)
+			projectile.name = proj_name
+
+			var/current_loc = usr.loc
+
+			projectile.loc = current_loc
+
+			for(var/i = 0,i < proj_lifespan,i++)
+				if(!projectile)
+					break
+
+				if(proj_insubstantial)
+					projectile.loc = get_step(projectile, projectile.dir)
+				else
+					step(projectile, projectile.dir)
+
+				if(projectile.loc == current_loc || i == proj_lifespan)
+					projectile.cast(current_loc)
+					break
+
+				var/mob/living/L = locate(/mob/living) in range(projectile, proj_trigger_range) - usr
+				if(L)
+					projectile.cast(L.loc)
+					break
+
+				if(proj_trail && projectile)
+					spawn(0)
+						if(projectile)
+							var/obj/effect/overlay/trail = new /obj/effect/overlay(projectile.loc)
+							trail.icon = proj_trail_icon
+							trail.icon_state = proj_trail_icon_state
+							trail.density = 0
+							spawn(proj_trail_lifespan)
+								del(trail)
+
+				current_loc = projectile.loc
+
+				sleep(proj_step_delay)
+
+			if(projectile)
+				del(projectile)

code/datums/spells/emplosion.dm

@@ -0,0 +1,13 @@
+/obj/effect/proc_holder/spell/targeted/emplosion
+	name = "Emplosion"
+	desc = "This spell emplodes an area."
+
+	var/emp_heavy = 2
+	var/emp_light = 3
+
+/obj/effect/proc_holder/spell/targeted/emplosion/cast(list/targets)
+
+	for(var/mob/living/target in targets)
+		empulse(target.loc, emp_heavy, emp_light)
+
+	return

code/datums/spells/ethereal_jaunt.dm

@@ -0,0 +1,101 @@
+/obj/effect/proc_holder/spell/targeted/ethereal_jaunt
+	name = "Ethereal Jaunt"
+	desc = "This spell creates your ethereal form, temporarily making you invisible and able to pass through walls."
+
+	school = "transmutation"
+	charge_max = 300
+	clothes_req = 1
+	invocation = "none"
+	invocation_type = "none"
+	range = -1
+	include_user = 1
+	centcomm_cancast = 0 //Prevent people from getting to centcomm
+
+	var phaseshift = 0
+	var/jaunt_duration = 50 //in deciseconds
+
+/obj/effect/proc_holder/spell/targeted/ethereal_jaunt/cast(list/targets) //magnets, so mostly hardcoded
+	for(var/mob/living/target in targets)
+		spawn(0)
+			var/mobloc = get_turf(target.loc)
+			var/obj/effect/dummy/spell_jaunt/holder = new /obj/effect/dummy/spell_jaunt( mobloc )
+			var/atom/movable/overlay/animation = new /atom/movable/overlay( mobloc )
+			animation.name = "water"
+			animation.density = 0
+			animation.anchored = 1
+			animation.icon = 'icons/mob/mob.dmi'
+			animation.icon_state = "liquify"
+			animation.layer = 5
+			animation.master = holder
+			if(phaseshift == 1)
+				animation.dir = target.dir
+				flick("phase_shift",animation)
+				target.loc = holder
+				target.client.eye = holder
+				sleep(jaunt_duration)
+				mobloc = get_turf(target.loc)
+				animation.loc = mobloc
+				target.canmove = 0
+				sleep(20)
+				animation.dir = target.dir
+				flick("phase_shift2",animation)
+				sleep(5)
+				if(!target.Move(mobloc))
+					for(var/direction in list(1,2,4,8,5,6,9,10))
+						var/turf/T = get_step(mobloc, direction)
+						if(T)
+							if(target.Move(T))
+								break
+				target.canmove = 1
+				target.client.eye = target
+				del(animation)
+				del(holder)
+			else
+				flick("liquify",animation)
+				target.loc = holder
+				target.client.eye = holder
+				var/datum/effect/effect/system/steam_spread/steam = new /datum/effect/effect/system/steam_spread()
+				steam.set_up(10, 0, mobloc)
+				steam.start()
+				sleep(jaunt_duration)
+				mobloc = get_turf(target.loc)
+				animation.loc = mobloc
+				steam.location = mobloc
+				steam.start()
+				target.canmove = 0
+				sleep(20)
+				flick("reappear",animation)
+				sleep(5)
+				if(!target.Move(mobloc))
+					for(var/direction in list(1,2,4,8,5,6,9,10))
+						var/turf/T = get_step(mobloc, direction)
+						if(T)
+							if(target.Move(T))
+								break
+				target.canmove = 1
+				target.client.eye = target
+				del(animation)
+				del(holder)
+
+/obj/effect/dummy/spell_jaunt
+	name = "water"
+	icon = 'icons/effects/effects.dmi'
+	icon_state = "nothing"
+	var/canmove = 1
+	density = 0
+	anchored = 1
+
+/obj/effect/dummy/spell_jaunt/relaymove(var/mob/user, direction)
+	if (!src.canmove) return
+	var/turf/newLoc = get_step(src,direction)
+	if(!(newLoc.flags & NOJAUNT))
+		loc = newLoc
+	else
+		user << "<span class='warning'>Some strange aura is blocking the way!</span>"
+	src.canmove = 0
+	spawn(2) src.canmove = 1
+
+/obj/effect/dummy/spell_jaunt/ex_act(blah)
+	return
+/obj/effect/dummy/spell_jaunt/bullet_act(blah)
+	return

code/datums/spells/explosion.dm

@@ -0,0 +1,15 @@
+/obj/effect/proc_holder/spell/targeted/explosion
+	name = "Explosion"
+	desc = "This spell explodes an area."
+
+	var/ex_severe = 1
+	var/ex_heavy = 2
+	var/ex_light = 3
+	var/ex_flash = 4
+
+/obj/effect/proc_holder/spell/targeted/explosion/cast(list/targets)
+
+	for(var/mob/living/target in targets)
+		explosion(target.loc,ex_severe,ex_heavy,ex_light,ex_flash)
+
+	return

code/datums/spells/genetic.dm

@@ -0,0 +1,31 @@
+/obj/effect/proc_holder/spell/targeted/genetic
+	name = "Genetic"
+	desc = "This spell inflicts a set of mutations and disabilities upon the target."
+
+	var/disabilities = 0 //bits
+	var/list/mutations = list() //mutation strings
+	var/duration = 100 //deciseconds
+	/*
+		Disabilities
+			1st bit - ?
+			2nd bit - ?
+			3rd bit - ?
+			4th bit - ?
+			5th bit - ?
+			6th bit - ?
+	*/
+
+/obj/effect/proc_holder/spell/targeted/genetic/cast(list/targets)
+
+	for(var/mob/living/target in targets)
+		for(var/x in mutations)
+			target.mutations.Add(x)
+		target.disabilities |= disabilities
+		target.update_mutations()	//update target's mutation overlays
+		spawn(duration)
+			for(var/x in mutations)
+				target.mutations.Remove(x)
+			target.disabilities &= ~disabilities
+			target.update_mutations()
+
+	return

code/datums/spells/horsemask.dm

@@ -0,0 +1,39 @@
+/obj/effect/proc_holder/spell/targeted/horsemask
+	name = "Curse of the Horseman"
+	desc = "This spell triggers a curse on a target, causing them to wield an unremovable horse head mask. They will speak like a horse! Any masks they are wearing will be disintegrated. This spell does not require robes."
+	school = "transmutation"
+	charge_type = "recharge"
+	charge_max = 150
+	charge_counter = 0
+	clothes_req = 0
+	stat_allowed = 0
+	invocation = "KN'A FTAGHU, PUCK 'BTHNK!"
+	invocation_type = "shout"
+	range = 7
+	selection_type = "range"
+	var/list/compatible_mobs = list(/mob/living/carbon/human, /mob/living/carbon/monkey)
+
+/obj/effect/proc_holder/spell/targeted/horsemask/cast(list/targets, mob/user = usr)
+	if(!targets.len)
+		user << "<span class='notice'>No target found in range.</span>"
+		return
+
+	var/mob/living/carbon/target = targets[1]
+
+	if(!(target.type in compatible_mobs))
+		user << "<span class='notice'>It'd be stupid to curse [target] with a horse's head!</span>"
+		return
+
+	if(!(target in oview(range)))//If they are not  in overview after selection.
+		user << "<span class='notice'>They are too far away!</span>"
+		return
+
+	var/obj/item/clothing/mask/horsehead/magichead = new /obj/item/clothing/mask/horsehead
+	magichead.canremove = 0		//curses!
+	magichead.flags_inv = null	//so you can still see their face
+	magichead.voicechange = 1	//NEEEEIIGHH
+	target.visible_message(	"<span class='danger'>[target]'s face  lights up in fire, and after the event a horse's head takes its place!</span>", \
+							"<span class='danger'>Your face burns up, and shortly after the fire you realise you have the face of a horse!</span>")
+	target.equip_to_slot(magichead, slot_wear_mask)
+
+	flick("e_flash", target.flash)

code/datums/spells/inflict_handler.dm

@@ -0,0 +1,59 @@
+/obj/effect/proc_holder/spell/targeted/inflict_handler
+	name = "Inflict Handler"
+	desc = "This spell blinds and/or destroys/damages/heals and/or weakens/stuns the target."
+
+	var/amt_weakened = 0
+	var/amt_paralysis = 0
+	var/amt_stunned = 0
+
+	//set to negatives for healing
+	var/amt_dam_fire = 0
+	var/amt_dam_brute = 0
+	var/amt_dam_oxy = 0
+	var/amt_dam_tox = 0
+
+	var/amt_eye_blind = 0
+	var/amt_eye_blurry = 0
+
+	var/destroys = "none" //can be "none", "gib" or "disintegrate"
+
+/obj/effect/proc_holder/spell/targeted/inflict_handler/cast(list/targets)
+
+	for(var/mob/living/target in targets)
+		switch(destroys)
+			if("gib")
+				target.gib()
+			if("gib_brain")
+				if(ishuman(target) || ismonkey(target))
+					var/mob/living/carbon/C = target
+					if(C.brain_op_stage != 4) // Their brain is already taken out
+						var/obj/item/brain/B = new(C.loc)
+						B.transfer_identity(C)
+				target.gib()
+			if("disintegrate")
+				target.dust()
+
+		if(!target)
+			continue
+		//damage
+		if(amt_dam_brute > 0)
+			if(amt_dam_fire >= 0)
+				target.take_overall_damage(amt_dam_brute,amt_dam_fire)
+			else if (amt_dam_fire < 0)
+				target.take_overall_damage(amt_dam_brute,0)
+				target.heal_overall_damage(0,amt_dam_fire)
+		else if(amt_dam_brute < 0)
+			if(amt_dam_fire > 0)
+				target.take_overall_damage(0,amt_dam_fire)
+				target.heal_overall_damage(amt_dam_brute,0)
+			else if (amt_dam_fire <= 0)
+				target.heal_overall_damage(amt_dam_brute,amt_dam_fire)
+		target.adjustToxLoss(amt_dam_tox)
+		target.oxyloss += amt_dam_oxy
+		//disabling
+		target.Weaken(amt_weakened)
+		target.Paralyse(amt_paralysis)
+		target.Stun(amt_stunned)
+
+		target.eye_blind += amt_eye_blind
+		target.eye_blurry += amt_eye_blurry

code/datums/spells/knock.dm

@@ -0,0 +1,19 @@
+/obj/effect/proc_holder/spell/aoe_turf/knock
+	name = "Knock"
+	desc = "This spell opens nearby doors and does not require wizard garb."
+
+	school = "transmutation"
+	charge_max = 100
+	clothes_req = 0
+	invocation = "AULIE OXIN FIERA"
+	invocation_type = "whisper"
+	range = 3
+
+/obj/effect/proc_holder/spell/aoe_turf/knock/cast(list/targets)
+	for(var/turf/T in targets)
+		for(var/obj/machinery/door/door in T.contents)
+			spawn(1)
+				if(istype(door,/obj/machinery/door/airlock))
+					door:locked = 0
+				door.open()
+	return

code/datums/spells/mind_transfer.dm

@@ -0,0 +1,114 @@
+/obj/effect/proc_holder/spell/targeted/mind_transfer
+	name = "Mind Transfer"
+	desc = "This spell allows the user to switch bodies with a target."
+
+	school = "transmutation"
+	charge_max = 600
+	clothes_req = 0
+	invocation = "GIN'YU CAPAN"
+	invocation_type = "whisper"
+	range = 1
+	var/list/protected_roles = list("Wizard","Changeling","Cultist") //which roles are immune to the spell
+	var/list/compatible_mobs = list(/mob/living/carbon/human,/mob/living/carbon/monkey) //which types of mobs are affected by the spell. NOTE: change at your own risk
+	var/base_spell_loss_chance = 20 //base probability of the wizard losing a spell in the process
+	var/spell_loss_chance_modifier = 7 //amount of probability of losing a spell added per spell (mind_transfer included)
+	var/spell_loss_amount = 1 //the maximum amount of spells possible to lose during a single transfer
+	var/msg_wait = 500 //how long in deciseconds it waits before telling that body doesn't feel right or mind swap robbed of a spell
+	var/paralysis_amount_caster = 20 //how much the caster is paralysed for after the spell
+	var/paralysis_amount_victim = 20 //how much the victim is paralysed for after the spell
+
+/*
+Urist: I don't feel like figuring out how you store object spells so I'm leaving this for you to do.
+Make sure spells that are removed from spell_list are actually removed and deleted when mind transfering.
+Also, you never added distance checking after target is selected. I've went ahead and did that.
+*/
+/obj/effect/proc_holder/spell/targeted/mind_transfer/cast(list/targets,mob/user = usr)
+	if(!targets.len)
+		user << "No mind found."
+		return
+
+	if(targets.len > 1)
+		user << "Too many minds! You're not a hive damnit!"//Whaa...aat?
+		return
+
+	var/mob/living/target = targets[1]
+
+	if(!(target in oview(range)))//If they are not in overview after selection. Do note that !() is necessary for in to work because ! takes precedence over it.
+		user << "They are too far away!"
+		return
+
+	if(!(target.type in compatible_mobs))
+		user << "Their mind isn't compatible with yours."
+		return
+
+	if(target.stat == DEAD)
+		user << "You didn't study necromancy back at the Space Wizard Federation academy."
+		return
+
+	if(!target.key || !target.mind)
+		user << "They appear to be catatonic. Not even magic can affect their vacant mind."
+		return
+
+	if(target.mind.special_role in protected_roles)
+		user << "Their mind is resisting your spell."
+		return
+
+	var/mob/living/victim = target//The target of the spell whos body will be transferred to.
+	var/mob/caster = user//The wizard/whomever doing the body transferring.
+
+	//SPELL LOSS BEGIN
+	//NOTE: The caster must ALWAYS keep mind transfer, even when other spells are lost.
+	var/obj/effect/proc_holder/spell/targeted/mind_transfer/m_transfer = locate() in user.spell_list//Find mind transfer directly.
+	var/list/checked_spells = user.spell_list
+	checked_spells -= m_transfer //Remove Mind Transfer from the list.
+
+	if(caster.spell_list.len)//If they have any spells left over after mind transfer is taken out. If they don't, we don't need this.
+		for(var/i=spell_loss_amount,(i>0&&checked_spells.len),i--)//While spell loss amount is greater than zero and checked_spells has spells in it, run this proc.
+			for(var/j=checked_spells.len,(j>0&&checked_spells.len),j--)//While the spell list to check is greater than zero and has spells in it, run this proc.
+				if(prob(base_spell_loss_chance))
+					checked_spells -= pick(checked_spells)//Pick a random spell to remove.
+					spawn(msg_wait)
+						victim << "The mind transfer has robbed you of a spell."
+					break//Spell lost. Break loop, going back to the previous for() statement.
+				else//Or keep checking, adding spell chance modifier to increase chance of losing a spell.
+					base_spell_loss_chance += spell_loss_chance_modifier
+
+	checked_spells += m_transfer//Add back Mind Transfer.
+	user.spell_list = checked_spells//Set user spell list to whatever the new list is.
+	//SPELL LOSS END
+
+	//MIND TRANSFER BEGIN
+	if(caster.mind.special_verbs.len)//If the caster had any special verbs, remove them from the mob verb list.
+		for(var/V in caster.mind.special_verbs)//Since the caster is using an object spell system, this is mostly moot.
+			caster.verbs -= V//But a safety nontheless.
+
+	if(victim.mind.special_verbs.len)//Now remove all of the victim's verbs.
+		for(var/V in victim.mind.special_verbs)
+			victim.verbs -= V
+
+	var/mob/dead/observer/ghost = victim.ghostize(0)
+	ghost.spell_list = victim.spell_list//If they have spells, transfer them. Now we basically have a backup mob.
+
+	caster.mind.transfer_to(victim)
+	victim.spell_list = caster.spell_list//Now they are inside the victim's body.
+
+	if(victim.mind.special_verbs.len)//To add all the special verbs for the original caster.
+		for(var/V in caster.mind.special_verbs)//Not too important but could come into play.
+			caster.verbs += V
+
+	ghost.mind.transfer_to(caster)
+	caster.key = ghost.key	//have to transfer the key since the mind was not active
+	caster.spell_list = ghost.spell_list
+
+	if(caster.mind.special_verbs.len)//If they had any special verbs, we add them here.
+		for(var/V in caster.mind.special_verbs)
+			caster.verbs += V
+	//MIND TRANSFER END
+
+	//Here we paralyze both mobs and knock them out for a time.
+	caster.Paralyse(paralysis_amount_caster)
+	victim.Paralyse(paralysis_amount_victim)
+
+	//After a certain amount of time the victim gets a message about being in a different body.
+	spawn(msg_wait)
+		caster << "\red You feel woozy and lightheaded. <b>Your body doesn't seem like your own.</b>"

code/datums/spells/projectile.dm

@@ -0,0 +1,83 @@
+/obj/effect/proc_holder/spell/targeted/projectile
+	name = "Projectile"
+	desc = "This spell summons projectiles which try to hit the targets."
+
+	var/proj_icon = 'icons/obj/projectiles.dmi'
+	var/proj_icon_state = "spell"
+	var/proj_name = "a spell projectile"
+
+	var/proj_trail = 0 //if it leaves a trail
+	var/proj_trail_lifespan = 0 //deciseconds
+	var/proj_trail_icon = 'icons/obj/wizard.dmi'
+	var/proj_trail_icon_state = "trail"
+
+	var/proj_type = "/obj/effect/proc_holder/spell/targeted" //IMPORTANT use only subtypes of this
+
+	var/proj_lingering = 0 //if it lingers or disappears upon hitting an obstacle
+	var/proj_homing = 1 //if it follows the target
+	var/proj_insubstantial = 0 //if it can pass through dense objects or not
+	var/proj_trigger_range = 0 //the range from target at which the projectile triggers cast(target)
+
+	var/proj_lifespan = 15 //in deciseconds * proj_step_delay
+	var/proj_step_delay = 1 //lower = faster
+
+/obj/effect/proc_holder/spell/targeted/projectile/cast(list/targets, mob/user = usr)
+
+	for(var/mob/living/target in targets)
+		spawn(0)
+			var/obj/effect/proc_holder/spell/targeted/projectile
+			if(istext(proj_type))
+				var/projectile_type = text2path(proj_type)
+				projectile = new projectile_type(user)
+			if(istype(proj_type,/obj/effect/proc_holder/spell))
+				projectile = new /obj/effect/proc_holder/spell/targeted/trigger(user)
+				projectile:linked_spells += proj_type
+			projectile.icon = proj_icon
+			projectile.icon_state = proj_icon_state
+			projectile.dir = get_dir(target,projectile)
+			projectile.name = proj_name
+
+			var/current_loc = usr.loc
+
+			projectile.loc = current_loc
+
+			for(var/i = 0,i < proj_lifespan,i++)
+				if(!projectile)
+					break
+
+				if(proj_homing)
+					if(proj_insubstantial)
+						projectile.dir = get_dir(projectile,target)
+						projectile.loc = get_step_to(projectile,target)
+					else
+						step_to(projectile,target)
+				else
+					if(proj_insubstantial)
+						projectile.loc = get_step(projectile,dir)
+					else
+						step(projectile,dir)
+
+				if(!proj_lingering && projectile.loc == current_loc) //if it didn't move since last time
+					del(projectile)
+					break
+
+				if(proj_trail && projectile)
+					spawn(0)
+						if(projectile)
+							var/obj/effect/overlay/trail = new /obj/effect/overlay(projectile.loc)
+							trail.icon = proj_trail_icon
+							trail.icon_state = proj_trail_icon_state
+							trail.density = 0
+							spawn(proj_trail_lifespan)
+								del(trail)
+
+				if(projectile.loc in range(target.loc,proj_trigger_range))
+					projectile.perform(list(target))
+					break
+
+				current_loc = projectile.loc
+
+				sleep(proj_step_delay)
+
+			if(projectile)
+				del(projectile)

code/datums/spells/trigger.dm

@@ -0,0 +1,28 @@
+/obj/effect/proc_holder/spell/targeted/trigger
+	name = "Trigger"
+	desc = "This spell triggers another spell or a few."
+
+	var/list/linked_spells = list() //those are just referenced by the trigger spell and are unaffected by it directly
+	var/list/starting_spells = list() //those are added on New() to contents from default spells and are deleted when the trigger spell is deleted to prevent memory leaks
+
+/obj/effect/proc_holder/spell/targeted/trigger/New()
+	..()
+
+	for(var/spell in starting_spells)
+		var/spell_to_add = text2path(spell)
+		new spell_to_add(src) //should result in adding to contents, needs testing
+
+/obj/effect/proc_holder/spell/targeted/trigger/Del()
+	for(var/spell in contents)
+		del(spell)
+
+	..()
+
+/obj/effect/proc_holder/spell/targeted/trigger/cast(list/targets)
+	for(var/mob/living/target in targets)
+		for(var/obj/effect/proc_holder/spell/spell in contents)
+			spell.perform(list(target),0)
+		for(var/obj/effect/proc_holder/spell/spell in linked_spells)
+			spell.perform(list(target),0)
+
+	return

code/datums/spells/turf_teleport.dm

@@ -0,0 +1,34 @@
+/obj/effect/proc_holder/spell/targeted/turf_teleport
+	name = "Turf Teleport"
+	desc = "This spell teleports the target to the turf in range."
+
+	var/inner_tele_radius = 1
+	var/outer_tele_radius = 2
+
+	var/include_space = 0 //whether it includes space tiles in possible teleport locations
+	var/include_dense = 0 //whether it includes dense tiles in possible teleport locations
+
+/obj/effect/proc_holder/spell/targeted/turf_teleport/cast(list/targets)
+	for(var/mob/living/target in targets)
+		var/list/turfs = new/list()
+		for(var/turf/T in range(target,outer_tele_radius))
+			if(T in range(target,inner_tele_radius)) continue
+			if(istype(T,/turf/space) && !include_space) continue
+			if(T.density && !include_dense) continue
+			if(T.x>world.maxx-outer_tele_radius || T.x<outer_tele_radius)	continue	//putting them at the edge is dumb
+			if(T.y>world.maxy-outer_tele_radius || T.y<outer_tele_radius)	continue
+			turfs += T
+
+		if(!turfs.len)
+			var/list/turfs_to_pick_from = list()
+			for(var/turf/T in orange(target,outer_tele_radius))
+				if(!(T in orange(target,inner_tele_radius)))
+					turfs_to_pick_from += T
+			turfs += pick(/turf in turfs_to_pick_from)
+
+		var/turf/picked = pick(turfs)
+
+		if(!picked || !isturf(picked))
+			return
+
+		target.loc = picked

code/datums/spells/wizard.dm

@@ -0,0 +1,327 @@
+/obj/effect/proc_holder/spell/targeted/projectile/magic_missile
+	name = "Magic Missile"
+	desc = "This spell fires several, slow moving, magic projectiles at nearby targets."
+
+	school = "evocation"
+	charge_max = 150
+	clothes_req = 1
+	invocation = "FORTI GY AMA"
+	invocation_type = "shout"
+	range = 7
+
+	max_targets = 0
+
+	proj_icon_state = "magicm"
+	proj_name = "a magic missile"
+	proj_lingering = 1
+	proj_type = "/obj/effect/proc_holder/spell/targeted/inflict_handler/magic_missile"
+
+	proj_lifespan = 20
+	proj_step_delay = 5
+
+	proj_trail = 1
+	proj_trail_lifespan = 5
+	proj_trail_icon_state = "magicmd"
+
+/obj/effect/proc_holder/spell/targeted/inflict_handler/magic_missile
+	amt_weakened = 5
+	amt_dam_fire = 10
+
+/obj/effect/proc_holder/spell/targeted/genetic/mutate
+	name = "Mutate"
+	desc = "This spell causes you to turn into a hulk and gain laser vision for a short while."
+
+	school = "transmutation"
+	charge_max = 400
+	clothes_req = 1
+	invocation = "BIRUZ BENNAR"
+	invocation_type = "shout"
+	message = "\blue You feel strong! You feel a pressure building behind your eyes!"
+	range = -1
+	include_user = 1
+
+	mutations = list(LASER, HULK)
+	duration = 300
+
+/obj/effect/proc_holder/spell/targeted/inflict_handler/disintegrate
+	name = "Disintegrate"
+	desc = "This spell instantly kills somebody adjacent to you with the vilest of magick."
+
+	school = "evocation"
+	charge_max = 600
+	clothes_req = 1
+	invocation = "EI NATH"
+	invocation_type = "shout"
+	range = 1
+
+	destroys = "gib_brain"
+
+	sparks_spread = 1
+	sparks_amt = 4
+
+/obj/effect/proc_holder/spell/targeted/smoke
+	name = "Smoke"
+	desc = "This spell spawns a cloud of choking smoke at your location and does not require wizard garb."
+
+	school = "conjuration"
+	charge_max = 120
+	clothes_req = 0
+	invocation = "none"
+	invocation_type = "none"
+	range = -1
+	include_user = 1
+
+	smoke_spread = 2
+	smoke_amt = 10
+
+/obj/effect/proc_holder/spell/targeted/emplosion/disable_tech
+	name = "Disable Tech"
+	desc = "This spell disables all weapons, cameras and most other technology in range."
+	charge_max = 400
+	clothes_req = 1
+	invocation = "NEC CANTIO"
+	invocation_type = "shout"
+	range = -1
+	include_user = 1
+
+	emp_heavy = 6
+	emp_light = 10
+
+/obj/effect/proc_holder/spell/targeted/turf_teleport/blink
+	name = "Blink"
+	desc = "This spell randomly teleports you a short distance."
+
+	school = "abjuration"
+	charge_max = 20
+	clothes_req = 1
+	invocation = "none"
+	invocation_type = "none"
+	range = -1
+	include_user = 1
+
+	smoke_spread = 1
+	smoke_amt = 10
+
+	inner_tele_radius = 0
+	outer_tele_radius = 6
+
+	centcomm_cancast = 0 //prevent people from getting to centcomm
+
+/obj/effect/proc_holder/spell/targeted/area_teleport/teleport
+	name = "Teleport"
+	desc = "This spell teleports you to a type of area of your selection."
+
+	school = "abjuration"
+	charge_max = 600
+	clothes_req = 1
+	invocation = "SCYAR NILA"
+	invocation_type = "shout"
+	range = -1
+	include_user = 1
+
+	smoke_spread = 1
+	smoke_amt = 5
+
+/obj/effect/proc_holder/spell/aoe_turf/conjure/forcewall
+	name = "Forcewall"
+	desc = "This spell creates an unbreakable wall that lasts for 30 seconds and does not need wizard garb."
+
+	school = "transmutation"
+	charge_max = 100
+	clothes_req = 0
+	invocation = "TARCOL MINTI ZHERI"
+	invocation_type = "whisper"
+	range = 0
+
+	summon_type = list("/obj/effect/forcefield")
+	summon_lifespan = 300
+
+
+/obj/effect/proc_holder/spell/aoe_turf/conjure/carp
+	name = "Summon Carp"
+	desc = "This spell conjures a simple carp."
+
+	school = "conjuration"
+	charge_max = 1200
+	clothes_req = 1
+	invocation = "NOUK FHUNMM SACP RISSKA"
+	invocation_type = "shout"
+	range = 1
+
+	summon_type = list(/mob/living/simple_animal/hostile/carp)
+
+
+/obj/effect/proc_holder/spell/aoe_turf/conjure/construct
+	name = "Artificer"
+	desc = "This spell conjures a construct which may be controlled by Shades"
+
+	school = "conjuration"
+	charge_max = 600
+	clothes_req = 0
+	invocation = "none"
+	invocation_type = "none"
+	range = 0
+
+	summon_type = list(/obj/structure/constructshell)
+
+
+/obj/effect/proc_holder/spell/aoe_turf/conjure/creature
+	name = "Summon Creature Swarm"
+	desc = "This spell tears the fabric of reality, allowing horrific daemons to spill forth"
+
+	school = "conjuration"
+	charge_max = 1200
+	clothes_req = 0
+	invocation = "IA IA"
+	invocation_type = "shout"
+	summon_amt = 10
+	range = 3
+
+	summon_type = list(/mob/living/simple_animal/hostile/creature)
+
+/obj/effect/proc_holder/spell/targeted/trigger/blind
+	name = "Blind"
+	desc = "This spell temporarily blinds a single person and does not require wizard garb."
+
+	school = "transmutation"
+	charge_max = 300
+	clothes_req = 0
+	invocation = "STI KALY"
+	invocation_type = "whisper"
+	message = "\blue Your eyes cry out in pain!"
+
+	starting_spells = list("/obj/effect/proc_holder/spell/targeted/inflict_handler/blind","/obj/effect/proc_holder/spell/targeted/genetic/blind")
+
+/obj/effect/proc_holder/spell/targeted/inflict_handler/blind
+	amt_eye_blind = 10
+	amt_eye_blurry = 20
+
+/obj/effect/proc_holder/spell/targeted/genetic/blind
+	disabilities = 1
+	duration = 300
+
+/obj/effect/proc_holder/spell/dumbfire/fireball
+	name = "Fireball"
+	desc = "This spell fires a fireball at a target and does not require wizard garb."
+
+	school = "evocation"
+	charge_max = 100
+	clothes_req = 0
+	invocation = "ONI SOMA"
+	invocation_type = "shout"
+	range = 20
+
+	proj_icon_state = "fireball"
+	proj_name = "a fireball"
+	proj_type = "/obj/effect/proc_holder/spell/turf/fireball"
+
+	proj_lifespan = 200
+	proj_step_delay = 1
+
+/obj/effect/proc_holder/spell/turf/fireball/cast(var/turf/T)
+	explosion(T, -1, 1, 2, 3)
+
+
+/obj/effect/proc_holder/spell/targeted/inflict_handler/fireball
+	amt_dam_brute = 20
+	amt_dam_fire = 25
+
+/obj/effect/proc_holder/spell/targeted/explosion/fireball
+	ex_severe = -1
+	ex_heavy = -1
+	ex_light = 2
+	ex_flash = 5
+
+
+
+
+
+
+//////////////////////////////Construct Spells/////////////////////////
+
+/obj/effect/proc_holder/spell/aoe_turf/conjure/construct/lesser
+	charge_max = 1800
+
+/obj/effect/proc_holder/spell/aoe_turf/conjure/floor
+	name = "Floor Construction"
+	desc = "This spell constructs a cult floor"
+
+	school = "conjuration"
+	charge_max = 20
+	clothes_req = 0
+	invocation = "none"
+	invocation_type = "none"
+	range = 0
+	summon_type = list(/turf/simulated/floor/engine/cult)
+	centcomm_cancast = 0 //Stop crashing the server by spawning turfs on transit tiles
+
+/obj/effect/proc_holder/spell/aoe_turf/conjure/wall
+	name = "Leser Construction"
+	desc = "This spell constructs a cult wall"
+
+	school = "conjuration"
+	charge_max = 100
+	clothes_req = 0
+	invocation = "none"
+	invocation_type = "none"
+	range = 0
+	summon_type = list(/turf/simulated/wall/cult)
+	centcomm_cancast = 0 //Stop crashing the server by spawning turfs on transit tiles
+
+/obj/effect/proc_holder/spell/aoe_turf/conjure/wall/reinforced
+	name = "Greater Construction"
+	desc = "This spell constructs a reinforced metal wall"
+
+	school = "conjuration"
+	charge_max = 300
+	clothes_req = 0
+	invocation = "none"
+	invocation_type = "none"
+	range = 0
+	centcomm_cancast = 0 //Stop crashing the server by spawning turfs on transit tiles
+	delay = 50
+
+	summon_type = list(/turf/simulated/wall/r_wall)
+
+/obj/effect/proc_holder/spell/aoe_turf/conjure/soulstone
+	name = "Summon Soulstone"
+	desc = "This spell reaches into Nar-Sie's realm, summoning one of the legendary fragments across time and space"
+
+	school = "conjuration"
+	charge_max = 3000
+	clothes_req = 0
+	invocation = "none"
+	invocation_type = "none"
+	range = 0
+
+	summon_type = list(/obj/item/device/soulstone)
+
+
+/obj/effect/proc_holder/spell/aoe_turf/conjure/lesserforcewall
+	name = "Shield"
+	desc = "This spell creates a temporary forcefield to shield yourself and allies from incoming fire"
+
+	school = "transmutation"
+	charge_max = 300
+	clothes_req = 0
+	invocation = "none"
+	invocation_type = "none"
+	range = 0
+	summon_type = list(/obj/effect/forcefield)
+	summon_lifespan = 50
+
+
+/obj/effect/proc_holder/spell/targeted/ethereal_jaunt/shift
+	name = "Phase Shift"
+	desc = "This spell allows you to pass through walls"
+
+	school = "transmutation"
+	charge_max = 200
+	clothes_req = 0
+	invocation = "none"
+	invocation_type = "none"
+	range = -1
+	include_user = 1
+	phaseshift = 1
+	jaunt_duration = 50 //in deciseconds
+	centcomm_cancast = 0 //Stop people from getting to centcomm