Aquaponics and Molluscs (#10067)

code/modules/reagents/Chemistry-Reagents/Chemistry-Reagents-Food-Drinks.dm

@@ -229,6 +229,11 @@
 	color = "#f5f4e9"
 	taste_description = "fish"
 
+/datum/reagent/nutriment/protein/seafood/mollusc
+	name = "Mollusc Protein"
+	taste_description = "cold, bitter slime"
+	hydration_factor = 6
+
 /datum/reagent/nutriment/protein/egg // Also bad for skrell.
 	name = "Egg Yolk"
 	color = "#FFFFAA"

code/modules/reagents/reagent_containers/food/snacks/fish.dm

@@ -22,3 +22,82 @@
 /obj/item/reagent_containers/food/snacks/fish/fishfillet
 	name = "fish fillet"
 	desc = "A fillet of fish."
+
+/obj/item/reagent_containers/food/snacks/fish/mollusc
+	name = "slimy meat"
+	desc = "Some slimy meat from clams or molluscs."
+	fish_type = "mollusc"
+	reagents_to_add = list(/datum/reagent/nutriment/protein/seafood/mollusc = 3)
+
+/obj/item/reagent_containers/food/snacks/fish/mollusc/clam
+	fish_type = "clam"
+
+/obj/item/reagent_containers/food/snacks/fish/mollusc/barnacle
+	fish_type = "barnacle"
+
+// Molluscs!
+/obj/item/trash/mollusc_shell
+	name = "mollusc shell"
+	icon = 'icons/obj/molluscs.dmi'
+	icon_state = "mollusc_shell"
+	desc = "The cracked shell of an unfortunate mollusc."
+
+/obj/item/trash/mollusc_shell/clam
+	name = "clamshell"
+	icon_state = "clam_shell"
+
+/obj/item/trash/mollusc_shell/barnacle
+	name = "barnacle shell"
+	icon_state = "barnacle_shell"
+
+/obj/item/mollusc
+	name = "mollusc"
+	w_class = ITEMSIZE_TINY
+	desc = "A small slimy mollusc. Fresh!"
+	desc_info = "You will need a sharp or edged implement to pry it open. You can also try opening it in your hand if you're strong enough."
+	icon = 'icons/obj/molluscs.dmi'
+	icon_state = "mollusc"
+	var/meat_type = /obj/item/reagent_containers/food/snacks/fish/mollusc
+	var/shell_type = /obj/item/trash/mollusc_shell
+
+/obj/item/mollusc/barnacle
+	name = "barnacle"
+	desc = "A hull barnacle, probably freshly scraped off a spaceship."
+	icon_state = "barnacle"
+	meat_type = /obj/item/reagent_containers/food/snacks/fish/mollusc/barnacle
+	shell_type = /obj/item/trash/mollusc_shell/barnacle
+
+/obj/item/mollusc/clam
+	name = "clam"
+	desc = "A free-ranging space clam."
+	icon_state = "clam"
+	meat_type = /obj/item/reagent_containers/food/snacks/fish/mollusc/clam
+	shell_type = /obj/item/trash/mollusc_shell/clam
+
+/obj/item/mollusc/proc/crack_shell(var/mob/user)
+	playsound(loc, /decl/sound_category/pickaxe_sound, 40, TRUE)
+	if(user && loc == user)
+		user.drop_from_inventory(src)
+	if(meat_type)
+		var/obj/item/meat = new meat_type(get_turf(src))
+		if(user)
+			user.put_in_hands(meat)
+	if(shell_type)
+		var/obj/item/shell = new shell_type(get_turf(src))
+		if(user)
+			user.put_in_hands(shell)
+	qdel(src)
+
+/obj/item/mollusc/attack_self(mob/user)
+	if(isvaurca(user) || isipc(user) || isunathi(user))
+		user.visible_message("<b>[user]</b> cracks open \the [src] with their hands.", SPAN_NOTICE("You crack open \the [src] with your hands."))
+		crack_shell(user)
+		return
+	return ..()
+
+/obj/item/mollusc/attackby(var/obj/item/thing, var/mob/user)
+	if(thing.sharp || thing.edge)
+		user.visible_message("<b>[user]</b> cracks open \the [src] with \the [thing].", SPAN_NOTICE("You crack open \the [src] with \the [thing]."))
+		crack_shell(user)
+		return
+	return ..()