Reflective Mirrors (#11677)

code/datums/observation/entered.dm

@@ -0,0 +1,24 @@
+//	Observer Pattern Implementation: Entered
+//		Registration type: /atom
+//
+//		Raised when: An /atom/movable instance has entered an atom.
+//
+//		Arguments that the called proc should expect:
+//			/atom/entered: The atom that was entered
+//			/atom/movable/enterer: The instance that entered the atom
+//			/atom/old_loc: The atom the enterer came from
+//
+
+var/datum/observ/entered/entered_event = new()
+
+/datum/observ/entered
+	name = "Entered"
+	expected_type = /atom
+
+/*******************
+* Entered Handling *
+*******************/
+
+/atom/Entered(atom/movable/enterer, atom/old_loc)
+	..()
+	entered_event.raise_event(src, enterer, old_loc)

code/datums/observation/exited.dm

@@ -0,0 +1,24 @@
+//	Observer Pattern Implementation: Exited
+//		Registration type: /atom
+//
+//		Raised when: An /atom/movable instance has exited an atom.
+//
+//		Arguments that the called proc should expect:
+//			/atom/entered: The atom that was exited from
+//			/atom/movable/exitee: The instance that exited the atom
+//			/atom/new_loc: The atom the exitee is now residing in
+//
+
+var/datum/observ/exited/exited_event = new()
+
+/datum/observ/exited
+	name = "Exited"
+	expected_type = /atom
+
+/******************
+* Exited Handling *
+******************/
+
+/atom/Exited(atom/movable/exitee, atom/new_loc)
+	. = ..()
+	exited_event.raise_event(src, exitee, new_loc)

code/game/objects/structures/mirror.dm

@@ -1,4 +1,3 @@
-//wip wip wup
 /obj/structure/mirror
 	name = "mirror"
 	desc = "A SalonPro Nano-Mirror(TM) brand mirror! The leading technology in hair salon products, utilizing nano-machinery to style your hair just right."
@@ -8,6 +7,29 @@
 	anchored = 1
 	var/shattered = 0
 
+	/// Visual object for handling the viscontents
+	var/datum/weakref/ref
+	vis_flags = VIS_HIDE
+	var/timerid = null
+
+/obj/structure/mirror/Initialize()
+	. = ..()
+	var/obj/effect/reflection/reflection = new(src.loc)
+	reflection.setup_visuals(src)
+	ref = WEAKREF(reflection)
+
+	entered_event.register(loc, reflection, /obj/effect/reflection/proc/check_vampire_enter)
+	exited_event.register(loc, reflection, /obj/effect/reflection/proc/check_vampire_exit)
+
+/obj/structure/mirror/Destroy()
+	var/obj/effect/reflection/reflection = ref.resolve()
+	if(istype(reflection))
+		entered_event.unregister(loc, reflection)
+		exited_event.unregister(loc, reflection)
+		qdel(reflection)
+	ref = null
+	return ..()
+
 /obj/structure/mirror/attack_hand(mob/user as mob)
 	if(shattered)
 		return
@@ -28,9 +50,13 @@
 	playsound(src, /decl/sound_category/glass_break_sound, 70, 1)
 	desc = "Oh no, seven years of bad luck!"
 
+	var/obj/effect/reflection/reflection = ref.resolve()
+	if(istype(reflection))
+		reflection.alpha_icon_state = "mirror_mask_broken"
+		reflection.update_mirror_filters()
+
 
 /obj/structure/mirror/bullet_act(var/obj/item/projectile/Proj)
-
 	if(prob(Proj.get_structure_damage() * 2))
 		if(!shattered)
 			shatter()
@@ -64,6 +90,84 @@
 		user.visible_message("<span class='danger'>[user] hits [src] and bounces off!</span>")
 	return 1
 
+/obj/effect/reflection
+	name = "reflection"
+	appearance_flags = KEEP_TOGETHER|TILE_BOUND|PIXEL_SCALE
+	mouse_opacity = 0
+	vis_flags = VIS_HIDE
+	layer = ABOVE_OBJ_LAYER
+	var/alpha_icon = 'icons/obj/watercloset.dmi'
+	var/alpha_icon_state = "mirror_mask"
+	var/obj/mirror
+	desc = "Why are you locked in the bathroom?"
+	anchored = TRUE
+	unacidable = TRUE
+
+	var/blur_filter
+
+/obj/effect/reflection/proc/setup_visuals(target)
+	mirror = target
+
+	if(mirror.pixel_x > 0)
+		dir = WEST
+	else if (mirror.pixel_x < 0)
+		dir = EAST
+
+	if(mirror.pixel_y > 0)
+		dir = SOUTH
+	else if (mirror.pixel_y < 0) 
+		dir = NORTH
+
+	pixel_x = mirror.pixel_x
+	pixel_y = mirror.pixel_y
+
+	blur_filter = filter(type="blur", size = 1)
+
+	update_mirror_filters()
+
+/obj/effect/reflection/proc/update_mirror_filters()
+	filters = null
+
+	vis_contents = null
+
+	if(!mirror)
+		return
+
+	var/matrix/M = matrix()
+	if(dir == WEST || dir == EAST)
+		M.Scale(-1, 1)
+	else if(dir == SOUTH|| dir == NORTH)
+		M.Scale(1, -1)
+		pixel_y = mirror.pixel_y + 5
+
+	transform = M
+
+	filters += filter("type" = "alpha", "icon" = icon(alpha_icon, alpha_icon_state), "x" = 0, "y" = 0)
+	for(var/mob/living/carbon/human/H in loc)
+		check_vampire_enter(H.loc, H)
+
+	vis_contents += get_turf(mirror)
+
+/obj/effect/reflection/proc/check_vampire_enter(var/turf/T, var/mob/living/carbon/human/H)
+	if(!istype(H))
+		return
+	var/datum/vampire/V = H.get_antag_datum(MODE_VAMPIRE)
+	if(V)
+		if(V.status & VAMP_ISTHRALL)
+			filters += blur_filter
+		else
+			H.vis_flags |= VIS_HIDE
+
+/obj/effect/reflection/proc/check_vampire_exit(var/turf/T, var/mob/living/carbon/human/H)
+	if(!istype(H))
+		return
+	var/datum/vampire/V = H.get_antag_datum(MODE_VAMPIRE)
+	if(V)
+		if(V.status & VAMP_ISTHRALL)
+			filters -= blur_filter
+		else
+			H.vis_flags &= ~VIS_HIDE
+
 /obj/item/mirror
 	name = "mirror"
 	desc = "A SalonPro Nano-Mirror(TM) brand mirror! Now a portable version."