Initial Commit

code/game/objects/effects/aliens.dm

@@ -0,0 +1,484 @@
+/* Alien Effects!
+ * Contains:
+ *		effect/alien
+ *		Resin
+ *		Weeds
+ *		Acid
+ *		Egg
+ */
+
+/*
+ * effect/alien
+ */
+/obj/effect/alien
+	name = "alien thing"
+	desc = "theres something alien about this"
+	icon = 'icons/mob/alien.dmi'
+//	unacidable = 1 //Aliens won't ment their own.
+
+
+/*
+ * Resin
+ */
+/obj/effect/alien/resin
+	name = "resin"
+	desc = "Looks like some kind of slimy growth."
+	icon_state = "resin"
+
+	density = 1
+	opacity = 1
+	anchored = 1
+	var/health = 200
+	//var/mob/living/affecting = null
+
+	wall
+		name = "resin wall"
+		desc = "Purple slime solidified into a wall."
+		icon_state = "resinwall" //same as resin, but consistency ho!
+
+	membrane
+		name = "resin membrane"
+		desc = "Purple slime just thin enough to let light pass through."
+		icon_state = "resinmembrane"
+		opacity = 0
+		health = 120
+
+/obj/effect/alien/resin/New()
+	..()
+	var/turf/T = get_turf(src)
+	T.thermal_conductivity = WALL_HEAT_TRANSFER_COEFFICIENT
+
+/obj/effect/alien/resin/Del()
+	var/turf/T = get_turf(src)
+	T.thermal_conductivity = initial(T.thermal_conductivity)
+	..()
+
+/obj/effect/alien/resin/proc/healthcheck()
+	if(health <=0)
+		density = 0
+		del(src)
+	return
+
+/obj/effect/alien/resin/bullet_act(var/obj/item/projectile/Proj)
+	health -= Proj.damage
+	..()
+	healthcheck()
+	return
+
+/obj/effect/alien/resin/ex_act(severity)
+	switch(severity)
+		if(1.0)
+			health-=50
+		if(2.0)
+			health-=50
+		if(3.0)
+			if (prob(50))
+				health-=50
+			else
+				health-=25
+	healthcheck()
+	return
+
+/obj/effect/alien/resin/blob_act()
+	health-=50
+	healthcheck()
+	return
+
+/obj/effect/alien/resin/meteorhit()
+	health-=50
+	healthcheck()
+	return
+
+/obj/effect/alien/resin/hitby(AM as mob|obj)
+	..()
+	for(var/mob/O in viewers(src, null))
+		O.show_message("\red <B>[src] was hit by [AM].</B>", 1)
+	var/tforce = 0
+	if(ismob(AM))
+		tforce = 10
+	else
+		tforce = AM:throwforce
+	playsound(loc, 'sound/effects/attackblob.ogg', 100, 1)
+	health = max(0, health - tforce)
+	healthcheck()
+	..()
+	return
+
+/obj/effect/alien/resin/attack_hand()
+	if (HULK in usr.mutations)
+		usr << "\blue You easily destroy the [name]."
+		for(var/mob/O in oviewers(src))
+			O.show_message("\red [usr] destroys the [name]!", 1)
+		health = 0
+	else
+		usr << "\blue You claw at the [name]."
+		for(var/mob/O in oviewers(src))
+			O.show_message("\red [usr] claws at the [name]!", 1)
+		health -= rand(5,10)
+	healthcheck()
+	return
+
+/obj/effect/alien/resin/attack_paw()
+	return attack_hand()
+
+/obj/effect/alien/resin/attack_alien()
+	if (islarva(usr))//Safety check for larva. /N
+		return
+	usr << "\green You claw at the [name]."
+	for(var/mob/O in oviewers(src))
+		O.show_message("\red [usr] claws at the resin!", 1)
+	playsound(loc, 'sound/effects/attackblob.ogg', 100, 1)
+	health -= rand(40, 60)
+	if(health <= 0)
+		usr << "\green You slice the [name] to pieces."
+		for(var/mob/O in oviewers(src))
+			O.show_message("\red [usr] slices the [name] apart!", 1)
+	healthcheck()
+	return
+
+/obj/effect/alien/resin/attackby(obj/item/weapon/W as obj, mob/user as mob)
+	/*if (istype(W, /obj/item/weapon/grab) && get_dist(src,user)<2)
+		var/obj/item/weapon/grab/G = W
+		if(isalien(user)&&(ishuman(G.affecting)||ismonkey(G.affecting)))
+		//Only aliens can stick humans and monkeys into resin walls. Also, the wall must not have a person inside already.
+			if(!affecting)
+				if(G.state<2)
+					user << "\red You need a better grip to do that!"
+					return
+				G.affecting.loc = src
+				G.affecting.paralysis = 10
+				for(var/mob/O in viewers(world.view, src))
+					if (O.client)
+						O << text("\green [] places [] in the resin wall!", G.assailant, G.affecting)
+				affecting=G.affecting
+				del(W)
+				spawn(0)
+					process()
+			else
+				user << "\red This wall is already occupied."
+		return */
+
+	var/aforce = W.force
+	health = max(0, health - aforce)
+	playsound(loc, 'sound/effects/attackblob.ogg', 100, 1)
+	healthcheck()
+	..()
+	return
+
+/obj/effect/alien/resin/CanPass(atom/movable/mover, turf/target, height=0, air_group=0)
+	if(air_group) return 0
+	if(istype(mover) && mover.checkpass(PASSGLASS))
+		return !opacity
+	return !density
+
+
+/*
+ * Weeds
+ */
+#define NODERANGE 3
+
+/obj/effect/alien/weeds
+	name = "weeds"
+	desc = "Weird purple weeds."
+	icon_state = "weeds"
+
+	anchored = 1
+	density = 0
+	var/health = 15
+	var/obj/effect/alien/weeds/node/linked_node = null
+
+/obj/effect/alien/weeds/node
+	icon_state = "weednode"
+	name = "purple sac"
+	desc = "Weird purple octopus-like thing."
+	luminosity = NODERANGE
+	var/node_range = NODERANGE
+
+/obj/effect/alien/weeds/node/New()
+	..(src.loc, src)
+
+
+/obj/effect/alien/weeds/New(pos, node)
+	..()
+	linked_node = node
+	if(istype(loc, /turf/space))
+		del(src)
+		return
+	if(icon_state == "weeds")icon_state = pick("weeds", "weeds1", "weeds2")
+	spawn(rand(150, 200))
+		if(src)
+			Life()
+	return
+
+/obj/effect/alien/weeds/proc/Life()
+	set background = 1
+	var/turf/U = get_turf(src)
+/*
+	if (locate(/obj/movable, U))
+		U = locate(/obj/movable, U)
+		if(U.density == 1)
+			del(src)
+			return
+
+Alien plants should do something if theres a lot of poison
+	if(U.poison> 200000)
+		health -= round(U.poison/200000)
+		update()
+		return
+*/
+	if (istype(U, /turf/space))
+		del(src)
+		return
+
+	direction_loop:
+		for(var/dirn in cardinal)
+			var/turf/T = get_step(src, dirn)
+
+			if (!istype(T) || T.density || locate(/obj/effect/alien/weeds) in T || istype(T.loc, /area/arrival) || istype(T, /turf/space))
+				continue
+
+			if(!linked_node || get_dist(linked_node, src) > linked_node.node_range)
+				return
+
+	//		if (locate(/obj/movable, T)) // don't propogate into movables
+	//			continue
+
+			for(var/obj/O in T)
+				if(O.density)
+					continue direction_loop
+
+			new /obj/effect/alien/weeds(T, linked_node)
+
+
+/obj/effect/alien/weeds/ex_act(severity)
+	switch(severity)
+		if(1.0)
+			del(src)
+		if(2.0)
+			if (prob(50))
+				del(src)
+		if(3.0)
+			if (prob(5))
+				del(src)
+	return
+
+/obj/effect/alien/weeds/attackby(var/obj/item/weapon/W, var/mob/user)
+	if(W.attack_verb.len)
+		visible_message("\red <B>\The [src] have been [pick(W.attack_verb)] with \the [W][(user ? " by [user]." : ".")]")
+	else
+		visible_message("\red <B>\The [src] have been attacked with \the [W][(user ? " by [user]." : ".")]")
+
+	var/damage = W.force / 4.0
+
+	if(istype(W, /obj/item/weapon/weldingtool))
+		var/obj/item/weapon/weldingtool/WT = W
+
+		if(WT.remove_fuel(0, user))
+			damage = 15
+			playsound(loc, 'sound/items/Welder.ogg', 100, 1)
+
+	health -= damage
+	healthcheck()
+
+/obj/effect/alien/weeds/proc/healthcheck()
+	if(health <= 0)
+		del(src)
+
+
+/obj/effect/alien/weeds/temperature_expose(datum/gas_mixture/air, exposed_temperature, exposed_volume)
+	if(exposed_temperature > 300)
+		health -= 5
+		healthcheck()
+
+/*/obj/effect/alien/weeds/burn(fi_amount)
+	if (fi_amount > 18000)
+		spawn( 0 )
+			del(src)
+			return
+		return 0
+	return 1
+*/
+
+#undef NODERANGE
+
+
+/*
+ * Acid
+ */
+/obj/effect/alien/acid
+	name = "acid"
+	desc = "Burbling corrossive stuff. I wouldn't want to touch it."
+	icon_state = "acid"
+
+	density = 0
+	opacity = 0
+	anchored = 1
+
+	var/atom/target
+	var/ticks = 0
+	var/target_strength = 0
+
+/obj/effect/alien/acid/New(loc, target)
+	..(loc)
+	src.target = target
+
+	if(isturf(target)) // Turf take twice as long to take down.
+		target_strength = 8
+	else
+		target_strength = 4
+	tick()
+
+/obj/effect/alien/acid/proc/tick()
+	if(!target)
+		del(src)
+
+	ticks += 1
+
+	if(ticks >= target_strength)
+
+		for(var/mob/O in hearers(src, null))
+			O.show_message("\green <B>[src.target] collapses under its own weight into a puddle of goop and undigested debris!</B>", 1)
+
+		if(istype(target, /turf/simulated/wall)) // I hate turf code.
+			var/turf/simulated/wall/W = target
+			W.dismantle_wall(1)
+		else
+			del(target)
+		del(src)
+		return
+
+	switch(target_strength - ticks)
+		if(6)
+			visible_message("\green <B>[src.target] is holding up against the acid!</B>")
+		if(4)
+			visible_message("\green <B>[src.target]\s structure is being melted by the acid!</B>")
+		if(2)
+			visible_message("\green <B>[src.target] is struggling to withstand the acid!</B>")
+		if(0 to 1)
+			visible_message("\green <B>[src.target] begins to crumble under the acid!</B>")
+	spawn(rand(150, 200)) tick()
+
+/*
+ * Egg
+ */
+/var/const //for the status var
+	BURST = 0
+	BURSTING = 1
+	GROWING = 2
+	GROWN = 3
+
+	MIN_GROWTH_TIME = 1800 //time it takes to grow a hugger
+	MAX_GROWTH_TIME = 3000
+
+/obj/effect/alien/egg
+	desc = "It looks like a weird egg"
+	name = "egg"
+	icon_state = "egg_growing"
+	density = 0
+	anchored = 1
+
+	var/health = 100
+	var/status = GROWING //can be GROWING, GROWN or BURST; all mutually exclusive
+
+	New()
+		if(aliens_allowed)
+			..()
+			spawn(rand(MIN_GROWTH_TIME,MAX_GROWTH_TIME))
+				Grow()
+		else
+			del(src)
+
+	attack_paw(user as mob)
+		if(isalien(user))
+			switch(status)
+				if(BURST)
+					user << "\red You clear the hatched egg."
+					del(src)
+					return
+				if(GROWING)
+					user << "\red The child is not developed yet."
+					return
+				if(GROWN)
+					user << "\red You retrieve the child."
+					Burst(0)
+					return
+		else
+			return attack_hand(user)
+
+	attack_hand(user as mob)
+		user << "It feels slimy."
+		return
+
+	proc/GetFacehugger()
+		return locate(/obj/item/clothing/mask/facehugger) in contents
+
+	proc/Grow()
+		icon_state = "egg"
+		status = GROWN
+		new /obj/item/clothing/mask/facehugger(src)
+		return
+
+	proc/Burst(var/kill = 1) //drops and kills the hugger if any is remaining
+		if(status == GROWN || status == GROWING)
+			var/obj/item/clothing/mask/facehugger/child = GetFacehugger()
+			icon_state = "egg_hatched"
+			flick("egg_opening", src)
+			status = BURSTING
+			spawn(15)
+				status = BURST
+				loc.contents += child//need to write the code for giving it to the alien later
+				if(kill && istype(child))
+					child.Die()
+				else
+					for(var/mob/M in range(1,src))
+						if(CanHug(M))
+							child.Attach(M)
+							break
+
+
+/obj/effect/alien/egg/bullet_act(var/obj/item/projectile/Proj)
+	health -= Proj.damage
+	..()
+	healthcheck()
+	return
+
+
+/obj/effect/alien/egg/attackby(var/obj/item/weapon/W, var/mob/user)
+	if(health <= 0)
+		return
+	if(W.attack_verb.len)
+		src.visible_message("\red <B>\The [src] has been [pick(W.attack_verb)] with \the [W][(user ? " by [user]." : ".")]")
+	else
+		src.visible_message("\red <B>\The [src] has been attacked with \the [W][(user ? " by [user]." : ".")]")
+	var/damage = W.force / 4.0
+
+	if(istype(W, /obj/item/weapon/weldingtool))
+		var/obj/item/weapon/weldingtool/WT = W
+
+		if(WT.remove_fuel(0, user))
+			damage = 15
+			playsound(src.loc, 'sound/items/Welder.ogg', 100, 1)
+
+	src.health -= damage
+	src.healthcheck()
+
+
+/obj/effect/alien/egg/proc/healthcheck()
+	if(health <= 0)
+		Burst()
+
+/obj/effect/alien/egg/temperature_expose(datum/gas_mixture/air, exposed_temperature, exposed_volume)
+	if(exposed_temperature > 500)
+		health -= 5
+		healthcheck()
+
+/obj/effect/alien/egg/HasProximity(atom/movable/AM as mob|obj)
+	if(status == GROWN)
+		if(!CanHug(AM))
+			return
+
+		var/mob/living/carbon/C = AM
+		if(C.stat == CONSCIOUS && C.status_flags & XENO_HOST)
+			return
+
+		Burst(0)

code/game/objects/effects/barsign.dm

@@ -0,0 +1,8 @@
+/obj/effect/sign/double/barsign
+	icon = 'icons/obj/barsigns.dmi'
+	icon_state = "empty"
+	anchored = 1
+
+	New()
+		var/list/valid_states = list("pinkflamingo", "magmasea", "limbo", "rustyaxe", "armokbar", "brokendrum", "meadbay", "thedamnwall", "thecavern", "cindikate", "theorchard", "thesaucyclown", "theclownshead", "whiskeyimplant", "carpecarp", "robustroadhouse", "greytide", "theredshirt")
+		src.icon_state = "[pick(valid_states)]"

code/game/objects/effects/biomass_rift.dm

@@ -0,0 +1,126 @@
+/*
+/obj/effect/biomass
+	icon = 'icons/obj/biomass.dmi'
+	icon_state = "stage1"
+	opacity = 0
+	density = 0
+	anchored = 1
+	layer = 20 //DEBUG
+	var/health = 10
+	var/stage = 1
+	var/obj/effect/rift/originalRift = null //the originating rift of that biomass
+	var/maxDistance = 15 //the maximum length of a thread
+	var/newSpreadDistance = 10 //the length of a thread at which new ones are created
+	var/curDistance = 1 //the current length of a thread
+	var/continueChance = 3 //weighed chance of continuing in the same direction. turning left or right has 1 weight both
+	var/spreadDelay = 1 //will change to something bigger later, but right now I want it to spread as fast as possible for testing
+
+/obj/effect/rift
+	icon = 'icons/obj/biomass.dmi'
+	icon_state = "rift"
+	var/list/obj/effect/biomass/linkedBiomass = list() //all the biomass patches that have spread from it
+	var/newicon = 1 //DEBUG
+
+/obj/effect/rift/New()
+	set background = 1
+
+	..()
+
+	for(var/turf/T in orange(1,src))
+		if(!IsValidBiomassLoc(T))
+			continue
+		var/obj/effect/biomass/starting = new /obj/effect/biomass(T)
+		starting.dir = get_dir(src,starting)
+		starting.originalRift = src
+		linkedBiomass += starting
+		spawn(1) //DEBUG
+			starting.icon_state = "[newicon]"
+
+/obj/effect/rift/Del()
+	for(var/obj/effect/biomass/biomass in linkedBiomass)
+		del(biomass)
+	..()
+
+/obj/effect/biomass/New()
+	set background = 1
+
+	..()
+	if(!IsValidBiomassLoc(loc,src))
+		del(src)
+		return
+	spawn(1) //so that the dir and stuff can be set by the source first
+		if(curDistance >= maxDistance)
+			return
+		switch(dir)
+			if(NORTHWEST)
+				dir = NORTH
+			if(NORTHEAST)
+				dir = EAST
+			if(SOUTHWEST)
+				dir = WEST
+			if(SOUTHEAST)
+				dir = SOUTH
+		sleep(spreadDelay)
+		Spread()
+
+/obj/effect/biomass/proc/Spread(var/direction = dir)
+	set background = 1
+	var/possibleDirsInt = 0
+
+	for(var/newDirection in cardinal)
+		if(newDirection == turn(direction,180)) //can't go backwards
+			continue
+		var/turf/T = get_step(loc,newDirection)
+		if(!IsValidBiomassLoc(T,src))
+			continue
+		possibleDirsInt |= newDirection
+
+	var/list/possibleDirs = list()
+
+	if(possibleDirsInt & direction)
+		for(var/i=0 , i<continueChance , i++)
+			possibleDirs += direction
+	if(possibleDirsInt & turn(direction,90))
+		possibleDirs += turn(direction,90)
+	if(possibleDirsInt & turn(direction,-90))
+		possibleDirs += turn(direction,-90)
+
+	if(!possibleDirs.len)
+		return
+
+	direction = pick(possibleDirs)
+
+	var/obj/effect/biomass/newBiomass = new /obj/effect/biomass(get_step(src,direction))
+	newBiomass.curDistance = curDistance + 1
+	newBiomass.maxDistance = maxDistance
+	newBiomass.dir = direction
+	newBiomass.originalRift = originalRift
+	newBiomass.icon_state = "[originalRift.newicon]" //DEBUG
+	originalRift.linkedBiomass += newBiomass
+
+	if(!(curDistance%newSpreadDistance))
+		var/obj/effect/rift/newrift = new /obj/effect/rift(loc)
+		if(originalRift.newicon <= 3)
+			newrift.newicon = originalRift.newicon + 1
+//		NewSpread()
+
+/obj/effect/biomass/proc/NewSpread(maxDistance = 15)
+	set background = 1
+	for(var/turf/T in orange(1,src))
+		if(!IsValidBiomassLoc(T,src))
+			continue
+		var/obj/effect/biomass/starting = new /obj/effect/biomass(T)
+		starting.dir = get_dir(src,starting)
+		starting.maxDistance = maxDistance
+
+/proc/IsValidBiomassLoc(turf/location,obj/effect/biomass/source = null)
+	set background = 1
+	for(var/obj/effect/biomass/biomass in location)
+		if(biomass != source)
+			return 0
+	if(istype(location,/turf/space))
+		return 0
+	if(location.density)
+		return 0
+	return 1
+*/

code/game/objects/effects/bump_teleporter.dm

@@ -0,0 +1,34 @@
+var/list/obj/effect/bump_teleporter/BUMP_TELEPORTERS = list()
+
+/obj/effect/bump_teleporter
+	name = "bump-teleporter"
+	icon = 'icons/mob/screen1.dmi'
+	icon_state = "x2"
+	var/id = null			//id of this bump_teleporter.
+	var/id_target = null	//id of bump_teleporter which this moves you to.
+	invisibility = 101 		//nope, can't see this
+	anchored = 1
+	density = 1
+	opacity = 0
+
+/obj/effect/bump_teleporter/New()
+	..()
+	BUMP_TELEPORTERS += src
+
+/obj/effect/bump_teleporter/Del()
+	BUMP_TELEPORTERS -= src
+	..()
+
+/obj/effect/bump_teleporter/Bumped(atom/user)
+	if(!ismob(user))
+		//user.loc = src.loc	//Stop at teleporter location
+		return
+
+	if(!id_target)
+		//user.loc = src.loc	//Stop at teleporter location, there is nowhere to teleport to.
+		return
+
+	for(var/obj/effect/bump_teleporter/BT in BUMP_TELEPORTERS)
+		if(BT.id == src.id_target)
+			usr.loc = BT.loc	//Teleport to location with correct id.
+			return

code/game/objects/effects/decals/Cleanable/aliens.dm

@@ -0,0 +1,33 @@
+/obj/effect/decal/cleanable/blood/xeno
+	name = "xeno blood"
+	desc = "It's green and acidic. It looks like... <i>blood?</i>"
+	icon = 'icons/effects/blood.dmi'
+	basecolor = "#05EE05"
+
+/obj/effect/decal/cleanable/blood/gibs/xeno
+	name = "xeno gibs"
+	desc = "Gnarly..."
+	icon_state = "xgib1"
+	random_icon_states = list("xgib1", "xgib2", "xgib3", "xgib4", "xgib5", "xgib6")
+	basecolor = "#05EE05"
+
+/obj/effect/decal/cleanable/blood/gibs/xeno/update_icon()
+	color = "#FFFFFF"
+
+/obj/effect/decal/cleanable/blood/gibs/xeno/up
+	random_icon_states = list("xgib1", "xgib2", "xgib3", "xgib4", "xgib5", "xgib6","xgibup1","xgibup1","xgibup1")
+
+/obj/effect/decal/cleanable/blood/gibs/xeno/down
+	random_icon_states = list("xgib1", "xgib2", "xgib3", "xgib4", "xgib5", "xgib6","xgibdown1","xgibdown1","xgibdown1")
+
+/obj/effect/decal/cleanable/blood/gibs/xeno/body
+	random_icon_states = list("xgibhead", "xgibtorso")
+
+/obj/effect/decal/cleanable/blood/gibs/xeno/limb
+	random_icon_states = list("xgibleg", "xgibarm")
+
+/obj/effect/decal/cleanable/blood/gibs/xeno/core
+	random_icon_states = list("xgibmid1", "xgibmid2", "xgibmid3")
+
+/obj/effect/decal/cleanable/blood/xtracks
+	basecolor = "#05EE05"

code/game/objects/effects/decals/Cleanable/fuel.dm

@@ -0,0 +1,57 @@
+obj/effect/decal/cleanable/liquid_fuel
+	//Liquid fuel is used for things that used to rely on volatile fuels or plasma being contained to a couple tiles.
+	icon = 'icons/effects/effects.dmi'
+	icon_state = "fuel"
+	layer = TURF_LAYER+0.2
+	anchored = 1
+	var/amount = 1 //Basically moles.
+
+	New(newLoc,amt=1)
+		src.amount = amt
+
+		//Be absorbed by any other liquid fuel in the tile.
+		for(var/obj/effect/decal/cleanable/liquid_fuel/other in newLoc)
+			if(other != src)
+				other.amount += src.amount
+				spawn other.Spread()
+				del src
+
+		Spread()
+		. = ..()
+
+	proc/Spread()
+		//Allows liquid fuels to sometimes flow into other tiles.
+		if(amount < 0.5) return
+		var/turf/simulated/S = loc
+		if(!istype(S)) return
+		for(var/d in cardinal)
+			if(rand(25))
+				var/turf/simulated/target = get_step(src,d)
+				var/turf/simulated/origin = get_turf(src)
+				if(origin.CanPass(null, target, 0, 0) && target.CanPass(null, origin, 0, 0))
+					if(!locate(/obj/effect/decal/cleanable/liquid_fuel) in target)
+						new/obj/effect/decal/cleanable/liquid_fuel(target, amount*0.25)
+						amount *= 0.75
+
+	flamethrower_fuel
+		icon_state = "mustard"
+		anchored = 0
+		New(newLoc, amt = 1, d = 0)
+			dir = d //Setting this direction means you won't get torched by your own flamethrower.
+			. = ..()
+
+		Spread()
+			//The spread for flamethrower fuel is much more precise, to create a wide fire pattern.
+			if(amount < 0.1) return
+			var/turf/simulated/S = loc
+			if(!istype(S)) return
+
+			for(var/d in list(turn(dir,90),turn(dir,-90), dir))
+				var/turf/simulated/O = get_step(S,d)
+				if(locate(/obj/effect/decal/cleanable/liquid_fuel/flamethrower_fuel) in O)
+					continue
+				if(O.CanPass(null, S, 0, 0) && S.CanPass(null, O, 0, 0))
+					new/obj/effect/decal/cleanable/liquid_fuel/flamethrower_fuel(O,amount*0.25,d)
+					O.hotspot_expose((T20C*2) + 380,500) //Light flamethrower fuel on fire immediately.
+
+			amount *= 0.25

code/game/objects/effects/decals/Cleanable/humans.dm

@@ -0,0 +1,209 @@
+#define DRYING_TIME 5 * 60*10                        //for 1 unit of depth in puddle (amount var)
+
+var/global/list/image/splatter_cache=list()
+
+/obj/effect/decal/cleanable/blood
+	name = "blood"
+	desc = "It's thick and gooey. Perhaps it's the chef's cooking?"
+	gender = PLURAL
+	density = 0
+	anchored = 1
+	layer = 2
+	icon = 'icons/effects/blood.dmi'
+	icon_state = "mfloor1"
+	random_icon_states = list("mfloor1", "mfloor2", "mfloor3", "mfloor4", "mfloor5", "mfloor6", "mfloor7")
+	var/base_icon = 'icons/effects/blood.dmi'
+	var/list/viruses = list()
+	blood_DNA = list()
+	var/basecolor="#A10808" // Color when wet.
+	var/list/datum/disease2/disease/virus2 = list()
+	var/amount = 5
+
+/obj/effect/decal/cleanable/blood/Del()
+	for(var/datum/disease/D in viruses)
+		D.cure(0)
+	..()
+
+/obj/effect/decal/cleanable/blood/New()
+	..()
+	update_icon()
+	if(istype(src, /obj/effect/decal/cleanable/blood/gibs))
+		return
+	if(istype(src, /obj/effect/decal/cleanable/blood/tracks))
+		return // We handle our own drying.
+	if(src.type == /obj/effect/decal/cleanable/blood)
+		if(src.loc && isturf(src.loc))
+			for(var/obj/effect/decal/cleanable/blood/B in src.loc)
+				if(B != src)
+					if (B.blood_DNA)
+						blood_DNA |= B.blood_DNA.Copy()
+					del(B)
+	spawn(DRYING_TIME * (amount+1))
+		dry()
+
+/obj/effect/decal/cleanable/blood/update_icon()
+	if(basecolor == "rainbow") basecolor = "#[pick(list("FF0000","FF7F00","FFFF00","00FF00","0000FF","4B0082","8F00FF"))]"
+	color = basecolor
+
+/obj/effect/decal/cleanable/blood/HasEntered(mob/living/carbon/human/perp)
+	if (!istype(perp))
+		return
+	if(amount < 1)
+		return
+
+	if(perp.shoes)//Adding blood to shoes
+		perp.shoes.blood_color = basecolor
+		perp.shoes:track_blood = max(amount,perp.shoes:track_blood)
+		if(!perp.shoes.blood_overlay)
+			perp.shoes.generate_blood_overlay()
+		if(!perp.shoes.blood_DNA)
+			perp.shoes.blood_DNA = list()
+			perp.shoes.blood_overlay.color = basecolor
+			perp.shoes.overlays += perp.shoes.blood_overlay
+		perp.shoes.blood_DNA |= blood_DNA.Copy()
+
+	else//Or feet
+		perp.feet_blood_color = basecolor
+		perp.track_blood = max(amount,perp.track_blood)
+		if(!perp.feet_blood_DNA)
+			perp.feet_blood_DNA = list()
+		perp.feet_blood_DNA |= blood_DNA.Copy()
+
+	perp.update_inv_shoes(1)
+	amount--
+
+/obj/effect/decal/cleanable/blood/proc/dry()
+		name = "dried [src.name]"
+		desc = "It's dry and crusty. Someone is not doing their job."
+		color = adjust_brightness(color, -50)
+		amount = 0
+
+/obj/effect/decal/cleanable/blood/attack_hand(mob/living/carbon/human/user)
+	..()
+	if (amount && istype(user))
+		add_fingerprint(user)
+		if (user.gloves)
+			return
+		var/taken = rand(1,amount)
+		amount -= taken
+		user << "<span class='notice'>You get some of \the [src] on your hands.</span>"
+		if (!user.blood_DNA)
+			user.blood_DNA = list()
+		user.blood_DNA |= blood_DNA.Copy()
+		user.bloody_hands += taken
+		user.hand_blood_color = basecolor
+		user.update_inv_gloves(1)
+		user.verbs += /mob/living/carbon/human/proc/bloody_doodle
+
+/obj/effect/decal/cleanable/blood/splatter
+        random_icon_states = list("mgibbl1", "mgibbl2", "mgibbl3", "mgibbl4", "mgibbl5")
+        amount = 2
+
+/obj/effect/decal/cleanable/blood/drip
+        name = "drips of blood"
+        desc = "It's red."
+        gender = PLURAL
+        icon = 'icons/effects/drip.dmi'
+        icon_state = "1"
+        random_icon_states = list("1","2","3","4","5")
+        amount = 0
+
+/obj/effect/decal/cleanable/blood/writing
+	icon_state = "tracks"
+	desc = "It looks like a writing in blood."
+	gender = NEUTER
+	random_icon_states = list("writing1","writing2","writing3","writing4","writing5")
+	amount = 0
+	var/message
+
+/obj/effect/decal/cleanable/blood/writing/New()
+	..()
+	if(random_icon_states.len)
+		for(var/obj/effect/decal/cleanable/blood/writing/W in loc)
+			random_icon_states.Remove(W.icon_state)
+		icon_state = pick(random_icon_states)
+	else
+		icon_state = "writing1"
+
+/obj/effect/decal/cleanable/blood/writing/examine()
+	..()
+	usr << "It reads: <font color='[basecolor]'>\"[message]\"<font>"
+
+/obj/effect/decal/cleanable/blood/gibs
+	name = "gibs"
+	desc = "They look bloody and gruesome."
+	gender = PLURAL
+	density = 0
+	anchored = 1
+	layer = 2
+	icon = 'icons/effects/blood.dmi'
+	icon_state = "gibbl5"
+	random_icon_states = list("gib1", "gib2", "gib3", "gib4", "gib5", "gib6")
+	var/fleshcolor = "#FFFFFF"
+
+/obj/effect/decal/cleanable/blood/gibs/update_icon()
+
+	var/image/giblets = new(base_icon, "[icon_state]_flesh", dir)
+	if(!fleshcolor || fleshcolor == "rainbow")
+		fleshcolor = "#[pick(list("FF0000","FF7F00","FFFF00","00FF00","0000FF","4B0082","8F00FF"))]"
+	giblets.color = fleshcolor
+
+	var/icon/blood = new(base_icon,"[icon_state]",dir)
+	if(basecolor == "rainbow") basecolor = "#[pick(list("FF0000","FF7F00","FFFF00","00FF00","0000FF","4B0082","8F00FF"))]"
+	blood.Blend(basecolor,ICON_MULTIPLY)
+
+	icon = blood
+	overlays.Cut()
+	overlays += giblets
+
+/obj/effect/decal/cleanable/blood/gibs/up
+	random_icon_states = list("gib1", "gib2", "gib3", "gib4", "gib5", "gib6","gibup1","gibup1","gibup1")
+
+/obj/effect/decal/cleanable/blood/gibs/down
+	random_icon_states = list("gib1", "gib2", "gib3", "gib4", "gib5", "gib6","gibdown1","gibdown1","gibdown1")
+
+/obj/effect/decal/cleanable/blood/gibs/body
+	random_icon_states = list("gibhead", "gibtorso")
+
+/obj/effect/decal/cleanable/blood/gibs/limb
+	random_icon_states = list("gibleg", "gibarm")
+
+/obj/effect/decal/cleanable/blood/gibs/core
+	random_icon_states = list("gibmid1", "gibmid2", "gibmid3")
+
+
+/obj/effect/decal/cleanable/blood/gibs/proc/streak(var/list/directions)
+        spawn (0)
+                var/direction = pick(directions)
+                for (var/i = 0, i < pick(1, 200; 2, 150; 3, 50; 4), i++)
+                        sleep(3)
+                        if (i > 0)
+                                var/obj/effect/decal/cleanable/blood/b = new /obj/effect/decal/cleanable/blood/splatter(src.loc)
+                                b.basecolor = src.basecolor
+                                b.update_icon()
+                                for(var/datum/disease/D in src.viruses)
+                                        var/datum/disease/ND = D.Copy(1)
+                                        b.viruses += ND
+                                        ND.holder = b
+
+                        if (step_to(src, get_step(src, direction), 0))
+                                break
+
+
+/obj/effect/decal/cleanable/mucus
+	name = "mucus"
+	desc = "Disgusting mucus."
+	gender = PLURAL
+	density = 0
+	anchored = 1
+	layer = 2
+	icon = 'icons/effects/blood.dmi'
+	icon_state = "mucus"
+	random_icon_states = list("mucus")
+
+	var/list/datum/disease2/disease/virus2 = list()
+	var/dry=0 // Keeps the lag down
+
+/obj/effect/decal/cleanable/mucus/New()
+	spawn(DRYING_TIME * 2)
+		dry=1

code/game/objects/effects/decals/Cleanable/misc.dm

@@ -0,0 +1,135 @@
+/obj/effect/decal/cleanable/generic
+	name = "clutter"
+	desc = "Someone should clean that up."
+	gender = PLURAL
+	density = 0
+	anchored = 1
+	layer = 2
+	icon = 'icons/obj/objects.dmi'
+	icon_state = "shards"
+
+/obj/effect/decal/cleanable/ash
+	name = "ashes"
+	desc = "Ashes to ashes, dust to dust, and into space."
+	gender = PLURAL
+	icon = 'icons/obj/objects.dmi'
+	icon_state = "ash"
+	anchored = 1
+
+/obj/effect/decal/cleanable/ash/attack_hand(mob/user as mob)
+	user << "<span class='notice'>[src] sifts through your fingers.</span>"
+	var/turf/simulated/floor/F = get_turf(src)
+	if (istype(F))
+		F.dirt += 4
+	del(src)
+
+/obj/effect/decal/cleanable/greenglow
+
+	New()
+		..()
+		spawn(1200)// 2 minutes
+			del(src)
+
+/obj/effect/decal/cleanable/dirt
+	name = "dirt"
+	desc = "Someone should clean that up."
+	gender = PLURAL
+	density = 0
+	anchored = 1
+	layer = 2
+	icon = 'icons/effects/effects.dmi'
+	icon_state = "dirt"
+	mouse_opacity = 0
+
+/obj/effect/decal/cleanable/flour
+	name = "flour"
+	desc = "It's still good. Four second rule!"
+	gender = PLURAL
+	density = 0
+	anchored = 1
+	layer = 2
+	icon = 'icons/effects/effects.dmi'
+	icon_state = "flour"
+
+/obj/effect/decal/cleanable/greenglow
+	name = "glowing goo"
+	desc = "Jeez. I hope that's not for lunch."
+	gender = PLURAL
+	density = 0
+	anchored = 1
+	layer = 2
+	luminosity = 1
+	icon = 'icons/effects/effects.dmi'
+	icon_state = "greenglow"
+
+/obj/effect/decal/cleanable/cobweb
+	name = "cobweb"
+	desc = "Somebody should remove that."
+	density = 0
+	anchored = 1
+	layer = 3
+	icon = 'icons/effects/effects.dmi'
+	icon_state = "cobweb1"
+
+/obj/effect/decal/cleanable/molten_item
+	name = "gooey grey mass"
+	desc = "It looks like a melted... something."
+	density = 0
+	anchored = 1
+	layer = 3
+	icon = 'icons/obj/chemical.dmi'
+	icon_state = "molten"
+
+/obj/effect/decal/cleanable/cobweb2
+	name = "cobweb"
+	desc = "Somebody should remove that."
+	density = 0
+	anchored = 1
+	layer = 3
+	icon = 'icons/effects/effects.dmi'
+	icon_state = "cobweb2"
+
+//Vomit (sorry)
+/obj/effect/decal/cleanable/vomit
+	name = "vomit"
+	desc = "Gosh, how unpleasant."
+	gender = PLURAL
+	density = 0
+	anchored = 1
+	layer = 2
+	icon = 'icons/effects/blood.dmi'
+	icon_state = "vomit_1"
+	random_icon_states = list("vomit_1", "vomit_2", "vomit_3", "vomit_4")
+	var/list/viruses = list()
+
+	Del()
+		for(var/datum/disease/D in viruses)
+			D.cure(0)
+		..()
+
+/obj/effect/decal/cleanable/tomato_smudge
+	name = "tomato smudge"
+	desc = "It's red."
+	density = 0
+	anchored = 1
+	layer = 2
+	icon = 'icons/effects/tomatodecal.dmi'
+	random_icon_states = list("tomato_floor1", "tomato_floor2", "tomato_floor3")
+
+/obj/effect/decal/cleanable/egg_smudge
+	name = "smashed egg"
+	desc = "Seems like this one won't hatch."
+	density = 0
+	anchored = 1
+	layer = 2
+	icon = 'icons/effects/tomatodecal.dmi'
+	random_icon_states = list("smashed_egg1", "smashed_egg2", "smashed_egg3")
+
+/obj/effect/decal/cleanable/pie_smudge //honk
+	name = "smashed pie"
+	desc = "It's pie cream from a cream pie."
+	density = 0
+	anchored = 1
+	layer = 2
+	icon = 'icons/effects/tomatodecal.dmi'
+	random_icon_states = list("smashed_pie")

code/game/objects/effects/decals/Cleanable/robots.dm

@@ -0,0 +1,50 @@
+/obj/effect/decal/cleanable/blood/gibs/robot
+	name = "robot debris"
+	desc = "It's a useless heap of junk... <i>or is it?</i>"
+	icon = 'icons/mob/robots.dmi'
+	icon_state = "gib1"
+	basecolor="#030303"
+	random_icon_states = list("gib1", "gib2", "gib3", "gib4", "gib5", "gib6", "gib7")
+
+/obj/effect/decal/cleanable/blood/gibs/robot/update_icon()
+	color = "#FFFFFF"
+
+/obj/effect/decal/cleanable/blood/gibs/robot/dry()	//pieces of robots do not dry up like
+	return
+
+/obj/effect/decal/cleanable/blood/gibs/robot/streak(var/list/directions)
+	spawn (0)
+		var/direction = pick(directions)
+		for (var/i = 0, i < pick(1, 200; 2, 150; 3, 50; 4), i++)
+			sleep(3)
+			if (i > 0)
+				if (prob(40))
+					var/obj/effect/decal/cleanable/blood/oil/streak = new(src.loc)
+					streak.update_icon()
+				else if (prob(10))
+					var/datum/effect/effect/system/spark_spread/s = new /datum/effect/effect/system/spark_spread
+					s.set_up(3, 1, src)
+					s.start()
+			if (step_to(src, get_step(src, direction), 0))
+				break
+
+/obj/effect/decal/cleanable/blood/gibs/robot/limb
+	random_icon_states = list("gibarm", "gibleg")
+
+/obj/effect/decal/cleanable/blood/gibs/robot/up
+	random_icon_states = list("gib1", "gib2", "gib3", "gib4", "gib5", "gib6", "gib7","gibup1","gibup1") //2:7 is close enough to 1:4
+
+/obj/effect/decal/cleanable/blood/gibs/robot/down
+	random_icon_states = list("gib1", "gib2", "gib3", "gib4", "gib5", "gib6", "gib7","gibdown1","gibdown1") //2:7 is close enough to 1:4
+
+/obj/effect/decal/cleanable/blood/oil
+	name = "motor oil"
+	desc = "It's black and greasy. Looks like Beepsky made another mess."
+	basecolor="#030303"
+
+/obj/effect/decal/cleanable/blood/oil/dry()
+	return
+
+/obj/effect/decal/cleanable/blood/oil/streak
+	random_icon_states = list("mgibbl1", "mgibbl2", "mgibbl3", "mgibbl4", "mgibbl5")
+	amount = 2

code/game/objects/effects/decals/Cleanable/tracks.dm

@@ -0,0 +1,161 @@
+// Stolen en masse from N3X15 of /vg/station with much gratitude.
+
+// The idea is to have 4 bits for coming and 4 for going.
+#define TRACKS_COMING_NORTH 1
+#define TRACKS_COMING_SOUTH 2
+#define TRACKS_COMING_EAST  4
+#define TRACKS_COMING_WEST  8
+#define TRACKS_GOING_NORTH  16
+#define TRACKS_GOING_SOUTH  32
+#define TRACKS_GOING_EAST   64
+#define TRACKS_GOING_WEST   128
+
+// 5 seconds
+#define TRACKS_CRUSTIFY_TIME   50
+
+// color-dir-dry
+var/global/list/image/fluidtrack_cache=list()
+
+/datum/fluidtrack
+	var/direction=0
+	var/basecolor="#A10808"
+	var/wet=0
+	var/fresh=1
+	var/crusty=0
+	var/image/overlay
+
+	New(_direction,_color,_wet)
+		src.direction=_direction
+		src.basecolor=_color
+		src.wet=_wet
+
+// Footprints, tire trails...
+/obj/effect/decal/cleanable/blood/tracks
+	amount = 0
+	random_icon_states = null
+	var/dirs=0
+	icon = 'icons/effects/fluidtracks.dmi'
+	icon_state = ""
+	var/coming_state="blood1"
+	var/going_state="blood2"
+	var/updatedtracks=0
+
+	// dir = id in stack
+	var/list/setdirs=list(
+		"1"=0,
+		"2"=0,
+		"4"=0,
+		"8"=0,
+		"16"=0,
+		"32"=0,
+		"64"=0,
+		"128"=0
+	)
+
+	// List of laid tracks and their colors.
+	var/list/datum/fluidtrack/stack=list()
+
+	/**
+	* Add tracks to an existing trail.
+	*
+	* @param DNA bloodDNA to add to collection.
+	* @param comingdir Direction tracks come from, or 0.
+	* @param goingdir Direction tracks are going to (or 0).
+	* @param bloodcolor Color of the blood when wet.
+	*/
+	proc/AddTracks(var/list/DNA, var/comingdir, var/goingdir, var/bloodcolor="#A10808")
+		var/updated=0
+		// Shift our goingdir 4 spaces to the left so it's in the GOING bitblock.
+		var/realgoing=goingdir<<4
+
+		// Current bit
+		var/b=0
+
+		// When tracks will start to dry out
+		var/t=world.time + TRACKS_CRUSTIFY_TIME
+
+		var/datum/fluidtrack/track
+
+		// Process 4 bits
+		for(var/bi=0;bi<4;bi++)
+			b=1<<bi
+			// COMING BIT
+			// If setting
+			if(comingdir&b)
+				// If not wet or not set
+				if(dirs&b)
+					var/sid=setdirs["[b]"]
+					track=stack[sid]
+					if(track.wet==t && track.basecolor==bloodcolor)
+						continue
+					// Remove existing stack entry
+					stack.Remove(track)
+				track=new /datum/fluidtrack(b,bloodcolor,t)
+				stack.Add(track)
+				setdirs["[b]"]=stack.Find(track)
+				updatedtracks |= b
+				updated=1
+
+			// GOING BIT (shift up 4)
+			b=b<<4
+			if(realgoing&b)
+				// If not wet or not set
+				if(dirs&b)
+					var/sid=setdirs["[b]"]
+					track=stack[sid]
+					if(track.wet==t && track.basecolor==bloodcolor)
+						continue
+					// Remove existing stack entry
+					stack.Remove(track)
+				track=new /datum/fluidtrack(b,bloodcolor,t)
+				stack.Add(track)
+				setdirs["[b]"]=stack.Find(track)
+				updatedtracks |= b
+				updated=1
+
+		dirs |= comingdir|realgoing
+		blood_DNA |= DNA.Copy()
+		if(updated)
+			update_icon()
+
+	update_icon()
+		overlays.Cut()
+		color = "#FFFFFF"
+		var/truedir=0
+
+		// Update ONLY the overlays that have changed.
+		for(var/datum/fluidtrack/track in stack)
+			var/stack_idx=setdirs["[track.direction]"]
+			var/state=coming_state
+			truedir=track.direction
+			if(truedir&240) // Check if we're in the GOING block
+				state=going_state
+				truedir=truedir>>4
+
+			if(track.overlay)
+				track.overlay=null
+			var/image/I = image(icon, icon_state=state, dir=num2dir(truedir))
+			I.color = track.basecolor
+
+			track.fresh=0
+			track.overlay=I
+			stack[stack_idx]=track
+			overlays += I
+		updatedtracks=0 // Clear our memory of updated tracks.
+
+/obj/effect/decal/cleanable/blood/tracks/footprints
+	name = "wet footprints"
+	desc = "Whoops..."
+	coming_state = "human1"
+	going_state  = "human2"
+	amount = 0
+
+/obj/effect/decal/cleanable/blood/tracks/wheels
+	name = "wet tracks"
+	desc = "Whoops..."
+	coming_state = "wheels"
+	going_state  = ""
+	desc = "They look like tracks left by wheels."
+	gender = PLURAL
+	random_icon_states = null
+	amount = 0

code/game/objects/effects/decals/cleanable.dm

@@ -0,0 +1,8 @@
+/obj/effect/decal/cleanable
+	var/list/random_icon_states = list()
+	var/targeted_by = null			// Used so cleanbots can't claim a mess.
+
+/obj/effect/decal/cleanable/New()
+	if (random_icon_states && length(src.random_icon_states) > 0)
+		src.icon_state = pick(src.random_icon_states)
+	..()

code/game/objects/effects/decals/contraband.dm

@@ -0,0 +1,191 @@
+
+//########################## CONTRABAND ;3333333333333333333 -Agouri ###################################################
+
+#define NUM_OF_POSTER_DESIGNS 10
+
+/obj/item/weapon/contraband
+	name = "contraband item"
+	desc = "You probably shouldn't be holding this."
+	icon = 'icons/obj/contraband.dmi'
+	force = 0
+
+
+/obj/item/weapon/contraband/poster
+	name = "rolled-up poster"
+	desc = "The poster comes with its own automatic adhesive mechanism, for easy pinning to any vertical surface."
+	icon_state = "rolled_poster"
+	var/serial_number = 0
+	var/obj/structure/sign/poster/resulting_poster = null //The poster that will be created is initialised and stored through contraband/poster's constructor
+
+
+/obj/item/weapon/contraband/poster/New(turf/loc, var/given_serial = 0)
+	if(given_serial == 0)
+		serial_number = rand(1, NUM_OF_POSTER_DESIGNS)
+		resulting_poster = new(serial_number)
+	else
+		serial_number = given_serial
+		//We don't give it a resulting_poster because if we called it with a given_serial it means that we're rerolling an already used poster.
+	name += " - No. [serial_number]"
+	..(loc)
+
+
+/*/obj/item/weapon/contraband/poster/attack(mob/M as mob, mob/user as mob)
+	src.add_fingerprint(user)
+	if(resulting_poster)
+		resulting_poster.add_fingerprint(user)
+	..()*/
+
+/*/obj/item/weapon/contraband/poster/attack(atom/A, mob/user as mob) //This shit is handled through the wall's attackby()
+	if(istype(A, /turf/simulated/wall))
+		if(resulting_poster == null)
+			return
+		else
+			var/turf/simulated/wall/W = A
+			var/check = 0
+			var/stuff_on_wall = 0
+			for(var/obj/O in W.contents) //Let's see if it already has a poster on it or too much stuff
+				if(istype(O,/obj/structure/sign/poster))
+					check = 1
+					break
+				stuff_on_wall++
+				if(stuff_on_wall == 3)
+					check = 1
+					break
+
+			if(check)
+				user << "<span class='notice'>The wall is far too cluttered to place a poster!</span>"
+				return
+
+			resulting_poster.loc = W //Looks like it's uncluttered enough. Place the poster
+			W.contents += resulting_poster
+
+			del(src)*/
+
+
+
+//############################## THE ACTUAL DECALS ###########################
+
+obj/structure/sign/poster
+	name = "poster"
+	desc = "A large piece of space-resistant printed paper. "
+	icon = 'icons/obj/contraband.dmi'
+	anchored = 1
+	var/serial_number	//Will hold the value of src.loc if nobody initialises it
+	var/ruined = 0
+
+
+obj/structure/sign/poster/New(var/serial)
+
+	serial_number = serial
+
+	if(serial_number == loc)
+		serial_number = rand(1, NUM_OF_POSTER_DESIGNS)	//This is for the mappers that want individual posters without having to use rolled posters.
+
+	icon_state = "poster[serial_number]"
+
+	switch(serial_number)
+		if(1)
+			name += " - Free Tonto"
+			desc += " A framed shred of a much larger flag, colors bled together and faded from age."
+		if(2)
+			name += " - Atmosia Declaration of Independence"
+			desc += " A relic of a failed rebellion"
+		if(3)
+			name += " - Fun Police"
+			desc += " A poster condemning the station's security forces."
+		if(4)
+			name += " - Lusty Xeno"
+			desc += " A heretical poster depicting the titular star of an equally heretical book."
+		if(5)
+			name += " - Syndicate Recruitment Poster"
+			desc += " See the galaxy! Shatter corrupt megacorporations! Join today!"
+		if(6)
+			name += " - Clown"
+			desc += " Honk."
+		if(7)
+			name += " - Smoke"
+			desc += " A poster depicting a carton of cigarettes."
+		if(8)
+			name += " - Grey Tide"
+			desc += " A rebellious poster symbolizing assistant solidarity."
+		if(9)
+			name += " - Missing Gloves"
+			desc += " This poster is about the uproar that followed Nanotrasen's financial cuts towards insulated-glove purchases."
+		if(10)
+			name += " - Hacking Guide"
+			desc += " This poster details the internal workings of the common Nanotrasen airlock."
+		else
+			name = "This shit just bugged. Report it to Agouri - polyxenitopalidou@gmail.com"
+			desc = "Why are you still here?"
+	..()
+
+obj/structure/sign/poster/attackby(obj/item/weapon/W as obj, mob/user as mob)
+	if(istype(W, /obj/item/weapon/wirecutters))
+		playsound(loc, 'sound/items/Wirecutter.ogg', 100, 1)
+		if(ruined)
+			user << "<span class='notice'>You remove the remnants of the poster.</span>"
+			del(src)
+		else
+			user << "<span class='notice'>You carefully remove the poster from the wall.</span>"
+			roll_and_drop(user.loc)
+		return
+
+
+/obj/structure/sign/poster/attack_hand(mob/user as mob)
+	if(ruined)
+		return
+	var/temp_loc = user.loc
+	switch(alert("Do I want to rip the poster from the wall?","You think...","Yes","No"))
+		if("Yes")
+			if(user.loc != temp_loc)
+				return
+			visible_message("<span class='warning'>[user] rips [src] in a single, decisive motion!</span>" )
+			playsound(src.loc, 'sound/items/poster_ripped.ogg', 100, 1)
+			ruined = 1
+			icon_state = "poster_ripped"
+			name = "ripped poster"
+			desc = "You can't make out anything from the poster's original print. It's ruined."
+			add_fingerprint(user)
+		if("No")
+			return
+
+/obj/structure/sign/poster/proc/roll_and_drop(turf/newloc)
+	var/obj/item/weapon/contraband/poster/P = new(src, serial_number)
+	P.resulting_poster = src
+	P.loc = newloc
+	src.loc = P
+
+
+//seperated to reduce code duplication. Moved here for ease of reference and to unclutter r_wall/attackby()
+/turf/simulated/wall/proc/place_poster(var/obj/item/weapon/contraband/poster/P, var/mob/user)
+	if(!P.resulting_poster)	return
+
+	var/stuff_on_wall = 0
+	for(var/obj/O in contents) //Let's see if it already has a poster on it or too much stuff
+		if(istype(O,/obj/structure/sign/poster))
+			user << "<span class='notice'>The wall is far too cluttered to place a poster!</span>"
+			return
+		stuff_on_wall++
+		if(stuff_on_wall == 3)
+			user << "<span class='notice'>The wall is far too cluttered to place a poster!</span>"
+			return
+
+	user << "<span class='notice'>You start placing the poster on the wall...</span>" //Looks like it's uncluttered enough. Place the poster.
+
+	//declaring D because otherwise if P gets 'deconstructed' we lose our reference to P.resulting_poster
+	var/obj/structure/sign/poster/D = P.resulting_poster
+
+	var/temp_loc = user.loc
+	flick("poster_being_set",D)
+	D.loc = src
+	del(P)	//delete it now to cut down on sanity checks afterwards. Agouri's code supports rerolling it anyway
+	playsound(D.loc, 'sound/items/poster_being_created.ogg', 100, 1)
+
+	sleep(17)
+	if(!D)	return
+
+	if(istype(src,/turf/simulated/wall) && user && user.loc == temp_loc)//Let's check if everything is still there
+		user << "<span class='notice'>You place the poster!</span>"
+	else
+		D.roll_and_drop(temp_loc)
+	return

code/game/objects/effects/decals/crayon.dm

@@ -0,0 +1,36 @@
+/obj/effect/decal/cleanable/crayon
+	name = "rune"
+	desc = "A rune drawn in crayon."
+	icon = 'icons/obj/rune.dmi'
+	layer = 2.1
+	anchored = 1
+
+	examine()
+		set src in view(2)
+		..()
+		return
+
+
+	New(location,main = "#FFFFFF",shade = "#000000",var/type = "rune")
+		..()
+		loc = location
+
+		name = type
+		desc = "A [type] drawn in crayon."
+
+		switch(type)
+			if("rune")
+				type = "rune[rand(1,6)]"
+			if("graffiti")
+				type = pick("amyjon","face","matt","revolution","engie","guy","end","dwarf","uboa")
+
+		var/icon/mainOverlay = new/icon('icons/effects/crayondecal.dmi',"[type]",2.1)
+		var/icon/shadeOverlay = new/icon('icons/effects/crayondecal.dmi',"[type]s",2.1)
+
+		mainOverlay.Blend(main,ICON_ADD)
+		shadeOverlay.Blend(shade,ICON_ADD)
+
+		overlays += mainOverlay
+		overlays += shadeOverlay
+
+		add_hiddenprint(usr)

code/game/objects/effects/decals/misc.dm

@@ -0,0 +1,24 @@
+/obj/effect/decal/point
+	name = "arrow"
+	desc = "It's an arrow hanging in mid-air. There may be a wizard about."
+	icon = 'icons/mob/screen1.dmi'
+	icon_state = "arrow"
+	layer = 16.0
+	anchored = 1
+
+/obj/effect/decal/point/point()
+	set src in oview()
+	set hidden = 1
+	return
+
+// Used for spray that you spray at walls, tables, hydrovats etc
+/obj/effect/decal/spraystill
+	density = 0
+	anchored = 1
+	layer = 50
+
+//Used by spraybottles.
+/obj/effect/decal/chempuff
+	name = "chemicals"
+	icon = 'icons/obj/chempuff.dmi'
+	pass_flags = PASSTABLE | PASSGRILLE

code/game/objects/effects/decals/remains.dm

@@ -0,0 +1,23 @@
+/obj/effect/decal/remains/human
+	name = "remains"
+	desc = "They look like human remains. They have a strange aura about them."
+	gender = PLURAL
+	icon = 'icons/effects/blood.dmi'
+	icon_state = "remains"
+	anchored = 1
+
+/obj/effect/decal/remains/xeno
+	name = "remains"
+	desc = "They look like the remains of something... alien. They have a strange aura about them."
+	gender = PLURAL
+	icon = 'icons/effects/blood.dmi'
+	icon_state = "remainsxeno"
+	anchored = 1
+
+/obj/effect/decal/remains/robot
+	name = "remains"
+	desc = "They look like the remains of something mechanical. They have a strange aura about them."
+	gender = PLURAL
+	icon = 'icons/mob/robots.dmi'
+	icon_state = "remainsrobot"
+	anchored = 1

code/game/objects/effects/decals/warning_stripes.dm

@@ -0,0 +1,9 @@
+/obj/effect/decal/warning_stripes
+	icon = 'icons/effects/warning_stripes.dmi'
+	layer = 2
+
+/obj/effect/decal/warning_stripes/New()
+	. = ..()
+
+	loc.overlays += src
+	del src

code/game/objects/effects/effect_system.dm

@@ -0,0 +1,899 @@
+/* This is an attempt to make some easily reusable "particle" type effect, to stop the code
+constantly having to be rewritten. An item like the jetpack that uses the ion_trail_follow system, just has one
+defined, then set up when it is created with New(). Then this same system can just be reused each time
+it needs to create more trails.A beaker could have a steam_trail_follow system set up, then the steam
+would spawn and follow the beaker, even if it is carried or thrown.
+*/
+
+
+/obj/effect/effect
+	name = "effect"
+	icon = 'icons/effects/effects.dmi'
+	mouse_opacity = 0
+	unacidable = 1//So effect are not targeted by alien acid.
+	flags = TABLEPASS
+
+/obj/effect/effect/water
+	name = "water"
+	icon = 'icons/effects/effects.dmi'
+	icon_state = "extinguish"
+	var/life = 15.0
+	flags = TABLEPASS
+	mouse_opacity = 0
+
+/obj/effect/proc/delete()
+	loc = null
+	if(reagents)
+		reagents.delete()
+	return
+
+
+/obj/effect/effect/water/New()
+	..()
+	//var/turf/T = src.loc
+	//if (istype(T, /turf))
+	//	T.firelevel = 0 //TODO: FIX
+	spawn( 70 )
+		delete()
+		return
+	return
+
+/obj/effect/effect/water/Del()
+	//var/turf/T = src.loc
+	//if (istype(T, /turf))
+	//	T.firelevel = 0 //TODO: FIX
+	..()
+	return
+
+/obj/effect/effect/water/Move(turf/newloc)
+	//var/turf/T = src.loc
+	//if (istype(T, /turf))
+	//	T.firelevel = 0 //TODO: FIX
+	if (--src.life < 1)
+		//SN src = null
+		delete()
+	if(newloc.density)
+		return 0
+	.=..()
+
+/obj/effect/effect/water/Bump(atom/A)
+	if(reagents)
+		reagents.reaction(A)
+	return ..()
+
+
+/datum/effect/effect/system
+	var/number = 3
+	var/cardinals = 0
+	var/turf/location
+	var/atom/holder
+	var/setup = 0
+
+	proc/set_up(n = 3, c = 0, turf/loc)
+		if(n > 10)
+			n = 10
+		number = n
+		cardinals = c
+		location = loc
+		setup = 1
+
+	proc/attach(atom/atom)
+		holder = atom
+
+	proc/start()
+
+
+/////////////////////////////////////////////
+// GENERIC STEAM SPREAD SYSTEM
+
+//Usage: set_up(number of bits of steam, use North/South/East/West only, spawn location)
+// The attach(atom/atom) proc is optional, and can be called to attach the effect
+// to something, like a smoking beaker, so then you can just call start() and the steam
+// will always spawn at the items location, even if it's moved.
+
+/* Example:
+var/datum/effect/system/steam_spread/steam = new /datum/effect/system/steam_spread() -- creates new system
+steam.set_up(5, 0, mob.loc) -- sets up variables
+OPTIONAL: steam.attach(mob)
+steam.start() -- spawns the effect
+*/
+/////////////////////////////////////////////
+/obj/effect/effect/steam
+	name = "steam"
+	icon = 'icons/effects/effects.dmi'
+	icon_state = "extinguish"
+	density = 0
+
+/datum/effect/effect/system/steam_spread
+
+	set_up(n = 3, c = 0, turf/loc)
+		if(n > 10)
+			n = 10
+		number = n
+		cardinals = c
+		location = loc
+
+	start()
+		var/i = 0
+		for(i=0, i<src.number, i++)
+			spawn(0)
+				if(holder)
+					src.location = get_turf(holder)
+				var/obj/effect/effect/steam/steam = new /obj/effect/effect/steam(src.location)
+				var/direction
+				if(src.cardinals)
+					direction = pick(cardinal)
+				else
+					direction = pick(alldirs)
+				for(i=0, i<pick(1,2,3), i++)
+					sleep(5)
+					step(steam,direction)
+				spawn(20)
+					steam.delete()
+
+/////////////////////////////////////////////
+//SPARK SYSTEM (like steam system)
+// The attach(atom/atom) proc is optional, and can be called to attach the effect
+// to something, like the RCD, so then you can just call start() and the sparks
+// will always spawn at the items location.
+/////////////////////////////////////////////
+
+/obj/effect/effect/sparks
+	name = "sparks"
+	icon_state = "sparks"
+	var/amount = 6.0
+	anchored = 1.0
+	mouse_opacity = 0
+
+/obj/effect/effect/sparks/New()
+	..()
+	playsound(src.loc, "sparks", 100, 1)
+	var/turf/T = src.loc
+	if (istype(T, /turf))
+		T.hotspot_expose(1000,100)
+	spawn (100)
+		delete()
+	return
+
+/obj/effect/effect/sparks/Del()
+	var/turf/T = src.loc
+	if (istype(T, /turf))
+		T.hotspot_expose(1000,100)
+	..()
+	return
+
+/obj/effect/effect/sparks/Move()
+	..()
+	var/turf/T = src.loc
+	if (istype(T, /turf))
+		T.hotspot_expose(1000,100)
+	return
+
+/datum/effect/effect/system/spark_spread
+	var/total_sparks = 0 // To stop it being spammed and lagging!
+
+	set_up(n = 3, c = 0, loca)
+		if(n > 10)
+			n = 10
+		number = n
+		cardinals = c
+		if(istype(loca, /turf/))
+			location = loca
+		else
+			location = get_turf(loca)
+
+	start()
+		var/i = 0
+		for(i=0, i<src.number, i++)
+			if(src.total_sparks > 20)
+				return
+			spawn(0)
+				if(holder)
+					src.location = get_turf(holder)
+				var/obj/effect/effect/sparks/sparks = new /obj/effect/effect/sparks(src.location)
+				src.total_sparks++
+				var/direction
+				if(src.cardinals)
+					direction = pick(cardinal)
+				else
+					direction = pick(alldirs)
+				for(i=0, i<pick(1,2,3), i++)
+					sleep(5)
+					step(sparks,direction)
+				spawn(20)
+					sparks.delete()
+					src.total_sparks--
+
+
+
+/////////////////////////////////////////////
+//// SMOKE SYSTEMS
+// direct can be optinally added when set_up, to make the smoke always travel in one direction
+// in case you wanted a vent to always smoke north for example
+/////////////////////////////////////////////
+
+
+/obj/effect/effect/smoke
+	name = "smoke"
+	icon_state = "smoke"
+	opacity = 1
+	anchored = 0.0
+	mouse_opacity = 0
+	var/amount = 6.0
+	var/time_to_live = 100
+
+	//Remove this bit to use the old smoke
+	icon = 'icons/effects/96x96.dmi'
+	pixel_x = -32
+	pixel_y = -32
+
+/obj/effect/effect/smoke/New()
+	..()
+	spawn (time_to_live)
+		delete()
+	return
+
+/obj/effect/effect/smoke/HasEntered(mob/living/carbon/M as mob )
+	..()
+	if(istype(M))
+		affect(M)
+
+/obj/effect/effect/smoke/proc/affect(var/mob/living/carbon/M)
+	if (istype(M))
+		return 0
+	if (M.internal != null && M.wear_mask && (M.wear_mask.flags & MASKINTERNALS))
+		return 0
+	return 1
+
+/////////////////////////////////////////////
+// Bad smoke
+/////////////////////////////////////////////
+
+/obj/effect/effect/smoke/bad
+	time_to_live = 200
+
+/obj/effect/effect/smoke/bad/Move()
+	..()
+	for(var/mob/living/carbon/M in get_turf(src))
+		affect(M)
+
+/obj/effect/effect/smoke/bad/affect(var/mob/living/carbon/M)
+	if (!..())
+		return 0
+	M.drop_item()
+	M.adjustOxyLoss(1)
+	if (M.coughedtime != 1)
+		M.coughedtime = 1
+		M.emote("cough")
+		spawn ( 20 )
+			M.coughedtime = 0
+
+/obj/effect/effect/smoke/bad/CanPass(atom/movable/mover, turf/target, height=0, air_group=0)
+	if(air_group || (height==0)) return 1
+	if(istype(mover, /obj/item/projectile/beam))
+		var/obj/item/projectile/beam/B = mover
+		B.damage = (B.damage/2)
+	return 1
+/////////////////////////////////////////////
+// Sleep smoke
+/////////////////////////////////////////////
+
+/obj/effect/effect/smoke/sleepy
+
+/obj/effect/effect/smoke/sleepy/Move()
+	..()
+	for(var/mob/living/carbon/M in get_turf(src))
+		affect(M)
+
+/obj/effect/effect/smoke/sleepy/affect(mob/living/carbon/M as mob )
+	if (!..())
+		return 0
+
+	M.drop_item()
+	M:sleeping += 1
+	if (M.coughedtime != 1)
+		M.coughedtime = 1
+		M.emote("cough")
+		spawn ( 20 )
+			M.coughedtime = 0
+/////////////////////////////////////////////
+// Mustard Gas
+/////////////////////////////////////////////
+
+
+/obj/effect/effect/smoke/mustard
+	name = "mustard gas"
+	icon_state = "mustard"
+
+/obj/effect/effect/smoke/mustard/Move()
+	..()
+	for(var/mob/living/carbon/human/R in get_turf(src))
+		affect(R)
+
+/obj/effect/effect/smoke/mustard/affect(var/mob/living/carbon/human/R)
+	if (!..())
+		return 0
+	if (R.wear_suit != null)
+		return 0
+
+	R.burn_skin(0.75)
+	if (R.coughedtime != 1)
+		R.coughedtime = 1
+		R.emote("gasp")
+		spawn (20)
+			R.coughedtime = 0
+	R.updatehealth()
+	return
+
+/////////////////////////////////////////////
+// Smoke spread
+/////////////////////////////////////////////
+
+/datum/effect/effect/system/smoke_spread
+	var/total_smoke = 0 // To stop it being spammed and lagging!
+	var/direction
+	var/smoke_type = /obj/effect/effect/smoke
+
+/datum/effect/effect/system/smoke_spread/set_up(n = 5, c = 0, loca, direct)
+	if(n > 10)
+		n = 10
+	number = n
+	cardinals = c
+	if(istype(loca, /turf/))
+		location = loca
+	else
+		location = get_turf(loca)
+	if(direct)
+		direction = direct
+
+/datum/effect/effect/system/smoke_spread/start()
+	var/i = 0
+	for(i=0, i<src.number, i++)
+		if(src.total_smoke > 20)
+			return
+		spawn(0)
+			if(holder)
+				src.location = get_turf(holder)
+			var/obj/effect/effect/smoke/smoke = new smoke_type(src.location)
+			src.total_smoke++
+			var/direction = src.direction
+			if(!direction)
+				if(src.cardinals)
+					direction = pick(cardinal)
+				else
+					direction = pick(alldirs)
+			for(i=0, i<pick(0,1,1,1,2,2,2,3), i++)
+				sleep(10)
+				step(smoke,direction)
+			spawn(smoke.time_to_live*0.75+rand(10,30))
+				if (smoke) smoke.delete()
+				src.total_smoke--
+
+
+/datum/effect/effect/system/smoke_spread/bad
+	smoke_type = /obj/effect/effect/smoke/bad
+
+/datum/effect/effect/system/smoke_spread/sleepy
+	smoke_type = /obj/effect/effect/smoke/sleepy
+
+
+/datum/effect/effect/system/smoke_spread/mustard
+	smoke_type = /obj/effect/effect/smoke/mustard
+/////////////////////////////////////////////
+// Chem smoke
+/////////////////////////////////////////////
+/obj/effect/effect/smoke/chem
+	icon = 'icons/effects/chemsmoke.dmi'
+
+/obj/effect/effect/smoke/chem/New()
+	..()
+	var/datum/reagents/R = new/datum/reagents(500)
+	reagents = R
+	R.my_atom = src
+	return
+
+/obj/effect/effect/smoke/chem/Move()
+	..()
+	for(var/atom/A in view(2, src))
+		if(reagents.has_reagent("radium")||reagents.has_reagent("uranium")||reagents.has_reagent("carbon")||reagents.has_reagent("thermite"))//Prevents unholy radium spam by reducing the number of 'greenglows' down to something reasonable -Sieve
+			if(prob(5))
+				reagents.reaction(A)
+		else
+			reagents.reaction(A)
+
+	return
+
+/obj/effect/effect/smoke/chem/affect(mob/living/carbon/M as mob )
+	reagents.reaction(M)
+
+/datum/effect/effect/system/smoke_spread/chem
+	smoke_type = /obj/effect/effect/smoke/chem
+	var/obj/chemholder
+
+	New()
+		..()
+		chemholder = new/obj()
+		var/datum/reagents/R = new/datum/reagents(500)
+		chemholder.reagents = R
+		R.my_atom = chemholder
+
+	set_up(var/datum/reagents/carry = null, n = 5, c = 0, loca, direct)
+		if(n > 20)
+			n = 20
+		number = n
+		cardinals = c
+		carry.copy_to(chemholder, carry.total_volume)
+
+
+		if(istype(loca, /turf/))
+			location = loca
+		else
+			location = get_turf(loca)
+		if(direct)
+			direction = direct
+
+		var/contained = ""
+		for(var/reagent in carry.reagent_list)
+			contained += " [reagent] "
+		if(contained)
+			contained = "\[[contained]\]"
+		var/area/A = get_area(location)
+
+		var/where = "[A.name] | [location.x], [location.y]"
+		var/whereLink = "<A HREF='?_src_=holder;adminplayerobservecoodjump=1;X=[location.x];Y=[location.y];Z=[location.z]'>[where]</a>"
+
+		if(carry.my_atom.fingerprintslast)
+			var/mob/M = get_mob_by_key(carry.my_atom.fingerprintslast)
+			var/more = ""
+			if(M)
+				more = "(<A HREF='?_src_=holder;adminmoreinfo=\ref[M]'>?</a>)"
+			message_admins("A chemical smoke reaction has taken place in ([whereLink])[contained]. Last associated key is [carry.my_atom.fingerprintslast][more].", 0, 1)
+			log_game("A chemical smoke reaction has taken place in ([where])[contained]. Last associated key is [carry.my_atom.fingerprintslast].")
+		else
+			message_admins("A chemical smoke reaction has taken place in ([whereLink]). No associated key.", 0, 1)
+			log_game("A chemical smoke reaction has taken place in ([where])[contained]. No associated key.")
+
+	start()
+		var/i = 0
+
+		var/color = mix_color_from_reagents(chemholder.reagents.reagent_list)
+
+		for(i=0, i<src.number, i++)
+			if(src.total_smoke > 20)
+				return
+			spawn(0)
+				if(holder)
+					src.location = get_turf(holder)
+				var/obj/effect/effect/smoke/chem/smoke = new /obj/effect/effect/smoke/chem(src.location)
+				src.total_smoke++
+				var/direction = src.direction
+				if(!direction)
+					if(src.cardinals)
+						direction = pick(cardinal)
+					else
+						direction = pick(alldirs)
+
+				if(chemholder.reagents.total_volume != 1) // can't split 1 very well
+					chemholder.reagents.copy_to(smoke, chemholder.reagents.total_volume / number) // copy reagents to each smoke, divide evenly
+
+				if(color)
+					smoke.icon += color // give the smoke color, if it has any to begin with
+				else
+					// if no color, just use the old smoke icon
+					smoke.icon = 'icons/effects/96x96.dmi'
+					smoke.icon_state = "smoke"
+
+				for(i=0, i<pick(0,1,1,1,2,2,2,3), i++)
+					sleep(10)
+					step(smoke,direction)
+				spawn(150+rand(10,30))
+					smoke.delete()
+					src.total_smoke--
+
+/////////////////////////////////////////////
+//////// Attach an Ion trail to any object, that spawns when it moves (like for the jetpack)
+/// just pass in the object to attach it to in set_up
+/// Then do start() to start it and stop() to stop it, obviously
+/// and don't call start() in a loop that will be repeated otherwise it'll get spammed!
+/////////////////////////////////////////////
+
+/obj/effect/effect/ion_trails
+	name = "ion trails"
+	icon_state = "ion_trails"
+	anchored = 1.0
+
+/datum/effect/effect/system/ion_trail_follow
+	var/turf/oldposition
+	var/processing = 1
+	var/on = 1
+
+	set_up(atom/atom)
+		attach(atom)
+		oldposition = get_turf(atom)
+
+	start()
+		if(!src.on)
+			src.on = 1
+			src.processing = 1
+		if(src.processing)
+			src.processing = 0
+			spawn(0)
+				var/turf/T = get_turf(src.holder)
+				if(T != src.oldposition)
+					if(istype(T, /turf/space))
+						var/obj/effect/effect/ion_trails/I = new /obj/effect/effect/ion_trails(src.oldposition)
+						src.oldposition = T
+						I.dir = src.holder.dir
+						flick("ion_fade", I)
+						I.icon_state = "blank"
+						spawn( 20 )
+							I.delete()
+					spawn(2)
+						if(src.on)
+							src.processing = 1
+							src.start()
+				else
+					spawn(2)
+						if(src.on)
+							src.processing = 1
+							src.start()
+
+	proc/stop()
+		src.processing = 0
+		src.on = 0
+
+
+
+
+/////////////////////////////////////////////
+//////// Attach a steam trail to an object (eg. a reacting beaker) that will follow it
+// even if it's carried of thrown.
+/////////////////////////////////////////////
+
+/datum/effect/effect/system/steam_trail_follow
+	var/turf/oldposition
+	var/processing = 1
+	var/on = 1
+
+	set_up(atom/atom)
+		attach(atom)
+		oldposition = get_turf(atom)
+
+	start()
+		if(!src.on)
+			src.on = 1
+			src.processing = 1
+		if(src.processing)
+			src.processing = 0
+			spawn(0)
+				if(src.number < 3)
+					var/obj/effect/effect/steam/I = new /obj/effect/effect/steam(src.oldposition)
+					src.number++
+					src.oldposition = get_turf(holder)
+					I.dir = src.holder.dir
+					spawn(10)
+						I.delete()
+						src.number--
+					spawn(2)
+						if(src.on)
+							src.processing = 1
+							src.start()
+				else
+					spawn(2)
+						if(src.on)
+							src.processing = 1
+							src.start()
+
+	proc/stop()
+		src.processing = 0
+		src.on = 0
+
+
+
+// Foam
+// Similar to smoke, but spreads out more
+// metal foams leave behind a foamed metal wall
+
+/obj/effect/effect/foam
+	name = "foam"
+	icon_state = "foam"
+	opacity = 0
+	anchored = 1
+	density = 0
+	layer = OBJ_LAYER + 0.9
+	mouse_opacity = 0
+	var/amount = 3
+	var/expand = 1
+	animate_movement = 0
+	var/metal = 0
+
+
+/obj/effect/effect/foam/New(loc, var/ismetal=0)
+	..(loc)
+	icon_state = "[ismetal ? "m":""]foam"
+	metal = ismetal
+	playsound(src, 'sound/effects/bubbles2.ogg', 80, 1, -3)
+	spawn(3 + metal*3)
+		process()
+	spawn(120)
+		processing_objects.Remove(src)
+		sleep(30)
+
+		if(metal)
+			var/obj/structure/foamedmetal/M = new(src.loc)
+			M.metal = metal
+			M.updateicon()
+
+		flick("[icon_state]-disolve", src)
+		sleep(5)
+		delete()
+	return
+
+// on delete, transfer any reagents to the floor
+/obj/effect/effect/foam/Del()
+	if(!metal && reagents)
+		for(var/atom/A in oview(0,src))
+			if(A == src)
+				continue
+			reagents.reaction(A, 1, 1)
+	..()
+
+/obj/effect/effect/foam/process()
+	if(--amount < 0)
+		return
+
+
+	for(var/direction in cardinal)
+
+
+		var/turf/T = get_step(src,direction)
+		if(!T)
+			continue
+
+		if(!T.Enter(src))
+			continue
+
+		var/obj/effect/effect/foam/F = locate() in T
+		if(F)
+			continue
+
+		F = new(T, metal)
+		F.amount = amount
+		if(!metal)
+			F.create_reagents(10)
+			if (reagents)
+				for(var/datum/reagent/R in reagents.reagent_list)
+					F.reagents.add_reagent(R.id,1)
+
+// foam disolves when heated
+// except metal foams
+/obj/effect/effect/foam/temperature_expose(datum/gas_mixture/air, exposed_temperature, exposed_volume)
+	if(!metal && prob(max(0, exposed_temperature - 475)))
+		flick("[icon_state]-disolve", src)
+
+		spawn(5)
+			delete()
+
+
+/obj/effect/effect/foam/HasEntered(var/atom/movable/AM)
+	if(metal)
+		return
+
+	if (istype(AM, /mob/living/carbon))
+		var/mob/M =	AM
+		if (istype(M, /mob/living/carbon/human) && (istype(M:shoes, /obj/item/clothing/shoes) && M:shoes.flags&NOSLIP))
+			return
+
+		M.stop_pulling()
+		M << "\blue You slipped on the foam!"
+		playsound(src.loc, 'sound/misc/slip.ogg', 50, 1, -3)
+		M.Stun(5)
+		M.Weaken(2)
+
+
+/datum/effect/effect/system/foam_spread
+	var/amount = 5				// the size of the foam spread.
+	var/list/carried_reagents	// the IDs of reagents present when the foam was mixed
+	var/metal = 0				// 0=foam, 1=metalfoam, 2=ironfoam
+
+
+
+
+	set_up(amt=5, loca, var/datum/reagents/carry = null, var/metalfoam = 0)
+		amount = round(sqrt(amt / 3), 1)
+		if(istype(loca, /turf/))
+			location = loca
+		else
+			location = get_turf(loca)
+
+		carried_reagents = list()
+		metal = metalfoam
+
+
+		// bit of a hack here. Foam carries along any reagent also present in the glass it is mixed
+		// with (defaults to water if none is present). Rather than actually transfer the reagents,
+		// this makes a list of the reagent ids and spawns 1 unit of that reagent when the foam disolves.
+
+
+		if(carry && !metal)
+			for(var/datum/reagent/R in carry.reagent_list)
+				carried_reagents += R.id
+
+	start()
+		spawn(0)
+			var/obj/effect/effect/foam/F = locate() in location
+			if(F)
+				F.amount += amount
+				return
+
+			F = new(src.location, metal)
+			F.amount = amount
+
+			if(!metal)			// don't carry other chemicals if a metal foam
+				F.create_reagents(10)
+
+				if(carried_reagents)
+					for(var/id in carried_reagents)
+						F.reagents.add_reagent(id,1)
+				else
+					F.reagents.add_reagent("water", 1)
+
+// wall formed by metal foams
+// dense and opaque, but easy to break
+
+/obj/structure/foamedmetal
+	icon = 'icons/effects/effects.dmi'
+	icon_state = "metalfoam"
+	density = 1
+	opacity = 1 	// changed in New()
+	anchored = 1
+	name = "foamed metal"
+	desc = "A lightweight foamed metal wall."
+	var/metal = 1		// 1=aluminum, 2=iron
+
+	New()
+		..()
+		update_nearby_tiles(1)
+
+
+
+	Del()
+
+		density = 0
+		update_nearby_tiles(1)
+		..()
+
+	proc/updateicon()
+		if(metal == 1)
+			icon_state = "metalfoam"
+		else
+			icon_state = "ironfoam"
+
+
+	ex_act(severity)
+		del(src)
+
+	blob_act()
+		del(src)
+
+	bullet_act()
+		if(metal==1 || prob(50))
+			del(src)
+
+	attack_paw(var/mob/user)
+		attack_hand(user)
+		return
+
+	attack_hand(var/mob/user)
+		if ((HULK in user.mutations) || (prob(75 - metal*25)))
+			user << "\blue You smash through the metal foam wall."
+			for(var/mob/O in oviewers(user))
+				if ((O.client && !( O.blinded )))
+					O << "\red [user] smashes through the foamed metal."
+
+			del(src)
+		else
+			user << "\blue You hit the metal foam but bounce off it."
+		return
+
+
+	attackby(var/obj/item/I, var/mob/user)
+
+		if (istype(I, /obj/item/weapon/grab))
+			var/obj/item/weapon/grab/G = I
+			G.affecting.loc = src.loc
+			for(var/mob/O in viewers(src))
+				if (O.client)
+					O << "\red [G.assailant] smashes [G.affecting] through the foamed metal wall."
+			del(I)
+			del(src)
+			return
+
+		if(prob(I.force*20 - metal*25))
+			user << "\blue You smash through the foamed metal with \the [I]."
+			for(var/mob/O in oviewers(user))
+				if ((O.client && !( O.blinded )))
+					O << "\red [user] smashes through the foamed metal."
+			del(src)
+		else
+			user << "\blue You hit the metal foam to no effect."
+
+	CanPass(atom/movable/mover, turf/target, height=1.5, air_group = 0)
+		if(air_group) return 0
+		return !density
+
+
+	proc/update_nearby_tiles(need_rebuild)
+		if(!air_master)
+			return 0
+
+		air_master.AddTurfToUpdate(get_turf(src))
+
+		return 1
+
+/datum/effect/effect/system/reagents_explosion
+	var/amount 						// TNT equivalent
+	var/flashing = 0			// does explosion creates flash effect?
+	var/flashing_factor = 0		// factor of how powerful the flash effect relatively to the explosion
+
+	set_up (amt, loc, flash = 0, flash_fact = 0)
+		amount = amt
+		if(istype(loc, /turf/))
+			location = loc
+		else
+			location = get_turf(loc)
+
+		flashing = flash
+		flashing_factor = flash_fact
+
+		return
+
+	start()
+		if (amount <= 2)
+			var/datum/effect/effect/system/spark_spread/s = new /datum/effect/effect/system/spark_spread
+			s.set_up(2, 1, location)
+			s.start()
+
+			for(var/mob/M in viewers(5, location))
+				M << "\red The solution violently explodes."
+			for(var/mob/M in viewers(1, location))
+				if (prob (50 * amount))
+					M << "\red The explosion knocks you down."
+					M.Weaken(rand(1,5))
+			return
+		else
+			var/devastation = -1
+			var/heavy = -1
+			var/light = -1
+			var/flash = -1
+
+			// Clamp all values to MAX_EXPLOSION_RANGE
+			if (round(amount/12) > 0)
+				devastation = min (MAX_EXPLOSION_RANGE, devastation + round(amount/12))
+
+			if (round(amount/6) > 0)
+				heavy = min (MAX_EXPLOSION_RANGE, heavy + round(amount/6))
+
+			if (round(amount/3) > 0)
+				light = min (MAX_EXPLOSION_RANGE, light + round(amount/3))
+
+			if (flash && flashing_factor)
+				flash += (round(amount/4) * flashing_factor)
+
+			for(var/mob/M in viewers(8, location))
+				M << "\red The solution violently explodes."
+
+			explosion(location, devastation, heavy, light, flash)
+
+	proc/holder_damage(var/atom/holder)
+		if(holder)
+			var/dmglevel = 4
+
+			if (round(amount/8) > 0)
+				dmglevel = 1
+			else if (round(amount/4) > 0)
+				dmglevel = 2
+			else if (round(amount/2) > 0)
+				dmglevel = 3
+
+			if(dmglevel<4) holder.ex_act(dmglevel)

code/game/objects/effects/gibs.dm

@@ -0,0 +1,78 @@
+/proc/gibs(atom/location, var/list/viruses, var/datum/dna/MobDNA)		//CARN MARKER
+	new /obj/effect/gibspawner/generic(get_turf(location),viruses,MobDNA)
+
+/proc/hgibs(atom/location, var/list/viruses, var/datum/dna/MobDNA, var/fleshcolor, var/bloodcolor)
+	new /obj/effect/gibspawner/human(get_turf(location),viruses,MobDNA,fleshcolor,bloodcolor)
+
+/proc/xgibs(atom/location, var/list/viruses)
+	new /obj/effect/gibspawner/xeno(get_turf(location),viruses)
+
+/proc/robogibs(atom/location, var/list/viruses)
+	new /obj/effect/gibspawner/robot(get_turf(location),viruses)
+
+/obj/effect/gibspawner
+	var/sparks = 0 //whether sparks spread on Gib()
+	var/virusProb = 20 //the chance for viruses to spread on the gibs
+	var/list/gibtypes = list()
+	var/list/gibamounts = list()
+	var/list/gibdirections = list() //of lists
+	var/fleshcolor //Used for gibbed humans.
+	var/bloodcolor //Used for gibbed humans.
+
+	New(location, var/list/viruses, var/datum/dna/MobDNA, var/fleshcolor, var/bloodcolor)
+		..()
+
+		if(fleshcolor) src.fleshcolor = fleshcolor
+		if(bloodcolor) src.bloodcolor = bloodcolor
+
+		if(istype(loc,/turf)) //basically if a badmin spawns it
+			Gib(loc,viruses,MobDNA)
+
+	proc/Gib(atom/location, var/list/viruses = list(), var/datum/dna/MobDNA = null)
+		if(gibtypes.len != gibamounts.len || gibamounts.len != gibdirections.len)
+			world << "\red Gib list length mismatch!"
+			return
+
+		var/obj/effect/decal/cleanable/blood/gibs/gib = null
+		for(var/datum/disease/D in viruses)
+			if(D.spread_type == SPECIAL)
+				del(D)
+
+		if(sparks)
+			var/datum/effect/effect/system/spark_spread/s = new /datum/effect/effect/system/spark_spread
+			s.set_up(2, 1, location)
+			s.start()
+
+		for(var/i = 1, i<= gibtypes.len, i++)
+			if(gibamounts[i])
+				for(var/j = 1, j<= gibamounts[i], j++)
+					var/gibType = gibtypes[i]
+					gib = new gibType(location)
+
+					// Apply human species colouration to masks.
+					if(fleshcolor)
+						gib.fleshcolor = fleshcolor
+					if(bloodcolor)
+						gib.basecolor = bloodcolor
+
+					gib.update_icon()
+
+					if(viruses.len > 0)
+						for(var/datum/disease/D in viruses)
+							if(prob(virusProb))
+								var/datum/disease/viruus = D.Copy(1)
+								gib.viruses += viruus
+								viruus.holder = gib
+
+					gib.blood_DNA = list()
+					if(MobDNA)
+						gib.blood_DNA[MobDNA.unique_enzymes] = MobDNA.b_type
+					else if(istype(src, /obj/effect/gibspawner/xeno))
+						gib.blood_DNA["UNKNOWN DNA"] = "X*"
+					else if(istype(src, /obj/effect/gibspawner/human)) // Probably a monkey
+						gib.blood_DNA["Non-human DNA"] = "A+"
+					var/list/directions = gibdirections[i]
+					if(directions.len)
+						gib.streak(directions)
+
+		del(src)

code/game/objects/effects/glowshroom.dm

@@ -0,0 +1,164 @@
+//separate dm since hydro is getting bloated already
+
+/obj/effect/glowshroom
+	name = "glowshroom"
+	anchored = 1
+	opacity = 0
+	density = 0
+	icon = 'icons/obj/lighting.dmi'
+	icon_state = "glowshroomf"
+	layer = 2.1
+	var/endurance = 30
+	var/potency = 30
+	var/delay = 1200
+	var/floor = 0
+	var/yield = 3
+	var/spreadChance = 40
+	var/spreadIntoAdjacentChance = 60
+	var/evolveChance = 2
+	var/lastTick = 0
+	var/spreaded = 1
+
+/obj/effect/glowshroom/single
+	spreadChance = 0
+
+/obj/effect/glowshroom/New()
+
+	..()
+
+	dir = CalcDir()
+
+	if(!floor)
+		switch(dir) //offset to make it be on the wall rather than on the floor
+			if(NORTH)
+				pixel_y = 32
+			if(SOUTH)
+				pixel_y = -32
+			if(EAST)
+				pixel_x = 32
+			if(WEST)
+				pixel_x = -32
+		icon_state = "glowshroom[rand(1,3)]"
+	else //if on the floor, glowshroom on-floor sprite
+		icon_state = "glowshroomf"
+
+	processing_objects += src
+
+	SetLuminosity(round(potency/10))
+	lastTick = world.timeofday
+
+/obj/effect/glowshroom/Del()
+	processing_objects -= src
+	..()
+
+/obj/effect/glowshroom/process()
+	if(!spreaded)
+		return
+
+	if(((world.timeofday - lastTick) > delay) || ((world.timeofday - lastTick) < 0))
+		lastTick = world.timeofday
+		spreaded = 0
+
+		for(var/i=1,i<=yield,i++)
+			if(prob(spreadChance))
+				var/list/possibleLocs = list()
+				var/spreadsIntoAdjacent = 0
+
+				if(prob(spreadIntoAdjacentChance))
+					spreadsIntoAdjacent = 1
+
+				for(var/turf/simulated/floor/plating/airless/asteroid/earth in view(3,src))
+					if(spreadsIntoAdjacent || !locate(/obj/effect/glowshroom) in view(1,earth))
+						possibleLocs += earth
+
+				if(!possibleLocs.len)
+					break
+
+				var/turf/newLoc = pick(possibleLocs)
+
+				var/shroomCount = 0 //hacky
+				var/placeCount = 1
+				for(var/obj/effect/glowshroom/shroom in newLoc)
+					shroomCount++
+				for(var/wallDir in cardinal)
+					var/turf/isWall = get_step(newLoc,wallDir)
+					if(isWall.density)
+						placeCount++
+				if(shroomCount >= placeCount)
+					continue
+
+				var/obj/effect/glowshroom/child = new /obj/effect/glowshroom(newLoc)
+				child.potency = potency
+				child.yield = yield
+				child.delay = delay
+				child.endurance = endurance
+
+				spreaded++
+
+		if(prob(evolveChance)) //very low chance to evolve on its own
+			potency += rand(4,6)
+
+/obj/effect/glowshroom/proc/CalcDir(turf/location = loc)
+	set background = 1
+	var/direction = 16
+
+	for(var/wallDir in cardinal)
+		var/turf/newTurf = get_step(location,wallDir)
+		if(newTurf.density)
+			direction |= wallDir
+
+	for(var/obj/effect/glowshroom/shroom in location)
+		if(shroom == src)
+			continue
+		if(shroom.floor) //special
+			direction &= ~16
+		else
+			direction &= ~shroom.dir
+
+	var/list/dirList = list()
+
+	for(var/i=1,i<=16,i <<= 1)
+		if(direction & i)
+			dirList += i
+
+	if(dirList.len)
+		var/newDir = pick(dirList)
+		if(newDir == 16)
+			floor = 1
+			newDir = 1
+		return newDir
+
+	floor = 1
+	return 1
+
+/obj/effect/glowshroom/attackby(obj/item/weapon/W as obj, mob/user as mob)
+	..()
+
+	endurance -= W.force
+
+	CheckEndurance()
+
+/obj/effect/glowshroom/ex_act(severity)
+	switch(severity)
+		if(1.0)
+			del(src)
+			return
+		if(2.0)
+			if (prob(50))
+				del(src)
+				return
+		if(3.0)
+			if (prob(5))
+				del(src)
+				return
+		else
+	return
+
+/obj/effect/glowshroom/temperature_expose(datum/gas_mixture/air, exposed_temperature, exposed_volume)
+	if(exposed_temperature > 300)
+		endurance -= 5
+		CheckEndurance()
+
+/obj/effect/glowshroom/proc/CheckEndurance()
+	if(endurance <= 0)
+		del(src)

code/game/objects/effects/landmarks.dm

@@ -0,0 +1,238 @@
+/obj/effect/landmark
+	name = "landmark"
+	icon = 'icons/mob/screen1.dmi'
+	icon_state = "x2"
+	anchored = 1.0
+	unacidable = 1
+
+/obj/effect/landmark/New()
+
+	..()
+	tag = text("landmark*[]", name)
+	invisibility = 101
+
+	switch(name)			//some of these are probably obsolete
+		if("shuttle")
+			shuttle_z = z
+			del(src)
+
+		if("airtunnel_stop")
+			airtunnel_stop = x
+
+		if("airtunnel_start")
+			airtunnel_start = x
+
+		if("airtunnel_bottom")
+			airtunnel_bottom = y
+
+		if("monkey")
+			monkeystart += loc
+			del(src)
+		if("start")
+			newplayer_start += loc
+			del(src)
+
+		if("wizard")
+			wizardstart += loc
+			del(src)
+
+		if("JoinLate")
+			latejoin += loc
+			del(src)
+
+		//prisoners
+		if("prisonwarp")
+			prisonwarp += loc
+			del(src)
+	//	if("mazewarp")
+	//		mazewarp += loc
+		if("Holding Facility")
+			holdingfacility += loc
+		if("tdome1")
+			tdome1	+= loc
+		if("tdome2")
+			tdome2 += loc
+		if("tdomeadmin")
+			tdomeadmin	+= loc
+		if("tdomeobserve")
+			tdomeobserve += loc
+		//not prisoners
+		if("prisonsecuritywarp")
+			prisonsecuritywarp += loc
+			del(src)
+
+		if("blobstart")
+			blobstart += loc
+			del(src)
+
+		if("xeno_spawn")
+			xeno_spawn += loc
+			del(src)
+
+		if("ninjastart")
+			ninjastart += loc
+			del(src)
+
+	landmarks_list += src
+	return 1
+
+/obj/effect/landmark/Del()
+	landmarks_list -= src
+	..()
+
+/obj/effect/landmark/start
+	name = "start"
+	icon = 'icons/mob/screen1.dmi'
+	icon_state = "x"
+	anchored = 1.0
+
+/obj/effect/landmark/start/New()
+	..()
+	tag = "start*[name]"
+	invisibility = 101
+
+	return 1
+
+//Costume spawner landmarks
+
+/obj/effect/landmark/costume/New() //costume spawner, selects a random subclass and disappears
+
+	var/list/options = typesof(/obj/effect/landmark/costume)
+	var/PICK= options[rand(1,options.len)]
+	new PICK(src.loc)
+	del(src)
+
+//SUBCLASSES.  Spawn a bunch of items and disappear likewise
+/obj/effect/landmark/costume/chicken/New()
+	new /obj/item/clothing/suit/chickensuit(src.loc)
+	new /obj/item/clothing/head/chicken(src.loc)
+	new /obj/item/weapon/reagent_containers/food/snacks/egg(src.loc)
+	del(src)
+
+/obj/effect/landmark/costume/gladiator/New()
+	new /obj/item/clothing/under/gladiator(src.loc)
+	new /obj/item/clothing/head/helmet/gladiator(src.loc)
+	del(src)
+
+/obj/effect/landmark/costume/madscientist/New()
+	new /obj/item/clothing/under/gimmick/rank/captain/suit(src.loc)
+	new /obj/item/clothing/head/flatcap(src.loc)
+	new /obj/item/clothing/suit/storage/labcoat/mad(src.loc)
+	new /obj/item/clothing/glasses/gglasses(src.loc)
+	del(src)
+
+/obj/effect/landmark/costume/elpresidente/New()
+	new /obj/item/clothing/under/gimmick/rank/captain/suit(src.loc)
+	new /obj/item/clothing/head/flatcap(src.loc)
+	new /obj/item/clothing/mask/cigarette/cigar/havana(src.loc)
+	new /obj/item/clothing/shoes/jackboots(src.loc)
+	del(src)
+
+/obj/effect/landmark/costume/nyangirl/New()
+	new /obj/item/clothing/under/schoolgirl(src.loc)
+	new /obj/item/clothing/head/kitty(src.loc)
+	del(src)
+
+/obj/effect/landmark/costume/maid/New()
+	new /obj/item/clothing/under/blackskirt(src.loc)
+	var/CHOICE = pick( /obj/item/clothing/head/beret , /obj/item/clothing/head/rabbitears )
+	new CHOICE(src.loc)
+	new /obj/item/clothing/glasses/sunglasses/blindfold(src.loc)
+	del(src)
+
+/obj/effect/landmark/costume/butler/New()
+	new /obj/item/clothing/suit/wcoat(src.loc)
+	new /obj/item/clothing/under/suit_jacket(src.loc)
+	new /obj/item/clothing/head/that(src.loc)
+	del(src)
+
+/obj/effect/landmark/costume/scratch/New()
+	new /obj/item/clothing/gloves/white(src.loc)
+	new /obj/item/clothing/shoes/white(src.loc)
+	new /obj/item/clothing/under/scratch(src.loc)
+	if (prob(30))
+		new /obj/item/clothing/head/cueball(src.loc)
+	del(src)
+
+/obj/effect/landmark/costume/highlander/New()
+	new /obj/item/clothing/under/kilt(src.loc)
+	new /obj/item/clothing/head/beret(src.loc)
+	del(src)
+
+/obj/effect/landmark/costume/prig/New()
+	new /obj/item/clothing/suit/wcoat(src.loc)
+	new /obj/item/clothing/glasses/monocle(src.loc)
+	var/CHOICE= pick( /obj/item/clothing/head/bowler, /obj/item/clothing/head/that)
+	new CHOICE(src.loc)
+	new /obj/item/clothing/shoes/black(src.loc)
+	new /obj/item/weapon/cane(src.loc)
+	new /obj/item/clothing/under/sl_suit(src.loc)
+	new /obj/item/clothing/mask/fakemoustache(src.loc)
+	del(src)
+
+/obj/effect/landmark/costume/plaguedoctor/New()
+	new /obj/item/clothing/suit/bio_suit/plaguedoctorsuit(src.loc)
+	new /obj/item/clothing/head/plaguedoctorhat(src.loc)
+	del(src)
+
+/obj/effect/landmark/costume/nightowl/New()
+	new /obj/item/clothing/under/owl(src.loc)
+	new /obj/item/clothing/mask/gas/owl_mask(src.loc)
+	del(src)
+
+/obj/effect/landmark/costume/waiter/New()
+	new /obj/item/clothing/under/waiter(src.loc)
+	var/CHOICE= pick( /obj/item/clothing/head/kitty, /obj/item/clothing/head/rabbitears)
+	new CHOICE(src.loc)
+	new /obj/item/clothing/suit/apron(src.loc)
+	del(src)
+
+/obj/effect/landmark/costume/pirate/New()
+	new /obj/item/clothing/under/pirate(src.loc)
+	new /obj/item/clothing/suit/pirate(src.loc)
+	var/CHOICE = pick( /obj/item/clothing/head/pirate , /obj/item/clothing/head/bandana )
+	new CHOICE(src.loc)
+	new /obj/item/clothing/glasses/eyepatch(src.loc)
+	del(src)
+
+/obj/effect/landmark/costume/commie/New()
+	new /obj/item/clothing/under/soviet(src.loc)
+	new /obj/item/clothing/head/ushanka(src.loc)
+	del(src)
+
+/obj/effect/landmark/costume/imperium_monk/New()
+	new /obj/item/clothing/suit/imperium_monk(src.loc)
+	if (prob(25))
+		new /obj/item/clothing/mask/gas/cyborg(src.loc)
+	del(src)
+
+/obj/effect/landmark/costume/holiday_priest/New()
+	new /obj/item/clothing/suit/holidaypriest(src.loc)
+	del(src)
+
+/obj/effect/landmark/costume/marisawizard/fake/New()
+	new /obj/item/clothing/head/wizard/marisa/fake(src.loc)
+	new/obj/item/clothing/suit/wizrobe/marisa/fake(src.loc)
+	del(src)
+
+/obj/effect/landmark/costume/cutewitch/New()
+	new /obj/item/clothing/under/sundress(src.loc)
+	new /obj/item/clothing/head/witchwig(src.loc)
+	new /obj/item/weapon/staff/broom(src.loc)
+	del(src)
+
+/obj/effect/landmark/costume/fakewizard/New()
+	new /obj/item/clothing/suit/wizrobe/fake(src.loc)
+	new /obj/item/clothing/head/wizard/fake(src.loc)
+	new /obj/item/weapon/staff/(src.loc)
+	del(src)
+
+/obj/effect/landmark/costume/sexyclown/New()
+	new /obj/item/clothing/mask/gas/sexyclown(src.loc)
+	new /obj/item/clothing/under/sexyclown(src.loc)
+	del(src)
+
+/obj/effect/landmark/costume/sexymime/New()
+	new /obj/item/clothing/mask/gas/sexymime(src.loc)
+	new /obj/item/clothing/under/sexymime(src.loc)
+	del(src)

code/game/objects/effects/manifest.dm

@@ -0,0 +1,21 @@
+/obj/effect/manifest
+	name = "manifest"
+	icon = 'icons/mob/screen1.dmi'
+	icon_state = "x"
+	unacidable = 1//Just to be sure.
+
+/obj/effect/manifest/New()
+
+	src.invisibility = 101
+	return
+
+/obj/effect/manifest/proc/manifest()
+	var/dat = "<B>Crew Manifest</B>:<BR>"
+	for(var/mob/living/carbon/human/M in mob_list)
+		dat += text("    <B>[]</B> -  []<BR>", M.name, M.get_assignment())
+	var/obj/item/weapon/paper/P = new /obj/item/weapon/paper( src.loc )
+	P.info = dat
+	P.name = "paper- 'Crew Manifest'"
+	//SN src = null
+	del(src)
+	return

code/game/objects/effects/mines.dm

@@ -0,0 +1,117 @@
+/obj/effect/mine
+	name = "Mine"
+	desc = "I Better stay away from that thing."
+	density = 1
+	anchored = 1
+	layer = 3
+	icon = 'icons/obj/weapons.dmi'
+	icon_state = "uglymine"
+	var/triggerproc = "explode" //name of the proc thats called when the mine is triggered
+	var/triggered = 0
+
+/obj/effect/mine/New()
+	icon_state = "uglyminearmed"
+
+/obj/effect/mine/HasEntered(AM as mob|obj)
+	Bumped(AM)
+
+/obj/effect/mine/Bumped(mob/M as mob|obj)
+
+	if(triggered) return
+
+	if(istype(M, /mob/living/carbon/human) || istype(M, /mob/living/carbon/monkey))
+		for(var/mob/O in viewers(world.view, src.loc))
+			O << "<font color='red'>[M] triggered the \icon[src] [src]</font>"
+		triggered = 1
+		call(src,triggerproc)(M)
+
+/obj/effect/mine/proc/triggerrad(obj)
+	var/datum/effect/effect/system/spark_spread/s = new /datum/effect/effect/system/spark_spread
+	s.set_up(3, 1, src)
+	s.start()
+	obj:radiation += 50
+	randmutb(obj)
+	domutcheck(obj,null)
+	spawn(0)
+		del(src)
+
+/obj/effect/mine/proc/triggerstun(obj)
+	if(ismob(obj))
+		var/mob/M = obj
+		M.Stun(30)
+	var/datum/effect/effect/system/spark_spread/s = new /datum/effect/effect/system/spark_spread
+	s.set_up(3, 1, src)
+	s.start()
+	spawn(0)
+		del(src)
+
+/obj/effect/mine/proc/triggern2o(obj)
+	//example: n2o triggerproc
+	//note: im lazy
+
+	for (var/turf/simulated/floor/target in range(1,src))
+		if(!target.blocks_air)
+
+			var/datum/gas_mixture/payload = new
+			var/datum/gas/sleeping_agent/trace_gas = new
+
+			trace_gas.moles = 30
+			payload += trace_gas
+
+			target.zone.air.merge(payload)
+
+	spawn(0)
+		del(src)
+
+/obj/effect/mine/proc/triggerplasma(obj)
+	for (var/turf/simulated/floor/target in range(1,src))
+		if(!target.blocks_air)
+
+			var/datum/gas_mixture/payload = new
+
+			payload.toxins = 30
+
+			target.zone.air.merge(payload)
+
+			target.hotspot_expose(1000, CELL_VOLUME)
+
+	spawn(0)
+		del(src)
+
+/obj/effect/mine/proc/triggerkick(obj)
+	var/datum/effect/effect/system/spark_spread/s = new /datum/effect/effect/system/spark_spread
+	s.set_up(3, 1, src)
+	s.start()
+	del(obj:client)
+	spawn(0)
+		del(src)
+
+/obj/effect/mine/proc/explode(obj)
+	explosion(loc, 0, 1, 2, 3)
+	spawn(0)
+		del(src)
+
+/obj/effect/mine/dnascramble
+	name = "Radiation Mine"
+	icon_state = "uglymine"
+	triggerproc = "triggerrad"
+
+/obj/effect/mine/plasma
+	name = "Plasma Mine"
+	icon_state = "uglymine"
+	triggerproc = "triggerplasma"
+
+/obj/effect/mine/kick
+	name = "Kick Mine"
+	icon_state = "uglymine"
+	triggerproc = "triggerkick"
+
+/obj/effect/mine/n2o
+	name = "N2O Mine"
+	icon_state = "uglymine"
+	triggerproc = "triggern2o"
+
+/obj/effect/mine/stun
+	name = "Stun Mine"
+	icon_state = "uglymine"
+	triggerproc = "triggerstun"

code/game/objects/effects/misc.dm

@@ -0,0 +1,8 @@
+//The effect when you wrap a dead body in gift wrap
+/obj/effect/spresent
+	name = "strange present"
+	desc = "It's a ... present?"
+	icon = 'icons/obj/items.dmi'
+	icon_state = "strangepresent"
+	density = 1
+	anchored = 0

code/game/objects/effects/overlays.dm

@@ -0,0 +1,34 @@
+/obj/effect/overlay
+	name = "overlay"
+	unacidable = 1
+	var/i_attached//Added for possible image attachments to objects. For hallucinations and the like.
+
+/obj/effect/overlay/beam//Not actually a projectile, just an effect.
+	name="beam"
+	icon='icons/effects/beam.dmi'
+	icon_state="b_beam"
+	var/tmp/atom/BeamSource
+	New()
+		..()
+		spawn(10) del src
+
+/obj/effect/overlay/palmtree_r
+	name = "Palm tree"
+	icon = 'icons/misc/beach2.dmi'
+	icon_state = "palm1"
+	density = 1
+	layer = 5
+	anchored = 1
+
+/obj/effect/overlay/palmtree_l
+	name = "Palm tree"
+	icon = 'icons/misc/beach2.dmi'
+	icon_state = "palm2"
+	density = 1
+	layer = 5
+	anchored = 1
+
+/obj/effect/overlay/coconut
+	name = "Coconuts"
+	icon = 'icons/misc/beach.dmi'
+	icon_state = "coconuts"

code/game/objects/effects/portals.dm

@@ -0,0 +1,47 @@
+/obj/effect/portal
+	name = "portal"
+	desc = "Looks unstable. Best to test it with the clown."
+	icon = 'icons/obj/stationobjs.dmi'
+	icon_state = "portal"
+	density = 1
+	unacidable = 1//Can't destroy energy portals.
+	var/failchance = 5
+	var/obj/item/target = null
+	var/creator = null
+	anchored = 1.0
+
+/obj/effect/portal/Bumped(mob/M as mob|obj)
+	spawn(0)
+		src.teleport(M)
+		return
+	return
+
+/obj/effect/portal/HasEntered(AM as mob|obj)
+	spawn(0)
+		src.teleport(AM)
+		return
+	return
+
+/obj/effect/portal/New()
+	spawn(300)
+		del(src)
+		return
+	return
+
+/obj/effect/portal/proc/teleport(atom/movable/M as mob|obj)
+	if(istype(M, /obj/effect)) //sparks don't teleport
+		return
+	if (M.anchored&&istype(M, /obj/mecha))
+		return
+	if (icon_state == "portal1")
+		return
+	if (!( target ))
+		del(src)
+		return
+	if (istype(M, /atom/movable))
+		if(prob(failchance)) //oh dear a problem, put em in deep space
+			src.icon_state = "portal1"
+			do_teleport(M, locate(rand(5, world.maxx - 5), rand(5, world.maxy -5), 3), 0)
+		else
+			do_teleport(M, target, 1) ///You will appear adjacent to the beacon
+

code/game/objects/effects/spawners/bombspawner.dm

@@ -0,0 +1,174 @@
+/* The old single tank bombs that dont really work anymore
+/obj/effect/spawner/bomb
+	name = "bomb"
+	icon = 'icons/mob/screen1.dmi'
+	icon_state = "x"
+	var/btype = 0  //0 = radio, 1= prox, 2=time
+	var/explosive = 1	// 0= firebomb
+	var/btemp = 500	// bomb temperature (degC)
+	var/active = 0
+
+/obj/effect/spawner/bomb/radio
+	btype = 0
+
+/obj/effect/spawner/bomb/proximity
+	btype = 1
+
+/obj/effect/spawner/bomb/timer
+	btype = 2
+
+/obj/effect/spawner/bomb/timer/syndicate
+	btemp = 450
+
+/obj/effect/spawner/bomb/suicide
+	btype = 3
+
+/obj/effect/spawner/bomb/New()
+	..()
+
+	switch (src.btype)
+		// radio
+		if (0)
+			var/obj/item/assembly/r_i_ptank/R = new /obj/item/assembly/r_i_ptank(src.loc)
+			var/obj/item/weapon/tank/plasma/p3 = new /obj/item/weapon/tank/plasma(R)
+			var/obj/item/device/radio/signaler/p1 = new /obj/item/device/radio/signaler(R)
+			var/obj/item/device/igniter/p2 = new /obj/item/device/igniter(R)
+			R.part1 = p1
+			R.part2 = p2
+			R.part3 = p3
+			p1.master = R
+			p2.master = R
+			p3.master = R
+			R.status = explosive
+			p1.b_stat = 0
+			p2.secured = 1
+			p3.air_contents.temperature = btemp + T0C
+
+		// proximity
+		if (1)
+			var/obj/item/assembly/m_i_ptank/R = new /obj/item/assembly/m_i_ptank(src.loc)
+			var/obj/item/weapon/tank/plasma/p3 = new /obj/item/weapon/tank/plasma(R)
+			var/obj/item/device/prox_sensor/p1 = new /obj/item/device/prox_sensor(R)
+			var/obj/item/device/igniter/p2 = new /obj/item/device/igniter(R)
+			R.part1 = p1
+			R.part2 = p2
+			R.part3 = p3
+			p1.master = R
+			p2.master = R
+			p3.master = R
+			R.status = explosive
+
+			p3.air_contents.temperature = btemp + T0C
+			p2.secured = 1
+
+			if(src.active)
+				R.part1.secured = 1
+				R.part1.icon_state = text("motion[]", 1)
+				R.c_state(1, src)
+
+		// timer
+		if (2)
+			var/obj/item/assembly/t_i_ptank/R = new /obj/item/assembly/t_i_ptank(src.loc)
+			var/obj/item/weapon/tank/plasma/p3 = new /obj/item/weapon/tank/plasma(R)
+			var/obj/item/device/timer/p1 = new /obj/item/device/timer(R)
+			var/obj/item/device/igniter/p2 = new /obj/item/device/igniter(R)
+			R.part1 = p1
+			R.part2 = p2
+			R.part3 = p3
+			p1.master = R
+			p2.master = R
+			p3.master = R
+			R.status = explosive
+
+			p3.air_contents.temperature = btemp + T0C
+			p2.secured = 1
+		//bombvest
+		if(3)
+			var/obj/item/clothing/suit/armor/a_i_a_ptank/R = new /obj/item/clothing/suit/armor/a_i_a_ptank(src.loc)
+			var/obj/item/weapon/tank/plasma/p4 = new /obj/item/weapon/tank/plasma(R)
+			var/obj/item/device/healthanalyzer/p1 = new /obj/item/device/healthanalyzer(R)
+			var/obj/item/device/igniter/p2 = new /obj/item/device/igniter(R)
+			var/obj/item/clothing/suit/armor/vest/p3 = new /obj/item/clothing/suit/armor/vest(R)
+			R.part1 = p1
+			R.part2 = p2
+			R.part3 = p3
+			R.part4 = p4
+			p1.master = R
+			p2.master = R
+			p3.master = R
+			p4.master = R
+			R.status = explosive
+
+			p4.air_contents.temperature = btemp + T0C
+			p2.secured = 1
+
+	del(src)
+*/
+
+/obj/effect/spawner/newbomb
+	name = "bomb"
+	icon = 'icons/mob/screen1.dmi'
+	icon_state = "x"
+	var/btype = 0 // 0=radio, 1=prox, 2=time
+
+	timer
+		btype = 2
+
+		syndicate
+
+	proximity
+		btype = 1
+
+	radio
+		btype = 0
+
+
+/obj/effect/spawner/newbomb/New()
+	..()
+
+	var/obj/item/device/transfer_valve/V = new(src.loc)
+	var/obj/item/weapon/tank/plasma/PT = new(V)
+	var/obj/item/weapon/tank/oxygen/OT = new(V)
+
+	V.tank_one = PT
+	V.tank_two = OT
+
+	PT.master = V
+	OT.master = V
+
+	PT.air_contents.temperature = PLASMA_FLASHPOINT
+	PT.air_contents.toxins = 3
+	PT.air_contents.carbon_dioxide = 17
+	PT.air_contents.update_values()
+
+	OT.air_contents.temperature = PLASMA_FLASHPOINT
+	OT.air_contents.oxygen = 20
+	OT.air_contents.update_values()
+
+	var/obj/item/device/assembly/S
+
+	switch (src.btype)
+		// radio
+		if (0)
+
+			S = new/obj/item/device/assembly/signaler(V)
+
+		// proximity
+		if (1)
+
+			S = new/obj/item/device/assembly/prox_sensor(V)
+
+		// timer
+		if (2)
+
+			S = new/obj/item/device/assembly/timer(V)
+
+
+	V.attached_device = S
+
+	S.holder = V
+	S.toggle_secure()
+
+	V.update_icon()
+
+	del(src)

code/game/objects/effects/spawners/gibspawner.dm

@@ -0,0 +1,36 @@
+/obj/effect/gibspawner
+	generic
+		gibtypes = list(/obj/effect/decal/cleanable/blood/gibs,/obj/effect/decal/cleanable/blood/gibs,/obj/effect/decal/cleanable/blood/gibs/core)
+		gibamounts = list(2,2,1)
+
+		New()
+			gibdirections = list(list(WEST, NORTHWEST, SOUTHWEST, NORTH),list(EAST, NORTHEAST, SOUTHEAST, SOUTH), list())
+			..()
+
+	human
+		gibtypes = list(/obj/effect/decal/cleanable/blood/gibs,/obj/effect/decal/cleanable/blood/gibs/down,/obj/effect/decal/cleanable/blood/gibs,/obj/effect/decal/cleanable/blood/gibs,/obj/effect/decal/cleanable/blood/gibs,/obj/effect/decal/cleanable/blood/gibs,/obj/effect/decal/cleanable/blood/gibs/core)
+		gibamounts = list(1,1,1,1,1,1,1)
+
+		New()
+			gibdirections = list(list(NORTH, NORTHEAST, NORTHWEST),list(SOUTH, SOUTHEAST, SOUTHWEST),list(WEST, NORTHWEST, SOUTHWEST),list(EAST, NORTHEAST, SOUTHEAST), alldirs, alldirs, list())
+			gibamounts[6] = pick(0,1,2)
+			..()
+
+	xeno
+		gibtypes = list(/obj/effect/decal/cleanable/blood/gibs/xeno/up,/obj/effect/decal/cleanable/blood/gibs/xeno/down,/obj/effect/decal/cleanable/blood/gibs/xeno,/obj/effect/decal/cleanable/blood/gibs/xeno,/obj/effect/decal/cleanable/blood/gibs/xeno/body,/obj/effect/decal/cleanable/blood/gibs/xeno/limb,/obj/effect/decal/cleanable/blood/gibs/xeno/core)
+		gibamounts = list(1,1,1,1,1,1,1)
+
+		New()
+			gibdirections = list(list(NORTH, NORTHEAST, NORTHWEST),list(SOUTH, SOUTHEAST, SOUTHWEST),list(WEST, NORTHWEST, SOUTHWEST),list(EAST, NORTHEAST, SOUTHEAST), alldirs, alldirs, list())
+			gibamounts[6] = pick(0,1,2)
+			..()
+
+	robot
+		sparks = 1
+		gibtypes = list(/obj/effect/decal/cleanable/blood/gibs/robot/up,/obj/effect/decal/cleanable/blood/gibs/robot/down,/obj/effect/decal/cleanable/blood/gibs/robot,/obj/effect/decal/cleanable/blood/gibs/robot,/obj/effect/decal/cleanable/blood/gibs/robot,/obj/effect/decal/cleanable/blood/gibs/robot/limb)
+		gibamounts = list(1,1,1,1,1,1)
+
+		New()
+			gibdirections = list(list(NORTH, NORTHEAST, NORTHWEST),list(SOUTH, SOUTHEAST, SOUTHWEST),list(WEST, NORTHWEST, SOUTHWEST),list(EAST, NORTHEAST, SOUTHEAST), alldirs, alldirs)
+			gibamounts[6] = pick(0,1,2)
+			..()

code/game/objects/effects/spawners/vaultspawner.dm

@@ -0,0 +1,26 @@
+/obj/effect/vaultspawner
+	var/maxX = 6
+	var/maxY = 6
+	var/minX = 2
+	var/minY = 2
+
+/obj/effect/vaultspawner/New(turf/location as turf,lX = minX,uX = maxX,lY = minY,uY = maxY,var/type = null)
+	if(!type)
+		type = pick("sandstone","rock","alien")
+
+	var/lowBoundX = location.x
+	var/lowBoundY = location.y
+
+	var/hiBoundX = location.x + rand(lX,uX)
+	var/hiBoundY = location.y + rand(lY,uY)
+
+	var/z = location.z
+
+	for(var/i = lowBoundX,i<=hiBoundX,i++)
+		for(var/j = lowBoundY,j<=hiBoundY,j++)
+			if(i == lowBoundX || i == hiBoundX || j == lowBoundY || j == hiBoundY)
+				new /turf/simulated/wall/vault(locate(i,j,z),type)
+			else
+				new /turf/simulated/floor/vault(locate(i,j,z),type)
+
+	del(src)

code/game/objects/effects/spiders.dm

@@ -0,0 +1,212 @@
+//generic procs copied from obj/effect/alien
+/obj/effect/spider
+	name = "web"
+	desc = "it's stringy and sticky"
+	icon = 'icons/effects/effects.dmi'
+	anchored = 1
+	density = 0
+	var/health = 15
+
+//similar to weeds, but only barfed out by nurses manually
+/obj/effect/spider/ex_act(severity)
+	switch(severity)
+		if(1.0)
+			del(src)
+		if(2.0)
+			if (prob(50))
+				del(src)
+		if(3.0)
+			if (prob(5))
+				del(src)
+	return
+
+/obj/effect/spider/attackby(var/obj/item/weapon/W, var/mob/user)
+	if(W.attack_verb.len)
+		visible_message("\red <B>\The [src] have been [pick(W.attack_verb)] with \the [W][(user ? " by [user]." : ".")]")
+	else
+		visible_message("\red <B>\The [src] have been attacked with \the [W][(user ? " by [user]." : ".")]")
+
+	var/damage = W.force / 4.0
+
+	if(istype(W, /obj/item/weapon/weldingtool))
+		var/obj/item/weapon/weldingtool/WT = W
+
+		if(WT.remove_fuel(0, user))
+			damage = 15
+			playsound(loc, 'sound/items/Welder.ogg', 100, 1)
+
+	health -= damage
+	healthcheck()
+
+/obj/effect/spider/bullet_act(var/obj/item/projectile/Proj)
+	..()
+	health -= Proj.damage
+	healthcheck()
+
+/obj/effect/spider/proc/healthcheck()
+	if(health <= 0)
+		del(src)
+
+/obj/effect/spider/temperature_expose(datum/gas_mixture/air, exposed_temperature, exposed_volume)
+	if(exposed_temperature > 300)
+		health -= 5
+		healthcheck()
+
+/obj/effect/spider/stickyweb
+	icon_state = "stickyweb1"
+	New()
+		if(prob(50))
+			icon_state = "stickyweb2"
+
+/obj/effect/spider/stickyweb/CanPass(atom/movable/mover, turf/target, height=0, air_group=0)
+	if(air_group || (height==0)) return 1
+	if(istype(mover, /mob/living/simple_animal/hostile/giant_spider))
+		return 1
+	else if(istype(mover, /mob/living))
+		if(prob(50))
+			mover << "\red You get stuck in \the [src] for a moment."
+			return 0
+	else if(istype(mover, /obj/item/projectile))
+		return prob(30)
+	return 1
+
+/obj/effect/spider/eggcluster
+	name = "egg cluster"
+	desc = "They seem to pulse slightly with an inner life"
+	icon_state = "eggs"
+	var/amount_grown = 0
+	New()
+		pixel_x = rand(3,-3)
+		pixel_y = rand(3,-3)
+		processing_objects.Add(src)
+
+/obj/effect/spider/eggcluster/process()
+	amount_grown += rand(0,2)
+	if(amount_grown >= 100)
+		var/num = rand(6,24)
+		for(var/i=0, i<num, i++)
+			new /obj/effect/spider/spiderling(src.loc)
+		del(src)
+
+/obj/effect/spider/spiderling
+	name = "spiderling"
+	desc = "It never stays still for long."
+	icon_state = "spiderling"
+	anchored = 0
+	layer = 2.7
+	health = 3
+	var/amount_grown = -1
+	var/obj/machinery/atmospherics/unary/vent_pump/entry_vent
+	var/travelling_in_vent = 0
+	New()
+		pixel_x = rand(6,-6)
+		pixel_y = rand(6,-6)
+		processing_objects.Add(src)
+		//50% chance to grow up
+		if(prob(50))
+			amount_grown = 1
+
+/obj/effect/spider/spiderling/Bump(atom/user)
+	if(istype(user, /obj/structure/table))
+		src.loc = user.loc
+	else
+		..()
+
+/obj/effect/spider/spiderling/proc/die()
+	visible_message("<span class='alert'>[src] dies!</span>")
+	new /obj/effect/decal/cleanable/spiderling_remains(src.loc)
+	del(src)
+
+/obj/effect/spider/spiderling/healthcheck()
+	if(health <= 0)
+		die()
+
+/obj/effect/spider/spiderling/process()
+	if(travelling_in_vent)
+		if(istype(src.loc, /turf))
+			travelling_in_vent = 0
+			entry_vent = null
+	else if(entry_vent)
+		if(get_dist(src, entry_vent) <= 1)
+			if(entry_vent.network && entry_vent.network.normal_members.len)
+				var/list/vents = list()
+				for(var/obj/machinery/atmospherics/unary/vent_pump/temp_vent in entry_vent.network.normal_members)
+					vents.Add(temp_vent)
+				if(!vents.len)
+					entry_vent = null
+					return
+				var/obj/machinery/atmospherics/unary/vent_pump/exit_vent = pick(vents)
+				/*if(prob(50))
+					src.visible_message("<B>[src] scrambles into the ventillation ducts!</B>")*/
+
+				spawn(rand(20,60))
+					loc = exit_vent
+					var/travel_time = round(get_dist(loc, exit_vent.loc) / 2)
+					spawn(travel_time)
+
+						if(!exit_vent || exit_vent.welded)
+							loc = entry_vent
+							entry_vent = null
+							return
+
+						if(prob(50))
+							src.visible_message("\blue You hear something squeezing through the ventilation ducts.",2)
+						sleep(travel_time)
+
+						if(!exit_vent || exit_vent.welded)
+							loc = entry_vent
+							entry_vent = null
+							return
+						loc = exit_vent.loc
+						entry_vent = null
+						var/area/new_area = get_area(loc)
+						if(new_area)
+							new_area.Entered(src)
+			else
+				entry_vent = null
+	//=================
+
+	else if(prob(25))
+		var/list/nearby = oview(5, src)
+		if(nearby.len)
+			var/target_atom = pick(nearby)
+			walk_to(src, target_atom, 5)
+			if(prob(25))
+				src.visible_message("\blue \the [src] skitters[pick(" away"," around","")].")
+	else if(prob(5))
+		//ventcrawl!
+		for(var/obj/machinery/atmospherics/unary/vent_pump/v in view(7,src))
+			if(!v.welded)
+				entry_vent = v
+				walk_to(src, entry_vent, 5)
+				break
+
+	if(prob(1))
+		src.visible_message("\blue \the [src] chitters.")
+	if(isturf(loc) && amount_grown > 0)
+		amount_grown += rand(0,2)
+		if(amount_grown >= 100)
+			var/spawn_type = pick(typesof(/mob/living/simple_animal/hostile/giant_spider))
+			new spawn_type(src.loc)
+			del(src)
+
+/obj/effect/decal/cleanable/spiderling_remains
+	name = "spiderling remains"
+	desc = "Green squishy mess."
+	icon = 'icons/effects/effects.dmi'
+	icon_state = "greenshatter"
+
+/obj/effect/spider/cocoon
+	name = "cocoon"
+	desc = "Something wrapped in silky spider web"
+	icon_state = "cocoon1"
+	health = 60
+
+	New()
+		icon_state = pick("cocoon1","cocoon2","cocoon3")
+
+/obj/effect/spider/cocoon/Del()
+	src.visible_message("\red \the [src] splits open.")
+	for(var/atom/movable/A in contents)
+		A.loc = src.loc
+	..()

code/game/objects/effects/step_triggers.dm

@@ -0,0 +1,117 @@
+/* Simple object type, calls a proc when "stepped" on by something */
+
+/obj/effect/step_trigger
+	var/affect_ghosts = 0
+	var/stopper = 1 // stops throwers
+	invisibility = 101 // nope cant see this shit
+	anchored = 1
+
+/obj/effect/step_trigger/proc/Trigger(var/atom/movable/A)
+	return 0
+
+/obj/effect/step_trigger/HasEntered(H as mob|obj)
+	..()
+	if(!H)
+		return
+	if(istype(H, /mob/dead/observer) && !affect_ghosts)
+		return
+	Trigger(H)
+
+
+
+/* Tosses things in a certain direction */
+
+/obj/effect/step_trigger/thrower
+	var/direction = SOUTH // the direction of throw
+	var/tiles = 3	// if 0: forever until atom hits a stopper
+	var/immobilize = 1 // if nonzero: prevents mobs from moving while they're being flung
+	var/speed = 1	// delay of movement
+	var/facedir = 0 // if 1: atom faces the direction of movement
+	var/nostop = 0 // if 1: will only be stopped by teleporters
+	var/list/affecting = list()
+
+	Trigger(var/atom/A)
+		if(!A || !istype(A, /atom/movable))
+			return
+		var/atom/movable/AM = A
+		var/curtiles = 0
+		var/stopthrow = 0
+		for(var/obj/effect/step_trigger/thrower/T in orange(2, src))
+			if(AM in T.affecting)
+				return
+
+		if(ismob(AM))
+			var/mob/M = AM
+			if(immobilize)
+				M.canmove = 0
+
+		affecting.Add(AM)
+		while(AM && !stopthrow)
+			if(tiles)
+				if(curtiles >= tiles)
+					break
+			if(AM.z != src.z)
+				break
+
+			curtiles++
+
+			sleep(speed)
+
+			// Calculate if we should stop the process
+			if(!nostop)
+				for(var/obj/effect/step_trigger/T in get_step(AM, direction))
+					if(T.stopper && T != src)
+						stopthrow = 1
+			else
+				for(var/obj/effect/step_trigger/teleporter/T in get_step(AM, direction))
+					if(T.stopper)
+						stopthrow = 1
+
+			if(AM)
+				var/predir = AM.dir
+				step(AM, direction)
+				if(!facedir)
+					AM.dir = predir
+
+
+
+		affecting.Remove(AM)
+
+		if(ismob(AM))
+			var/mob/M = AM
+			if(immobilize)
+				M.canmove = 1
+
+/* Stops things thrown by a thrower, doesn't do anything */
+
+/obj/effect/step_trigger/stopper
+
+/* Instant teleporter */
+
+/obj/effect/step_trigger/teleporter
+	var/teleport_x = 0	// teleportation coordinates (if one is null, then no teleport!)
+	var/teleport_y = 0
+	var/teleport_z = 0
+
+	Trigger(var/atom/movable/A)
+		if(teleport_x && teleport_y && teleport_z)
+
+			A.x = teleport_x
+			A.y = teleport_y
+			A.z = teleport_z
+
+/* Random teleporter, teleports atoms to locations ranging from teleport_x - teleport_x_offset, etc */
+
+/obj/effect/step_trigger/teleporter/random
+	var/teleport_x_offset = 0
+	var/teleport_y_offset = 0
+	var/teleport_z_offset = 0
+
+	Trigger(var/atom/movable/A)
+		if(teleport_x && teleport_y && teleport_z)
+			if(teleport_x_offset && teleport_y_offset && teleport_z_offset)
+
+				A.x = rand(teleport_x, teleport_x_offset)
+				A.y = rand(teleport_y, teleport_y_offset)
+				A.z = rand(teleport_z, teleport_z_offset)
+