Merge pull request #11458 from PsiOmegaDelta/151117-MultitoolPower

Multitool Upgrade

code/datums/expansions/expansion.dm

@@ -0,0 +1,37 @@
+/datum/expansion
+	var/datum/holder = null // The holder
+
+/datum/expansion/New(var/atom/holder)
+	if(!istype(holder))
+		CRASH("Invalid holder.")
+	src.holder = holder
+	..()
+
+/datum/expansion/Destroy()
+	holder = null
+	return ..()
+
+/datum/expansion/CanUseTopic(var/mob/user)
+	return holder && user ? STATUS_INTERACTIVE : STATUS_CLOSE
+
+/datum/expansion/Topic()
+	if(..())
+		return 1
+	if(CanUseTopic(usr) != STATUS_INTERACTIVE)
+		return 1
+	return 0
+
+/obj
+	var/list/datum/expansion/expansions = list()
+
+/obj/Destroy()
+	if(expansions)
+		for(var/expansion in expansions)
+			qdel(expansions[expansion])
+		expansions.Cut()
+	return ..()
+
+/obj/proc/set_expansion(var/type, var/instance)
+	if(expansions[type])
+		qdel(expansions[type])
+	expansions[type] = instance

code/datums/expansions/multitool/_multitool.dm

@@ -0,0 +1,3 @@
+#define MT_NOACTION 0
+#define MT_REFRESH 1
+#define MT_CLOSE 2

code/datums/expansions/multitool/circuitboards/circuitboards.dm

@@ -0,0 +1,5 @@
+/datum/expansion/multitool/circuitboards/CanUseTopic(var/mob/user)
+	if(isAI(user)) // No remote AI access
+		return STATUS_CLOSE
+
+	return ..()

code/datums/expansions/multitool/circuitboards/stationalert.dm

@@ -0,0 +1,29 @@
+/datum/expansion/multitool/circuitboards/stationalert/get_interact_window(var/obj/item/device/multitool/M, var/mob/user)
+	var/obj/item/weapon/circuitboard/stationalert/SA = holder
+	. += "<b>Alarm Sources</b><br>"
+	. += "<table>"
+	for(var/datum/alarm_handler/AH in alarm_manager.all_handlers)
+		. += "<tr>"
+		. += "<td>[AH.category]</td>"
+		if(AH in SA.alarm_handlers)
+			. += "<td><span class='good'>&#9724</span>Active</td><td><a href='?src=\ref[src];remove=\ref[AH]'>Inactivate</a></td>"
+		else
+			. += "<td><span class='bad'>&#9724</span>Inactive</td><td><a href='?src=\ref[src];add=\ref[AH]'>Activate</a></td>"
+		. += "</tr>"
+	. += "</table>"
+
+/datum/expansion/multitool/circuitboards/stationalert/on_topic(href, href_list, usr)
+	var/obj/item/weapon/circuitboard/stationalert/SA = holder
+	if(href_list["add"])
+		var/datum/alarm_handler/AH = locate(href_list["add"]) in alarm_manager.all_handlers
+		if(AH)
+			SA.alarm_handlers |= AH
+			return MT_REFRESH
+
+	if(href_list["remove"])
+		var/datum/alarm_handler/AH = locate(href_list["remove"]) in alarm_manager.all_handlers
+		if(AH)
+			SA.alarm_handlers -= AH
+			return MT_REFRESH
+
+	return ..()

code/datums/expansions/multitool/cloning.dm

@@ -0,0 +1,28 @@
+/datum/expansion/multitool/cryo/get_interact_window(var/obj/item/device/multitool/M, var/mob/user)
+	. += buffer(M)
+	. += "<HR><b>Connected Cloning Pods:</b><br>"
+	var/obj/machinery/computer/cloning/C = holder
+	for(var/atom/cloning_pod in C.pods)
+		. += "[cloning_pod.name]<br>"
+
+/datum/expansion/multitool/cryo/receive_buffer(var/obj/item/device/multitool/M, var/atom/buffer, var/mob/user)
+	var/obj/machinery/clonepod/P = buffer
+	var/obj/machinery/computer/cloning/C = holder
+
+	if(!istype(P))
+		user << "<span class='warning'>No valid connection data in \the [M] buffer.</span>"
+		return MT_NOACTION
+
+	var/is_connected = (P in C.pods)
+	if(!is_connected)
+		if(C.connect_pod(P))
+			user << "<span class='notice'>You connect \the [P] to \the [C].</span>"
+		else
+			user << "<span class='warning'>You failed to connect \the [P] to \the [C].</span>"
+		return MT_REFRESH
+
+	if(C.release_pod(P))
+		user << "<span class='notice'>You disconnect \the [P] from \the [C].</span>"
+	else
+		user << "<span class='notice'>You failed to disconnect \the [P] from \the [C].</span>"
+	return MT_REFRESH

code/datums/expansions/multitool/multitool.dm

@@ -0,0 +1,89 @@
+/datum/expansion/multitool
+	var/window_x = 370
+	var/window_y = 470
+	var/list/interact_predicates
+
+/datum/expansion/multitool/New(var/atom/holder, var/list/can_interact_predicates)
+	..()
+	interact_predicates = can_interact_predicates ? can_interact_predicates : list()
+
+/datum/expansion/multitool/Destroy()
+	interact_predicates.Cut()
+	return ..()
+
+/datum/expansion/multitool/proc/interact(var/obj/item/device/multitool/M, var/mob/user)
+	if(CanUseTopic(user) != STATUS_INTERACTIVE)
+		return
+
+	var/html = get_interact_window(M, user)
+	if(html)
+		var/datum/browser/popup = new(usr, "multitool", "Multitool Menu", window_x, window_y)
+		popup.set_content(html)
+		popup.set_title_image(user.browse_rsc_icon(M.icon, M.icon_state))
+		popup.open()
+	else
+		close_window(usr)
+
+/datum/expansion/multitool/proc/get_interact_window(var/obj/item/device/multitool/M, var/mob/user)
+	return
+
+/datum/expansion/multitool/proc/close_window(var/mob/user)
+	user << browse(null, "window=multitool")
+
+/datum/expansion/multitool/proc/buffer(var/obj/item/device/multitool/multitool)
+	. += "<b>Buffer Memory:</b><br>"
+	var/buffer_name = multitool.get_buffer_name()
+	if(buffer_name)
+		. += "[buffer_name] <a href='?src=\ref[src];send=\ref[multitool.buffer_object]'>Send</a> <a href='?src=\ref[src];purge=1'>Purge</a><br>"
+	else
+		. += "No connection stored in the buffer."
+
+/datum/expansion/multitool/CanUseTopic(var/mob/user)
+	. = ..()
+	if(. == STATUS_CLOSE)
+		return
+
+	if(!user.get_multitool())
+		return STATUS_CLOSE
+
+	if(!all_predicates_true(list(holder, user), interact_predicates))
+		return STATUS_CLOSE
+
+	var/datum/host = holder.nano_host()
+	return user.default_can_use_topic(host)
+
+/datum/expansion/multitool/Topic(href, href_list)
+	if(..())
+		close_window(usr)
+		return 1
+
+	var/mob/user = usr
+	var/obj/item/device/multitool/M = user.get_multitool()
+	if(href_list["send"])
+		var/atom/buffer = locate(href_list["send"])
+		. = send_buffer(M, buffer, user)
+	else if(href_list["purge"])
+		M.set_buffer(null)
+		. = MT_REFRESH
+	else
+		. = on_topic(href, href_list, user)
+
+	switch(.)
+		if(MT_REFRESH)
+			interact(M, user)
+		if(MT_CLOSE)
+			close_window(user)
+	return 1
+
+/datum/expansion/multitool/proc/on_topic(href, href_list, usr)
+	return MT_NOACTION
+
+/datum/expansion/multitool/proc/send_buffer(var/obj/item/device/multitool/M, var/atom/buffer, var/mob/user)
+	if(M.get_buffer() == buffer && buffer)
+		receive_buffer(M, buffer, user)
+	else if(!buffer)
+		user << "<span class='warning'>Unable to acquire data from the buffered object. Purging from memory.</span>"
+	return MT_REFRESH
+
+/datum/expansion/multitool/proc/receive_buffer(var/obj/item/device/multitool/M, var/atom/buffer, var/mob/user)
+	return

code/datums/expansions/multitool/store.dm

@@ -0,0 +1,10 @@
+/datum/expansion/multitool/store/interact(var/obj/item/device/multitool/M, var/mob/user)
+	if(CanUseTopic(user) != STATUS_INTERACTIVE)
+		return
+
+	if(M.get_buffer() == holder)
+		M.set_buffer(null)
+		user << "<span class='warning'>You purge the connection data of \the [holder] from \the [M].</span>"
+	else
+		M.set_buffer(holder)
+		user << "<span class='notice'>You load connection data from \the [holder] to \the [M].</span>"