Initial Commit

code/modules/assembly/assembly.dm

@@ -0,0 +1,179 @@
+/obj/item/device/assembly
+	name = "assembly"
+	desc = "A small electronic device that should never exist."
+	icon = 'icons/obj/assemblies/new_assemblies.dmi'
+	icon_state = ""
+	flags = FPRINT | TABLEPASS| CONDUCT
+	w_class = 2.0
+	m_amt = 100
+	g_amt = 0
+	w_amt = 0
+	throwforce = 2
+	throw_speed = 3
+	throw_range = 10
+	origin_tech = "magnets=1"
+
+	var/secured = 1
+	var/list/attached_overlays = null
+	var/obj/item/device/assembly_holder/holder = null
+	var/cooldown = 0//To prevent spam
+	var/wires = WIRE_RECEIVE | WIRE_PULSE
+
+	var/const/WIRE_RECEIVE = 1			//Allows Pulsed(0) to call Activate()
+	var/const/WIRE_PULSE = 2				//Allows Pulse(0) to act on the holder
+	var/const/WIRE_PULSE_SPECIAL = 4		//Allows Pulse(0) to act on the holders special assembly
+	var/const/WIRE_RADIO_RECEIVE = 8		//Allows Pulsed(1) to call Activate()
+	var/const/WIRE_RADIO_PULSE = 16		//Allows Pulse(1) to send a radio message
+
+	proc/activate()									//What the device does when turned on
+		return
+
+	proc/pulsed(var/radio = 0)						//Called when another assembly acts on this one, var/radio will determine where it came from for wire calcs
+		return
+
+	proc/pulse(var/radio = 0)						//Called when this device attempts to act on another device, var/radio determines if it was sent via radio or direct
+		return
+
+	proc/toggle_secure()								//Code that has to happen when the assembly is un\secured goes here
+		return
+
+	proc/attach_assembly(var/obj/A, var/mob/user)	//Called when an assembly is attacked by another
+		return
+
+	proc/process_cooldown()							//Called via spawn(10) to have it count down the cooldown var
+		return
+
+	proc/holder_movement()							//Called when the holder is moved
+		return
+
+	interact(mob/user as mob)					//Called when attack_self is called
+		return
+
+
+	process_cooldown()
+		cooldown--
+		if(cooldown <= 0)	return 0
+		spawn(10)
+			process_cooldown()
+		return 1
+
+
+	pulsed(var/radio = 0)
+		if(holder && (wires & WIRE_RECEIVE))
+			activate()
+		if(radio && (wires & WIRE_RADIO_RECEIVE))
+			activate()
+		return 1
+
+
+	pulse(var/radio = 0)
+		if(holder && (wires & WIRE_PULSE))
+			holder.process_activation(src, 1, 0)
+		if(holder && (wires & WIRE_PULSE_SPECIAL))
+			holder.process_activation(src, 0, 1)
+//		if(radio && (wires & WIRE_RADIO_PULSE))
+			//Not sure what goes here quite yet send signal?
+		return 1
+
+
+	activate()
+		if(!secured || (cooldown > 0))	return 0
+		cooldown = 2
+		spawn(10)
+			process_cooldown()
+		return 1
+
+
+	toggle_secure()
+		secured = !secured
+		update_icon()
+		return secured
+
+
+	attach_assembly(var/obj/item/device/assembly/A, var/mob/user)
+		holder = new/obj/item/device/assembly_holder(get_turf(src))
+		if(holder.attach(A,src,user))
+			user << "\blue You attach \the [A] to \the [src]!"
+			return 1
+		return 0
+
+
+	attackby(obj/item/weapon/W as obj, mob/user as mob)
+		if(isassembly(W))
+			var/obj/item/device/assembly/A = W
+			if((!A.secured) && (!secured))
+				attach_assembly(A,user)
+				return
+		if(isscrewdriver(W))
+			if(toggle_secure())
+				user << "\blue \The [src] is ready!"
+			else
+				user << "\blue \The [src] can now be attached!"
+			return
+		..()
+		return
+
+
+	process()
+		processing_objects.Remove(src)
+		return
+
+
+	examine()
+		set src in view()
+		..()
+		if((in_range(src, usr) || loc == usr))
+			if(secured)
+				usr << "\The [src] is ready!"
+			else
+				usr << "\The [src] can be attached!"
+		return
+
+
+	attack_self(mob/user as mob)
+		if(!user)	return 0
+		user.set_machine(src)
+		interact(user)
+		return 1
+
+
+	interact(mob/user as mob)
+		return //HTML MENU FOR WIRES GOES HERE
+
+/*
+	var/small_icon_state = null//If this obj will go inside the assembly use this for icons
+	var/list/small_icon_state_overlays = null//Same here
+	var/obj/holder = null
+	var/cooldown = 0//To prevent spam
+
+	proc
+		Activate()//Called when this assembly is pulsed by another one
+		Process_cooldown()//Call this via spawn(10) to have it count down the cooldown var
+		Attach_Holder(var/obj/H, var/mob/user)//Called when an assembly holder attempts to attach, sets src's loc in here
+
+
+	Activate()
+		if(cooldown > 0)
+			return 0
+		cooldown = 2
+		spawn(10)
+			Process_cooldown()
+		//Rest of code here
+		return 0
+
+
+	Process_cooldown()
+		cooldown--
+		if(cooldown <= 0)	return 0
+		spawn(10)
+			Process_cooldown()
+		return 1
+
+
+	Attach_Holder(var/obj/H, var/mob/user)
+		if(!H)	return 0
+		if(!H.IsAssemblyHolder())	return 0
+		//Remember to have it set its loc somewhere in here
+
+
+*/

code/modules/assembly/bomb.dm

@@ -0,0 +1,155 @@
+/obj/item/device/onetankbomb
+	name = "bomb"
+	icon = 'icons/obj/tank.dmi'
+	item_state = "assembly"
+	throwforce = 5
+	w_class = 3.0
+	throw_speed = 2
+	throw_range = 4
+	flags = FPRINT | TABLEPASS| CONDUCT //Copied this from old code, so this may or may not be necessary
+	var/status = 0   //0 - not readied //1 - bomb finished with welder
+	var/obj/item/device/assembly_holder/bombassembly = null   //The first part of the bomb is an assembly holder, holding an igniter+some device
+	var/obj/item/weapon/tank/bombtank = null //the second part of the bomb is a plasma tank
+
+/obj/item/device/onetankbomb/examine()
+	..()
+	bombtank.examine()
+
+/obj/item/device/onetankbomb/update_icon()
+	if(bombtank)
+		icon_state = bombtank.icon_state
+	if(bombassembly)
+		overlays += bombassembly.icon_state
+		overlays += bombassembly.overlays
+		overlays += "bomb_assembly"
+
+/obj/item/device/onetankbomb/attackby(obj/item/weapon/W as obj, mob/user as mob)
+	if(istype(W, /obj/item/device/analyzer))
+		bombtank.attackby(W, user)
+		return
+	if(istype(W, /obj/item/weapon/wrench) && !status)	//This is basically bomb assembly code inverted. apparently it works.
+
+		user << "<span class='notice'>You disassemble [src].</span>"
+
+		bombassembly.loc = user.loc
+		bombassembly.master = null
+		bombassembly = null
+
+		bombtank.loc = user.loc
+		bombtank.master = null
+		bombtank = null
+
+		del(src)
+		return
+	if((istype(W, /obj/item/weapon/weldingtool) && W:welding))
+		if(!status)
+			status = 1
+			bombers += "[key_name(user)] welded a single tank bomb. Temp: [bombtank.air_contents.temperature-T0C]"
+			message_admins("[key_name_admin(user)] welded a single tank bomb. Temp: [bombtank.air_contents.temperature-T0C]")
+			user << "<span class='notice'>A pressure hole has been bored to [bombtank] valve. \The [bombtank] can now be ignited.</span>"
+		else
+			status = 0
+			bombers += "[key_name(user)] unwelded a single tank bomb. Temp: [bombtank.air_contents.temperature-T0C]"
+			user << "<span class='notice'>The hole has been closed.</span>"
+	add_fingerprint(user)
+	..()
+
+/obj/item/device/onetankbomb/attack_self(mob/user as mob) //pressing the bomb accesses its assembly
+	bombassembly.attack_self(user, 1)
+	add_fingerprint(user)
+	return
+
+/obj/item/device/onetankbomb/receive_signal()	//This is mainly called by the sensor through sense() to the holder, and from the holder to here.
+	visible_message("\icon[src] *beep* *beep*", "*beep* *beep*")
+	sleep(10)
+	if(!src)
+		return
+	if(status)
+		bombtank.ignite()	//if its not a dud, boom (or not boom if you made shitty mix) the ignite proc is below, in this file
+	else
+		bombtank.release()
+
+/obj/item/device/onetankbomb/HasProximity(atom/movable/AM as mob|obj)
+	if(bombassembly)
+		bombassembly.HasProximity(AM)
+
+// ---------- Procs below are for tanks that are used exclusively in 1-tank bombs ----------
+
+/obj/item/weapon/tank/proc/bomb_assemble(W,user)	//Bomb assembly proc. This turns assembly+tank into a bomb
+	var/obj/item/device/assembly_holder/S = W
+	var/mob/M = user
+	if(!S.secured)										//Check if the assembly is secured
+		return
+	if(isigniter(S.a_left) == isigniter(S.a_right))		//Check if either part of the assembly has an igniter, but if both parts are igniters, then fuck it
+		return
+
+	var/obj/item/device/onetankbomb/R = new /obj/item/device/onetankbomb(loc)
+
+	M.drop_item()			//Remove the assembly from your hands
+	M.remove_from_mob(src)	//Remove the tank from your character,in case you were holding it
+	M.put_in_hands(R)		//Equips the bomb if possible, or puts it on the floor.
+
+	R.bombassembly = S	//Tell the bomb about its assembly part
+	S.master = R		//Tell the assembly about its new owner
+	S.loc = R			//Move the assembly out of the fucking way
+
+	R.bombtank = src	//Same for tank
+	master = R
+	loc = R
+	R.update_icon()
+	return
+
+/obj/item/weapon/tank/proc/ignite()	//This happens when a bomb is told to explode
+	var/fuel_moles = air_contents.toxins + air_contents.oxygen/6
+	var/strength = 1
+
+	var/turf/ground_zero = get_turf(loc)
+	loc = null
+
+	if(air_contents.temperature > (T0C + 400))
+		strength = (fuel_moles/15)
+
+		if(strength >=1)
+			explosion(ground_zero, round(strength,1), round(strength*2,1), round(strength*3,1), round(strength*4,1))
+		else if(strength >=0.5)
+			explosion(ground_zero, 0, 1, 2, 4)
+		else if(strength >=0.2)
+			explosion(ground_zero, -1, 0, 1, 2)
+		else
+			ground_zero.assume_air(air_contents)
+			ground_zero.hotspot_expose(1000, 125)
+
+	else if(air_contents.temperature > (T0C + 250))
+		strength = (fuel_moles/20)
+
+		if(strength >=1)
+			explosion(ground_zero, 0, round(strength,1), round(strength*2,1), round(strength*3,1))
+		else if (strength >=0.5)
+			explosion(ground_zero, -1, 0, 1, 2)
+		else
+			ground_zero.assume_air(air_contents)
+			ground_zero.hotspot_expose(1000, 125)
+
+	else if(air_contents.temperature > (T0C + 100))
+		strength = (fuel_moles/25)
+
+		if (strength >=1)
+			explosion(ground_zero, -1, 0, round(strength,1), round(strength*3,1))
+		else
+			ground_zero.assume_air(air_contents)
+			ground_zero.hotspot_expose(1000, 125)
+
+	else
+		ground_zero.assume_air(air_contents)
+		ground_zero.hotspot_expose(1000, 125)
+
+	if(master)
+		del(master)
+	del(src)
+
+/obj/item/weapon/tank/proc/release()	//This happens when the bomb is not welded. Tank contents are just spat out.
+	var/datum/gas_mixture/removed = air_contents.remove(air_contents.total_moles())
+	var/turf/simulated/T = get_turf(src)
+	if(!T)
+		return
+	T.assume_air(removed)

code/modules/assembly/helpers.dm

@@ -0,0 +1,44 @@
+/proc/isassembly(O)
+	if(istype(O, /obj/item/device/assembly))
+		return 1
+	return 0
+
+/proc/isigniter(O)
+	if(istype(O, /obj/item/device/assembly/igniter))
+		return 1
+	return 0
+
+/proc/isinfared(O)
+	if(istype(O, /obj/item/device/assembly/infra))
+		return 1
+	return 0
+
+/proc/isprox(O)
+	if(istype(O, /obj/item/device/assembly/prox_sensor))
+		return 1
+	return 0
+
+/proc/issignaler(O)
+	if(istype(O, /obj/item/device/assembly/signaler))
+		return 1
+	return 0
+
+/proc/istimer(O)
+	if(istype(O, /obj/item/device/assembly/timer))
+		return 1
+	return 0
+
+/*
+Name:	IsSpecialAssembly
+Desc:	If true is an object that can be attached to an assembly holder but is a special thing like a plasma can or door
+*/
+
+/obj/proc/IsSpecialAssembly()
+	return 0
+
+/*
+Name:	IsAssemblyHolder
+Desc:	If true is an object that can hold an assemblyholder object
+*/
+/obj/proc/IsAssemblyHolder()
+	return 0

code/modules/assembly/holder.dm

@@ -0,0 +1,274 @@
+/obj/item/device/assembly_holder
+	name = "Assembly"
+	icon = 'icons/obj/assemblies/new_assemblies.dmi'
+	icon_state = "holder"
+	item_state = "assembly"
+	flags = FPRINT | TABLEPASS| CONDUCT
+	throwforce = 5
+	w_class = 2.0
+	throw_speed = 3
+	throw_range = 10
+
+	var/secured = 0
+	var/obj/item/device/assembly/a_left = null
+	var/obj/item/device/assembly/a_right = null
+	var/obj/special_assembly = null
+
+	proc/attach(var/obj/item/device/D, var/obj/item/device/D2, var/mob/user)
+		return
+
+	proc/attach_special(var/obj/O, var/mob/user)
+		return
+
+	proc/process_activation(var/obj/item/device/D)
+		return
+
+	proc/detached()
+		return
+
+
+	IsAssemblyHolder()
+		return 1
+
+
+	attach(var/obj/item/device/D, var/obj/item/device/D2, var/mob/user)
+		if((!D)||(!D2))	return 0
+		if((!isassembly(D))||(!isassembly(D2)))	return 0
+		if((D:secured)||(D2:secured))	return 0
+		if(user)
+			user.remove_from_mob(D)
+			user.remove_from_mob(D2)
+		D:holder = src
+		D2:holder = src
+		D.loc = src
+		D2.loc = src
+		a_left = D
+		a_right = D2
+		name = "[D.name]-[D2.name] assembly"
+		update_icon()
+		usr.put_in_hands(src)
+
+		return 1
+
+
+	attach_special(var/obj/O, var/mob/user)
+		if(!O)	return
+		if(!O.IsSpecialAssembly())	return 0
+
+/*		if(O:Attach_Holder())
+			special_assembly = O
+			update_icon()
+			src.name = "[a_left.name] [a_right.name] [special_assembly.name] assembly"
+*/
+		return
+
+
+	update_icon()
+		overlays.Cut()
+		if(a_left)
+			overlays += "[a_left.icon_state]_left"
+			for(var/O in a_left.attached_overlays)
+				overlays += "[O]_l"
+		if(a_right)
+			src.overlays += "[a_right.icon_state]_right"
+			for(var/O in a_right.attached_overlays)
+				overlays += "[O]_r"
+		if(master)
+			master.update_icon()
+
+/*		if(special_assembly)
+			special_assembly.update_icon()
+			if(special_assembly:small_icon_state)
+				src.overlays += special_assembly:small_icon_state
+				for(var/O in special_assembly:small_icon_state_overlays)
+					src.overlays += O
+*/
+
+	examine()
+		set src in view()
+		..()
+		if ((in_range(src, usr) || src.loc == usr))
+			if (src.secured)
+				usr << "\The [src] is ready!"
+			else
+				usr << "\The [src] can be attached!"
+		return
+
+
+	HasProximity(atom/movable/AM as mob|obj)
+		if(a_left)
+			a_left.HasProximity(AM)
+		if(a_right)
+			a_right.HasProximity(AM)
+		if(special_assembly)
+			special_assembly.HasProximity(AM)
+
+
+	HasEntered(atom/movable/AM as mob|obj)
+		if(a_left)
+			a_left.HasEntered(AM)
+		if(a_right)
+			a_right.HasEntered(AM)
+		if(special_assembly)
+			special_assembly.HasEntered(AM)
+
+
+	on_found(mob/finder as mob)
+		if(a_left)
+			a_left.on_found(finder)
+		if(a_right)
+			a_right.on_found(finder)
+		if(special_assembly)
+			if(istype(special_assembly, /obj/item))
+				var/obj/item/S = special_assembly
+				S.on_found(finder)
+
+
+	Move()
+		..()
+		if(a_left && a_right)
+			a_left.holder_movement()
+			a_right.holder_movement()
+//		if(special_assembly)
+//			special_assembly:holder_movement()
+		return
+
+
+	attack_hand()//Perhapse this should be a holder_pickup proc instead, can add if needbe I guess
+		if(a_left && a_right)
+			a_left.holder_movement()
+			a_right.holder_movement()
+//		if(special_assembly)
+//			special_assembly:Holder_Movement()
+		..()
+		return
+
+
+	attackby(obj/item/weapon/W as obj, mob/user as mob)
+		if(isscrewdriver(W))
+			if(!a_left || !a_right)
+				user << "\red BUG:Assembly part missing, please report this!"
+				return
+			a_left.toggle_secure()
+			a_right.toggle_secure()
+			secured = !secured
+			if(secured)
+				user << "\blue \The [src] is ready!"
+			else
+				user << "\blue \The [src] can now be taken apart!"
+			update_icon()
+			return
+		else if(W.IsSpecialAssembly())
+			attach_special(W, user)
+		else
+			..()
+		return
+
+
+	attack_self(mob/user as mob)
+		src.add_fingerprint(user)
+		if(src.secured)
+			if(!a_left || !a_right)
+				user << "\red Assembly part missing!"
+				return
+			if(istype(a_left,a_right.type))//If they are the same type it causes issues due to window code
+				switch(alert("Which side would you like to use?",,"Left","Right"))
+					if("Left")	a_left.attack_self(user)
+					if("Right")	a_right.attack_self(user)
+				return
+			else
+				if(!istype(a_left,/obj/item/device/assembly/igniter))
+					a_left.attack_self(user)
+				if(!istype(a_right,/obj/item/device/assembly/igniter))
+					a_right.attack_self(user)
+		else
+			var/turf/T = get_turf(src)
+			if(!T)	return 0
+			if(a_left)
+				a_left:holder = null
+				a_left.loc = T
+			if(a_right)
+				a_right:holder = null
+				a_right.loc = T
+			spawn(0)
+				del(src)
+		return
+
+
+	process_activation(var/obj/D, var/normal = 1, var/special = 1)
+		if(!D)	return 0
+		if(!secured)
+			visible_message("\icon[src] *beep* *beep*", "*beep* *beep*")
+		if((normal) && (a_right) && (a_left))
+			if(a_right != D)
+				a_right.pulsed(0)
+			if(a_left != D)
+				a_left.pulsed(0)
+		if(master)
+			master.receive_signal()
+//		if(special && special_assembly)
+//			if(!special_assembly == D)
+//				special_assembly.dothings()
+		return 1
+
+
+
+
+
+
+
+/obj/item/device/assembly_holder/timer_igniter
+	name = "timer-igniter assembly"
+
+	New()
+		..()
+
+		var/obj/item/device/assembly/igniter/ign = new(src)
+		ign.secured = 1
+		ign.holder = src
+		var/obj/item/device/assembly/timer/tmr = new(src)
+		tmr.time=5
+		tmr.secured = 1
+		tmr.holder = src
+		processing_objects.Add(tmr)
+		a_left = tmr
+		a_right = ign
+		secured = 1
+		update_icon()
+		name = initial(name) + " ([tmr.time] secs)"
+
+		loc.verbs += /obj/item/device/assembly_holder/timer_igniter/verb/configure
+
+	detached()
+		loc.verbs -= /obj/item/device/assembly_holder/timer_igniter/verb/configure
+		..()
+
+	verb/configure()
+		set name = "Set Timer"
+		set category = "Object"
+		set src in usr
+
+		if ( !(usr.stat || usr.restrained()) )
+			var/obj/item/device/assembly_holder/holder
+			if(istype(src,/obj/item/weapon/grenade/chem_grenade))
+				var/obj/item/weapon/grenade/chem_grenade/gren = src
+				holder=gren.detonator
+			var/obj/item/device/assembly/timer/tmr = holder.a_left
+			if(!istype(tmr,/obj/item/device/assembly/timer))
+				tmr = holder.a_right
+			if(!istype(tmr,/obj/item/device/assembly/timer))
+				usr << "<span class='notice'>This detonator has no timer.</span>"
+				return
+
+			if(tmr.timing)
+				usr << "<span class='notice'>Clock is ticking already.</span>"
+			else
+				var/ntime = input("Enter desired time in seconds", "Time", "5") as num
+				if (ntime>0 && ntime<1000)
+					tmr.time = ntime
+					name = initial(name) + "([tmr.time] secs)"
+					usr << "<span class='notice'>Timer set to [tmr.time] seconds.</span>"
+				else
+					usr << "<span class='notice'>Timer can't be [ntime<=0?"negative":"more than 1000 seconds"].</span>"
+		else
+			usr << "<span class='notice'>You cannot do this while [usr.stat?"unconscious/dead":"restrained"].</span>"

code/modules/assembly/igniter.dm

@@ -0,0 +1,39 @@
+/obj/item/device/assembly/igniter
+	name = "igniter"
+	desc = "A small electronic device able to ignite combustable substances."
+	icon_state = "igniter"
+	m_amt = 500
+	g_amt = 50
+	w_amt = 10
+	origin_tech = "magnets=1"
+
+	secured = 1
+	wires = WIRE_RECEIVE
+
+	activate()
+		if(!..())	return 0//Cooldown check
+
+		if(holder && istype(holder.loc,/obj/item/weapon/grenade/chem_grenade))
+			var/obj/item/weapon/grenade/chem_grenade/grenade = holder.loc
+			grenade.prime()
+		else
+			var/turf/location = get_turf(loc)
+			if(location)
+				location.hotspot_expose(1000,1000)
+			if (istype(src.loc,/obj/item/device/assembly_holder))
+				if (istype(src.loc.loc, /obj/structure/reagent_dispensers/fueltank/))
+					var/obj/structure/reagent_dispensers/fueltank/tank = src.loc.loc
+					if (tank && tank.modded)
+						tank.explode()
+
+			var/datum/effect/effect/system/spark_spread/s = new /datum/effect/effect/system/spark_spread
+			s.set_up(3, 1, src)
+			s.start()
+
+		return 1
+
+
+	attack_self(mob/user as mob)
+		activate()
+		add_fingerprint(user)
+		return

code/modules/assembly/infrared.dm

@@ -0,0 +1,267 @@
+//This file was auto-corrected by findeclaration.exe on 25.5.2012 20:42:32
+
+/obj/item/device/assembly/infra
+	name = "infrared emitter"
+	desc = "Emits a visible or invisible beam and is triggered when the beam is interrupted."
+	icon_state = "infrared"
+	m_amt = 1000
+	g_amt = 500
+	w_amt = 100
+	origin_tech = "magnets=2"
+
+	wires = WIRE_PULSE
+
+	secured = 0
+
+	var/on = 0
+	var/visible = 0
+	var/obj/effect/beam/i_beam/first = null
+
+	proc
+		trigger_beam()
+
+
+	activate()
+		if(!..())	return 0//Cooldown check
+		on = !on
+		update_icon()
+		return 1
+
+
+	toggle_secure()
+		secured = !secured
+		if(secured)
+			processing_objects.Add(src)
+		else
+			on = 0
+			if(first)	del(first)
+			processing_objects.Remove(src)
+		update_icon()
+		return secured
+
+
+	update_icon()
+		overlays.Cut()
+		attached_overlays = list()
+		if(on)
+			overlays += "infrared_on"
+			attached_overlays += "infrared_on"
+
+		if(holder)
+			holder.update_icon()
+		return
+
+
+	process()//Old code
+		if(!on)
+			if(first)
+				del(first)
+				return
+
+		if((!(first) && (secured && (istype(loc, /turf) || (holder && istype(holder.loc, /turf))))))
+			var/obj/effect/beam/i_beam/I = new /obj/effect/beam/i_beam((holder ? holder.loc : loc) )
+			I.master = src
+			I.density = 1
+			I.dir = dir
+			step(I, I.dir)
+			if(I)
+				I.density = 0
+				first = I
+				I.vis_spread(visible)
+				spawn(0)
+					if(I)
+						//world << "infra: setting limit"
+						I.limit = 8
+						//world << "infra: processing beam \ref[I]"
+						I.process()
+					return
+		return
+
+
+	attack_hand()
+		del(first)
+		..()
+		return
+
+
+	Move()
+		var/t = dir
+		..()
+		dir = t
+		del(first)
+		return
+
+
+	holder_movement()
+		if(!holder)	return 0
+//		dir = holder.dir
+		del(first)
+		return 1
+
+
+	trigger_beam()
+		if((!secured)||(!on)||(cooldown > 0))	return 0
+		pulse(0)
+		if(!holder)
+			visible_message("\icon[src] *beep* *beep*")
+		cooldown = 2
+		spawn(10)
+			process_cooldown()
+		return
+
+
+	interact(mob/user as mob)//TODO: change this this to the wire control panel
+		if(!secured)	return
+		user.set_machine(src)
+		var/dat = text("<TT><B>Infrared Laser</B>\n<B>Status</B>: []<BR>\n<B>Visibility</B>: []<BR>\n</TT>", (on ? text("<A href='?src=\ref[];state=0'>On</A>", src) : text("<A href='?src=\ref[];state=1'>Off</A>", src)), (src.visible ? text("<A href='?src=\ref[];visible=0'>Visible</A>", src) : text("<A href='?src=\ref[];visible=1'>Invisible</A>", src)))
+		dat += "<BR><BR><A href='?src=\ref[src];refresh=1'>Refresh</A>"
+		dat += "<BR><BR><A href='?src=\ref[src];close=1'>Close</A>"
+		user << browse(dat, "window=infra")
+		onclose(user, "infra")
+		return
+
+
+	Topic(href, href_list)
+		..()
+		if(!usr.canmove || usr.stat || usr.restrained() || !in_range(loc, usr))
+			usr << browse(null, "window=infra")
+			onclose(usr, "infra")
+			return
+
+		if(href_list["state"])
+			on = !(on)
+			update_icon()
+
+		if(href_list["visible"])
+			visible = !(visible)
+			spawn(0)
+				if(first)
+					first.vis_spread(visible)
+
+		if(href_list["close"])
+			usr << browse(null, "window=infra")
+			return
+
+		if(usr)
+			attack_self(usr)
+
+		return
+
+
+	verb/rotate()//This could likely be better
+		set name = "Rotate Infrared Laser"
+		set category = "Object"
+		set src in usr
+
+		dir = turn(dir, 90)
+		return
+
+
+
+/***************************IBeam*********************************/
+
+/obj/effect/beam/i_beam
+	name = "i beam"
+	icon = 'icons/obj/projectiles.dmi'
+	icon_state = "ibeam"
+	var/obj/effect/beam/i_beam/next = null
+	var/obj/item/device/assembly/infra/master = null
+	var/limit = null
+	var/visible = 0.0
+	var/left = null
+	anchored = 1.0
+	flags = TABLEPASS
+
+
+/obj/effect/beam/i_beam/proc/hit()
+	//world << "beam \ref[src]: hit"
+	if(master)
+		//world << "beam hit \ref[src]: calling master \ref[master].hit"
+		master.trigger_beam()
+	del(src)
+	return
+
+/obj/effect/beam/i_beam/proc/vis_spread(v)
+	//world << "i_beam \ref[src] : vis_spread"
+	visible = v
+	spawn(0)
+		if(next)
+			//world << "i_beam \ref[src] : is next [next.type] \ref[next], calling spread"
+			next.vis_spread(v)
+		return
+	return
+
+/obj/effect/beam/i_beam/process()
+	//world << "i_beam \ref[src] : process"
+
+	if((loc.density || !(master)))
+	//	world << "beam hit loc [loc] or no master [master], deleting"
+		del(src)
+		return
+	//world << "proccess: [src.left] left"
+
+	if(left > 0)
+		left--
+	if(left < 1)
+		if(!(visible))
+			invisibility = 101
+		else
+			invisibility = 0
+	else
+		invisibility = 0
+
+
+	//world << "now [src.left] left"
+	var/obj/effect/beam/i_beam/I = new /obj/effect/beam/i_beam(loc)
+	I.master = master
+	I.density = 1
+	I.dir = dir
+	//world << "created new beam \ref[I] at [I.x] [I.y] [I.z]"
+	step(I, I.dir)
+
+	if(I)
+		//world << "step worked, now at [I.x] [I.y] [I.z]"
+		if(!(next))
+			//world << "no next"
+			I.density = 0
+			//world << "spreading"
+			I.vis_spread(visible)
+			next = I
+			spawn(0)
+				//world << "limit = [limit] "
+				if((I && limit > 0))
+					I.limit = limit - 1
+					//world << "calling next process"
+					I.process()
+				return
+		else
+			//world << "is a next: \ref[next], deleting beam \ref[I]"
+			del(I)
+	else
+		//world << "step failed, deleting \ref[next]"
+		del(next)
+	spawn(10)
+		process()
+		return
+	return
+
+/obj/effect/beam/i_beam/Bump()
+	del(src)
+	return
+
+/obj/effect/beam/i_beam/Bumped()
+	hit()
+	return
+
+/obj/effect/beam/i_beam/HasEntered(atom/movable/AM as mob|obj)
+	if(istype(AM, /obj/effect/beam))
+		return
+	spawn(0)
+		hit()
+		return
+	return
+
+/obj/effect/beam/i_beam/Del()
+	del(next)
+	..()
+	return

code/modules/assembly/mousetrap.dm

@@ -0,0 +1,128 @@
+/obj/item/device/assembly/mousetrap
+	name = "mousetrap"
+	desc = "A handy little spring-loaded trap for catching pesty rodents."
+	icon_state = "mousetrap"
+	m_amt = 100
+	w_amt = 10
+	origin_tech = "combat=1"
+	var/armed = 0
+
+
+	examine()
+		..()
+		if(armed)
+			usr << "It looks like it's armed."
+
+	update_icon()
+		if(armed)
+			icon_state = "mousetraparmed"
+		else
+			icon_state = "mousetrap"
+		if(holder)
+			holder.update_icon()
+
+	proc/triggered(mob/target as mob, var/type = "feet")
+		if(!armed)
+			return
+		var/datum/organ/external/affecting = null
+		if(ishuman(target))
+			var/mob/living/carbon/human/H = target
+			switch(type)
+				if("feet")
+					if(!H.shoes)
+						affecting = H.get_organ(pick("l_leg", "r_leg"))
+						H.Weaken(3)
+				if("l_hand", "r_hand")
+					if(!H.gloves)
+						affecting = H.get_organ(type)
+						H.Stun(3)
+			if(affecting)
+				if(affecting.take_damage(1, 0))
+					H.UpdateDamageIcon()
+				H.updatehealth()
+		else if(ismouse(target))
+			var/mob/living/simple_animal/mouse/M = target
+			visible_message("\red <b>SPLAT!</b>")
+			M.splat()
+		playsound(target.loc, 'sound/effects/snap.ogg', 50, 1)
+		layer = MOB_LAYER - 0.2
+		armed = 0
+		update_icon()
+		pulse(0)
+
+
+	attack_self(mob/living/user as mob)
+		if(!armed)
+			user << "<span class='notice'>You arm [src].</span>"
+		else
+			if(((user.getBrainLoss() >= 60 || (CLUMSY in user.mutations)) && prob(50)))
+				var/which_hand = "l_hand"
+				if(!user.hand)
+					which_hand = "r_hand"
+				triggered(user, which_hand)
+				user.visible_message("<span class='warning'>[user] accidentally sets off [src], breaking their fingers.</span>", \
+									 "<span class='warning'>You accidentally trigger [src]!</span>")
+				return
+			user << "<span class='notice'>You disarm [src].</span>"
+		armed = !armed
+		update_icon()
+		playsound(user.loc, 'sound/weapons/handcuffs.ogg', 30, 1, -3)
+
+
+	attack_hand(mob/living/user as mob)
+		if(armed)
+			if(((user.getBrainLoss() >= 60 || CLUMSY in user.mutations)) && prob(50))
+				var/which_hand = "l_hand"
+				if(!user.hand)
+					which_hand = "r_hand"
+				triggered(user, which_hand)
+				user.visible_message("<span class='warning'>[user] accidentally sets off [src], breaking their fingers.</span>", \
+									 "<span class='warning'>You accidentally trigger [src]!</span>")
+				return
+		..()
+
+
+	HasEntered(AM as mob|obj)
+		if(armed)
+			if(ishuman(AM))
+				var/mob/living/carbon/H = AM
+				if(H.m_intent == "run")
+					triggered(H)
+					H.visible_message("<span class='warning'>[H] accidentally steps on [src].</span>", \
+									  "<span class='warning'>You accidentally step on [src]</span>")
+			if(ismouse(AM))
+				triggered(AM)
+		..()
+
+
+	on_found(mob/finder as mob)
+		if(armed)
+			finder.visible_message("<span class='warning'>[finder] accidentally sets off [src], breaking their fingers.</span>", \
+								   "<span class='warning'>You accidentally trigger [src]!</span>")
+			triggered(finder, finder.hand ? "l_hand" : "r_hand")
+			return 1	//end the search!
+		return 0
+
+
+	hitby(A as mob|obj)
+		if(!armed)
+			return ..()
+		visible_message("<span class='warning'>[src] is triggered by [A].</span>")
+		triggered(null)
+
+
+/obj/item/device/assembly/mousetrap/armed
+	icon_state = "mousetraparmed"
+	armed = 1
+
+
+/obj/item/device/assembly/mousetrap/verb/hide_under()
+	set src in oview(1)
+	set name = "Hide"
+	set category = "Object"
+
+	if(usr.stat)
+		return
+
+	layer = TURF_LAYER+0.2
+	usr << "<span class='notice'>You hide [src].</span>"

code/modules/assembly/proximity.dm

@@ -0,0 +1,165 @@
+/obj/item/device/assembly/prox_sensor
+	name = "proximity sensor"
+	desc = "Used for scanning and alerting when someone enters a certain proximity."
+	icon_state = "prox"
+	m_amt = 800
+	g_amt = 200
+	w_amt = 50
+	origin_tech = "magnets=1"
+
+	wires = WIRE_PULSE
+
+	secured = 0
+
+	var/scanning = 0
+	var/timing = 0
+	var/time = 10
+
+	var/range = 2
+
+	proc
+		toggle_scan()
+		sense()
+
+
+	activate()
+		if(!..())	return 0//Cooldown check
+		timing = !timing
+		update_icon()
+		return 0
+
+
+	toggle_secure()
+		secured = !secured
+		if(secured)
+			processing_objects.Add(src)
+		else
+			scanning = 0
+			timing = 0
+			processing_objects.Remove(src)
+		update_icon()
+		return secured
+
+
+	HasProximity(atom/movable/AM as mob|obj)
+		if (istype(AM, /obj/effect/beam))	return
+		if (AM.move_speed < 12)	sense()
+		return
+
+
+	sense()
+		var/turf/mainloc = get_turf(src)
+//		if(scanning && cooldown <= 0)
+//			mainloc.visible_message("\icon[src] *boop* *boop*", "*boop* *boop*")
+		if((!holder && !secured)||(!scanning)||(cooldown > 0))	return 0
+		pulse(0)
+		if(!holder)
+			mainloc.visible_message("\icon[src] *beep* *beep*", "*beep* *beep*")
+		cooldown = 2
+		spawn(10)
+			process_cooldown()
+		return
+
+
+	process()
+		if(scanning)
+			var/turf/mainloc = get_turf(src)
+			for(var/mob/living/A in range(range,mainloc))
+				if (A.move_speed < 12)
+					sense()
+
+		if(timing && (time >= 0))
+			time--
+		if(timing && time <= 0)
+			timing = 0
+			toggle_scan()
+			time = 10
+		return
+
+
+	dropped()
+		spawn(0)
+			sense()
+			return
+		return
+
+
+	toggle_scan()
+		if(!secured)	return 0
+		scanning = !scanning
+		update_icon()
+		return
+
+
+	update_icon()
+		overlays.Cut()
+		attached_overlays = list()
+		if(timing)
+			overlays += "prox_timing"
+			attached_overlays += "prox_timing"
+		if(scanning)
+			overlays += "prox_scanning"
+			attached_overlays += "prox_scanning"
+		if(holder)
+			holder.update_icon()
+		if(holder && istype(holder.loc,/obj/item/weapon/grenade/chem_grenade))
+			var/obj/item/weapon/grenade/chem_grenade/grenade = holder.loc
+			grenade.primed(scanning)
+		return
+
+
+	Move()
+		..()
+		sense()
+		return
+
+
+	interact(mob/user as mob)//TODO: Change this to the wires thingy
+		if(!secured)
+			user.show_message("\red The [name] is unsecured!")
+			return 0
+		var/second = time % 60
+		var/minute = (time - second) / 60
+		var/dat = text("<TT><B>Proximity Sensor</B>\n[] []:[]\n<A href='?src=\ref[];tp=-30'>-</A> <A href='?src=\ref[];tp=-1'>-</A> <A href='?src=\ref[];tp=1'>+</A> <A href='?src=\ref[];tp=30'>+</A>\n</TT>", (timing ? text("<A href='?src=\ref[];time=0'>Arming</A>", src) : text("<A href='?src=\ref[];time=1'>Not Arming</A>", src)), minute, second, src, src, src, src)
+		dat += text("<BR>Range: <A href='?src=\ref[];range=-1'>-</A> [] <A href='?src=\ref[];range=1'>+</A>", src, range, src)
+		dat += "<BR><A href='?src=\ref[src];scanning=1'>[scanning?"Armed":"Unarmed"]</A> (Movement sensor active when armed!)"
+		dat += "<BR><BR><A href='?src=\ref[src];refresh=1'>Refresh</A>"
+		dat += "<BR><BR><A href='?src=\ref[src];close=1'>Close</A>"
+		user << browse(dat, "window=prox")
+		onclose(user, "prox")
+		return
+
+
+	Topic(href, href_list)
+		..()
+		if(!usr.canmove || usr.stat || usr.restrained() || !in_range(loc, usr))
+			usr << browse(null, "window=prox")
+			onclose(usr, "prox")
+			return
+
+		if(href_list["scanning"])
+			toggle_scan()
+
+		if(href_list["time"])
+			timing = text2num(href_list["time"])
+			update_icon()
+
+		if(href_list["tp"])
+			var/tp = text2num(href_list["tp"])
+			time += tp
+			time = min(max(round(time), 0), 600)
+
+		if(href_list["range"])
+			var/r = text2num(href_list["range"])
+			range += r
+			range = min(max(range, 1), 5)
+
+		if(href_list["close"])
+			usr << browse(null, "window=prox")
+			return
+
+		if(usr)
+			attack_self(usr)
+
+
+		return

code/modules/assembly/shock_kit.dm

@@ -0,0 +1,46 @@
+/obj/item/assembly/shock_kit
+	name = "electrohelmet assembly"
+	desc = "This appears to be made from both an electropack and a helmet."
+	icon_state = "shock_kit"
+	var/obj/item/clothing/head/helmet/part1 = null
+	var/obj/item/device/radio/electropack/part2 = null
+	var/status = 0
+	w_class = 5.0
+	flags = FPRINT | TABLEPASS| CONDUCT
+
+/obj/item/assembly/shock_kit/Del()
+	del(part1)
+	del(part2)
+	..()
+	return
+
+/obj/item/assembly/shock_kit/attackby(obj/item/weapon/W as obj, mob/user as mob)
+	if(istype(W, /obj/item/weapon/wrench) && !status)
+		var/turf/T = loc
+		if(ismob(T))
+			T = T.loc
+		part1.loc = T
+		part2.loc = T
+		part1.master = null
+		part2.master = null
+		part1 = null
+		part2 = null
+		del(src)
+		return
+	if(istype(W, /obj/item/weapon/screwdriver))
+		status = !status
+		user << "<span class='notice'>[src] is now [status ? "secured" : "unsecured"]!</span>"
+	add_fingerprint(user)
+	return
+
+/obj/item/assembly/shock_kit/attack_self(mob/user as mob)
+	part1.attack_self(user, status)
+	part2.attack_self(user, status)
+	add_fingerprint(user)
+	return
+
+/obj/item/assembly/shock_kit/receive_signal()
+	if(istype(loc, /obj/structure/stool/bed/chair/e_chair))
+		var/obj/structure/stool/bed/chair/e_chair/C = loc
+		C.shock()
+	return

code/modules/assembly/signaler.dm

@@ -0,0 +1,174 @@
+/obj/item/device/assembly/signaler
+	name = "remote signaling device"
+	desc = "Used to remotely activate devices."
+	icon_state = "signaller"
+	item_state = "signaler"
+	m_amt = 1000
+	g_amt = 200
+	w_amt = 100
+	origin_tech = "magnets=1"
+	wires = WIRE_RECEIVE | WIRE_PULSE | WIRE_RADIO_PULSE | WIRE_RADIO_RECEIVE
+
+	secured = 1
+
+	var/code = 30
+	var/frequency = 1457
+	var/delay = 0
+	var/airlock_wire = null
+	var/datum/radio_frequency/radio_connection
+	var/deadman = 0
+
+	New()
+		..()
+		spawn(40)
+			set_frequency(frequency)
+		return
+
+
+	activate()
+		if(cooldown > 0)	return 0
+		cooldown = 2
+		spawn(10)
+			process_cooldown()
+
+		signal()
+		return 1
+
+	update_icon()
+		if(holder)
+			holder.update_icon()
+		return
+
+	interact(mob/user as mob, flag1)
+		var/t1 = "-------"
+//		if ((src.b_stat && !( flag1 )))
+//			t1 = text("-------<BR>\nGreen Wire: []<BR>\nRed Wire:   []<BR>\nBlue Wire:  []<BR>\n", (src.wires & 4 ? text("<A href='?src=\ref[];wires=4'>Cut Wire</A>", src) : text("<A href='?src=\ref[];wires=4'>Mend Wire</A>", src)), (src.wires & 2 ? text("<A href='?src=\ref[];wires=2'>Cut Wire</A>", src) : text("<A href='?src=\ref[];wires=2'>Mend Wire</A>", src)), (src.wires & 1 ? text("<A href='?src=\ref[];wires=1'>Cut Wire</A>", src) : text("<A href='?src=\ref[];wires=1'>Mend Wire</A>", src)))
+//		else
+//			t1 = "-------"	Speaker: [src.listening ? "<A href='byond://?src=\ref[src];listen=0'>Engaged</A>" : "<A href='byond://?src=\ref[src];listen=1'>Disengaged</A>"]<BR>
+		var/dat = {"
+	<TT>
+
+	<A href='byond://?src=\ref[src];send=1'>Send Signal</A><BR>
+	<B>Frequency/Code</B> for signaler:<BR>
+	Frequency:
+	<A href='byond://?src=\ref[src];freq=-10'>-</A>
+	<A href='byond://?src=\ref[src];freq=-2'>-</A>
+	[format_frequency(src.frequency)]
+	<A href='byond://?src=\ref[src];freq=2'>+</A>
+	<A href='byond://?src=\ref[src];freq=10'>+</A><BR>
+
+	Code:
+	<A href='byond://?src=\ref[src];code=-5'>-</A>
+	<A href='byond://?src=\ref[src];code=-1'>-</A>
+	[src.code]
+	<A href='byond://?src=\ref[src];code=1'>+</A>
+	<A href='byond://?src=\ref[src];code=5'>+</A><BR>
+	[t1]
+	</TT>"}
+		user << browse(dat, "window=radio")
+		onclose(user, "radio")
+		return
+
+
+	Topic(href, href_list)
+		..()
+
+		if(!usr.canmove || usr.stat || usr.restrained() || !in_range(loc, usr))
+			usr << browse(null, "window=radio")
+			onclose(usr, "radio")
+			return
+
+		if (href_list["freq"])
+			var/new_frequency = (frequency + text2num(href_list["freq"]))
+			if(new_frequency < 1200 || new_frequency > 1600)
+				new_frequency = sanitize_frequency(new_frequency)
+			set_frequency(new_frequency)
+
+		if(href_list["code"])
+			src.code += text2num(href_list["code"])
+			src.code = round(src.code)
+			src.code = min(100, src.code)
+			src.code = max(1, src.code)
+
+		if(href_list["send"])
+			spawn( 0 )
+				signal()
+
+		if(usr)
+			attack_self(usr)
+
+		return
+
+
+	proc/signal()
+		if(!radio_connection) return
+
+		var/datum/signal/signal = new
+		signal.source = src
+		signal.encryption = code
+		signal.data["message"] = "ACTIVATE"
+		radio_connection.post_signal(src, signal)
+		return
+/*
+		for(var/obj/item/device/assembly/signaler/S in world)
+			if(!S)	continue
+			if(S == src)	continue
+			if((S.frequency == src.frequency) && (S.code == src.code))
+				spawn(0)
+					if(S)	S.pulse(0)
+		return 0*/
+
+
+	pulse(var/radio = 0)
+		if(istype(src.loc, /obj/machinery/door/airlock) && src.airlock_wire && src.wires)
+			var/obj/machinery/door/airlock/A = src.loc
+			A.pulse(src.airlock_wire)
+		else if(holder)
+			holder.process_activation(src, 1, 0)
+		else
+			..(radio)
+		return 1
+
+
+	receive_signal(datum/signal/signal)
+		if(!signal)	return 0
+		if(signal.encryption != code)	return 0
+		if(!(src.wires & WIRE_RADIO_RECEIVE))	return 0
+		pulse(1)
+
+		if(!holder)
+			for(var/mob/O in hearers(1, src.loc))
+				O.show_message(text("\icon[] *beep* *beep*", src), 3, "*beep* *beep*", 2)
+		return
+
+
+	proc/set_frequency(new_frequency)
+		if(!radio_controller)
+			sleep(20)
+		if(!radio_controller)
+			return
+		radio_controller.remove_object(src, frequency)
+		frequency = new_frequency
+		radio_connection = radio_controller.add_object(src, frequency, RADIO_CHAT)
+		return
+
+	process()
+		if(!deadman)
+			processing_objects.Remove(src)
+		var/mob/M = src.loc
+		if(!M || !ismob(M))
+			if(prob(5))
+				signal()
+			deadman = 0
+			processing_objects.Remove(src)
+		else if(prob(5))
+			M.visible_message("[M]'s finger twitches a bit over [src]'s signal button!")
+		return
+
+	verb/deadman_it()
+		set src in usr
+		set name = "Threaten to push the button!"
+		set desc = "BOOOOM!"
+		deadman = 1
+		processing_objects.Add(src)
+		usr.visible_message("\red [usr] moves their finger over [src]'s signal button...")

code/modules/assembly/timer.dm

@@ -0,0 +1,110 @@
+/obj/item/device/assembly/timer
+	name = "timer"
+	desc = "Used to time things. Works well with contraptions which has to count down. Tick tock."
+	icon_state = "timer"
+	m_amt = 500
+	g_amt = 50
+	w_amt = 10
+	origin_tech = "magnets=1"
+
+	wires = WIRE_PULSE
+
+	secured = 0
+
+	var/timing = 0
+	var/time = 10
+
+	proc
+		timer_end()
+
+
+	activate()
+		if(!..())	return 0//Cooldown check
+		
+		timing = !timing
+
+		update_icon()
+		return 0
+
+
+	toggle_secure()
+		secured = !secured
+		if(secured)
+			processing_objects.Add(src)
+		else
+			timing = 0
+			processing_objects.Remove(src)
+		update_icon()
+		return secured
+
+
+	timer_end()
+		if(!secured)	return 0
+		pulse(0)
+		if(!holder)
+			visible_message("\icon[src] *beep* *beep*", "*beep* *beep*")
+		cooldown = 2
+		spawn(10)
+			process_cooldown()
+		return
+
+
+	process()
+		if(timing && (time > 0))
+			time--
+		if(timing && time <= 0)
+			timing = 0
+			timer_end()
+			time = 10
+		return
+
+
+	update_icon()
+		overlays.Cut()
+		attached_overlays = list()
+		if(timing)
+			overlays += "timer_timing"
+			attached_overlays += "timer_timing"
+		if(holder)
+			holder.update_icon()
+		return
+
+
+	interact(mob/user as mob)//TODO: Have this use the wires
+		if(!secured)
+			user.show_message("\red The [name] is unsecured!")
+			return 0
+		var/second = time % 60
+		var/minute = (time - second) / 60
+		var/dat = text("<TT><B>Timing Unit</B>\n[] []:[]\n<A href='?src=\ref[];tp=-30'>-</A> <A href='?src=\ref[];tp=-1'>-</A> <A href='?src=\ref[];tp=1'>+</A> <A href='?src=\ref[];tp=30'>+</A>\n</TT>", (timing ? text("<A href='?src=\ref[];time=0'>Timing</A>", src) : text("<A href='?src=\ref[];time=1'>Not Timing</A>", src)), minute, second, src, src, src, src)
+		dat += "<BR><BR><A href='?src=\ref[src];refresh=1'>Refresh</A>"
+		dat += "<BR><BR><A href='?src=\ref[src];close=1'>Close</A>"
+		user << browse(dat, "window=timer")
+		onclose(user, "timer")
+		return
+
+
+	Topic(href, href_list)
+		..()
+		if(!usr.canmove || usr.stat || usr.restrained() || !in_range(loc, usr))
+			usr << browse(null, "window=timer")
+			onclose(usr, "timer")
+			return
+
+		if(href_list["time"])
+			timing = text2num(href_list["time"])
+			update_icon()
+
+		if(href_list["tp"])
+			var/tp = text2num(href_list["tp"])
+			time += tp
+			time = min(max(round(time), 0), 600)
+
+		if(href_list["close"])
+			usr << browse(null, "window=timer")
+			return
+
+		if(usr)
+			attack_self(usr)
+
+		return