Initial Commit

code/game/objects/items/weapons/implants/implant.dm

@@ -0,0 +1,503 @@
+#define MALFUNCTION_TEMPORARY 1
+#define MALFUNCTION_PERMANENT 2
+/obj/item/weapon/implant
+	name = "implant"
+	icon = 'icons/obj/device.dmi'
+	icon_state = "implant"
+	var/implanted = null
+	var/mob/imp_in = null
+	var/datum/organ/external/part = null
+	item_color = "b"
+	var/allow_reagents = 0
+	var/malfunction = 0
+
+	proc/trigger(emote, source as mob)
+		return
+
+	proc/activate()
+		return
+
+	// What does the implant do upon injection?
+	// return 0 if the implant fails (ex. Revhead and loyalty implant.)
+	// return 1 if the implant succeeds (ex. Nonrevhead and loyalty implant.)
+	proc/implanted(var/mob/source)
+		return 1
+
+	proc/get_data()
+		return "No information available"
+
+	proc/hear(message, source as mob)
+		return
+
+	proc/islegal()
+		return 0
+
+	proc/meltdown()	//breaks it down, making implant unrecongizible
+		imp_in << "\red You feel something melting inside [part ? "your [part.display_name]" : "you"]!"
+		if (part)
+			part.take_damage(burn = 15, used_weapon = "Electronics meltdown")
+		else
+			var/mob/living/M = imp_in
+			M.apply_damage(15,BURN)
+		name = "melted implant"
+		desc = "Charred circuit in melted plastic case. Wonder what that used to be..."
+		icon_state = "implant_melted"
+		malfunction = MALFUNCTION_PERMANENT
+
+	Del()
+		if(part)
+			part.implants.Remove(src)
+		..()
+
+/obj/item/weapon/implant/tracking
+	name = "tracking implant"
+	desc = "Track with this."
+	var/id = 1.0
+
+
+	get_data()
+		var/dat = {"<b>Implant Specifications:</b><BR>
+<b>Name:</b> Tracking Beacon<BR>
+<b>Life:</b> 10 minutes after death of host<BR>
+<b>Important Notes:</b> None<BR>
+<HR>
+<b>Implant Details:</b> <BR>
+<b>Function:</b> Continuously transmits low power signal. Useful for tracking.<BR>
+<b>Special Features:</b><BR>
+<i>Neuro-Safe</i>- Specialized shell absorbs excess voltages self-destructing the chip if
+a malfunction occurs thereby securing safety of subject. The implant will melt and
+disintegrate into bio-safe elements.<BR>
+<b>Integrity:</b> Gradient creates slight risk of being overcharged and frying the
+circuitry. As a result neurotoxins can cause massive damage.<HR>
+Implant Specifics:<BR>"}
+		return dat
+
+	emp_act(severity)
+		if (malfunction)	//no, dawg, you can't malfunction while you are malfunctioning
+			return
+		malfunction = MALFUNCTION_TEMPORARY
+
+		var/delay = 20
+		switch(severity)
+			if(1)
+				if(prob(60))
+					meltdown()
+			if(2)
+				delay = rand(5*60*10,15*60*10)	//from 5 to 15 minutes of free time
+
+		spawn(delay)
+			malfunction--
+
+
+/obj/item/weapon/implant/dexplosive
+	name = "explosive"
+	desc = "And boom goes the weasel."
+	icon_state = "implant_evil"
+
+	get_data()
+		var/dat = {"
+<b>Implant Specifications:</b><BR>
+<b>Name:</b> Robust Corp RX-78 Employee Management Implant<BR>
+<b>Life:</b> Activates upon death.<BR>
+<b>Important Notes:</b> Explodes<BR>
+<HR>
+<b>Implant Details:</b><BR>
+<b>Function:</b> Contains a compact, electrically detonated explosive that detonates upon receiving a specially encoded signal or upon host death.<BR>
+<b>Special Features:</b> Explodes<BR>
+<b>Integrity:</b> Implant will occasionally be degraded by the body's immune system and thus will occasionally malfunction."}
+		return dat
+
+
+	trigger(emote, source as mob)
+		if(emote == "deathgasp")
+			src.activate("death")
+		return
+
+
+	activate(var/cause)
+		if((!cause) || (!src.imp_in))	return 0
+		explosion(src, -1, 0, 2, 3, 0)//This might be a bit much, dono will have to see.
+		if(src.imp_in)
+			src.imp_in.gib()
+
+	islegal()
+		return 0
+
+//BS12 Explosive
+/obj/item/weapon/implant/explosive
+	name = "explosive implant"
+	desc = "A military grade micro bio-explosive. Highly dangerous."
+	var/elevel = "Localized Limb"
+	var/phrase = "supercalifragilisticexpialidocious"
+	icon_state = "implant_evil"
+
+	get_data()
+		var/dat = {"
+<b>Implant Specifications:</b><BR>
+<b>Name:</b> Robust Corp RX-78 Intimidation Class Implant<BR>
+<b>Life:</b> Activates upon codephrase.<BR>
+<b>Important Notes:</b> Explodes<BR>
+<HR>
+<b>Implant Details:</b><BR>
+<b>Function:</b> Contains a compact, electrically detonated explosive that detonates upon receiving a specially encoded signal or upon host death.<BR>
+<b>Special Features:</b> Explodes<BR>
+<b>Integrity:</b> Implant will occasionally be degraded by the body's immune system and thus will occasionally malfunction."}
+		return dat
+
+	hear_talk(mob/M as mob, msg)
+		hear(msg)
+		return
+
+	hear(var/msg)
+		var/list/replacechars = list("'" = "","\"" = "",">" = "","<" = "","(" = "",")" = "")
+		msg = sanitize_simple(msg, replacechars)
+		if(findtext(msg,phrase))
+			activate()
+			del(src)
+
+	activate()
+		if (malfunction == MALFUNCTION_PERMANENT)
+			return
+
+		var/need_gib = null
+		if(istype(imp_in, /mob/))
+			var/mob/T = imp_in
+			message_admins("Explosive implant triggered in [T] ([T.key]). (<A HREF='?_src_=holder;adminplayerobservecoodjump=1;X=[T.x];Y=[T.y];Z=[T.z]'>JMP</a>) ")
+			log_game("Explosive implant triggered in [T] ([T.key]).")
+			need_gib = 1
+
+			if(ishuman(imp_in))
+				if (elevel == "Localized Limb")
+					if(part) //For some reason, small_boom() didn't work. So have this bit of working copypaste.
+						imp_in.visible_message("\red Something beeps inside [imp_in][part ? "'s [part.display_name]" : ""]!")
+						playsound(loc, 'sound/items/countdown.ogg', 75, 1, -3)
+						sleep(25)
+						if (istype(part,/datum/organ/external/chest) ||	\
+							istype(part,/datum/organ/external/groin) ||	\
+							istype(part,/datum/organ/external/head))
+							part.createwound(BRUISE, 60)	//mangle them instead
+							explosion(get_turf(imp_in), -1, -1, 2, 3)
+							del(src)
+						else
+							explosion(get_turf(imp_in), -1, -1, 2, 3)
+							part.droplimb(1)
+							del(src)
+				if (elevel == "Destroy Body")
+					explosion(get_turf(T), -1, 0, 1, 6)
+					T.gib()
+				if (elevel == "Full Explosion")
+					explosion(get_turf(T), 0, 1, 3, 6)
+					T.gib()
+
+			else
+				explosion(get_turf(imp_in), 0, 1, 3, 6)
+
+		if(need_gib)
+			imp_in.gib()
+
+		var/turf/t = get_turf(imp_in)
+
+		if(t)
+			t.hotspot_expose(3500,125)
+
+	implanted(mob/source as mob)
+		elevel = alert("What sort of explosion would you prefer?", "Implant Intent", "Localized Limb", "Destroy Body", "Full Explosion")
+		phrase = input("Choose activation phrase:") as text
+		var/list/replacechars = list("'" = "","\"" = "",">" = "","<" = "","(" = "",")" = "")
+		phrase = sanitize_simple(phrase, replacechars)
+		usr.mind.store_memory("Explosive implant in [source] can be activated by saying something containing the phrase ''[src.phrase]'', <B>say [src.phrase]</B> to attempt to activate.", 0, 0)
+		usr << "The implanted explosive implant in [source] can be activated by saying something containing the phrase ''[src.phrase]'', <B>say [src.phrase]</B> to attempt to activate."
+		return 1
+
+	emp_act(severity)
+		if (malfunction)
+			return
+		malfunction = MALFUNCTION_TEMPORARY
+		switch (severity)
+			if (2.0)	//Weak EMP will make implant tear limbs off.
+				if (prob(50))
+					small_boom()
+			if (1.0)	//strong EMP will melt implant either making it go off, or disarming it
+				if (prob(70))
+					if (prob(50))
+						small_boom()
+					else
+						if (prob(50))
+							activate()		//50% chance of bye bye
+						else
+							meltdown()		//50% chance of implant disarming
+		spawn (20)
+			malfunction--
+
+	islegal()
+		return 0
+
+	proc/small_boom()
+		if (ishuman(imp_in) && part)
+			imp_in.visible_message("\red Something beeps inside [imp_in][part ? "'s [part.display_name]" : ""]!")
+			playsound(loc, 'sound/items/countdown.ogg', 75, 1, -3)
+			spawn(25)
+				if (ishuman(imp_in) && part)
+					//No tearing off these parts since it's pretty much killing
+					//and you can't replace groins
+					if (istype(part,/datum/organ/external/chest) ||	\
+						istype(part,/datum/organ/external/groin) ||	\
+						istype(part,/datum/organ/external/head))
+						part.createwound(BRUISE, 60)	//mangle them instead
+					else
+						part.droplimb(1)
+				explosion(get_turf(imp_in), -1, -1, 2, 3)
+				del(src)
+
+/obj/item/weapon/implant/chem
+	name = "chemical implant"
+	desc = "Injects things."
+	allow_reagents = 1
+
+	get_data()
+		var/dat = {"
+<b>Implant Specifications:</b><BR>
+<b>Name:</b> Robust Corp MJ-420 Prisoner Management Implant<BR>
+<b>Life:</b> Deactivates upon death but remains within the body.<BR>
+<b>Important Notes: Due to the system functioning off of nutrients in the implanted subject's body, the subject<BR>
+will suffer from an increased appetite.</B><BR>
+<HR>
+<b>Implant Details:</b><BR>
+<b>Function:</b> Contains a small capsule that can contain various chemicals. Upon receiving a specially encoded signal<BR>
+the implant releases the chemicals directly into the blood stream.<BR>
+<b>Special Features:</b>
+<i>Micro-Capsule</i>- Can be loaded with any sort of chemical agent via the common syringe and can hold 50 units.<BR>
+Can only be loaded while still in its original case.<BR>
+<b>Integrity:</b> Implant will last so long as the subject is alive. However, if the subject suffers from malnutrition,<BR>
+the implant may become unstable and either pre-maturely inject the subject or simply break."}
+		return dat
+
+
+	New()
+		..()
+		var/datum/reagents/R = new/datum/reagents(50)
+		reagents = R
+		R.my_atom = src
+
+
+	trigger(emote, source as mob)
+		if(emote == "deathgasp")
+			src.activate(src.reagents.total_volume)
+		return
+
+
+	activate(var/cause)
+		if((!cause) || (!src.imp_in))	return 0
+		var/mob/living/carbon/R = src.imp_in
+		src.reagents.trans_to(R, cause)
+		R << "You hear a faint *beep*."
+		if(!src.reagents.total_volume)
+			R << "You hear a faint click from your chest."
+			spawn(0)
+				del(src)
+		return
+
+	emp_act(severity)
+		if (malfunction)
+			return
+		malfunction = MALFUNCTION_TEMPORARY
+
+		switch(severity)
+			if(1)
+				if(prob(60))
+					activate(20)
+			if(2)
+				if(prob(30))
+					activate(5)
+
+		spawn(20)
+			malfunction--
+
+/obj/item/weapon/implant/loyalty
+	name = "loyalty implant"
+	desc = "Makes you loyal or such."
+
+	get_data()
+		var/dat = {"
+<b>Implant Specifications:</b><BR>
+<b>Name:</b> Nanotrasen Employee Management Implant<BR>
+<b>Life:</b> Ten years.<BR>
+<b>Important Notes:</b> Personnel injected with this device tend to be much more loyal to the company.<BR>
+<HR>
+<b>Implant Details:</b><BR>
+<b>Function:</b> Contains a small pod of nanobots that manipulate the host's mental functions.<BR>
+<b>Special Features:</b> Will prevent and cure most forms of brainwashing.<BR>
+<b>Integrity:</b> Implant will last so long as the nanobots are inside the bloodstream."}
+		return dat
+
+
+	implanted(mob/M)
+		if(!istype(M, /mob/living/carbon/human))	return 0
+		var/mob/living/carbon/human/H = M
+		if(H.mind in ticker.mode.head_revolutionaries)
+			H.visible_message("[H] seems to resist the implant!", "You feel the corporate tendrils of Nanotrasen try to invade your mind!")
+			return 0
+		else if(H.mind in ticker.mode:revolutionaries)
+			ticker.mode:remove_revolutionary(H.mind)
+		H << "\blue You feel a surge of loyalty towards Nanotrasen."
+		return 1
+
+
+/obj/item/weapon/implant/adrenalin
+	name = "adrenalin"
+	desc = "Removes all stuns and knockdowns."
+	var/uses
+
+	get_data()
+		var/dat = {"
+<b>Implant Specifications:</b><BR>
+<b>Name:</b> Cybersun Industries Adrenalin Implant<BR>
+<b>Life:</b> Five days.<BR>
+<b>Important Notes:</b> <font color='red'>Illegal</font><BR>
+<HR>
+<b>Implant Details:</b> Subjects injected with implant can activate a massive injection of adrenalin.<BR>
+<b>Function:</b> Contains nanobots to stimulate body to mass-produce Adrenalin.<BR>
+<b>Special Features:</b> Will prevent and cure most forms of brainwashing.<BR>
+<b>Integrity:</b> Implant can only be used three times before the nanobots are depleted."}
+		return dat
+
+
+	trigger(emote, mob/source as mob)
+		if (src.uses < 1)	return 0
+		if (emote == "pale")
+			src.uses--
+			source << "\blue You feel a sudden surge of energy!"
+			source.SetStunned(0)
+			source.SetWeakened(0)
+			source.SetParalysis(0)
+
+		return
+
+
+	implanted(mob/source)
+		source.mind.store_memory("A implant can be activated by using the pale emote, <B>say *pale</B> to attempt to activate.", 0, 0)
+		source << "The implanted freedom implant can be activated by using the pale emote, <B>say *pale</B> to attempt to activate."
+		return 1
+
+
+/obj/item/weapon/implant/death_alarm
+	name = "death alarm implant"
+	desc = "An alarm which monitors host vital signs and transmits a radio message upon death."
+	var/mobname = "Will Robinson"
+
+	get_data()
+		var/dat = {"
+<b>Implant Specifications:</b><BR>
+<b>Name:</b> NanoTrasen \"Profit Margin\" Class Employee Lifesign Sensor<BR>
+<b>Life:</b> Activates upon death.<BR>
+<b>Important Notes:</b> Alerts crew to crewmember death.<BR>
+<HR>
+<b>Implant Details:</b><BR>
+<b>Function:</b> Contains a compact radio signaler that triggers when the host's lifesigns cease.<BR>
+<b>Special Features:</b> Alerts crew to crewmember death.<BR>
+<b>Integrity:</b> Implant will occasionally be degraded by the body's immune system and thus will occasionally malfunction."}
+		return dat
+
+	process()
+		if (!implanted) return
+		var/mob/M = imp_in
+
+		if(isnull(M)) // If the mob got gibbed
+			activate()
+		else if(M.stat == 2)
+			activate("death")
+
+	activate(var/cause)
+		var/mob/M = imp_in
+		var/area/t = get_area(M)
+		switch (cause)
+			if("death")
+				var/obj/item/device/radio/headset/a = new /obj/item/device/radio/headset(null)
+				if(istype(t, /area/syndicate_station) || istype(t, /area/syndicate_mothership) || istype(t, /area/shuttle/syndicate_elite) )
+					//give the syndies a bit of stealth
+					a.autosay("[mobname] has died in Space!", "[mobname]'s Death Alarm")
+				else
+					a.autosay("[mobname] has died in [t.name]!", "[mobname]'s Death Alarm")
+				del(a)
+				processing_objects.Remove(src)
+			if ("emp")
+				var/obj/item/device/radio/headset/a = new /obj/item/device/radio/headset(null)
+				var/name = prob(50) ? t.name : pick(teleportlocs)
+				a.autosay("[mobname] has died in [name]!", "[mobname]'s Death Alarm")
+				del(a)
+			else
+				var/obj/item/device/radio/headset/a = new /obj/item/device/radio/headset(null)
+				a.autosay("[mobname] has died-zzzzt in-in-in...", "[mobname]'s Death Alarm")
+				del(a)
+				processing_objects.Remove(src)
+
+	emp_act(severity)			//for some reason alarms stop going off in case they are emp'd, even without this
+		if (malfunction)		//so I'm just going to add a meltdown chance here
+			return
+		malfunction = MALFUNCTION_TEMPORARY
+
+		activate("emp")	//let's shout that this dude is dead
+		if(severity == 1)
+			if(prob(40))	//small chance of obvious meltdown
+				meltdown()
+			else if (prob(60))	//but more likely it will just quietly die
+				malfunction = MALFUNCTION_PERMANENT
+			processing_objects.Remove(src)
+
+		spawn(20)
+			malfunction--
+
+	implanted(mob/source as mob)
+		mobname = source.real_name
+		processing_objects.Add(src)
+		return 1
+
+/obj/item/weapon/implant/compressed
+	name = "compressed matter implant"
+	desc = "Based on compressed matter technology, can store a single item."
+	icon_state = "implant_evil"
+	var/activation_emote = "sigh"
+	var/obj/item/scanned = null
+
+	get_data()
+		var/dat = {"
+<b>Implant Specifications:</b><BR>
+<b>Name:</b> NanoTrasen \"Profit Margin\" Class Employee Lifesign Sensor<BR>
+<b>Life:</b> Activates upon death.<BR>
+<b>Important Notes:</b> Alerts crew to crewmember death.<BR>
+<HR>
+<b>Implant Details:</b><BR>
+<b>Function:</b> Contains a compact radio signaler that triggers when the host's lifesigns cease.<BR>
+<b>Special Features:</b> Alerts crew to crewmember death.<BR>
+<b>Integrity:</b> Implant will occasionally be degraded by the body's immune system and thus will occasionally malfunction."}
+		return dat
+
+	trigger(emote, mob/source as mob)
+		if (src.scanned == null)
+			return 0
+
+		if (emote == src.activation_emote)
+			source << "The air glows as \the [src.scanned.name] uncompresses."
+			activate()
+
+	activate()
+		var/turf/t = get_turf(src)
+		if (imp_in)
+			imp_in.put_in_hands(scanned)
+		else
+			scanned.loc = t
+		del src
+
+	implanted(mob/source as mob)
+		src.activation_emote = input("Choose activation emote:") in list("blink", "blink_r", "eyebrow", "chuckle", "twitch_s", "frown", "nod", "blush", "giggle", "grin", "groan", "shrug", "smile", "pale", "sniff", "whimper", "wink")
+		if (source.mind)
+			source.mind.store_memory("Compressed matter implant can be activated by using the [src.activation_emote] emote, <B>say *[src.activation_emote]</B> to attempt to activate.", 0, 0)
+		source << "The implanted compressed matter implant can be activated by using the [src.activation_emote] emote, <B>say *[src.activation_emote]</B> to attempt to activate."
+		return 1
+
+	islegal()
+		return 0
+
+/obj/item/weapon/implant/cortical
+	name = "cortical stack"
+	desc = "A fist-sized mass of biocircuits and chips."

code/game/objects/items/weapons/implants/implantcase.dm

@@ -0,0 +1,130 @@
+//This file was auto-corrected by findeclaration.exe on 25.5.2012 20:42:32
+
+/obj/item/weapon/implantcase
+	name = "Glass Case"
+	desc = "A case containing an implant."
+	icon_state = "implantcase-0"
+	item_state = "implantcase"
+	throw_speed = 1
+	throw_range = 5
+	w_class = 1.0
+	var/obj/item/weapon/implant/imp = null
+	proc
+		update()
+
+
+	update()
+		if (src.imp)
+			src.icon_state = text("implantcase-[]", src.imp.item_color)
+		else
+			src.icon_state = "implantcase-0"
+		return
+
+
+	attackby(obj/item/weapon/I as obj, mob/user as mob)
+		..()
+		if (istype(I, /obj/item/weapon/pen))
+			var/t = input(user, "What would you like the label to be?", text("[]", src.name), null)  as text
+			if (user.get_active_hand() != I)
+				return
+			if((!in_range(src, usr) && src.loc != user))
+				return
+			t = copytext(sanitize(t),1,MAX_MESSAGE_LEN)
+			if(t)
+				src.name = text("Glass Case- '[]'", t)
+			else
+				src.name = "Glass Case"
+		else if(istype(I, /obj/item/weapon/reagent_containers/syringe))
+			if(!src.imp)	return
+			if(!src.imp.allow_reagents)	return
+			if(src.imp.reagents.total_volume >= src.imp.reagents.maximum_volume)
+				user << "\red [src] is full."
+			else
+				spawn(5)
+					I.reagents.trans_to(src.imp, 5)
+					user << "\blue You inject 5 units of the solution. The syringe now contains [I.reagents.total_volume] units."
+		else if (istype(I, /obj/item/weapon/implanter))
+			if (I:imp)
+				if ((src.imp || I:imp.implanted))
+					return
+				I:imp.loc = src
+				src.imp = I:imp
+				I:imp = null
+				src.update()
+				I:update()
+			else
+				if (src.imp)
+					if (I:imp)
+						return
+					src.imp.loc = I
+					I:imp = src.imp
+					src.imp = null
+					update()
+				I:update()
+		return
+
+
+
+/obj/item/weapon/implantcase/tracking
+	name = "Glass Case- 'Tracking'"
+	desc = "A case containing a tracking implant."
+	icon = 'icons/obj/items.dmi'
+	icon_state = "implantcase-b"
+
+
+	New()
+		src.imp = new /obj/item/weapon/implant/tracking( src )
+		..()
+		return
+
+
+
+/obj/item/weapon/implantcase/explosive
+	name = "Glass Case- 'Explosive'"
+	desc = "A case containing an explosive implant."
+	icon = 'icons/obj/items.dmi'
+	icon_state = "implantcase-r"
+
+
+	New()
+		src.imp = new /obj/item/weapon/implant/explosive( src )
+		..()
+		return
+
+
+
+/obj/item/weapon/implantcase/chem
+	name = "Glass Case- 'Chem'"
+	desc = "A case containing a chemical implant."
+	icon = 'icons/obj/items.dmi'
+	icon_state = "implantcase-b"
+/obj/item/weapon/implantcase/chem/New()
+
+	src.imp = new /obj/item/weapon/implant/chem( src )
+	..()
+	return
+
+
+/obj/item/weapon/implantcase/loyalty
+	name = "Glass Case- 'Loyalty'"
+	desc = "A case containing a loyalty implant."
+	icon = 'icons/obj/items.dmi'
+	icon_state = "implantcase-r"
+
+
+	New()
+		src.imp = new /obj/item/weapon/implant/loyalty( src )
+		..()
+		return
+
+
+/obj/item/weapon/implantcase/death_alarm
+	name = "Glass Case- 'Death Alarm'"
+	desc = "A case containing a death alarm implant."
+	icon = 'icons/obj/items.dmi'
+	icon_state = "implantcase-b"
+
+	New()
+		src.imp = new /obj/item/weapon/implant/death_alarm( src )
+		..()
+		return

code/game/objects/items/weapons/implants/implantchair.dm

@@ -0,0 +1,171 @@
+//This file was auto-corrected by findeclaration.exe on 25.5.2012 20:42:32
+
+/obj/machinery/implantchair
+	name = "loyalty implanter"
+	desc = "Used to implant occupants with loyalty implants."
+	icon = 'icons/obj/machines/implantchair.dmi'
+	icon_state = "implantchair"
+	density = 1
+	opacity = 0
+	anchored = 1
+
+	var/ready = 1
+	var/malfunction = 0
+	var/list/obj/item/weapon/implant/loyalty/implant_list = list()
+	var/max_implants = 5
+	var/injection_cooldown = 600
+	var/replenish_cooldown = 6000
+	var/replenishing = 0
+	var/mob/living/carbon/occupant = null
+	var/injecting = 0
+
+	proc
+		go_out()
+		put_mob(mob/living/carbon/M as mob)
+		implant(var/mob/M)
+		add_implants()
+
+
+	New()
+		..()
+		add_implants()
+
+
+	attack_hand(mob/user as mob)
+		user.set_machine(src)
+		var/health_text = ""
+		if(src.occupant)
+			if(src.occupant.health <= -100)
+				health_text = "<FONT color=red>Dead</FONT>"
+			else if(src.occupant.health < 0)
+				health_text = "<FONT color=red>[round(src.occupant.health,0.1)]</FONT>"
+			else
+				health_text = "[round(src.occupant.health,0.1)]"
+
+		var/dat ="<B>Implanter Status</B><BR>"
+
+		dat +="<B>Current occupant:</B> [src.occupant ? "<BR>Name: [src.occupant]<BR>Health: [health_text]<BR>" : "<FONT color=red>None</FONT>"]<BR>"
+		dat += "<B>Implants:</B> [src.implant_list.len ? "[implant_list.len]" : "<A href='?src=\ref[src];replenish=1'>Replenish</A>"]<BR>"
+		if(src.occupant)
+			dat += "[src.ready ? "<A href='?src=\ref[src];implant=1'>Implant</A>" : "Recharging"]<BR>"
+		user.set_machine(src)
+		user << browse(dat, "window=implant")
+		onclose(user, "implant")
+
+
+	Topic(href, href_list)
+		if((get_dist(src, usr) <= 1) || istype(usr, /mob/living/silicon/ai))
+			if(href_list["implant"])
+				if(src.occupant)
+					injecting = 1
+					go_out()
+					ready = 0
+					spawn(injection_cooldown)
+						ready = 1
+
+			if(href_list["replenish"])
+				ready = 0
+				spawn(replenish_cooldown)
+					add_implants()
+					ready = 1
+
+			src.updateUsrDialog()
+			src.add_fingerprint(usr)
+			return
+
+
+	attackby(var/obj/item/weapon/G as obj, var/mob/user as mob)
+		if(istype(G, /obj/item/weapon/grab))
+			if(!ismob(G:affecting))
+				return
+			for(var/mob/living/carbon/slime/M in range(1,G:affecting))
+				if(M.Victim == G:affecting)
+					usr << "[G:affecting:name] will not fit into the [src.name] because they have a slime latched onto their head."
+					return
+			var/mob/M = G:affecting
+			if(put_mob(M))
+				del(G)
+		src.updateUsrDialog()
+		return
+
+
+	go_out(var/mob/M)
+		if(!( src.occupant ))
+			return
+		if(M == occupant) // so that the guy inside can't eject himself -Agouri
+			return
+		if (src.occupant.client)
+			src.occupant.client.eye = src.occupant.client.mob
+			src.occupant.client.perspective = MOB_PERSPECTIVE
+		src.occupant.loc = src.loc
+		if(injecting)
+			implant(src.occupant)
+			injecting = 0
+		src.occupant = null
+		icon_state = "implantchair"
+		return
+
+
+	put_mob(mob/living/carbon/M as mob)
+		if(!iscarbon(M))
+			usr << "\red <B>The [src.name] cannot hold this!</B>"
+			return
+		if(src.occupant)
+			usr << "\red <B>The [src.name] is already occupied!</B>"
+			return
+		if(M.client)
+			M.client.perspective = EYE_PERSPECTIVE
+			M.client.eye = src
+		M.stop_pulling()
+		M.loc = src
+		src.occupant = M
+		src.add_fingerprint(usr)
+		icon_state = "implantchair_on"
+		return 1
+
+
+	implant(var/mob/M)
+		if (!istype(M, /mob/living/carbon))
+			return
+		if(!implant_list.len)	return
+		for(var/obj/item/weapon/implant/loyalty/imp in implant_list)
+			if(!imp)	continue
+			if(istype(imp, /obj/item/weapon/implant/loyalty))
+				for (var/mob/O in viewers(M, null))
+					O.show_message("\red [M] has been implanted by the [src.name].", 1)
+
+				if(imp.implanted(M))
+					imp.loc = M
+					imp.imp_in = M
+					imp.implanted = 1
+				implant_list -= imp
+				break
+		return
+
+
+	add_implants()
+		for(var/i=0, i<src.max_implants, i++)
+			var/obj/item/weapon/implant/loyalty/I = new /obj/item/weapon/implant/loyalty(src)
+			implant_list += I
+		return
+
+	verb
+		get_out()
+			set name = "Eject occupant"
+			set category = "Object"
+			set src in oview(1)
+			if(usr.stat != 0)
+				return
+			src.go_out(usr)
+			add_fingerprint(usr)
+			return
+
+
+		move_inside()
+			set name = "Move Inside"
+			set category = "Object"
+			set src in oview(1)
+			if(usr.stat != 0 || stat & (NOPOWER|BROKEN))
+				return
+			put_mob(usr)
+			return

code/game/objects/items/weapons/implants/implanter.dm

@@ -0,0 +1,122 @@
+/obj/item/weapon/implanter
+	name = "implanter"
+	icon = 'icons/obj/items.dmi'
+	icon_state = "implanter0"
+	item_state = "syringe_0"
+	throw_speed = 1
+	throw_range = 5
+	w_class = 2.0
+	var/obj/item/weapon/implant/imp = null
+
+/obj/item/weapon/implanter/proc/update()
+
+
+/obj/item/weapon/implanter/update()
+	if (src.imp)
+		src.icon_state = "implanter1"
+	else
+		src.icon_state = "implanter0"
+	return
+
+
+/obj/item/weapon/implanter/attack(mob/M as mob, mob/user as mob)
+	if (!istype(M, /mob/living/carbon))
+		return
+	if (user && src.imp)
+		for (var/mob/O in viewers(M, null))
+			O.show_message("\red [user] is attemping to implant [M].", 1)
+
+		var/turf/T1 = get_turf(M)
+		if (T1 && ((M == user) || do_after(user, 50)))
+			if(user && M && (get_turf(M) == T1) && src && src.imp)
+				for (var/mob/O in viewers(M, null))
+					O.show_message("\red [M] has been implanted by [user].", 1)
+
+				M.attack_log += text("\[[time_stamp()]\] <font color='orange'> Implanted with [src.name] ([src.imp.name])  by [user.name] ([user.ckey])</font>")
+				user.attack_log += text("\[[time_stamp()]\] <font color='red'>Used the [src.name] ([src.imp.name]) to implant [M.name] ([M.ckey])</font>")
+				msg_admin_attack("[user.name] ([user.ckey]) implanted [M.name] ([M.ckey]) with [src.name] (INTENT: [uppertext(user.a_intent)]) (<A HREF='?_src_=holder;adminplayerobservecoodjump=1;X=[user.x];Y=[user.y];Z=[user.z]'>JMP</a>)")
+
+				user.show_message("\red You implanted the implant into [M].")
+				if(src.imp.implanted(M))
+					src.imp.loc = M
+					src.imp.imp_in = M
+					src.imp.implanted = 1
+					if (ishuman(M))
+						var/mob/living/carbon/human/H = M
+						var/datum/organ/external/affected = H.get_organ(user.zone_sel.selecting)
+						affected.implants += src.imp
+						imp.part = affected
+
+				src.imp = null
+				update()
+	return
+
+
+
+/obj/item/weapon/implanter/loyalty
+	name = "implanter-loyalty"
+
+/obj/item/weapon/implanter/loyalty/New()
+	src.imp = new /obj/item/weapon/implant/loyalty( src )
+	..()
+	update()
+	return
+
+
+
+/obj/item/weapon/implanter/explosive
+	name = "implanter (E)"
+
+/obj/item/weapon/implanter/explosive/New()
+	src.imp = new /obj/item/weapon/implant/explosive( src )
+	..()
+	update()
+	return
+
+/obj/item/weapon/implanter/adrenalin
+	name = "implanter-adrenalin"
+
+/obj/item/weapon/implanter/adrenalin/New()
+	src.imp = new /obj/item/weapon/implant/adrenalin(src)
+	..()
+	update()
+	return
+
+/obj/item/weapon/implanter/compressed
+	name = "implanter (C)"
+	icon_state = "cimplanter1"
+
+/obj/item/weapon/implanter/compressed/New()
+	imp = new /obj/item/weapon/implant/compressed( src )
+	..()
+	update()
+	return
+
+/obj/item/weapon/implanter/compressed/update()
+	if (imp)
+		var/obj/item/weapon/implant/compressed/c = imp
+		if(!c.scanned)
+			icon_state = "cimplanter1"
+		else
+			icon_state = "cimplanter2"
+	else
+		icon_state = "cimplanter0"
+	return
+
+/obj/item/weapon/implanter/compressed/attack(mob/M as mob, mob/user as mob)
+	var/obj/item/weapon/implant/compressed/c = imp
+	if (!c)	return
+	if (c.scanned == null)
+		user << "Please scan an object with the implanter first."
+		return
+	..()
+
+/obj/item/weapon/implanter/compressed/afterattack(atom/A, mob/user as mob)
+	if(istype(A,/obj/item) && imp)
+		var/obj/item/weapon/implant/compressed/c = imp
+		if (c.scanned)
+			user << "\red Something is already scanned inside the implant!"
+			return
+		imp:scanned = A
+		A.loc.contents.Remove(A)
+		update()

code/game/objects/items/weapons/implants/implantfreedom.dm

@@ -0,0 +1,71 @@
+//This file was auto-corrected by findeclaration.exe on 25.5.2012 20:42:32
+
+/obj/item/weapon/implant/freedom
+	name = "freedom implant"
+	desc = "Use this to escape from those evil Red Shirts."
+	item_color = "r"
+	var/activation_emote = "chuckle"
+	var/uses = 1.0
+
+
+	New()
+		src.activation_emote = pick("blink", "blink_r", "eyebrow", "chuckle", "twitch_s", "frown", "nod", "blush", "giggle", "grin", "groan", "shrug", "smile", "pale", "sniff", "whimper", "wink")
+		src.uses = rand(1, 5)
+		..()
+		return
+
+
+	trigger(emote, mob/living/carbon/source as mob)
+		if (src.uses < 1)	return 0
+		if (emote == src.activation_emote)
+			src.uses--
+			source << "You feel a faint click."
+			if (source.handcuffed)
+				var/obj/item/weapon/W = source.handcuffed
+				source.handcuffed = null
+				source.update_inv_handcuffed()
+				if (source.client)
+					source.client.screen -= W
+				if (W)
+					W.loc = source.loc
+					dropped(source)
+					if (W)
+						W.layer = initial(W.layer)
+			if (source.legcuffed)
+				var/obj/item/weapon/W = source.legcuffed
+				source.legcuffed = null
+				source.update_inv_legcuffed()
+				if (source.client)
+					source.client.screen -= W
+				if (W)
+					W.loc = source.loc
+					dropped(source)
+					if (W)
+						W.layer = initial(W.layer)
+		return
+
+
+	implanted(mob/living/carbon/source)
+		source.mind.store_memory("Freedom implant can be activated by using the [src.activation_emote] emote, <B>say *[src.activation_emote]</B> to attempt to activate.", 0, 0)
+		source << "The implanted freedom implant can be activated by using the [src.activation_emote] emote, <B>say *[src.activation_emote]</B> to attempt to activate."
+		return 1
+
+
+	get_data()
+		var/dat = {"
+<b>Implant Specifications:</b><BR>
+<b>Name:</b> Freedom Beacon<BR>
+<b>Life:</b> optimum 5 uses<BR>
+<b>Important Notes:</b> <font color='red'>Illegal</font><BR>
+<HR>
+<b>Implant Details:</b> <BR>
+<b>Function:</b> Transmits a specialized cluster of signals to override handcuff locking
+mechanisms<BR>
+<b>Special Features:</b><BR>
+<i>Neuro-Scan</i>- Analyzes certain shadow signals in the nervous system<BR>
+<b>Integrity:</b> The battery is extremely weak and commonly after injection its
+life can drive down to only 1 use.<HR>
+No Implant Specifics"}
+		return dat
+
+

code/game/objects/items/weapons/implants/implantpad.dm

@@ -0,0 +1,98 @@
+//This file was auto-corrected by findeclaration.exe on 25.5.2012 20:42:32
+
+/obj/item/weapon/implantpad
+	name = "implantpad"
+	desc = "Used to modify implants."
+	icon = 'icons/obj/items.dmi'
+	icon_state = "implantpad-0"
+	item_state = "electronic"
+	throw_speed = 1
+	throw_range = 5
+	w_class = 2.0
+	var/obj/item/weapon/implantcase/case = null
+	var/broadcasting = null
+	var/listening = 1.0
+	proc
+		update()
+
+
+	update()
+		if (src.case)
+			src.icon_state = "implantpad-1"
+		else
+			src.icon_state = "implantpad-0"
+		return
+
+
+	attack_hand(mob/user as mob)
+		if ((src.case && (user.l_hand == src || user.r_hand == src)))
+			user.put_in_active_hand(case)
+
+			src.case.add_fingerprint(user)
+			src.case = null
+
+			src.add_fingerprint(user)
+			update()
+		else
+			return ..()
+		return
+
+
+	attackby(obj/item/weapon/implantcase/C as obj, mob/user as mob)
+		..()
+		if(istype(C, /obj/item/weapon/implantcase))
+			if(!( src.case ))
+				user.drop_item()
+				C.loc = src
+				src.case = C
+		else
+			return
+		src.update()
+		return
+
+
+	attack_self(mob/user as mob)
+		user.set_machine(src)
+		var/dat = "<B>Implant Mini-Computer:</B><HR>"
+		if (src.case)
+			if(src.case.imp)
+				if(istype(src.case.imp, /obj/item/weapon/implant))
+					dat += src.case.imp.get_data()
+					if(istype(src.case.imp, /obj/item/weapon/implant/tracking))
+						dat += {"ID (1-100):
+						<A href='byond://?src=\ref[src];tracking_id=-10'>-</A>
+						<A href='byond://?src=\ref[src];tracking_id=-1'>-</A> [case.imp:id]
+						<A href='byond://?src=\ref[src];tracking_id=1'>+</A>
+						<A href='byond://?src=\ref[src];tracking_id=10'>+</A><BR>"}
+			else
+				dat += "The implant casing is empty."
+		else
+			dat += "Please insert an implant casing!"
+		user << browse(dat, "window=implantpad")
+		onclose(user, "implantpad")
+		return
+
+
+	Topic(href, href_list)
+		..()
+		if (usr.stat)
+			return
+		if ((usr.contents.Find(src)) || ((in_range(src, usr) && istype(src.loc, /turf))))
+			usr.set_machine(src)
+			if (href_list["tracking_id"])
+				var/obj/item/weapon/implant/tracking/T = src.case.imp
+				T.id += text2num(href_list["tracking_id"])
+				T.id = min(100, T.id)
+				T.id = max(1, T.id)
+
+			if (istype(src.loc, /mob))
+				attack_self(src.loc)
+			else
+				for(var/mob/M in viewers(1, src))
+					if (M.client)
+						src.attack_self(M)
+			src.add_fingerprint(usr)
+		else
+			usr << browse(null, "window=implantpad")
+			return
+		return

code/game/objects/items/weapons/implants/implantuplink.dm

@@ -0,0 +1,23 @@
+/obj/item/weapon/implant/uplink
+	name = "uplink"
+	desc = "Summon things."
+	var/activation_emote = "chuckle"
+
+/obj/item/weapon/implant/uplink/New()
+	activation_emote = pick("blink", "blink_r", "eyebrow", "chuckle", "twitch_s", "frown", "nod", "blush", "giggle", "grin", "groan", "shrug", "smile", "pale", "sniff", "whimper", "wink")
+	hidden_uplink = new(src)
+	hidden_uplink.uses = 5
+	..()
+	return
+
+/obj/item/weapon/implant/uplink/implanted(mob/source)
+	activation_emote = input("Choose activation emote:") in list("blink", "blink_r", "eyebrow", "chuckle", "twitch_s", "frown", "nod", "blush", "giggle", "grin", "groan", "shrug", "smile", "pale", "sniff", "whimper", "wink")
+	source.mind.store_memory("Uplink implant can be activated by using the [src.activation_emote] emote, <B>say *[src.activation_emote]</B> to attempt to activate.", 0, 0)
+	source << "The implanted uplink implant can be activated by using the [src.activation_emote] emote, <B>say *[src.activation_emote]</B> to attempt to activate."
+	return 1
+
+
+/obj/item/weapon/implant/uplink/trigger(emote, mob/source as mob)
+	if(hidden_uplink && usr == source) // Let's not have another people activate our uplink
+		hidden_uplink.check_trigger(source, emote, activation_emote)
+	return