Restructuring a bunch of files in prep for widespread path changes.

code/game/objects/items/weapons/material/bats.dm

@@ -0,0 +1,80 @@
+/obj/item/weapon/twohanded/baseballbat
+	name = "wooden bat"
+	desc = "HOME RUN!"
+	icon_state = "metalbat0"
+	base_icon = "metalbat"
+	item_state = "metalbat"
+	sharp = 0
+	edge = 0
+	w_class = 3
+	force = 10
+	throw_speed = 3
+	throw_range = 7
+	throwforce = 7
+	attack_verb = list("smashed", "beaten", "slammed", "smacked", "struck", "battered", "bonked")
+	hitsound = 'sound/weapons/genhit3.ogg'
+	force_wielded = 20
+	health = 10
+	var/material/material
+
+/obj/item/weapon/twohanded/baseballbat/New(var/newloc, var/material_key)
+	..(newloc)
+	if(!material_key)
+		material_key = "wood"
+	material = get_material_by_name(material_key)
+	if(!material)
+		qdel(src)
+	else
+		name = "[material.display_name] bat"
+		base_name = name
+		health = round(material.integrity/10)
+		force = round(material.get_blunt_damage()/2)
+		force_unwielded = force
+		force_wielded = material.get_blunt_damage()
+		color = material.icon_colour
+		if(material.products_need_process())
+			processing_objects |= src
+
+/obj/item/weapon/twohanded/baseballbat/Destroy()
+	processing_objects -= src
+	..()
+
+/obj/item/weapon/twohanded/baseballbat/attack()
+	if(!..())
+		return
+	if(!prob(material.hardness))
+		health--
+	if(health<=0)
+		shatter()
+
+/obj/item/weapon/twohanded/baseballbat/proc/shatter()
+	var/turf/T = get_turf(src)
+	T.visible_message("<span class='danger'>\The [src] shatters!</span>")
+	if(istype(loc, /mob/living))
+		var/mob/living/M = loc
+		M.drop_from_inventory(src)
+	playsound(src, "shatter", 70, 1)
+	new material.shard_type(T)
+	qdel(src)
+
+/obj/item/weapon/twohanded/baseballbat/process()
+	if(!material.radioactivity)
+		return
+	for(var/mob/living/L in range(1,src))
+		L.apply_effect(round(material.radioactivity/3),IRRADIATE,0)
+
+//Predefined materials go here.
+/obj/item/weapon/twohanded/baseballbat/metal/New(var/newloc)
+	..(newloc,"steel")
+
+/obj/item/weapon/twohanded/baseballbat/uranium/New(var/newloc)
+	..(newloc,"uranium")
+
+/obj/item/weapon/twohanded/baseballbat/gold/New(var/newloc)
+	..(newloc,"gold")
+
+/obj/item/weapon/twohanded/baseballbat/platinum/New(var/newloc)
+	..(newloc,"platinum")
+
+/obj/item/weapon/twohanded/baseballbat/diamond/New(var/newloc)
+	..(newloc,"diamond")

code/game/objects/items/weapons/material/kitchen.dm

@@ -0,0 +1,392 @@
+/obj/item/weapon/kitchen
+	icon = 'icons/obj/kitchen.dmi'
+
+/*
+ * Utensils
+ */
+/obj/item/weapon/kitchen/utensil
+	force = 5.0
+	w_class = 1.0
+	throwforce = 5.0
+	throw_speed = 3
+	throw_range = 5
+	flags = CONDUCT
+	origin_tech = "materials=1"
+	attack_verb = list("attacked", "stabbed", "poked")
+	sharp = 0
+
+	var/loaded      //Descriptive string for currently loaded food object.
+
+/obj/item/weapon/kitchen/utensil/New()
+	if (prob(60))
+		src.pixel_y = rand(0, 4)
+
+	create_reagents(5)
+	return
+
+/obj/item/weapon/kitchen/utensil/attack(mob/living/carbon/M as mob, mob/living/carbon/user as mob)
+	if(!istype(M))
+		return ..()
+
+	if(user.a_intent != I_HELP)
+		if(user.zone_sel.selecting == "head" || user.zone_sel.selecting == "eyes")
+			if((CLUMSY in user.mutations) && prob(50))
+				M = user
+			return eyestab(M,user)
+		else
+			return ..()
+
+	if (reagents.total_volume > 0)
+		reagents.trans_to_mob(M, reagents.total_volume, CHEM_INGEST)
+		if(M == user)
+			for(var/mob/O in viewers(M, null))
+				O.show_message(text("\blue [] eats some [] from \the [].", user, loaded, src), 1)
+				M.reagents.add_reagent("nutriment", 1)
+		else
+			for(var/mob/O in viewers(M, null))
+				O.show_message(text("\blue [] feeds [] some [] from \the []", user, M, loaded, src), 1)
+				M.reagents.add_reagent("nutriment", 1)
+		playsound(M.loc,'sound/items/eatfood.ogg', rand(10,40), 1)
+		overlays.Cut()
+		return
+	else
+		..()
+
+/obj/item/weapon/kitchen/utensil/fork
+	name = "fork"
+	desc = "It's a fork. Sure is pointy."
+	icon_state = "fork"
+
+/obj/item/weapon/kitchen/utensil/pfork
+	name = "plastic fork"
+	desc = "Yay, no washing up to do."
+	icon_state = "pfork"
+
+/obj/item/weapon/kitchen/utensil/spoon
+	name = "spoon"
+	desc = "It's a spoon. You can see your own upside-down face in it."
+	icon_state = "spoon"
+	attack_verb = list("attacked", "poked")
+
+/obj/item/weapon/kitchen/utensil/pspoon
+	name = "plastic spoon"
+	desc = "It's a plastic spoon. How dull."
+	icon_state = "pspoon"
+	attack_verb = list("attacked", "poked")
+
+/*
+ * Knives
+ */
+/obj/item/weapon/kitchen/utensil/knife
+	name = "knife"
+	desc = "Can cut through any food."
+	icon_state = "knife"
+	force = 10.0
+	throwforce = 10.0
+	sharp = 1
+	edge = 1
+
+	suicide_act(mob/user)
+		viewers(user) << pick("\red <b>[user] is slitting \his wrists with the [src.name]! It looks like \he's trying to commit suicide.</b>", \
+							"\red <b>[user] is slitting \his throat with the [src.name]! It looks like \he's trying to commit suicide.</b>", \
+							"\red <b>[user] is slitting \his stomach open with the [src.name]! It looks like \he's trying to commit seppuku.</b>")
+		return (BRUTELOSS)
+
+/obj/item/weapon/kitchen/utensil/knife/attack(target as mob, mob/living/user as mob)
+	if ((CLUMSY in user.mutations) && prob(50))
+		user << "\red You accidentally cut yourself with the [src]."
+		user.take_organ_damage(20)
+		return
+	playsound(loc, 'sound/weapons/bladeslice.ogg', 50, 1, -1)
+	return ..()
+
+/obj/item/weapon/kitchen/utensil/pknife
+	name = "plastic knife"
+	desc = "The bluntest of blades."
+	icon_state = "pknife"
+	force = 1
+	throwforce = 1
+	sharp = 0
+	edge = 1 //for cutting pizzas
+
+/obj/item/weapon/kitchen/utensil/knife/attack(target as mob, mob/living/user as mob)
+	if ((CLUMSY in user.mutations) && prob(50))
+		user << "\red You somehow managed to cut yourself with the [src]."
+		user.take_organ_damage(20)
+		return
+	playsound(loc, 'sound/weapons/bladeslice.ogg', 50, 1, -1)
+	return ..()
+
+/*
+ * Rolling Pins
+ */
+
+/obj/item/weapon/kitchen/rollingpin
+	name = "rolling pin"
+	desc = "Used to knock out the Bartender."
+	icon_state = "rolling_pin"
+	force = 8.0
+	throwforce = 10.0
+	throw_speed = 2
+	throw_range = 7
+	w_class = 3.0
+	attack_verb = list("bashed", "battered", "bludgeoned", "thrashed", "whacked") //I think the rollingpin attackby will end up ignoring this anyway.
+
+/obj/item/weapon/kitchen/rollingpin/attack(mob/living/M as mob, mob/living/user as mob)
+	if ((CLUMSY in user.mutations) && prob(50))
+		user << "\red The [src] slips out of your hand and hits your head."
+		user.take_organ_damage(10)
+		user.Paralyse(2)
+		return
+
+	M.attack_log += text("\[[time_stamp()]\] <font color='orange'>Has been attacked with [src.name] by [user.name] ([user.ckey])</font>")
+	user.attack_log += text("\[[time_stamp()]\] <font color='red'>Used the [src.name] to attack [M.name] ([M.ckey])</font>")
+	msg_admin_attack("[user.name] ([user.ckey]) used the [src.name] to attack [M.name] ([M.ckey]) (<A HREF='?_src_=holder;adminplayerobservecoodjump=1;X=[user.x];Y=[user.y];Z=[user.z]'>JMP</a>)")
+
+	var/t = user:zone_sel.selecting
+	if (t == "head")
+		if(ishuman(M))
+			var/mob/living/carbon/human/H = M
+			if (H.stat < 2 && H.health < 50 && prob(90))
+				// ******* Check
+				if (istype(H, /obj/item/clothing/head) && H.flags & 8 && prob(80))
+					H << "\red The helmet protects you from being hit hard in the head!"
+					return
+				var/time = rand(2, 6)
+				if (prob(75))
+					H.Paralyse(time)
+				else
+					H.Stun(time)
+				if(H.stat != 2)	H.stat = 1
+				user.visible_message("\red <B>[H] has been knocked unconscious!</B>", "\red <B>You knock [H] unconscious!</B>")
+				return
+			else
+				H.visible_message("\red [user] tried to knock [H] unconscious!", "\red [user] tried to knock you unconscious!")
+				H.eye_blurry += 3
+	return ..()
+
+/*
+ * Trays - Agouri
+ */
+/obj/item/weapon/tray
+	name = "tray"
+	icon = 'icons/obj/food.dmi'
+	icon_state = "tray"
+	desc = "A metal tray to lay food on."
+	throwforce = 12.0
+	throwforce = 10.0
+	throw_speed = 1
+	throw_range = 5
+	w_class = 3.0
+	flags = CONDUCT
+	matter = list(DEFAULT_WALL_MATERIAL = 3000)
+	/* // NOPE
+	var/food_total= 0
+	var/burger_amt = 0
+	var/cheese_amt = 0
+	var/fries_amt = 0
+	var/classyalcdrink_amt = 0
+	var/alcdrink_amt = 0
+	var/bottle_amt = 0
+	var/soda_amt = 0
+	var/carton_amt = 0
+	var/pie_amt = 0
+	var/meatbreadslice_amt = 0
+	var/salad_amt = 0
+	var/miscfood_amt = 0
+	*/
+	var/list/carrying = list() // List of things on the tray. - Doohl
+	var/max_carry = 10 // w_class = 1 -- takes up 1
+					   // w_class = 2 -- takes up 3
+					   // w_class = 3 -- takes up 5
+
+/obj/item/weapon/tray/attack(mob/living/carbon/M as mob, mob/living/carbon/user as mob)
+
+	// Drop all the things. All of them.
+	overlays.Cut()
+	for(var/obj/item/I in carrying)
+		I.loc = M.loc
+		carrying.Remove(I)
+		if(isturf(I.loc))
+			spawn()
+				for(var/i = 1, i <= rand(1,2), i++)
+					if(I)
+						step(I, pick(NORTH,SOUTH,EAST,WEST))
+						sleep(rand(2,4))
+
+
+	if((CLUMSY in user.mutations) && prob(50))              //What if he's a clown?
+		M << "\red You accidentally slam yourself with the [src]!"
+		M.Weaken(1)
+		user.take_organ_damage(2)
+		if(prob(50))
+			playsound(M, 'sound/items/trayhit1.ogg', 50, 1)
+			return
+		else
+			playsound(M, 'sound/items/trayhit2.ogg', 50, 1) //sound playin'
+			return //it always returns, but I feel like adding an extra return just for safety's sakes. EDIT; Oh well I won't :3
+
+	var/mob/living/carbon/human/H = M      ///////////////////////////////////// /Let's have this ready for later.
+
+
+	if(!(user.zone_sel.selecting == ("eyes" || "head"))) //////////////hitting anything else other than the eyes
+		if(prob(33))
+			src.add_blood(H)
+			var/turf/location = H.loc
+			if (istype(location, /turf/simulated))
+				location.add_blood(H)     ///Plik plik, the sound of blood
+
+		M.attack_log += text("\[[time_stamp()]\] <font color='orange'>Has been attacked with [src.name] by [user.name] ([user.ckey])</font>")
+		user.attack_log += text("\[[time_stamp()]\] <font color='red'>Used the [src.name] to attack [M.name] ([M.ckey])</font>")
+		msg_admin_attack("[user.name] ([user.ckey]) used the [src.name] to attack [M.name] ([M.ckey]) (<A HREF='?_src_=holder;adminplayerobservecoodjump=1;X=[user.x];Y=[user.y];Z=[user.z]'>JMP</a>)")
+
+		if(prob(15))
+			M.Weaken(3)
+			M.take_organ_damage(3)
+		else
+			M.take_organ_damage(5)
+		if(prob(50))
+			playsound(M, 'sound/items/trayhit1.ogg', 50, 1)
+			for(var/mob/O in viewers(M, null))
+				O.show_message(text("\red <B>[] slams [] with the tray!</B>", user, M), 1)
+			return
+		else
+			playsound(M, 'sound/items/trayhit2.ogg', 50, 1)  //we applied the damage, we played the sound, we showed the appropriate messages. Time to return and stop the proc
+			for(var/mob/O in viewers(M, null))
+				O.show_message(text("\red <B>[] slams [] with the tray!</B>", user, M), 1)
+			return
+
+
+	if(istype(M, /mob/living/carbon/human) && ((H.head && H.head.flags & HEADCOVERSEYES) || (H.wear_mask && H.wear_mask.flags & MASKCOVERSEYES) || (H.glasses && H.glasses.flags & GLASSESCOVERSEYES)))
+		M << "\red You get slammed in the face with the tray, against your mask!"
+		if(prob(33))
+			src.add_blood(H)
+			if (H.wear_mask)
+				H.wear_mask.add_blood(H)
+			if (H.head)
+				H.head.add_blood(H)
+			if (H.glasses && prob(33))
+				H.glasses.add_blood(H)
+			var/turf/location = H.loc
+			if (istype(location, /turf/simulated))     //Addin' blood! At least on the floor and item :v
+				location.add_blood(H)
+
+		if(prob(50))
+			playsound(M, 'sound/items/trayhit1.ogg', 50, 1)
+			for(var/mob/O in viewers(M, null))
+				O.show_message(text("\red <B>[] slams [] with the tray!</B>", user, M), 1)
+		else
+			playsound(M, 'sound/items/trayhit2.ogg', 50, 1)  //sound playin'
+			for(var/mob/O in viewers(M, null))
+				O.show_message(text("\red <B>[] slams [] with the tray!</B>", user, M), 1)
+		if(prob(10))
+			M.Stun(rand(1,3))
+			M.take_organ_damage(3)
+			return
+		else
+			M.take_organ_damage(5)
+			return
+
+	else //No eye or head protection, tough luck!
+		M << "\red You get slammed in the face with the tray!"
+		if(prob(33))
+			src.add_blood(M)
+			var/turf/location = H.loc
+			if (istype(location, /turf/simulated))
+				location.add_blood(H)
+
+		if(prob(50))
+			playsound(M, 'sound/items/trayhit1.ogg', 50, 1)
+			for(var/mob/O in viewers(M, null))
+				O.show_message(text("\red <B>[] slams [] in the face with the tray!</B>", user, M), 1)
+		else
+			playsound(M, 'sound/items/trayhit2.ogg', 50, 1)  //sound playin' again
+			for(var/mob/O in viewers(M, null))
+				O.show_message(text("\red <B>[] slams [] in the face with the tray!</B>", user, M), 1)
+		if(prob(30))
+			M.Stun(rand(2,4))
+			M.take_organ_damage(4)
+			return
+		else
+			M.take_organ_damage(8)
+			if(prob(30))
+				M.Weaken(2)
+				return
+			return
+
+/obj/item/weapon/tray/var/cooldown = 0	//shield bash cooldown. based on world.time
+
+/obj/item/weapon/tray/attackby(obj/item/weapon/W as obj, mob/user as mob)
+	if(istype(W, /obj/item/weapon/kitchen/rollingpin))
+		if(cooldown < world.time - 25)
+			user.visible_message("<span class='warning'>[user] bashes [src] with [W]!</span>")
+			playsound(user.loc, 'sound/effects/shieldbash.ogg', 50, 1)
+			cooldown = world.time
+	else
+		..()
+
+/*
+===============~~~~~================================~~~~~====================
+=																			=
+=  Code for trays carrying things. By Doohl for Doohl erryday Doohl Doohl~  =
+=																			=
+===============~~~~~================================~~~~~====================
+*/
+/obj/item/weapon/tray/proc/calc_carry()
+	// calculate the weight of the items on the tray
+	var/val = 0 // value to return
+
+	for(var/obj/item/I in carrying)
+		if(I.w_class == 1.0)
+			val ++
+		else if(I.w_class == 2.0)
+			val += 3
+		else
+			val += 5
+
+	return val
+
+/obj/item/weapon/tray/pickup(mob/user)
+
+	if(!isturf(loc))
+		return
+
+	for(var/obj/item/I in loc)
+		if( I != src && !I.anchored && !istype(I, /obj/item/clothing/under) && !istype(I, /obj/item/clothing/suit) && !istype(I, /obj/item/projectile) )
+			var/add = 0
+			if(I.w_class == 1.0)
+				add = 1
+			else if(I.w_class == 2.0)
+				add = 3
+			else
+				add = 5
+			if(calc_carry() + add >= max_carry)
+				break
+
+			I.loc = src
+			carrying.Add(I)
+			overlays += image("icon" = I.icon, "icon_state" = I.icon_state, "layer" = 30 + I.layer)
+
+/obj/item/weapon/tray/dropped(mob/user)
+
+	var/mob/living/M
+	for(M in src.loc) //to handle hand switching
+		return
+
+	var/foundtable = 0
+	for(var/obj/structure/table/T in loc)
+		foundtable = 1
+		break
+
+	overlays.Cut()
+
+	for(var/obj/item/I in carrying)
+		I.loc = loc
+		carrying.Remove(I)
+		if(!foundtable && isturf(loc))
+			// if no table, presume that the person just shittily dropped the tray on the ground and made a mess everywhere!
+			spawn()
+				for(var/i = 1, i <= rand(1,2), i++)
+					if(I)
+						step(I, pick(NORTH,SOUTH,EAST,WEST))
+						sleep(rand(2,4))

code/game/objects/items/weapons/material/knives.dm

@@ -0,0 +1,106 @@
+/obj/item/weapon/butterfly
+	name = "butterfly knife"
+	desc = "A basic metal blade concealed in a lightweight plasteel grip. Small enough when folded to fit in a pocket."
+	icon_state = "butterflyknife"
+	item_state = null
+	hitsound = null
+	var/active = 0
+	w_class = 2
+	force = 2
+	sharp = 0
+	edge = 0
+	throw_speed = 3
+	throw_range = 4
+	throwforce = 7
+	attack_verb = list("patted", "tapped")
+
+/obj/item/weapon/butterfly/switchblade
+	name = "switchblade"
+	desc = "A classic switchblade with gold engraving. Just holding it makes you feel like a gangster."
+	icon_state = "switchblade"
+
+/obj/item/weapon/butterfly/attack_self(mob/user)
+	active = !active
+	if(active)
+		user << "<span class='notice'>You flip out your [src].</span>"
+		playsound(user, 'sound/weapons/flipblade.ogg', 15, 1)
+		force = 15 //bay adjustments
+		throwforce = 12
+		edge = 1
+		sharp = 1
+		hitsound = 'sound/weapons/bladeslice.ogg'
+		icon_state += "_open"
+		w_class = 3
+		attack_verb = list("attacked", "slashed", "stabbed", "sliced", "torn", "ripped", "diced", "cut")
+	else
+		user << "<span class='notice'>The butterfly knife can now be concealed.</span>"
+		force = initial(force)
+		edge = 0
+		sharp = 0
+		hitsound = initial(hitsound)
+		icon_state = initial(icon_state)
+		w_class = initial(w_class)
+		attack_verb = initial(attack_verb)
+		add_fingerprint(user)
+
+/*
+ * Kitchen knives
+ */
+/obj/item/weapon/kitchenknife
+	name = "kitchen knife"
+	icon = 'icons/obj/kitchen.dmi'
+	icon_state = "knife"
+	desc = "A general purpose Chef's Knife made by SpaceCook Incorporated. Guaranteed to stay sharp for years to come."
+	flags = CONDUCT
+	sharp = 1
+	edge = 1
+	force = 10.0
+	w_class = 3.0
+	throwforce = 6.0
+	throw_speed = 3
+	throw_range = 6
+	matter = list(DEFAULT_WALL_MATERIAL = 12000)
+	origin_tech = "materials=1"
+	attack_verb = list("slashed", "stabbed", "sliced", "torn", "ripped", "diced", "cut")
+
+	suicide_act(mob/user)
+		viewers(user) << pick("\red <b>[user] is slitting \his wrists with the [src.name]! It looks like \he's trying to commit suicide.</b>", \
+							"\red <b>[user] is slitting \his throat with the [src.name]! It looks like \he's trying to commit suicide.</b>", \
+							"\red <b>[user] is slitting \his stomach open with the [src.name]! It looks like \he's trying to commit seppuku.</b>")
+		return (BRUTELOSS)
+
+/obj/item/weapon/kitchenknife/hook
+	name = "meat hook"
+	desc = "A sharp, metal hook what sticks into things."
+	icon_state = "hook_knife"
+	item_state = "hook_knife"
+
+/obj/item/weapon/kitchenknife/ritual
+	name = "ritual knife"
+	desc = "The unearthly energies that once powered this blade are now dormant."
+	icon = 'icons/obj/wizard.dmi'
+	icon_state = "render"
+
+/*
+ * Bucher's cleaver
+ */
+/obj/item/weapon/butch
+	name = "butcher's cleaver"
+	icon = 'icons/obj/kitchen.dmi'
+	icon_state = "butch"
+	desc = "A huge thing used for chopping and chopping up meat. This includes clowns and clown-by-products."
+	flags = CONDUCT
+	force = 15.0
+	w_class = 2.0
+	throwforce = 8.0
+	throw_speed = 3
+	throw_range = 6
+	matter = list(DEFAULT_WALL_MATERIAL = 12000)
+	origin_tech = "materials=1"
+	attack_verb = list("cleaved", "slashed", "stabbed", "sliced", "torn", "ripped", "diced", "cut")
+	sharp = 1
+	edge = 1
+
+/obj/item/weapon/butch/attack(mob/living/carbon/M as mob, mob/living/carbon/user as mob)
+	playsound(loc, 'sound/weapons/bladeslice.ogg', 50, 1, -1)
+	return ..()

code/game/objects/items/weapons/material/misc.dm

@@ -0,0 +1,11 @@
+/obj/item/weapon/harpoon
+	name = "harpoon"
+	sharp = 1
+	edge = 0
+	desc = "Tharr she blows!"
+	icon_state = "harpoon"
+	item_state = "harpoon"
+	force = 20
+	throwforce = 15
+	w_class = 3
+	attack_verb = list("jabbed","stabbed","ripped")

code/game/objects/items/weapons/material/shards.dm

@@ -0,0 +1,120 @@
+// Glass shards
+
+/obj/item/weapon/shard
+	name = "shard"
+	icon = 'icons/obj/shards.dmi'
+	icon_state = "large"
+	sharp = 1
+	edge = 1
+	desc = "Made of nothing. How does this even exist?" // set based on material, if this desc is visible it's a bug (shards default to being made of glass)
+	w_class = 2.0
+	force = 5.0
+	throwforce = 8.0
+	item_state = "shard-glass"
+	//matter = list("glass" = 3750) // Weld it into sheets before you use it!
+	attack_verb = list("stabbed", "slashed", "sliced", "cut")
+
+	gender = "neuter"
+	var/material/material = null
+
+/obj/item/weapon/shard/suicide_act(mob/user)
+		viewers(user) << pick("\red <b>[user] is slitting \his wrists with \the [src]! It looks like \he's trying to commit suicide.</b>", \
+							"\red <b>[user] is slitting \his throat with \the [src]! It looks like \he's trying to commit suicide.</b>")
+		return (BRUTELOSS)
+
+/obj/item/weapon/shard/attack(mob/living/carbon/M as mob, mob/living/carbon/user as mob)
+	playsound(loc, 'sound/weapons/bladeslice.ogg', 50, 1, -1)
+	return ..()
+
+/obj/item/weapon/shard/Bump()
+
+	spawn( 0 )
+		if (prob(20))
+			src.force = 15
+		else
+			src.force = 4
+		..()
+		return
+	return
+
+/obj/item/weapon/shard/New(loc, material/material)
+	..(loc)
+
+	if(!material || !istype(material)) // We either don't have a material or we've been passed an invalid material. Use glass instead.
+		material = get_material_by_name("glass")
+
+	set_material(material)
+
+/obj/item/weapon/shard/proc/set_material(material/material)
+	if(istype(material))
+		src.material = material
+		icon_state = "[material.shard_icon][pick("large", "medium", "small")]"
+		pixel_x = rand(-8, 8)
+		pixel_y = rand(-8, 8)
+		update_material()
+		update_icon()
+
+/obj/item/weapon/shard/proc/update_material()
+	if(material)
+		if(material.shard_type)
+			name = "[material.display_name] [material.shard_type]"
+			desc = "A small piece of [material.display_name]. It looks sharp, you wouldn't want to step on it barefoot. Could probably be used as ... a throwing weapon?"
+			switch(material.shard_type)
+				if(SHARD_SPLINTER, SHARD_SHRAPNEL)
+					gender = "plural"
+				else
+					gender = "neuter"
+		else
+			qdel(src)
+			return
+	else
+		name = initial(name)
+		desc = initial(desc)
+
+/obj/item/weapon/shard/update_icon()
+	if(material)
+		color = material.icon_colour
+		// 1-(1-x)^2, so that glass shards with 0.3 opacity end up somewhat visible at 0.51 opacity
+		alpha = 255 * (1 - (1 - material.opacity)*(1 - material.opacity))
+	else
+		color = "#ffffff"
+		alpha = 255
+
+/obj/item/weapon/shard/attackby(obj/item/weapon/W as obj, mob/user as mob)
+	if(istype(W, /obj/item/weapon/weldingtool) && material.shard_can_repair)
+		var/obj/item/weapon/weldingtool/WT = W
+		if(WT.remove_fuel(0, user))
+			material.place_sheet(loc)
+			qdel(src)
+			return
+	return ..()
+
+/obj/item/weapon/shard/Crossed(AM as mob|obj)
+	if(ismob(AM))
+		var/mob/M = AM
+		M << "\red <B>You step on \the [src]!</B>"
+		playsound(src.loc, 'sound/effects/glass_step.ogg', 50, 1) // not sure how to handle metal shards with sounds
+		if(ishuman(M))
+			var/mob/living/carbon/human/H = M
+
+			if(H.species.flags & IS_SYNTHETIC || (H.species.siemens_coefficient<0.5)) //Thick skin.
+				return
+
+			if( !H.shoes && ( !H.wear_suit || !(H.wear_suit.body_parts_covered & FEET) ) )
+				var/obj/item/organ/external/affecting = H.get_organ(pick("l_foot", "r_foot"))
+				if(affecting.status & ORGAN_ROBOT)
+					return
+				if(affecting.take_damage(5, 0))
+					H.UpdateDamageIcon()
+				H.updatehealth()
+				if(!(H.species && (H.species.flags & NO_PAIN)))
+					H.Weaken(3)
+	..()
+
+// Preset types - left here for the code that uses them
+
+/obj/item/weapon/shard/shrapnel/New(loc)
+	..(loc, get_material_by_name("steel"))
+
+/obj/item/weapon/shard/phoron/New(loc)
+	..(loc, get_material_by_name("phoron glass"))

code/game/objects/items/weapons/material/swords.dm

@@ -0,0 +1,49 @@
+/obj/item/weapon/claymore
+	name = "claymore"
+	desc = "What are you standing around staring at this for? Get to killing!"
+	icon_state = "claymore"
+	item_state = "claymore"
+	flags = CONDUCT
+	slot_flags = SLOT_BELT
+	force = 40
+	throwforce = 10
+	sharp = 1
+	edge = 1
+	w_class = 3
+	attack_verb = list("attacked", "slashed", "stabbed", "sliced", "torn", "ripped", "diced", "cut")
+
+	IsShield()
+		return 1
+
+	suicide_act(mob/user)
+		viewers(user) << "<span class='danger'>[user] is falling on the [src.name]! It looks like \he's trying to commit suicide.</span>"
+		return(BRUTELOSS)
+
+/obj/item/weapon/claymore/attack(mob/living/carbon/M as mob, mob/living/carbon/user as mob)
+	playsound(loc, 'sound/weapons/bladeslice.ogg', 50, 1, -1)
+	return ..()
+
+/obj/item/weapon/katana
+	name = "katana"
+	desc = "Woefully underpowered in D20"
+	icon_state = "katana"
+	item_state = "katana"
+	flags = CONDUCT
+	slot_flags = SLOT_BELT | SLOT_BACK
+	force = 40
+	throwforce = 10
+	sharp = 1
+	edge = 1
+	w_class = 3
+	attack_verb = list("attacked", "slashed", "stabbed", "sliced", "torn", "ripped", "diced", "cut")
+
+	suicide_act(mob/user)
+		viewers(user) << "<span class='danger'>[user] is slitting \his stomach open with the [src.name]! It looks like \he's trying to commit seppuku.</span>"
+		return(BRUTELOSS)
+
+/obj/item/weapon/katana/IsShield()
+		return 1
+
+/obj/item/weapon/katana/attack(mob/living/carbon/M as mob, mob/living/carbon/user as mob)
+	playsound(loc, 'sound/weapons/bladeslice.ogg', 50, 1, -1)
+	return ..()

code/game/objects/items/weapons/material/thrown.dm

@@ -0,0 +1,31 @@
+/obj/item/weapon/star
+	name = "shuriken"
+	desc = "A sharp, perfectly weighted piece of metal."
+	icon_state = "star"
+	force = 5
+	throw_speed = 10
+	throwforce =  15
+	throw_range = 15
+	sharp = 1
+	edge =  1
+	matter = list(DEFAULT_WALL_MATERIAL = 500)
+
+	var/poisoned = 0
+
+/obj/item/weapon/star/New()
+	..()
+	src.pixel_x = rand(-12, 12)
+	src.pixel_y = rand(-12, 12)
+
+//TODO: consider making this something done with reagents.
+/obj/item/weapon/star/throw_impact(atom/hit_atom)
+	..()
+	if(poisoned && istype(hit_atom,/mob/living))
+		var/mob/living/M = hit_atom
+		M.adjustToxLoss(rand(20,40))
+		poisoned = 0
+		color = null
+
+/obj/item/weapon/star/ninja
+	color = "#007700"
+	poisoned = 1

code/game/objects/items/weapons/material/twohanded.dm

@@ -0,0 +1,207 @@
+/* Two-handed Weapons
+ * Contains:
+ * 		Twohanded
+ *		Fireaxe
+ *		Double-Bladed Energy Swords
+ */
+
+/*##################################################################
+##################### TWO HANDED WEAPONS BE HERE~ -Agouri :3 ########
+####################################################################*/
+
+//Rewrote TwoHanded weapons stuff and put it all here. Just copypasta fireaxe to make new ones ~Carn
+//This rewrite means we don't have two variables for EVERY item which are used only by a few weapons.
+//It also tidies stuff up elsewhere.
+
+/*
+ * Twohanded
+ */
+/obj/item/weapon/twohanded
+	var/wielded = 0
+	var/force_wielded = 0
+	var/force_unwielded
+	var/wieldsound = null
+	var/unwieldsound = null
+	var/base_icon
+	var/base_name
+
+/obj/item/weapon/twohanded/proc/unwield()
+	wielded = 0
+	force = force_unwielded
+	name = "[base_name]"
+	update_icon()
+
+/obj/item/weapon/twohanded/proc/wield()
+	wielded = 1
+	force = force_wielded
+	name = "[base_name] (Wielded)"
+	update_icon()
+
+/obj/item/weapon/twohanded/New()
+	..()
+	update_icon()
+	force_unwielded = force
+	base_name = name
+
+/obj/item/weapon/twohanded/mob_can_equip(M as mob, slot)
+	//Cannot equip wielded items.
+	if(wielded)
+		M << "<span class='warning'>Unwield the [base_name] first!</span>"
+		return 0
+
+	return ..()
+
+/obj/item/weapon/twohanded/dropped(mob/user as mob)
+	//handles unwielding a twohanded weapon when dropped as well as clearing up the offhand
+	if(user)
+		var/obj/item/weapon/twohanded/O = user.get_inactive_hand()
+		if(istype(O))
+			O.unwield()
+	return	unwield()
+
+/obj/item/weapon/twohanded/update_icon()
+	icon_state = "[base_icon][wielded]"
+	item_state = icon_state
+
+/obj/item/weapon/twohanded/pickup(mob/user)
+	unwield()
+
+/obj/item/weapon/twohanded/attack_self(mob/user as mob)
+
+	..()
+
+	if(istype(user, /mob/living/carbon/human))
+		var/mob/living/carbon/human/H = user
+		if(H.species.is_small)
+			user << "<span class='warning'>It's too heavy for you to wield fully.</span>"
+			return
+	else
+		return
+
+	if(wielded) //Trying to unwield it
+		unwield()
+		user << "<span class='notice'>You are now carrying the [name] with one hand.</span>"
+		if (src.unwieldsound)
+			playsound(src.loc, unwieldsound, 50, 1)
+
+		var/obj/item/weapon/twohanded/offhand/O = user.get_inactive_hand()
+		if(O && istype(O))
+			O.unwield()
+
+	else //Trying to wield it
+		if(user.get_inactive_hand())
+			user << "<span class='warning'>You need your other hand to be empty</span>"
+			return
+		wield()
+		user << "<span class='notice'>You grab the [base_name] with both hands.</span>"
+		if (src.wieldsound)
+			playsound(src.loc, wieldsound, 50, 1)
+
+		var/obj/item/weapon/twohanded/offhand/O = new(user) ////Let's reserve his other hand~
+		O.name = "[base_name] - offhand"
+		O.desc = "Your second grip on the [base_name]"
+		user.put_in_inactive_hand(O)
+
+	if(istype(user,/mob/living/carbon/human))
+		var/mob/living/carbon/human/H = user
+		H.update_inv_l_hand()
+		H.update_inv_r_hand()
+
+	return
+
+///////////OFFHAND///////////////
+/obj/item/weapon/twohanded/offhand
+	w_class = 5.0
+	icon_state = "offhand"
+	name = "offhand"
+
+/obj/item/weapon/twohanded/offhand/unwield()
+	qdel(src)
+
+/obj/item/weapon/twohanded/offhand/wield()
+	qdel(src)
+
+/obj/item/weapon/twohanded/offhand/update_icon()
+	return
+
+/*
+ * Fireaxe
+ */
+/obj/item/weapon/twohanded/fireaxe  // DEM AXES MAN, marker -Agouri
+	icon_state = "fireaxe0"
+	base_icon = "fireaxe"
+	name = "fire axe"
+	desc = "Truly, the weapon of a madman. Who would think to fight fire with an axe?"
+	force = 15
+	sharp = 1
+	edge = 1
+	w_class = 4.0
+	slot_flags = SLOT_BACK
+	force_wielded = 30
+	attack_verb = list("attacked", "chopped", "cleaved", "torn", "cut")
+
+/obj/item/weapon/twohanded/fireaxe/afterattack(atom/A as mob|obj|turf|area, mob/user as mob, proximity)
+	if(!proximity) return
+	..()
+	if(A && wielded && (istype(A,/obj/structure/window) || istype(A,/obj/structure/grille))) //destroys windows and grilles in one hit
+		if(istype(A,/obj/structure/window)) //should just make a window.Break() proc but couldn't bother with it
+			var/obj/structure/window/W = A
+			W.shatter()
+
+/*
+ * Double-Bladed Energy Swords - Cheridan
+ */
+/obj/item/weapon/twohanded/dualsaber
+	icon_state = "dualsaber0"
+	base_icon = "dualsaber"
+	name = "double-bladed energy sword"
+	desc = "Handle with care."
+	force = 3
+	throwforce = 5.0
+	throw_speed = 1
+	throw_range = 5
+	w_class = 2.0
+	force_wielded = 30
+	wieldsound = 'sound/weapons/saberon.ogg'
+	unwieldsound = 'sound/weapons/saberoff.ogg'
+	flags = NOSHIELD
+	origin_tech = "magnets=3;syndicate=4"
+	attack_verb = list("attacked", "slashed", "stabbed", "sliced", "torn", "ripped", "diced", "cut")
+	sharp = 1
+	edge = 1
+
+/obj/item/weapon/twohanded/dualsaber/attack(target as mob, mob/living/user as mob)
+	..()
+	if((CLUMSY in user.mutations) && (wielded) &&prob(40))
+		user << "\red You twirl around a bit before losing your balance and impaling yourself on the [src]."
+		user.take_organ_damage(20,25)
+		return
+	if((wielded) && prob(50))
+		spawn(0)
+			for(var/i in list(1,2,4,8,4,2,1,2,4,8,4,2))
+				user.set_dir(i)
+				sleep(1)
+
+/obj/item/weapon/twohanded/dualsaber/IsShield()
+	if(wielded)
+		return 1
+	else
+		return 0
+
+//spears, bay edition
+/obj/item/weapon/twohanded/spear
+	icon_state = "spearglass0"
+	base_icon = "spearglass"
+	name = "spear"
+	desc = "A haphazardly-constructed yet still deadly weapon of ancient design."
+	force = 10
+	w_class = 4.0
+	slot_flags = SLOT_BACK
+	force_wielded = 22 // Was 13, Buffed - RR
+	throwforce = 20
+	throw_speed = 3
+	edge = 0
+	sharp = 1
+	flags = NOSHIELD
+	hitsound = 'sound/weapons/bladeslice.ogg'
+	attack_verb = list("attacked", "poked", "jabbed", "torn", "gored")