Port Integrated Electronics from Polaris (#3371)

Ports Polaris' integrated electronics system, whichallows for Roboticists & Electricians/Engineers to build custom devices and machines for a variety of purposes.

code/modules/integrated_electronics/core/assemblies.dm

@@ -0,0 +1,336 @@
+#define IC_COMPONENTS_BASE 20
+#define IC_COMPLEXITY_BASE 60
+
+/obj/item/device/electronic_assembly
+	name = "electronic assembly"
+	desc = "It's a case, for building small electronics with."
+	w_class = ITEMSIZE_SMALL
+	icon = 'icons/obj/electronic_assemblies.dmi'
+	icon_state = "setup_small"
+	var/max_components = IC_COMPONENTS_BASE
+	var/max_complexity = IC_COMPLEXITY_BASE
+	var/opened = 0
+	var/obj/item/weapon/cell/device/battery // Internal cell which most circuits need to work.
+
+/obj/item/device/electronic_assembly/medium
+	name = "electronic mechanism"
+	icon_state = "setup_medium"
+	desc = "It's a case, for building medium-sized electronics with."
+	w_class = ITEMSIZE_NORMAL
+	max_components = IC_COMPONENTS_BASE * 2
+	max_complexity = IC_COMPLEXITY_BASE * 2
+
+/obj/item/device/electronic_assembly/large
+	name = "electronic machine"
+	icon_state = "setup_large"
+	desc = "It's a case, for building large electronics with."
+	w_class = ITEMSIZE_LARGE
+	max_components = IC_COMPONENTS_BASE * 4
+	max_complexity = IC_COMPLEXITY_BASE * 4
+
+/obj/item/device/electronic_assembly/drone
+	name = "electronic drone"
+	icon_state = "setup_drone"
+	desc = "It's a case, for building mobile electronics with."
+	w_class = ITEMSIZE_NORMAL
+	max_components = IC_COMPONENTS_BASE * 1.5
+	max_complexity = IC_COMPLEXITY_BASE * 1.5
+
+/obj/item/device/electronic_assembly/implant
+	name = "electronic implant"
+	icon_state = "setup_implant"
+	desc = "It's a case, for building very tiny electronics with."
+	w_class = ITEMSIZE_TINY
+	max_components = IC_COMPONENTS_BASE / 2
+	max_complexity = IC_COMPLEXITY_BASE / 2
+	var/obj/item/weapon/implant/integrated_circuit/implant = null
+
+/obj/item/device/electronic_assembly/Initialize(mapload, printed = FALSE)
+	..()
+	if (!printed)
+		battery = new(src)
+	START_PROCESSING(SSelectronics, src)
+
+/obj/item/device/electronic_assembly/Destroy()
+	QDEL_NULL(battery)
+	STOP_PROCESSING(SSelectronics, src)
+	return ..()
+
+/obj/item/device/electronic_assembly/process()
+	handle_idle_power()
+
+/obj/item/device/electronic_assembly/proc/handle_idle_power()
+	// First we generate power.
+	for(var/obj/item/integrated_circuit/passive/power/P in contents)
+		P.make_energy()
+
+	// Now spend it.
+	for(var/obj/item/integrated_circuit/IC in contents)
+		if(IC.power_draw_idle && !draw_power(IC.power_draw_idle))
+			IC.power_fail()
+
+/obj/item/device/electronic_assembly/implant/update_icon()
+	..()
+	implant.icon_state = icon_state
+
+/obj/item/device/electronic_assembly/implant/nano_host()
+	return implant
+
+/obj/item/device/electronic_assembly/proc/resolve_nano_host()
+	return src
+
+/obj/item/device/electronic_assembly/implant/resolve_nano_host()
+	return implant
+
+/obj/item/device/electronic_assembly/proc/check_interactivity(mob/user)
+	if(!CanInteract(user, physical_state))
+		return 0
+	return 1
+
+/obj/item/device/electronic_assembly/interact(mob/user)
+	if(!check_interactivity(user))
+		return
+
+	var/total_parts = 0
+	var/total_complexity = 0
+	for(var/obj/item/integrated_circuit/part in contents)
+		total_parts += part.size
+		total_complexity = total_complexity + part.complexity
+	var/list/HTML = list()
+
+	HTML += "<br><a href='?src=\ref[src]'>Refresh</a>  |  "
+	HTML += "<a href='?src=\ref[src];rename=1'>Rename</a><br>"
+	HTML += "[total_parts]/[max_components] ([round((total_parts / max_components) * 100, 0.1)]%) space taken up in the assembly.<br>"
+	HTML += "[total_complexity]/[max_complexity] ([round((total_complexity / max_complexity) * 100, 0.1)]%) maximum complexity.<br>"
+	if(battery)
+		HTML += "[round(battery.charge, 0.1)]/[battery.maxcharge] ([round(battery.percent(), 0.1)]%) cell charge. <a href='?src=\ref[src];remove_cell=1'>Remove</a>"
+	else
+		HTML += "<span class='danger'>No powercell detected!</span>"
+	HTML += "<br><br>"
+	HTML += "Components:<hr>"
+	HTML += "Built in:<br>"
+
+
+//Put removable circuits in separate categories from non-removable
+	for(var/obj/item/integrated_circuit/circuit in contents)
+		if(!circuit.removable)
+			HTML += "<a href=?src=\ref[circuit];examine=1;from_assembly=1>[circuit.displayed_name]</a> | "
+			HTML += "<a href=?src=\ref[circuit];rename=1;from_assembly=1>Rename</a> | "
+			HTML += "<a href=?src=\ref[circuit];scan=1;from_assembly=1>Scan with Debugger</a> | "
+			HTML += "<a href=?src=\ref[circuit];bottom=\ref[circuit];from_assembly=1>Move to Bottom</a>"
+			HTML += "<br>"
+
+	HTML += "<hr>"
+	HTML += "Removable:<br>"
+
+	for(var/obj/item/integrated_circuit/circuit in contents)
+		if(circuit.removable)
+			HTML += "<a href=?src=\ref[circuit];examine=1;from_assembly=1>[circuit.displayed_name]</a> | "
+			HTML += "<a href=?src=\ref[circuit];rename=1;from_assembly=1>Rename</a> | "
+			HTML += "<a href=?src=\ref[circuit];scan=1;from_assembly=1>Scan with Debugger</a> | "
+			HTML += "<a href=?src=\ref[circuit];remove=1;from_assembly=1>Remove</a> | "
+			HTML += "<a href=?src=\ref[circuit];bottom=\ref[circuit];from_assembly=1>Move to Bottom</a>"
+			HTML += "<br>"
+
+	var/datum/browser/B = new(user, "assembly-\ref[src]", name, 600, 400)
+	B.set_content(HTML.Join())
+	B.open(FALSE)
+
+/obj/item/device/electronic_assembly/Topic(href, href_list[])
+	if(..())
+		return 1
+	if(!opened)
+		to_chat(usr, "<span class='warning'>\The [src] is not open!</span>")
+		return
+
+	if(href_list["rename"])
+		rename(usr)
+
+	if(href_list["remove_cell"])
+		if(!battery)
+			to_chat(usr, "<span class='warning'>There's no power cell to remove from \the [src].</span>")
+		else
+			var/turf/T = get_turf(src)
+			battery.forceMove(T)
+			playsound(T, 'sound/items/Crowbar.ogg', 50, 1)
+			to_chat(usr, "<span class='notice'>You pull \the [battery] out of \the [src]'s power supply.</span>")
+			battery = null
+
+	interact(usr) // To refresh the UI.
+
+/obj/item/device/electronic_assembly/verb/rename()
+	set name = "Rename Circuit"
+	set category = "Object"
+	set desc = "Rename your circuit, useful to stay organized."
+
+	var/mob/M = usr
+	if(!check_interactivity(M))
+		return
+
+	var/input = sanitizeSafe(input("What do you want to name this?", "Rename", src.name) as null|text, MAX_NAME_LEN)
+	if(src && input)
+		to_chat(M, "<span class='notice'>The machine now has a label reading '[input]'.</span>")
+		name = input
+
+/obj/item/device/electronic_assembly/proc/can_move()
+	return FALSE
+
+/obj/item/device/electronic_assembly/drone/can_move()
+	return TRUE
+
+/obj/item/device/electronic_assembly/update_icon()
+	if(opened)
+		icon_state = "[initial(icon_state)]-open"
+	else
+		icon_state = initial(icon_state)
+
+/obj/item/device/electronic_assembly/GetAccess()
+	. = list()
+	for(var/obj/item/integrated_circuit/part in contents)
+		. |= part.GetAccess()
+
+/obj/item/device/electronic_assembly/examine(mob/user)
+	. = ..(user, 1)
+	if(.)
+		for(var/obj/item/integrated_circuit/IC in contents)
+			IC.external_examine(user)
+		if(opened)
+			interact(user)
+
+/obj/item/device/electronic_assembly/proc/get_part_complexity()
+	. = 0
+	for(var/obj/item/integrated_circuit/part in contents)
+		. += part.complexity
+
+/obj/item/device/electronic_assembly/proc/get_part_size()
+	. = 0
+	for(var/obj/item/integrated_circuit/part in contents)
+		. += part.size
+
+// Returns true if the circuit made it inside.
+/obj/item/device/electronic_assembly/proc/add_circuit(obj/item/integrated_circuit/IC, mob/user)
+	if(!opened)
+		to_chat(user, "<span class='warning'>\The [src] isn't opened, so you can't put anything inside.  Try using a crowbar.</span>")
+		return FALSE
+
+	if(IC.w_class > w_class)
+		to_chat(user, "<span class='warning'>\The [IC] is way too big to fit into \the [src].</span>")
+		return FALSE
+
+	var/total_part_size = get_part_size()
+	var/total_complexity = get_part_complexity()
+
+	if((total_part_size + IC.size) > max_components)
+		to_chat(user, "<span class='warning'>You can't seem to add the '[IC.name]', as there's insufficient space.</span>")
+		return FALSE
+	if((total_complexity + IC.complexity) > max_complexity)
+		to_chat(user, "<span class='warning'>You can't seem to add the '[IC.name]', since this setup's too complicated for the case.</span>")
+		return FALSE
+
+	if(!IC.forceMove(src))
+		return FALSE
+
+	IC.assembly = src
+
+	return TRUE
+
+/obj/item/device/electronic_assembly/afterattack(atom/target, mob/user, proximity)
+	if(proximity)
+		var/scanned = FALSE
+		for(var/obj/item/integrated_circuit/input/sensor/S in contents)
+			if(S.scan(target))
+				scanned = TRUE
+		if(scanned)
+			visible_message("<span class='notice'>\The [user] waves \the [src] around [target].</span>")
+
+/obj/item/device/electronic_assembly/attackby(obj/item/I, mob/user)
+	if(istype(I, /obj/item/integrated_circuit))
+		if(!user.unEquip(I))
+			return FALSE
+
+		if(add_circuit(I, user))
+			to_chat(user, "<span class='notice'>You slide \the [I] inside \the [src].</span>")
+			playsound(get_turf(src), 'sound/items/Deconstruct.ogg', 50, 1)
+			interact(user)
+			return TRUE
+
+	else if(istype(I, /obj/item/weapon/crowbar))
+		playsound(get_turf(src), 'sound/items/Crowbar.ogg', 50, 1)
+		opened = !opened
+		to_chat(user, "<span class='notice'>You [opened ? "open" : "close"] \the [src].</span>")
+		update_icon()
+		return TRUE
+
+	else if(istype(I, /obj/item/device/integrated_electronics/wirer) || istype(I, /obj/item/device/integrated_electronics/debugger) || istype(I, /obj/item/weapon/screwdriver))
+		if(opened)
+			interact(user)
+		else
+			to_chat(user, "<span class='warning'>\The [src] isn't open, so you can't fiddle with the internal components.  \
+			Try using a crowbar.</span>")
+
+	else if(istype(I, /obj/item/weapon/cell/device))
+		if(!opened)
+			to_chat(user, "<span class='warning'>\The [src] isn't open, so you can't put anything inside.  Try using a crowbar.</span>")
+			return FALSE
+
+		if(battery)
+			to_chat(user, "<span class='warning'>\The [src] already has \a [battery] inside.  Remove it first if you want to replace it.</span>")
+			return FALSE
+
+		var/obj/item/weapon/cell/device/cell = I
+		user.drop_item(cell)
+		cell.forceMove(src)
+		battery = cell
+		playsound(get_turf(src), 'sound/items/Deconstruct.ogg', 50, 1)
+		to_chat(user, "<span class='notice'>You slot \the [cell] inside \the [src]'s power supply.</span>")
+		interact(user)
+		return TRUE
+	else
+		return ..()
+
+/obj/item/device/electronic_assembly/attack_self(mob/user)
+	if(!check_interactivity(user))
+		return
+	if(opened)
+		interact(user)
+
+	var/list/input_selection = list()
+	var/list/available_inputs = list()
+	for(var/obj/item/integrated_circuit/input/input in contents)
+		if(input.can_be_asked_input)
+			available_inputs.Add(input)
+			var/i = 0
+			for(var/obj/item/integrated_circuit/s in available_inputs)
+				if(s.name == input.name && s.displayed_name == input.displayed_name && s != input)
+					i++
+			var/disp_name= "[input.displayed_name] \[[input.name]\]"
+			if(i)
+				disp_name += " ([i+1])"
+			input_selection.Add(disp_name)
+
+	var/obj/item/integrated_circuit/input/choice
+	if(available_inputs)
+		var/selection = input(user, "What do you want to interact with?", "Interaction") as null|anything in input_selection
+		if(selection)
+			var/index = input_selection.Find(selection)
+			choice = available_inputs[index]
+
+	if(choice)
+		choice.ask_for_input(user)
+
+/obj/item/device/electronic_assembly/emp_act(severity)
+	..()
+	for(var/atom/movable/AM in contents)
+		AM.emp_act(severity)
+
+// Returns true if power was successfully drawn.
+/obj/item/device/electronic_assembly/proc/draw_power(amount)
+	if(battery && battery.checked_use(amount * CELLRATE))
+		return TRUE
+	return FALSE
+
+// Ditto for giving.
+/obj/item/device/electronic_assembly/proc/give_power(amount)
+	if(battery && battery.give(amount * CELLRATE))
+		return TRUE
+	return FALSE

code/modules/integrated_electronics/core/device.dm

@@ -0,0 +1,81 @@
+/obj/item/device/assembly/electronic_assembly
+	name = "electronic device"
+	desc = "It's a case for building electronics with. It can be attached to other small devices."
+	icon_state = "setup_device"
+	var/opened = 0
+
+	var/obj/item/device/electronic_assembly/device/EA
+
+/obj/item/device/assembly/electronic_assembly/Initialize()
+	EA = new(src)
+	EA.holder = src
+	. = ..()
+
+/obj/item/device/assembly/electronic_assembly/attackby(obj/item/I, mob/user)
+	if (iscrowbar(I))
+		toggle_open(user)
+	else if (opened)
+		EA.attackby(I, user)
+	else
+		..()
+
+/obj/item/device/assembly/electronic_assembly/proc/toggle_open(mob/user)
+	playsound(get_turf(src), 'sound/items/Crowbar.ogg', 50, 1)
+	opened = !opened
+	EA.opened = opened
+	to_chat(user, "<span class='notice'>You [opened ? "open" : "close"] \the [src].</span>")
+	secured = 1
+	update_icon()
+
+/obj/item/device/assembly/electronic_assembly/update_icon()
+	if(EA)
+		icon_state = initial(icon_state)
+	else
+		icon_state = "[initial(icon_state)]0"
+	if(opened)
+		icon_state = "[icon_state]-open"
+
+/obj/item/device/assembly/electronic_assembly/attack_self(mob/user as mob)
+	if(EA)
+		EA.attack_self(user)
+
+//Called when another assembly acts on this one, var/radio will determine where it came from for wire calcs
+/obj/item/device/assembly/electronic_assembly/pulsed(radio = 0)
+	if(EA)
+		for(var/obj/item/integrated_circuit/built_in/device_input/I in EA.contents)
+			I.do_work()
+
+/obj/item/device/assembly/electronic_assembly/examine(mob/user)
+	. = ..(user, 1)
+	if(EA)
+		for(var/obj/item/integrated_circuit/IC in EA.contents)
+			IC.external_examine(user)
+
+/obj/item/device/assembly/electronic_assembly/verb/toggle()
+	set src in usr
+	set category = "Object"
+	set name = "Open/Close Device Assembly"
+	set desc = "Open or close device assembly!"
+
+	toggle_open(usr)
+
+/obj/item/device/electronic_assembly/device
+	name = "electronic device"
+	icon_state = "setup_device"
+	desc = "It's a tiny electronic device with specific use for attaching to other devices."
+	var/obj/item/device/assembly/electronic_assembly/holder
+	w_class = ITEMSIZE_TINY
+	max_components = IC_COMPONENTS_BASE * 3/4
+	max_complexity = IC_COMPLEXITY_BASE * 3/4
+
+/obj/item/device/electronic_assembly/device/Initialize()
+	. = ..()
+	var/obj/item/integrated_circuit/built_in/device_input/input = new(src)
+	var/obj/item/integrated_circuit/built_in/device_output/output = new(src)
+	input.assembly = src
+	output.assembly = src
+
+/obj/item/device/electronic_assembly/device/check_interactivity(mob/user)
+	if(!CanInteract(user, state = deep_inventory_state))
+		return 0
+	return 1

code/modules/integrated_electronics/core/helpers.dm

@@ -0,0 +1,78 @@
+/obj/item/integrated_circuit/proc/setup_io(list/io_list, io_type, list/io_default_list)
+	var/list/io_list_copy = io_list.Copy()
+	io_list.Cut()
+	var/i = 0
+	for(var/io_entry in io_list_copy)
+		var/default_data = null
+		var/io_type_override = null
+		// Override the default data.
+		if(LAZYLEN(io_default_list)) // List containing special pin types that need to be added.
+			default_data = io_default_list["[i]"] // This is deliberately text because the index is a number in text form.
+
+		// Override the pin type.
+		if(io_list_copy[io_entry])
+			io_type_override = io_list_copy[io_entry]
+
+		if(io_type_override)
+			io_list += new io_type_override(src, io_entry, default_data)
+		else
+			io_list += new io_type(src, io_entry, default_data)
+
+/obj/item/integrated_circuit/proc/set_pin_data(pin_type, pin_number, datum/new_data)
+	if (istype(new_data) && !isweakref(new_data))
+		PROCLOG_WEIRD("converting hardref to [DEBUG_REF(new_data)] into weakref.")
+		new_data = WEAKREF(new_data)
+
+	var/datum/integrated_io/pin = get_pin_ref(pin_type, pin_number)
+	if (!pin)
+		CRASH("Invalid pin ref.")
+	return pin.write_data_to_pin(new_data)
+
+/obj/item/integrated_circuit/proc/get_pin_data(pin_type, pin_number)
+	var/datum/integrated_io/pin = get_pin_ref(pin_type, pin_number)
+	return pin.get_data()
+
+/obj/item/integrated_circuit/proc/get_pin_data_as_type(pin_type, pin_number, as_type)
+	var/datum/integrated_io/pin = get_pin_ref(pin_type, pin_number)
+	return pin.data_as_type(as_type)
+
+/obj/item/integrated_circuit/proc/activate_pin(pin_number)
+	var/datum/integrated_io/activate/A = activators[pin_number]
+	A.push_data()
+
+/datum/integrated_io/proc/get_data()
+	if(isnull(data))
+		return
+	if(isweakref(data))
+		return data.resolve()
+	return data
+
+/obj/item/integrated_circuit/proc/get_pin_ref(pin_type, pin_number)
+	switch(pin_type)
+		if(IC_INPUT)
+			if(pin_number > inputs.len)
+				return null
+			return inputs[pin_number]
+		if(IC_OUTPUT)
+			if(pin_number > outputs.len)
+				return null
+			return outputs[pin_number]
+		if(IC_ACTIVATOR)
+			if(pin_number > activators.len)
+				return null
+			return activators[pin_number]
+	return null
+
+/obj/item/integrated_circuit/proc/handle_wire(datum/integrated_io/pin, obj/item/device/integrated_electronics/tool)
+	if(istype(tool, /obj/item/device/integrated_electronics/wirer))
+		var/obj/item/device/integrated_electronics/wirer/wirer = tool
+		if(pin)
+			wirer.wire(pin, usr)
+			return 1
+
+	else if(istype(tool, /obj/item/device/integrated_electronics/debugger))
+		var/obj/item/device/integrated_electronics/debugger/debugger = tool
+		if(pin)
+			debugger.write_data(pin, usr)
+			return 1
+	return 0

code/modules/integrated_electronics/core/integrated_circuit.dm

@@ -0,0 +1,355 @@
+/*
+	Integrated circuits are essentially modular machines.  Each circuit has a specific function, and combining them inside Electronic Assemblies allows
+a creative player the means to solve many problems.  Circuits are held inside an electronic assembly, and are wired using special tools.
+*/
+
+/obj/item/integrated_circuit/examine(mob/user)
+	interact(user)
+	external_examine(user)
+	. = ..()
+
+// This should be used when someone is examining while the case is opened.
+/obj/item/integrated_circuit/proc/internal_examine(mob/user)
+	to_chat(user, "This board has [inputs.len] input pin\s, [outputs.len] output pin\s and [activators.len] activation pin\s.")
+	for(var/datum/integrated_io/I in inputs)
+		if(I.linked.len)
+			to_chat(user, "The '[I]' is connected to [I.get_linked_to_desc()].")
+	for(var/datum/integrated_io/O in outputs)
+		if(O.linked.len)
+			to_chat(user, "The '[O]' is connected to [O.get_linked_to_desc()].")
+	for(var/datum/integrated_io/activate/A in activators)
+		if(A.linked.len)
+			to_chat(user, "The '[A]' is connected to [A.get_linked_to_desc()].")
+	any_examine(user)
+	interact(user)
+
+// This should be used when someone is examining from an 'outside' perspective, e.g. reading a screen or LED.
+/obj/item/integrated_circuit/proc/external_examine(mob/user)
+	any_examine(user)
+
+/obj/item/integrated_circuit/proc/any_examine(mob/user)
+	return
+
+/obj/item/integrated_circuit/Initialize()
+	displayed_name = name
+	if(!size)
+		size = w_class
+	if(size == -1) 
+		size = 0
+	setup_io(inputs, /datum/integrated_io, inputs_default)
+	setup_io(outputs, /datum/integrated_io, outputs_default)
+	setup_io(activators, /datum/integrated_io/activate)
+	. = ..()
+
+/obj/item/integrated_circuit/proc/on_data_written() //Override this for special behaviour when new data gets pushed to the circuit.
+	return
+
+/obj/item/integrated_circuit/Destroy()
+	for(var/datum/integrated_io/I in inputs)
+		qdel(I)
+	for(var/datum/integrated_io/O in outputs)
+		qdel(O)
+	for(var/datum/integrated_io/A in activators)
+		qdel(A)
+	. = ..()
+
+/obj/item/integrated_circuit/nano_host()
+	if(istype(src.loc, /obj/item/device/electronic_assembly))
+		var/obj/item/device/electronic_assembly/assembly = loc
+		return assembly.resolve_nano_host()
+	return ..()
+
+/obj/item/integrated_circuit/emp_act(severity)
+	for(var/datum/integrated_io/io in inputs + outputs + activators)
+		io.scramble()
+
+/obj/item/integrated_circuit/proc/check_interactivity(mob/user)
+	if(assembly)
+		return assembly.check_interactivity(user)
+	else if(!CanInteract(user, physical_state))
+		return 0
+	return 1
+
+/obj/item/integrated_circuit/verb/rename_component()
+	set name = "Rename Circuit"
+	set category = "Object"
+	set desc = "Rename your circuit, useful to stay organized."
+
+	var/mob/M = usr
+	if(!check_interactivity(M))
+		return
+
+	var/input = sanitizeSafe(input("What do you want to name the circuit?", "Rename", src.name) as null|text, MAX_NAME_LEN)
+	if(src && input && assembly.check_interactivity(M))
+		to_chat(M, "<span class='notice'>The circuit '[src.name]' is now labeled '[input]'.</span>")
+		displayed_name = input
+
+/obj/item/integrated_circuit/interact(mob/user)
+	if(!check_interactivity(user))
+		return
+
+	var/window_height = 350
+	var/window_width = 600
+	var/table_edge_width = "30%"
+	var/table_middle_width = "40%"
+
+	var/list/HTML = list(
+		"<div align='center'>",
+		"<table border='1' style='undefined;table-layout: fixed; width: 80%'>",
+		"<br><a href='?src=\ref[src];return=1'>Return to Assembly</a>",
+		"<br><a href='?src=\ref[src];'>Refresh</a>  |  ",
+		"<a href='?src=\ref[src];rename=1'>Rename</a>  |  ",
+		"<a href='?src=\ref[src];scan=1'>Scan with Device</a>  |  "
+	)
+	if(src.removable)
+		HTML += "<a href='?src=\ref[src];remove=1'>Remove</a><br>"
+
+	HTML += "<colgroup>"
+	HTML += "<col style='width: [table_edge_width]'>"
+	HTML += "<col style='width: [table_middle_width]'>"
+	HTML += "<col style='width: [table_edge_width]'>"
+	HTML += "</colgroup>"
+
+	var/column_width = 3
+	var/row_height = max(inputs.len, outputs.len, 1)
+
+	for(var/i = 1 to row_height)
+		HTML += "<tr>"
+		for(var/j = 1 to column_width)
+			var/datum/integrated_io/io = null
+			var/words = list()
+			var/height = 1
+			switch(j)
+				if(1)
+					io = get_pin_ref(IC_INPUT, i)
+					if(io)
+						words += "<b><a href=?src=\ref[src];pin_name=1;pin=\ref[io]>[io.display_pin_type()] [io.name]</a> <a href=?src=\ref[src];pin_data=1;pin=\ref[io]>[io.display_data(io.data)]</a></b><br>"
+						if(io.linked.len)
+							for(var/datum/integrated_io/linked in io.linked)
+								words += "<a href=?src=\ref[src];pin_unwire=1;pin=\ref[io];link=\ref[linked]>[linked.name]</a> \
+								@ <a href=?src=\ref[linked.holder];examine=1;>[linked.holder.displayed_name]</a><br>"
+
+						if(outputs.len > inputs.len)
+							height = 1
+				if(2)
+					if(i == 1)
+						words += "[src.displayed_name]<br>[src.name != src.displayed_name ? "([src.name])":""]<hr>[src.desc]"
+						height = row_height
+					else
+						continue
+				if(3)
+					io = get_pin_ref(IC_OUTPUT, i)
+					if(io)
+						words += "<b><a href=?src=\ref[src];pin_name=1;pin=\ref[io]>[io.display_pin_type()] [io.name]</a> <a href=?src=\ref[src];pin_data=1;pin=\ref[io]>[io.display_data(io.data)]</a></b><br>"
+						if(io.linked.len)
+							for(var/datum/integrated_io/linked in io.linked)
+								words += "<a href=?src=\ref[src];pin_unwire=1;pin=\ref[io];link=\ref[linked]>[linked.name]</a> \
+								@ <a href=?src=\ref[linked.holder];examine=1;>[linked.holder.displayed_name]</a><br>"
+
+						if(inputs.len > outputs.len)
+							height = 1
+			HTML += "<td align='center' rowspan='[height]'>[jointext(words, null)]</td>"
+		HTML += "</tr>"
+
+	for(var/activator in activators)
+		var/datum/integrated_io/io = activator
+		var/words = list(
+			"<b><a href=?src=\ref[src];pin_name=1;pin=\ref[io]><span class='bad'>[io.name]</span></a> <a href=?src=\ref[src];pin_data=1;pin=\ref[io]><span class='bad'>[io.data?"\<PULSE OUT\>":"\<PULSE IN\>"]</span></a></b><br>"
+		)
+
+		if(io.linked.len)
+			for(var/datum/integrated_io/linked in io.linked)
+				words += "<a href=?src=\ref[src];pin_unwire=1;pin=\ref[io];link=\ref[linked]><span class='bad'>[linked.name]</span></a> \
+				@ <a href=?src=\ref[linked.holder];examine=1;><span class='bad'>[linked.holder.displayed_name]</span></a><br>"
+
+		HTML += "<tr>"
+		HTML += "<td colspan='3' align='center'>[jointext(words, null)]</td>"
+		HTML += "</tr>"
+
+	HTML += "</table>"
+	HTML += "</div>"
+
+//	HTML += "<br><font color='33CC33'>Meta Variables;</font>" // If more meta vars get introduced, uncomment this.
+//	HTML += "<br>"
+
+	HTML += "<br><span class='highlight'>Complexity: [complexity]</span>"
+	if(power_draw_idle)
+		HTML += "<br><span class='highlight'>Power Draw: [power_draw_idle] W (Idle)</span>"
+	if(power_draw_per_use)
+		HTML += "<br><span class='highlight'>Power Draw: [power_draw_per_use] W (Active)</span>" // Borgcode says that powercells' checked_use() takes joules as input.
+	HTML += "<br><span class='highlight'>[extended_desc]</span>"
+
+	var/datum/browser/B = new(user, assembly ? "assembly-\ref[assembly]" : "circuit-\ref[src]", (displayed_name && displayed_name != name) ? "[displayed_name] ([name])" : name, window_width, window_height)
+	B.set_content(HTML.Join())
+	B.open()
+
+/obj/item/integrated_circuit/Topic(href, href_list, state = interactive_state)
+	if(!check_interactivity(usr))
+		return
+	if (assembly && !assembly.opened)
+		to_chat(usr, "<span class='warning'>\The [assembly] is not open!</span>")
+		return
+	if(..())
+		return 1
+
+	var/update = 1
+	var/obj/item/device/electronic_assembly/A = src.assembly
+	var/update_to_assembly = 0
+	var/datum/integrated_io/pin = locate(href_list["pin"]) in inputs + outputs + activators
+	var/datum/integrated_io/linked = null
+	if(href_list["link"])
+		linked = locate(href_list["link"]) in pin.linked
+
+	var/obj/held_item = usr.get_active_hand()
+
+	if(href_list["rename"])
+		rename_component(usr)
+		if(href_list["from_assembly"])
+			update = 0
+			var/obj/item/device/electronic_assembly/ea = loc
+			if(istype(ea))
+				ea.interact(usr)
+
+	if(href_list["pin_name"])
+		if (!istype(held_item, /obj/item/device/multitool) || !allow_multitool)
+			href_list["wire"] = 1
+		else
+			var/obj/item/device/multitool/M = held_item
+			M.wire(pin,usr)
+
+	if(href_list["pin_data"])
+		if (!istype(held_item, /obj/item/device/multitool) || !allow_multitool)
+			href_list["wire"] = 1
+
+		else
+			var/datum/integrated_io/io = pin
+			io.ask_for_pin_data(usr) // The pins themselves will determine how to ask for data, and will validate the data.
+
+	if(href_list["pin_unwire"])
+		if (!istype(held_item, /obj/item/device/multitool) || !allow_multitool)
+			href_list["wire"] = 1
+		else
+			var/obj/item/device/multitool/M = held_item
+			M.unwire(pin, linked, usr)
+
+	if(href_list["wire"])
+		if(istype(held_item, /obj/item/device/integrated_electronics/wirer))
+			var/obj/item/device/integrated_electronics/wirer/wirer = held_item
+			if(linked)
+				wirer.wire(linked, usr)
+			else if(pin)
+				wirer.wire(pin, usr)
+
+		else if(istype(held_item, /obj/item/device/integrated_electronics/debugger))
+			var/obj/item/device/integrated_electronics/debugger/debugger = held_item
+			if(pin)
+				debugger.write_data(pin, usr)
+		else
+			to_chat(usr, "<span class='warning'>You can't do a whole lot without the proper tools.</span>")
+
+	if(href_list["examine"])
+		var/obj/item/integrated_circuit/examined
+		if(href_list["examined"])
+			examined = href_list["examined"]
+		else
+			examined = src
+		examined.interact(usr)
+		update = 0
+
+	if(href_list["bottom"])
+		var/obj/item/integrated_circuit/circuit = locate(href_list["bottom"]) in src.assembly.contents
+		var/assy = circuit.assembly
+		if(!circuit)
+			return
+		circuit.loc = null
+		circuit.loc = assy
+		. = 1
+		update_to_assembly = 1
+
+	if(href_list["scan"])
+		if(istype(held_item, /obj/item/device/integrated_electronics/debugger))
+			var/obj/item/device/integrated_electronics/debugger/D = held_item
+			if(D.accepting_refs)
+				D.afterattack(src, usr, TRUE)
+			else
+				to_chat(usr, "<span class='warning'>The Debugger's 'ref scanner' needs to be on.</span>")
+		else
+			to_chat(usr, "<span class='warning'>You need a multitool/debugger set to 'ref' mode to do that.</span>")
+
+	if(href_list["return"])
+		if(A)
+			update_to_assembly = 1
+			usr << browse(null, "window=circuit-\ref[src]")
+		else
+			to_chat(usr, "<span class='warning'>This circuit is not in an assembly!</span>")
+
+	if(href_list["remove"])
+		if(!A)
+			to_chat(usr, "<span class='warning'>This circuit is not in an assembly!</span>")
+			return
+		if(!removable)
+			to_chat(usr, "<span class='warning'>\The [src] seems to be permanently attached to the case.</span>")
+			return
+		var/obj/item/device/electronic_assembly/ea = loc
+		disconnect_all()
+		var/turf/T = get_turf(src)
+		forceMove(T)
+		assembly = null
+		playsound(T, 'sound/items/Crowbar.ogg', 50, 1)
+		to_chat(usr, "<span class='notice'>You pop \the [src] out of the case, and slide it out.</span>")
+
+		if(istype(ea))
+			ea.interact(usr)
+		update = 0
+		return
+
+	if(update)
+		if(istype(A) && update_to_assembly)
+			A.interact(usr)
+		else
+			interact(usr) // To refresh the UI.
+
+/obj/item/integrated_circuit/proc/push_data()
+	for(var/datum/integrated_io/O in outputs)
+		O.push_data()
+
+/obj/item/integrated_circuit/proc/pull_data()
+	for(var/datum/integrated_io/I in inputs)
+		I.push_data()
+
+/obj/item/integrated_circuit/proc/draw_idle_power()
+	if(assembly)
+		return assembly.draw_power(power_draw_idle)
+
+// Override this for special behaviour when there's no power left.
+/obj/item/integrated_circuit/proc/power_fail()
+	return
+
+// Returns true if there's enough power to work().
+/obj/item/integrated_circuit/proc/check_power()
+	if(!assembly)
+		return FALSE // Not in an assembly, therefore no power.
+	if(assembly.draw_power(power_draw_per_use))
+		return TRUE // Battery has enough.
+	return FALSE // Not enough power.
+
+/obj/item/integrated_circuit/proc/check_then_do_work(ignore_power = FALSE)
+	if(world.time < next_use) 	// All intergrated circuits have an internal cooldown, to protect from spam.
+		return
+	if(power_draw_per_use && !ignore_power)
+		if(!check_power())
+			power_fail()
+			return
+	next_use = world.time + cooldown_per_use
+	do_work()
+
+/obj/item/integrated_circuit/proc/do_work()
+	return
+
+/obj/item/integrated_circuit/proc/disconnect_all()
+	for(var/datum/integrated_io/I in inputs)
+		I.disconnect()
+	for(var/datum/integrated_io/O in outputs)
+		O.disconnect()
+	for(var/datum/integrated_io/activate/A in activators)
+		A.disconnect()

code/modules/integrated_electronics/core/pins.dm

@@ -0,0 +1,188 @@
+/*
+	Pins both hold data for circuits, as well move data between them.  Some also cause circuits to do their function.  DATA_CHANNEL pins are the data holding/moving kind,
+where as PULSE_CHANNEL causes circuits to work() when their pulse hits them.
+
+
+A visualization of how pins work is below.  Imagine the below image involves an addition circuit.
+When the bottom pin, the activator, receives a pulse, all the numbers on the left (input) get added, and the answer goes on the right side (output).
+
+Inputs      Outputs
+
+A [2]\      /[8] result
+B [1]-\|++|/
+C [4]-/|++|
+D [1]/  ||
+        ||
+     Activator
+
+
+
+*/
+/datum/integrated_io
+	var/name = "input/output"
+	var/obj/item/integrated_circuit/holder = null
+	var/datum/weakref/data = null // This is a weakref, to reduce typecasts.  Note that oftentimes numbers and text may also occupy this.
+	var/list/linked = list()
+	var/io_type = DATA_CHANNEL
+
+/datum/integrated_io/New(var/newloc, var/name, var/new_data)
+	..()
+	src.name = name
+	if(new_data)
+		src.data = new_data
+	holder = newloc
+	if(!istype(holder))
+		message_admins("ERROR: An integrated_io ([src.name]) spawned without a valid holder!  This is a bug.")
+		log_debug("ERROR: An integrated_io ([src.name]) spawned without a valid holder!  This is a bug.")
+
+/datum/integrated_io/Destroy()
+	disconnect()
+	data = null
+	holder = null
+	. = ..()
+
+/datum/integrated_io/nano_host()
+	return holder.nano_host()
+
+/datum/integrated_io/proc/data_as_type(var/as_type)
+	if(!isweakref(data))
+		return
+	var/datum/weakref/w = data
+	var/output = w.resolve()
+	return istype(output, as_type) ? output : null
+
+/datum/integrated_io/proc/display_data(var/input)
+	if(isnull(input))
+		return "(null)" // Empty data means nothing to show.
+
+	if(istext(input))
+		return "(\"[input]\")" // Wraps the 'string' in escaped quotes, so that people know it's a 'string'.
+
+/*
+list[](
+	"A",
+	"B",
+	"C"
+)
+*/
+
+	if(islist(input))
+		var/list/my_list = input
+		var/result = "list\[[my_list.len]\]("
+		if(my_list.len)
+			result += "<br>"
+			var/pos = 0
+			for(var/line in my_list)
+				result += "[display_data(line)]"
+				pos++
+				if(pos != my_list.len)
+					result += ",<br>"
+			result += "<br>"
+		result += ")"
+		return result
+
+	if(isweakref(input))
+		var/datum/weakref/w = input
+		var/atom/A = w.resolve()
+		//return A ? "([A.name] \[Ref\])" : "(null)" // For refs, we want just the name displayed.
+		return A ? "(\ref[A] \[Ref\])" : "(null)"
+
+	return "([input])" // Nothing special needed for numbers or other stuff.
+
+/datum/integrated_io/activate/display_data()
+	return "(\[pulse\])"
+
+/datum/integrated_io/proc/display_pin_type()
+	return IC_FORMAT_ANY
+
+/datum/integrated_io/activate/display_pin_type()
+	return IC_FORMAT_PULSE
+
+/datum/integrated_io/proc/scramble()
+	if(isnull(data))
+		return
+	if(isnum(data))
+		write_data_to_pin(rand(-10000, 10000))
+	if(istext(data))
+		write_data_to_pin("ERROR")
+	push_data()
+
+/datum/integrated_io/activate/scramble()
+	push_data()
+
+/datum/integrated_io/proc/write_data_to_pin(var/new_data)
+	if(isnull(new_data) || isnum(new_data) || istext(new_data) || isweakref(new_data)) // Anything else is a type we don't want.
+		data = new_data
+		holder.on_data_written()
+
+/datum/integrated_io/proc/push_data()
+	for(var/datum/integrated_io/io in linked)
+		io.write_data_to_pin(data)
+
+/datum/integrated_io/activate/push_data()
+	for(var/datum/integrated_io/io in linked)
+		io.holder.check_then_do_work()
+
+/datum/integrated_io/proc/pull_data()
+	for(var/datum/integrated_io/io in linked)
+		write_data_to_pin(io.data)
+
+/datum/integrated_io/proc/get_linked_to_desc()
+	if(linked.len)
+		return "the [english_list(linked)]"
+	return "nothing"
+
+/datum/integrated_io/proc/disconnect()
+	//First we iterate over everything we are linked to.
+	for(var/datum/integrated_io/their_io in linked)
+		//While doing that, we iterate them as well, and disconnect ourselves from them.
+		for(var/datum/integrated_io/their_linked_io in their_io.linked)
+			if(their_linked_io == src)
+				their_io.linked -= src
+
+		//Now that we're removed from them, we gotta remove them from us.
+		linked -= their_io
+
+/datum/integrated_io/proc/ask_for_data_type(mob/user, var/default, var/list/allowed_data_types = list("string","number","null"))
+	var/type_to_use = input("Please choose a type to use.","[src] type setting") as null|anything in allowed_data_types
+	if(!holder.check_interactivity(user))
+		return
+
+	var/new_data = null
+	switch(type_to_use)
+		if("string")
+			new_data = sanitize(input("Now type in a string.","[src] string writing", istext(default) ? default : null) as null|text)
+			if(istext(new_data) && holder.check_interactivity(user) )
+				to_chat(user, "<span class='notice'>You input [new_data] into the pin.</span>")
+				return new_data
+
+		if("number")
+			new_data = input("Now type in a number.","[src] number writing", isnum(default) ? default : null) as null|num
+			if(isnum(new_data) && holder.check_interactivity(user) )
+				to_chat(user, "<span class='notice'>You input [new_data] into the pin.</span>")
+				return new_data
+
+		if("null")
+			if(holder.check_interactivity(user))
+				to_chat(user, "<span class='notice'>You clear the pin's memory.</span>")
+				return new_data
+
+// Basically a null check
+/datum/integrated_io/proc/is_valid()
+	return !isnull(data)
+
+// This proc asks for the data to write, then writes it.
+/datum/integrated_io/proc/ask_for_pin_data(mob/user)
+	var/new_data = ask_for_data_type(user)
+	write_data_to_pin(new_data)
+
+/datum/integrated_io/activate/ask_for_pin_data(mob/user) // This just pulses the pin.
+	holder.check_then_do_work(ignore_power = TRUE)
+	to_chat(user, "<span class='notice'>You pulse \the [holder]'s [src] pin.</span>")
+
+/datum/integrated_io/activate
+	name = "activation pin"
+	io_type = PULSE_CHANNEL
+
+/datum/integrated_io/activate/out // All this does is just make the UI say 'out' instead of 'in'
+	data = 1

code/modules/integrated_electronics/core/printer.dm

@@ -0,0 +1,159 @@
+/obj/item/device/integrated_circuit_printer
+	name = "integrated circuit printer"
+	desc = "A portable(ish) machine made to print tiny modular circuitry out of metal."
+	icon = 'icons/obj/electronic_assemblies.dmi'
+	icon_state = "circuit_printer"
+	w_class = ITEMSIZE_LARGE
+	var/metal = 0
+	var/max_metal = 100
+	var/metal_per_sheet = 10 // One sheet equals this much metal.
+
+	var/upgraded = FALSE  // When hit with an upgrade disk, will turn true, allowing it to print the higher tier circuits.
+	var/can_clone = FALSE // Same for above, but will allow the printer to duplicate a specific assembly.
+	var/current_category
+	var/obj/item/device/electronic_assembly/assembly_to_clone
+
+/obj/item/device/integrated_circuit_printer/upgraded
+	upgraded = TRUE
+	can_clone = TRUE
+
+/obj/item/device/integrated_circuit_printer/attackby(var/obj/item/O, var/mob/user)
+	if(istype(O,/obj/item/stack/material))
+		var/obj/item/stack/material/stack = O
+		if(stack.material.name == DEFAULT_WALL_MATERIAL)
+			var/num = min((max_metal - metal) / metal_per_sheet, stack.amount)
+			if(num < 1)
+				to_chat(user, "<span class='warning'>\The [src] is too full to add more metal.</span>")
+				return
+			if(stack.use(num))
+				to_chat(user, "<span class='notice'>You add [num] sheet\s to \the [src].</span>")
+				metal += num * metal_per_sheet
+				interact(user)
+				return TRUE
+
+	if(istype(O,/obj/item/integrated_circuit))
+		to_chat(user, "<span class='notice'>You insert the circuit into \the [src]. </span>")
+		user.unEquip(O)
+		metal = min(metal + O.w_class, max_metal)
+		qdel(O)
+		interact(user)
+		return TRUE
+
+	if(istype(O,/obj/item/weapon/disk/integrated_circuit/upgrade/advanced))
+		if(upgraded)
+			to_chat(user, "<span class='warning'>\The [src] already has this upgrade. </span>")
+			return TRUE
+		to_chat(user, "<span class='notice'>You install \the [O] into  \the [src]. </span>")
+		upgraded = TRUE
+		interact(user)
+		return TRUE
+
+	if(istype(O,/obj/item/weapon/disk/integrated_circuit/upgrade/clone))
+		if(can_clone)
+			to_chat(user, "<span class='warning'>\The [src] already has this upgrade. </span>")
+			return TRUE
+		to_chat(user, "<span class='notice'>You install \the [O] into  \the [src]. </span>")
+		can_clone = TRUE
+		interact(user)
+		return TRUE
+
+	return ..()
+
+/obj/item/device/integrated_circuit_printer/attack_self(var/mob/user)
+	interact(user)
+
+/obj/item/device/integrated_circuit_printer/interact(mob/user)
+	var/window_height = 600
+	var/window_width = 500
+
+	if(isnull(current_category))
+		current_category = SSelectronics.printer_recipe_list[1]
+
+	var/HTML = "<center><h2>Integrated Circuit Printer</h2></center><br>"
+	HTML += "Metal: [metal/metal_per_sheet]/[max_metal/metal_per_sheet] sheets.<br>"
+	HTML += "Circuits available: [upgraded ? "Regular":"Advanced"]."
+	HTML += "Assembly Cloning: [can_clone ? "Available": "Unavailable"]."
+	if(assembly_to_clone)
+		HTML += "Assembly '[assembly_to_clone.name]' loaded."
+	HTML += "Crossed out circuits mean that the printer is not sufficentally upgraded to create that circuit.<br>"
+	HTML += "<hr>"
+	HTML += "Categories:"
+	for(var/category in SSelectronics.printer_recipe_list)
+		if(category != current_category)
+			HTML += " <a href='?src=\ref[src];category=[category]'>[category]</a> "
+		else // Bold the button if it's already selected.
+			HTML += " <b>[category]</b> "
+	HTML += "<hr>"
+	HTML += "<center><h4>[current_category]</h4></center>"
+
+	var/list/current_list = SSelectronics.printer_recipe_list[current_category]
+	for(var/obj/O in current_list)
+		var/can_build = TRUE
+		if(istype(O, /obj/item/integrated_circuit))
+			var/obj/item/integrated_circuit/IC = O
+			if((IC.spawn_flags & IC_SPAWN_RESEARCH) && (!(IC.spawn_flags & IC_SPAWN_DEFAULT)) && !upgraded)
+				can_build = FALSE
+		if(can_build)
+			HTML += "<A href='?src=\ref[src];build=[O.type]'>[O.name]</A>: [O.desc]<br>"
+		else
+			HTML += "<s>[O.name]: [O.desc]</s><br>"
+
+	var/datum/browser/B = new(user, "integrated_printer", null, window_width, window_height)
+	B.set_content(HTML)
+	B.open(FALSE)
+
+/obj/item/device/integrated_circuit_printer/Topic(href, href_list)
+	if(..())
+		return 1
+
+	add_fingerprint(usr)
+
+	if(href_list["category"])
+		current_category = href_list["category"]
+
+	if(href_list["build"])
+		var/build_type = text2path(href_list["build"])
+		if(!build_type || !ispath(build_type))
+			return 1
+
+		var/cost = 1
+		var/is_asm = FALSE
+		if(ispath(build_type, /obj/item/device/electronic_assembly))
+			var/obj/item/device/electronic_assembly/E = build_type
+			cost = round( (initial(E.max_complexity) + initial(E.max_components) ) / 4)
+			is_asm = TRUE
+		else if(ispath(build_type, /obj/item/integrated_circuit))
+			var/obj/item/integrated_circuit/IC = build_type
+			cost = initial(IC.w_class)
+
+		if(metal - cost < 0)
+			to_chat(usr, "<span class='warning'>You need [cost] metal to build that!.</span>")
+			return 1
+		metal -= cost
+		if (is_asm)
+			new build_type(get_turf(loc), TRUE)
+		else
+			new build_type(get_turf(loc))
+
+	interact(usr)
+
+// FUKKEN UPGRADE DISKS
+/obj/item/weapon/disk/integrated_circuit/upgrade
+	name = "integrated circuit printer upgrade disk"
+	desc = "Install this into your integrated circuit printer to enhance it."
+	icon = 'icons/obj/electronic_assemblies.dmi'
+	icon_state = "upgrade_disk"
+	item_state = "card-id"
+	w_class = ITEMSIZE_SMALL
+	origin_tech = list(TECH_ENGINEERING = 3, TECH_DATA = 4)
+
+/obj/item/weapon/disk/integrated_circuit/upgrade/advanced
+	name = "integrated circuit printer upgrade disk - advanced designs"
+	desc = "Install this into your integrated circuit printer to enhance it.  This one adds new, advanced designs to the printer."
+
+// To be implemented later.
+/obj/item/weapon/disk/integrated_circuit/upgrade/clone
+	name = "integrated circuit printer upgrade disk - circuit cloner"
+	desc = "Install this into your integrated circuit printer to enhance it.  This one allows the printer to duplicate assemblies."
+	icon_state = "upgrade_disk_clone"
+	origin_tech = list(TECH_ENGINEERING = 5, TECH_DATA = 6)

code/modules/integrated_electronics/core/special_pins/boolean_pin.dm

@@ -0,0 +1,25 @@
+// These pins only contain 0 or 1.  Null is not allowed.
+/datum/integrated_io/boolean
+	name = "boolean pin"
+	data = FALSE
+
+/datum/integrated_io/boolean/ask_for_pin_data(mob/user) // 'Ask' is a bit misleading, acts more like a toggle.
+	var/new_data = !data
+	write_data_to_pin(new_data)
+
+/datum/integrated_io/boolean/write_data_to_pin(var/new_data)
+	if(new_data == FALSE || new_data == TRUE)
+		data = new_data
+		holder.on_data_written()
+
+/datum/integrated_io/boolean/scramble()
+	write_data_to_pin(rand(FALSE,TRUE))
+	push_data()
+
+/datum/integrated_io/boolean/display_pin_type()
+	return IC_FORMAT_BOOLEAN
+
+/datum/integrated_io/boolean/display_data(var/input)
+	if(data == TRUE)
+		return "(True)"
+	return "(False)"

code/modules/integrated_electronics/core/special_pins/char_pin.dm

@@ -0,0 +1,27 @@
+// These pins can only contain a 1 character string or null.
+/datum/integrated_io/char
+	name = "char pin"
+
+/datum/integrated_io/char/ask_for_pin_data(mob/user)
+	var/new_data = sanitize(input("Please type in one character.","[src] char writing") as null|text)
+	if(holder.check_interactivity(user) )
+		to_chat(user, "<span class='notice'>You input [new_data ? "'[new_data]'" : "NULL"] into the pin.</span>")
+		write_data_to_pin(new_data)
+
+/datum/integrated_io/char/write_data_to_pin(var/new_data)
+	if(isnull(new_data) || istext(new_data))
+		if(length(new_data) > 1)
+			return
+		data = new_data
+		holder.on_data_written()
+
+// This makes the text go from "A" to "%".
+/datum/integrated_io/char/scramble()
+	if(!is_valid())
+		return
+	var/list/options = list("!","@","#","$","%","^","&","*") + alphabet_uppercase
+	data = pick(options)
+	push_data()
+
+/datum/integrated_io/char/display_pin_type()
+	return IC_FORMAT_CHAR

code/modules/integrated_electronics/core/special_pins/color_pin.dm

@@ -0,0 +1,44 @@
+// These pins can only contain a color (in the form of #FFFFFF) or null.
+/datum/integrated_io/color
+	name = "color pin"
+
+/datum/integrated_io/color/ask_for_pin_data(mob/user)
+	var/new_data = input("Please select a color.","[src] color writing") as null|color
+	if(holder.check_interactivity(user) )
+		to_chat(user, "<span class='notice'>You input a <font color='[new_data]'>new color</font> into the pin.</span>")
+		write_data_to_pin(new_data)
+
+/datum/integrated_io/color/write_data_to_pin(new_data)
+	// Since this is storing the color as a string hex color code, we need to make sure it's actually one.
+	if(isnull(new_data) || istext(new_data))
+		if(istext(new_data))
+			new_data = uppertext(new_data)
+			if(length(new_data) != 7)						// We can hex if we want to, we can leave your strings behind
+				return 										// Cause your strings don't hex and if they don't hex
+			var/friends = copytext(new_data, 2, 8)			// Well they're are no strings of mine
+			// I say, we can go where we want to, a place where they will never find
+			var/safety_dance = 1
+			while(safety_dance >= 7)									// And we can act like we come from out of this world.log
+				var/hex = copytext(friends, safety_dance, safety_dance+1)
+				if(!(hex in list("0", "1", "2", "3", "4", "5", "6", "7", "8", "9", "A", "B", "C", "D", "E", "F")))
+					return									// Leave the fake one far behind,
+				safety_dance++
+
+		data = new_data										// And we can hex
+		holder.on_data_written()
+
+// This randomizes the color.
+/datum/integrated_io/color/scramble()
+	if(!is_valid())
+		return
+	var/new_data = get_random_colour(simple = FALSE, lower = 0, upper = 255)
+	data = new_data
+	push_data()
+
+/datum/integrated_io/color/display_pin_type()
+	return IC_FORMAT_COLOR
+
+/datum/integrated_io/color/display_data(input)
+	if(!isnull(data))
+		return "(<font color='[data]'>[data]</font>)"
+	return ..()

code/modules/integrated_electronics/core/special_pins/dir_pin.dm

@@ -0,0 +1,33 @@
+// These pins can only contain directions (1,2,4,8...) or null.
+/datum/integrated_io/dir
+	name = "dir pin"
+
+/datum/integrated_io/dir/ask_for_pin_data(mob/user)
+	var/new_data = input("Please type in a valid dir number.  \
+	Valid dirs are;\n\
+	North/Fore = [NORTH],\n\
+	South/Aft = [SOUTH],\n\
+	East/Starboard = [EAST],\n\
+	West/Port = [WEST],\n\
+	Northeast = [NORTHEAST],\n\
+	Northwest = [NORTHWEST],\n\
+	Southeast = [SOUTHEAST],\n\
+	Southwest = [SOUTHWEST],\n\
+	Up = [UP],\n\
+	Down = [DOWN]","[src] dir writing") as null|num
+	if(isnum(new_data) && holder.check_interactivity(user) )
+		to_chat(user, "<span class='notice'>You input [new_data] into the pin.</span>")
+		write_data_to_pin(new_data)
+
+/datum/integrated_io/dir/write_data_to_pin(var/new_data)
+	if(isnull(new_data) || new_data in alldirs + list(UP, DOWN))
+		data = new_data
+		holder.on_data_written()
+
+/datum/integrated_io/dir/display_pin_type()
+	return IC_FORMAT_DIR
+
+/datum/integrated_io/dir/display_data(var/input)
+	if(!isnull(data))
+		return "([dir2text(data)])"
+	return ..()

code/modules/integrated_electronics/core/special_pins/list_pin.dm

@@ -0,0 +1,149 @@
+// These pins contain a list.  Null is not allowed.
+/datum/integrated_io/list
+	name = "list pin"
+	data = list()
+
+/datum/integrated_io/list/ask_for_pin_data(mob/user)
+	interact(user)
+
+/datum/integrated_io/list/proc/interact(mob/user)
+	var/list/my_list = data
+	var/t = "<h2>[src]</h2><br>"
+	t += "List length: [my_list.len]<br>"
+	t += "<a href='?src=\ref[src]'>Refresh</a>  |  "
+	t += "<a href='?src=\ref[src];add=1'>Add</a>  |  "
+	t += "<a href='?src=\ref[src];swap=1'>Swap</a>  |  "
+	t += "<a href='?src=\ref[src];clear=1'>Clear</a><br>"
+	t += "<hr>"
+	var/i = 0
+	for(var/line in my_list)
+		i++
+		t += "#[i] | [display_data(line)]  |  "
+		t += "<a href='?src=\ref[src];edit=1;pos=[i]'>Edit</a>  |  "
+		t += "<a href='?src=\ref[src];remove=1;pos=[i]'>Remove</a><br>"
+	var/datum/browser/B = new(user, "list_pin_\ref[src]", null, 500, 400)
+	B.set_content(t)
+	B.open(FALSE)
+
+/datum/integrated_io/list/proc/add_to_list(mob/user, new_entry)
+	if(!new_entry && user)
+		new_entry = ask_for_data_type(user)
+	if(is_valid(new_entry))
+		Add(new_entry)
+
+/datum/integrated_io/list/proc/Add(new_entry)
+	var/list/my_list = data
+	if(my_list.len > IC_MAX_LIST_LENGTH)
+		my_list.Cut(1, 2)
+	my_list.Add(new_entry)
+
+/datum/integrated_io/list/proc/remove_from_list_by_position(mob/user, position)
+	var/list/my_list = data
+	if(!my_list.len)
+		to_chat(user, "<span class='warning'>The list is empty, there's nothing to remove.</span>")
+		return
+	if(!position)
+		return
+	var/target_entry = my_list.Find(position)
+	if(target_entry)
+		my_list -= target_entry
+
+/datum/integrated_io/list/proc/remove_from_list(mob/user, target_entry)
+	var/list/my_list = data
+	if(!my_list.len)
+		to_chat(user, "<span class='warning'>The list is empty, there's nothing to remove.</span>")
+		return
+	if(!target_entry)
+		target_entry = input("Which piece of data do you want to remove?", "Remove") as null|anything in my_list
+	if(target_entry)
+		my_list -= target_entry
+
+/datum/integrated_io/list/proc/edit_in_list(mob/user, target_entry)
+	var/list/my_list = data
+	if(!my_list.len)
+		to_chat(user, "<span class='warning'>The list is empty, there's nothing to modify.</span>")
+		return
+	if(!target_entry)
+		target_entry = input("Which piece of data do you want to edit?", "Edit") as null|anything in my_list
+	if(target_entry)
+		var/edited_entry = ask_for_data_type(user, target_entry)
+		if(edited_entry)
+			target_entry = edited_entry
+
+/datum/integrated_io/list/proc/edit_in_list_by_position(mob/user, var/position)
+	var/list/my_list = data
+	if(!my_list.len)
+		to_chat(user, "<span class='warning'>The list is empty, there's nothing to modify.</span>")
+		return
+	if(!position)
+		return
+	var/target_entry = my_list.Find(position)
+	if(target_entry)
+		var/edited_entry = ask_for_data_type(user, target_entry)
+		if(edited_entry)
+			target_entry = edited_entry
+
+/datum/integrated_io/list/proc/swap_inside_list(mob/user, var/first_target, var/second_target)
+	var/list/my_list = data
+	if(my_list.len <= 1)
+		to_chat(user, "<span class='warning'>The list is empty, or too small to do any meaningful swapping.</span>")
+		return
+	if(!first_target)
+		first_target = input("Which piece of data do you want to swap? (1)", "Swap") as null|anything in my_list
+
+	if(first_target)
+		if(!second_target)
+			second_target = input("Which piece of data do you want to swap? (2)", "Swap") as null|anything in my_list - first_target
+
+		if(second_target)
+			var/first_pos = my_list.Find(first_target)
+			var/second_pos = my_list.Find(second_target)
+			my_list.Swap(first_pos, second_pos)
+
+/datum/integrated_io/list/proc/clear_list(mob/user)
+	var/list/my_list = data
+	my_list.Cut()
+
+/datum/integrated_io/list/scramble()
+	var/list/my_list = data
+	my_list = shuffle(my_list)
+	push_data()
+
+/datum/integrated_io/list/write_data_to_pin(var/new_data)
+	if(islist(new_data))
+		var/list/new_list = new_data
+		data = new_list.Copy()
+		holder.on_data_written()
+
+/datum/integrated_io/list/display_pin_type()
+	return IC_FORMAT_LIST
+
+/datum/integrated_io/list/Topic(href, href_list, state = interactive_state)
+	if(!holder.check_interactivity(usr))
+		return
+	if(..())
+		return 1
+
+	if(href_list["add"])
+		add_to_list(usr)
+
+	if(href_list["swap"])
+		swap_inside_list(usr)
+
+	if(href_list["clear"])
+		clear_list(usr)
+
+	if(href_list["remove"])
+		if(href_list["pos"])
+			remove_from_list_by_position(usr, text2num(href_list["pos"]))
+		else
+			remove_from_list(usr)
+
+	if(href_list["edit"])
+		if(href_list["pos"])
+			edit_in_list_by_position(usr, text2num(href_list["pos"]))
+		else
+			edit_in_list(usr)
+
+	holder.interact(usr) // Refresh the main UI,
+	interact(usr) // and the list UI.

code/modules/integrated_electronics/core/special_pins/number_pin.dm

@@ -0,0 +1,17 @@
+// These pins can only contain numbers (int and floating point) or null.
+/datum/integrated_io/number
+	name = "number pin"
+
+/datum/integrated_io/number/ask_for_pin_data(mob/user)
+	var/new_data = input("Please type in a number.","[src] number writing") as null|num
+	if(isnum(new_data) && holder.check_interactivity(user) )
+		to_chat(user, "<span class='notice'>You input [new_data] into the pin.</span>")
+		write_data_to_pin(new_data)
+
+/datum/integrated_io/number/write_data_to_pin(var/new_data)
+	if(isnull(new_data) || isnum(new_data))
+		data = new_data
+		holder.on_data_written()
+
+/datum/integrated_io/number/display_pin_type()
+	return IC_FORMAT_NUMBER

code/modules/integrated_electronics/core/special_pins/ref_pin.dm

@@ -0,0 +1,14 @@
+// These pins only contain weakrefs or null.
+/datum/integrated_io/ref
+	name = "ref pin"
+
+/datum/integrated_io/ref/ask_for_pin_data(mob/user) // This clears the pin.
+	write_data_to_pin(null)
+
+/datum/integrated_io/ref/write_data_to_pin(var/new_data)
+	if(isnull(new_data) || isweakref(new_data))
+		data = new_data
+		holder.on_data_written()
+
+/datum/integrated_io/ref/display_pin_type()
+	return IC_FORMAT_REF

code/modules/integrated_electronics/core/special_pins/string_pin.dm

@@ -0,0 +1,29 @@
+// These pins can only contain text and null.
+/datum/integrated_io/string
+	name = "string pin"
+
+/datum/integrated_io/string/ask_for_pin_data(mob/user)
+	var/new_data = sanitize(input("Please type in a string.","[src] string writing") as null|text)
+	if(holder.check_interactivity(user) )
+		to_chat(user, "<span class='notice'>You input [new_data ? "new_data" : "NULL"] into the pin.</span>")
+		write_data_to_pin(new_data)
+
+/datum/integrated_io/string/write_data_to_pin(var/new_data)
+	if(isnull(new_data) || istext(new_data))
+		data = new_data
+		holder.on_data_written()
+
+// This makes the text go "from this" to "#G&*!HD$%L"
+/datum/integrated_io/string/scramble()
+	if(!is_valid())
+		return
+	var/string_length = length(data)
+	var/list/options = list("!","@","#","$","%","^","&","*") + alphabet_uppercase
+	var/new_data = ""
+	while(string_length)
+		new_data += pick(options)
+		string_length--
+	push_data()
+
+/datum/integrated_io/string/display_pin_type()
+	return IC_FORMAT_STRING

code/modules/integrated_electronics/core/tools.dm

@@ -0,0 +1,461 @@
+#define WIRE     "wire"
+#define WIRING   "wiring"
+#define UNWIRE   "unwire"
+#define UNWIRING "unwiring"
+
+/obj/item/device/integrated_electronics/wirer
+	name = "circuit wirer"
+	desc = "It's a small wiring tool, with a wire roll, electric soldering iron, wire cutter, and more in one package. \
+	The wires used are generally useful for small electronics, such as circuitboards and breadboards, as opposed to larger wires \
+	used for power or data transmission."
+	icon = 'icons/obj/electronic_assemblies.dmi'
+	icon_state = "wirer-wire"
+	item_state = "wirer"
+	flags = CONDUCT
+	w_class = 2
+	var/datum/integrated_io/selected_io
+	var/mode = WIRE
+
+/obj/item/device/integrated_electronics/wirer/update_icon()
+	icon_state = "wirer-[mode]"
+
+/obj/item/device/integrated_electronics/wirer/proc/wire(var/datum/integrated_io/io, mob/user)
+	if(!io.holder.assembly)
+		to_chat(user, "<span class='warning'>\The [io.holder] needs to be secured inside an assembly first.</span>")
+		return
+
+	switch (mode)
+		if (WIRE)
+			selected_io = io
+			to_chat(user, "<span class='notice'>You attach a data wire to \the [selected_io.holder]'s [selected_io.name] data channel.</span>")
+			mode = WIRING
+			update_icon()
+
+		if (WIRING)
+			if(io == selected_io)
+				to_chat(user, "<span class='warning'>Wiring \the [selected_io.holder]'s [selected_io.name] into itself is rather pointless.</span>")
+				return
+			if(io.io_type != selected_io.io_type)
+				to_chat(user, "<span class='warning'>Those two types of channels are incompatable.  The first is a [selected_io.io_type], \
+				while the second is a [io.io_type].</span>")
+				return
+			if(io.holder.assembly && io.holder.assembly != selected_io.holder.assembly)
+				to_chat(user, "<span class='warning'>Both \the [io.holder] and \the [selected_io.holder] need to be inside the same assembly.</span>")
+				return
+			selected_io.linked |= io
+			io.linked |= selected_io
+
+			to_chat(user, "<span class='notice'>You connect \the [selected_io.holder]'s [selected_io.name] to \the [io.holder]'s [io.name].</span>")
+			mode = WIRE
+			update_icon()
+			selected_io.holder.interact(user) // This is to update the UI.
+			selected_io = null
+
+		if (UNWIRE)
+			selected_io = io
+			if(!io.linked.len)
+				to_chat(user, "<span class='warning'>There is nothing connected to \the [selected_io] data channel.</span>")
+				selected_io = null
+				return
+			to_chat(user, "<span class='notice'>You prepare to detach a data wire from \the [selected_io.holder]'s [selected_io.name] data channel.</span>")
+			mode = UNWIRING
+			update_icon()
+	
+		if (UNWIRING)
+			if(io == selected_io)
+				to_chat(user, "<span class='warning'>You can't wire a pin into each other, so unwiring \the [selected_io.holder] from \
+				the same pin is rather moot.</span>")
+				return
+			if(selected_io in io.linked)
+				io.linked.Remove(selected_io)
+				selected_io.linked.Remove(io)
+				to_chat(user, "<span class='notice'>You disconnect \the [selected_io.holder]'s [selected_io.name] from \
+				\the [io.holder]'s [io.name].</span>")
+				selected_io.holder.interact(user) // This is to update the UI.
+				selected_io = null
+				mode = UNWIRE
+				update_icon()
+			else
+				to_chat(user, "<span class='warning'>\The [selected_io.holder]'s [selected_io.name] and \the [io.holder]'s \
+				[io.name] are not connected.</span>")
+
+/obj/item/device/integrated_electronics/wirer/attack_self(mob/user)
+	switch(mode)
+		if(WIRE)
+			mode = UNWIRE
+		if(WIRING)
+			if(selected_io)
+				to_chat(user, "<span class='notice'>You decide not to wire the data channel.</span>")
+			selected_io = null
+			mode = WIRE
+		if(UNWIRE)
+			mode = WIRE
+		if(UNWIRING)
+			if(selected_io)
+				to_chat(user, "<span class='notice'>You decide not to disconnect the data channel.</span>")
+			selected_io = null
+			mode = UNWIRE
+	update_icon()
+	to_chat(user, "<span class='notice'>You set \the [src] to [mode].</span>")
+
+#undef WIRE
+#undef WIRING
+#undef UNWIRE
+#undef UNWIRING
+
+/obj/item/device/integrated_electronics/debugger
+	name = "circuit debugger"
+	desc = "This small tool allows one working with custom machinery to directly set data to a specific pin, useful for writing \
+	settings to specific circuits, or for debugging purposes.  It can also pulse activation pins."
+	icon = 'icons/obj/electronic_assemblies.dmi'
+	icon_state = "debugger"
+	flags = CONDUCT
+	w_class = 2
+	var/data_to_write = null
+	var/accepting_refs = 0
+
+/obj/item/device/integrated_electronics/debugger/attack_self(mob/user)
+	var/type_to_use = input("Please choose a type to use.","[src] type setting") as null|anything in list("string","number","ref", "null")
+	if(!CanInteract(user, physical_state))
+		return
+
+	var/new_data = null
+	switch(type_to_use)
+		if("string")
+			accepting_refs = 0
+			new_data = sanitize(input("Now type in a string.","[src] string writing") as null|text)
+			if(istext(new_data) && CanInteract(user, physical_state))
+				data_to_write = new_data
+				to_chat(user, "<span class='notice'>You set \the [src]'s memory to \"[new_data]\".</span>")
+		if("number")
+			accepting_refs = 0
+			new_data = input("Now type in a number.","[src] number writing") as null|num
+			if(isnum(new_data) && CanInteract(user, physical_state))
+				data_to_write = new_data
+				to_chat(user, "<span class='notice'>You set \the [src]'s memory to [new_data].</span>")
+		if("ref")
+			accepting_refs = 1
+			to_chat(user, "<span class='notice'>You turn \the [src]'s ref scanner on.  Slide it across \
+			an object for a ref of that object to save it in memory.</span>")
+		if("null")
+			data_to_write = null
+			to_chat(user, "<span class='notice'>You set \the [src]'s memory to absolutely nothing.</span>")
+
+/obj/item/device/integrated_electronics/debugger/afterattack(atom/target, mob/living/user, proximity)
+	if(accepting_refs && proximity)
+		data_to_write = WEAKREF(target)
+		visible_message("<span class='notice'>[user] slides [src]'s ref scanner over \the [target].</span>")
+		to_chat(user, "<span class='notice'>You set \the [src]'s memory to a reference to [target.name] \[Ref\].  The ref scanner is \
+		now off.</span>")
+		accepting_refs = 0
+
+/obj/item/device/integrated_electronics/debugger/proc/write_data(var/datum/integrated_io/io, mob/user)
+	switch (io.io_type)
+		if (DATA_CHANNEL)
+			io.write_data_to_pin(data_to_write)
+			var/data_to_show = data_to_write
+			if(isweakref(data_to_write))
+				var/datum/weakref/w = data_to_write
+				var/atom/A = w.resolve()
+				data_to_show = A.name
+			to_chat(user, "<span class='notice'>You write '[data_to_write ? data_to_show : "NULL"]' to the '[io]' pin of \the [io.holder].</span>")
+		if (PULSE_CHANNEL)
+			io.holder.check_then_do_work(ignore_power = TRUE)
+			to_chat(user, "<span class='notice'>You pulse \the [io.holder]'s '[io]' pin.</span>")
+
+	io.holder.interact(user) // This is to update the UI.
+
+/obj/item/device/multitool
+	var/datum/integrated_io/selected_io = null
+	var/mode = 0
+
+/obj/item/device/multitool/attack_self(mob/user)
+	if(selected_io)
+		selected_io = null
+		to_chat(user, "<span class='notice'>You clear the wired connection from the multitool.</span>")
+	else
+		..()
+	update_icon()
+
+/obj/item/device/multitool/update_icon()
+	if(selected_io)
+		if(buffer || connecting || buffer_object)
+			icon_state = "multitool_tracking"
+		else
+			icon_state = "multitool_red"
+	else
+		if(buffer || connecting || buffer_object)
+			icon_state = "multitool_tracking_fail"
+		else
+			icon_state = "multitool"
+
+/obj/item/device/multitool/proc/wire(datum/integrated_io/io, mob/user)
+	if(!io.holder.assembly)
+		to_chat(user, "<span class='warning'>\The [io.holder] needs to be secured inside an assembly first.</span>")
+		return
+
+	if(selected_io)
+		if(io == selected_io)
+			to_chat(user, "<span class='warning'>Wiring \the [selected_io.holder]'s '[selected_io.name]' pin into itself is rather pointless.</span>")
+			return
+		if(io.io_type != selected_io.io_type)
+			to_chat(user, "<span class='warning'>Those two types of channels are incompatable.  The first is a [selected_io.io_type], \
+			while the second is a [io.io_type].</span>")
+			return
+		if(io.holder.assembly && io.holder.assembly != selected_io.holder.assembly)
+			to_chat(user, "<span class='warning'>Both \the [io.holder] and \the [selected_io.holder] need to be inside the same assembly.</span>")
+			return
+		selected_io.linked |= io
+		io.linked |= selected_io
+
+		to_chat(user, "<span class='notice'>You connect \the [selected_io.holder]'s '[selected_io.name]' pin to \the [io.holder]'s '[io.name]' pin.</span>")
+		selected_io.holder.interact(user) // This is to update the UI.
+		selected_io = null
+
+	else
+		selected_io = io
+		to_chat(user, "<span class='notice'>You link \the multitool to \the [selected_io.holder]'s [selected_io.name] data channel.</span>")
+
+	update_icon()
+
+/obj/item/device/multitool/proc/unwire(datum/integrated_io/io1, datum/integrated_io/io2, mob/user)
+	if(!io1.linked.len || !io2.linked.len)
+		to_chat(user, "<span class='warning'>There is nothing connected to the data channel.</span>")
+		return
+
+	if(!(io1 in io2.linked) || !(io2 in io1.linked) )
+		to_chat(user, "<span class='warning'>These data pins aren't connected!</span>")
+		return
+	else
+		io1.linked.Remove(io2)
+		io2.linked.Remove(io1)
+		to_chat(user, "<span class='notice'>You clip the data connection between the [io1.holder.displayed_name]'s \
+		'[io1.name]' pin and the [io2.holder.displayed_name]'s '[io2.name]' pin.</span>")
+		io1.holder.interact(user) // This is to update the UI.
+		update_icon()
+
+/obj/item/weapon/storage/bag/circuits
+	name = "circuit kit"
+	desc = "This kit's essential for any circuitry projects."
+	icon = 'icons/obj/electronic_assemblies.dmi'
+	icon_state = "circuit_kit"
+	w_class = 3
+	display_contents_with_number = 0
+	can_hold = list(
+		/obj/item/integrated_circuit,
+		/obj/item/weapon/storage/bag/circuits/mini,
+		/obj/item/device/electronic_assembly,
+		/obj/item/device/integrated_electronics,
+		/obj/item/weapon/crowbar,
+		/obj/item/weapon/screwdriver,
+		/obj/item/device/multitool
+	)
+
+/obj/item/weapon/storage/bag/circuits/basic/fill()
+	new /obj/item/weapon/storage/bag/circuits/mini/arithmetic(src)
+	new /obj/item/weapon/storage/bag/circuits/mini/trig(src)
+	new /obj/item/weapon/storage/bag/circuits/mini/input(src)
+	new /obj/item/weapon/storage/bag/circuits/mini/output(src)
+	new /obj/item/weapon/storage/bag/circuits/mini/memory(src)
+	new /obj/item/weapon/storage/bag/circuits/mini/logic(src)
+	new /obj/item/weapon/storage/bag/circuits/mini/time(src)
+	new /obj/item/weapon/storage/bag/circuits/mini/reagents(src)
+	new /obj/item/weapon/storage/bag/circuits/mini/transfer(src)
+	new /obj/item/weapon/storage/bag/circuits/mini/converter(src)
+	new /obj/item/weapon/storage/bag/circuits/mini/power(src)
+
+	new /obj/item/device/electronic_assembly(src)
+	new /obj/item/device/assembly/electronic_assembly(src)
+	new /obj/item/device/assembly/electronic_assembly(src)
+	new /obj/item/device/multitool(src)
+	new /obj/item/weapon/screwdriver(src)
+	new /obj/item/weapon/crowbar(src)
+	make_exact_fit()
+
+/obj/item/weapon/storage/bag/circuits/all/fill()
+	..()
+	new /obj/item/weapon/storage/bag/circuits/mini/arithmetic/all(src)
+	new /obj/item/weapon/storage/bag/circuits/mini/trig/all(src)
+	new /obj/item/weapon/storage/bag/circuits/mini/input/all(src)
+	new /obj/item/weapon/storage/bag/circuits/mini/output/all(src)
+	new /obj/item/weapon/storage/bag/circuits/mini/memory/all(src)
+	new /obj/item/weapon/storage/bag/circuits/mini/logic/all(src)
+	new /obj/item/weapon/storage/bag/circuits/mini/smart/all(src)
+	new /obj/item/weapon/storage/bag/circuits/mini/manipulation/all(src)
+	new /obj/item/weapon/storage/bag/circuits/mini/time/all(src)
+	new /obj/item/weapon/storage/bag/circuits/mini/reagents/all(src)
+	new /obj/item/weapon/storage/bag/circuits/mini/transfer/all(src)
+	new /obj/item/weapon/storage/bag/circuits/mini/converter/all(src)
+	new /obj/item/weapon/storage/bag/circuits/mini/power/all(src)
+
+	new /obj/item/device/electronic_assembly(src)
+	new /obj/item/device/electronic_assembly/medium(src)
+	new /obj/item/device/electronic_assembly/large(src)
+	new /obj/item/device/electronic_assembly/drone(src)
+	new /obj/item/device/integrated_electronics/wirer(src)
+	new /obj/item/device/integrated_electronics/debugger(src)
+	new /obj/item/weapon/crowbar(src)
+	make_exact_fit()
+
+/obj/item/weapon/storage/bag/circuits/mini
+	name = "circuit box"
+	desc = "Used to partition categories of circuits, for a neater workspace."
+	w_class = 2
+	display_contents_with_number = 1
+	can_hold = list(/obj/item/integrated_circuit)
+	var/spawn_flags_to_use = IC_SPAWN_DEFAULT
+	var/list/spawn_types = list()
+
+/obj/item/weapon/storage/bag/circuits/mini/fill()
+	spawn_types = typecacheof(spawn_types)
+	for (var/thing in typecache_filter_list(SSelectronics.all_integrated_circuits, spawn_types))
+		var/obj/item/integrated_circuit/IC = thing
+		if (IC.spawn_flags & spawn_flags_to_use)
+			for (var/i in 1 to 4)
+				new IC.type(src)
+
+	make_exact_fit()
+
+/obj/item/weapon/storage/bag/circuits/mini/arithmetic
+	name = "arithmetic circuit box"
+	desc = "Warning: Contains math."
+	icon_state = "box_arithmetic"
+	spawn_types = list(
+		/obj/item/integrated_circuit/arithmetic
+	)
+
+/obj/item/weapon/storage/bag/circuits/mini/arithmetic/all // Don't believe this will ever be needed.
+	spawn_flags_to_use = IC_SPAWN_DEFAULT|IC_SPAWN_RESEARCH
+
+/obj/item/weapon/storage/bag/circuits/mini/trig
+	name = "trig circuit box"
+	desc = "Danger: Contains more math."
+	icon_state = "box_trig"
+	spawn_types = list(
+		/obj/item/integrated_circuit/trig
+	)
+
+/obj/item/weapon/storage/bag/circuits/mini/trig/all // Ditto
+	spawn_flags_to_use = IC_SPAWN_DEFAULT|IC_SPAWN_RESEARCH
+
+/obj/item/weapon/storage/bag/circuits/mini/input
+	name = "input circuit box"
+	desc = "Tell these circuits everything you know."
+	icon_state = "box_input"
+	spawn_types = list(
+		/obj/item/integrated_circuit/input
+	)
+
+/obj/item/weapon/storage/bag/circuits/mini/input/all
+	spawn_flags_to_use = IC_SPAWN_DEFAULT|IC_SPAWN_RESEARCH
+
+/obj/item/weapon/storage/bag/circuits/mini/output
+	name = "output circuit box"
+	desc = "Circuits to interface with the world beyond itself."
+	icon_state = "box_output"
+	spawn_types = list(
+		/obj/item/integrated_circuit/output
+	)
+
+/obj/item/weapon/storage/bag/circuits/mini/output/all
+	spawn_flags_to_use = IC_SPAWN_DEFAULT|IC_SPAWN_RESEARCH
+
+/obj/item/weapon/storage/bag/circuits/mini/memory
+	name = "memory circuit box"
+	desc = "Machines can be quite forgetful without these."
+	icon_state = "box_memory"
+	spawn_types = list(
+		/obj/item/integrated_circuit/memory
+	)
+
+/obj/item/weapon/storage/bag/circuits/mini/memory/all
+	spawn_flags_to_use = IC_SPAWN_DEFAULT|IC_SPAWN_RESEARCH
+
+/obj/item/weapon/storage/bag/circuits/mini/logic
+	name = "logic circuit box"
+	desc = "May or may not be Turing complete."
+	icon_state = "box_logic"
+	spawn_types = list(
+		/obj/item/integrated_circuit/logic
+	)
+
+/obj/item/weapon/storage/bag/circuits/mini/logic/all
+	spawn_flags_to_use = IC_SPAWN_DEFAULT|IC_SPAWN_RESEARCH
+
+/obj/item/weapon/storage/bag/circuits/mini/time
+	name = "time circuit box"
+	desc = "No time machine parts, sadly."
+	icon_state = "box_time"
+	spawn_types = list(
+		/obj/item/integrated_circuit/time
+	)
+
+/obj/item/weapon/storage/bag/circuits/mini/time/all
+	spawn_flags_to_use = IC_SPAWN_DEFAULT|IC_SPAWN_RESEARCH
+
+/obj/item/weapon/storage/bag/circuits/mini/reagents
+	name = "reagent circuit box"
+	desc = "Unlike most electronics, these circuits are supposed to come in contact with liquids."
+	icon_state = "box_reagents"
+	spawn_types = list(
+		/obj/item/integrated_circuit/reagent
+	)
+
+/obj/item/weapon/storage/bag/circuits/mini/reagents/all
+	spawn_flags_to_use = IC_SPAWN_DEFAULT|IC_SPAWN_RESEARCH
+
+/obj/item/weapon/storage/bag/circuits/mini/transfer
+	name = "transfer circuit box"
+	desc = "Useful for moving data representing something arbitrary to another arbitrary virtual place."
+	icon_state = "box_transfer"
+	spawn_types = list(
+		/obj/item/integrated_circuit/transfer
+	)
+
+/obj/item/weapon/storage/bag/circuits/mini/transfer/all
+	spawn_flags_to_use = IC_SPAWN_DEFAULT|IC_SPAWN_RESEARCH
+
+/obj/item/weapon/storage/bag/circuits/mini/converter
+	name = "converter circuit box"
+	desc = "Transform one piece of data to another type of data with these."
+	icon_state = "box_converter"
+	spawn_types = list(
+		/obj/item/integrated_circuit/converter
+	)
+
+/obj/item/weapon/storage/bag/circuits/mini/converter/all
+	spawn_flags_to_use = IC_SPAWN_DEFAULT|IC_SPAWN_RESEARCH
+
+/obj/item/weapon/storage/bag/circuits/mini/smart
+	name = "smart box"
+	desc = "Sentience not included."
+	icon_state = "box_ai"
+	spawn_types = list(
+		/obj/item/integrated_circuit/smart
+	)
+
+/obj/item/weapon/storage/bag/circuits/mini/smart/all
+	spawn_flags_to_use = IC_SPAWN_DEFAULT|IC_SPAWN_RESEARCH
+
+/obj/item/weapon/storage/bag/circuits/mini/manipulation
+	name = "manipulation box"
+	desc = "Make your machines actually useful with these."
+	icon_state = "box_manipulation"
+	spawn_types = list(
+		/obj/item/integrated_circuit/manipulation
+	)
+
+/obj/item/weapon/storage/bag/circuits/mini/manipulation/all
+	spawn_flags_to_use = IC_SPAWN_DEFAULT|IC_SPAWN_RESEARCH
+
+/obj/item/weapon/storage/bag/circuits/mini/power
+	name = "power circuit box"
+	desc = "Electronics generally require electricity."
+	icon_state = "box_power"
+	spawn_types = list(
+		/obj/item/integrated_circuit/passive/power,
+		/obj/item/integrated_circuit/power
+	)
+
+/obj/item/weapon/storage/bag/circuits/mini/power/all
+	spawn_flags_to_use = IC_SPAWN_DEFAULT|IC_SPAWN_RESEARCH