//This file was auto-corrected by findeclaration.exe on 25.5.2012 20:42:31

GLOBAL_LIST_EMPTY(priority_air_alarms)
GLOBAL_LIST_EMPTY(minor_air_alarms)


/obj/machinery/computer/atmos_alert
	name = "atmospheric alert computer"
	desc = "Used to access atmospheric sensors."
	circuit = /obj/item/circuitboard/atmos_alert

	icon_screen = "alert:0"
	icon_keyboard = "cyan_key"
	icon_keyboard_emis = "cyan_key_mask"
	light_color = LIGHT_COLOR_CYAN

/obj/machinery/computer/atmos_alert/Initialize()
	. = ..()
	GLOB.atmosphere_alarm.register_alarm(src, TYPE_PROC_REF(/atom, update_icon))

/obj/machinery/computer/atmos_alert/Destroy()
	GLOB.atmosphere_alarm.unregister_alarm(src)
	return ..()

/obj/machinery/computer/atmos_alert/attack_hand(mob/user)
	ui_interact(user)

/obj/machinery/computer/atmos_alert/ui_interact(mob/user, ui_key = "main", var/datum/nanoui/ui = null, var/force_open = 1)
	var/data[0]
	var/major_alarms[0]
	var/minor_alarms[0]

	for(var/datum/alarm/alarm in GLOB.atmosphere_alarm.major_alarms())
		major_alarms[++major_alarms.len] = list("name" = sanitize(alarm.alarm_name()), "ref" = "[REF(alarm)]")

	for(var/datum/alarm/alarm in GLOB.atmosphere_alarm.minor_alarms())
		minor_alarms[++minor_alarms.len] = list("name" = sanitize(alarm.alarm_name()), "ref" = "[REF(alarm)]")

	data["priority_alarms"] = major_alarms
	data["minor_alarms"] = minor_alarms

	ui = SSnanoui.try_update_ui(user, src, ui_key, ui, data, force_open)
	if(!ui)
		ui = new(user, src, ui_key, "atmos_alert.tmpl", src.name, 500, 500)
		ui.set_initial_data(data)
		ui.open()
		ui.set_auto_update(1)

/obj/machinery/computer/atmos_alert/update_icon()
	if(!(stat & (NOPOWER|BROKEN)))
		var/list/alarms = GLOB.atmosphere_alarm.major_alarms()
		if(alarms.len)
			icon_screen = "alert:2"
		else
			alarms = GLOB.atmosphere_alarm.minor_alarms()
			if(alarms.len)
				icon_screen = "alert:1"
			else
				icon_screen = initial(icon_screen)
	..()

/obj/machinery/computer/atmos_alert/Topic(href, href_list)
	if(..())
		return 1

	if(href_list["clear_alarm"])
		var/datum/alarm/alarm = locate(href_list["clear_alarm"]) in GLOB.atmosphere_alarm.alarms
		if(alarm)
			for(var/datum/alarm_source/alarm_source in alarm.sources)
				var/obj/machinery/alarm/air_alarm = alarm_source.source
				if(istype(air_alarm))
					var/list/new_ref = list("atmos_reset" = 1)
					air_alarm.Topic(href, new_ref, state = GLOB.air_alarm_topic)
		return 1


GLOBAL_DATUM_INIT(air_alarm_topic, /datum/ui_state/air_alarm_topic, new())

/datum/ui_state/air_alarm_topic/href_list(var/mob/user)
	var/list/extra_href = list()
	extra_href["remote_connection"] = 1
	extra_href["remote_access"] = 1

	return extra_href