//////////////////////////////////////////////////////////////////
//				SLIME CORE EXTRACTION							//
//////////////////////////////////////////////////////////////////

/singleton/surgery_step/slime/is_valid_target(mob/living/carbon/slime/target)
	return istype(target, /mob/living/carbon/slime/)

/singleton/surgery_step/slime/can_use(mob/living/user, mob/living/carbon/slime/target, target_zone, obj/item/tool)
	SHOULD_CALL_PARENT(FALSE)
	return isslime(target) && target.stat == DEAD

/singleton/surgery_step/slime/cut_flesh
	name = "Open Slime"
	allowed_tools = list(
	TOOL_SCALPEL = 100,
	/obj/item/material/knife = 75,
	/obj/item/material/shard = 50
	)
	base_surgery_time = 3.5 SECONDS
	skill_requirements = alist(XENOBIOLOGY_SKILL_COMPONENT = SKILL_LEVEL_TRAINED)

/singleton/surgery_step/slime/cut_flesh/can_use(mob/living/user, mob/living/carbon/slime/target, target_zone, obj/item/tool)
	return ..() && istype(target) && target.core_removal_stage == ORGAN_CLOSED

/singleton/surgery_step/slime/cut_flesh/begin_step(mob/user, mob/living/carbon/slime/target, target_zone, obj/item/tool)
	user.visible_message("[user] starts cutting through [target]'s flesh with \the [tool].", \
		"You start cutting through [target]'s flesh with \the [tool].")
	..()

/singleton/surgery_step/slime/cut_flesh/end_step(mob/living/user, mob/living/carbon/slime/target, target_zone, obj/item/tool)
	user.visible_message(SPAN_NOTICE("[user] cuts through [target]'s flesh with \the [tool]."),	\
		SPAN_NOTICE("You cut through [target]'s flesh with \the [tool], revealing its silky innards."))
	target.core_removal_stage = ORGAN_OPEN_INCISION

/singleton/surgery_step/slime/cut_flesh/fail_step(mob/living/user, mob/living/carbon/slime/target, target_zone, obj/item/tool)
	user.visible_message(SPAN_WARNING("[user]'s hand slips, tearing [target]'s flesh with \the [tool]!"), \
		SPAN_WARNING("Your hand slips, tearing [target]'s flesh with \the [tool]!"))

/singleton/surgery_step/slime/cut_innards
	name = "Cut Innards"
	allowed_tools = list(
	TOOL_SCALPEL = 100,
	/obj/item/material/knife = 75,
	/obj/item/material/shard = 50
	)
	base_surgery_time = 4.5 SECONDS
	skill_requirements = alist(XENOBIOLOGY_SKILL_COMPONENT = SKILL_LEVEL_TRAINED)

/singleton/surgery_step/slime/cut_innards/can_use(mob/living/user, mob/living/carbon/slime/target, target_zone, obj/item/tool)
	return ..() && istype(target) && target.core_removal_stage == ORGAN_OPEN_INCISION

/singleton/surgery_step/slime/cut_innards/begin_step(mob/user, mob/living/carbon/slime/target, target_zone, obj/item/tool)
	user.visible_message("[user] starts cutting [target]'s silky innards apart with \the [tool].", \
		"You start cutting [target]'s silky innards apart with \the [tool].")
	..()

/singleton/surgery_step/slime/cut_innards/end_step(mob/living/user, mob/living/carbon/slime/target, target_zone, obj/item/tool)
	user.visible_message(SPAN_NOTICE("[user] cuts [target]'s innards apart with \the [tool], exposing the cores."),	\
		SPAN_NOTICE("You cut [target]'s innards apart with \the [tool], exposing the cores."))
	target.core_removal_stage = ORGAN_OPEN_RETRACTED

/singleton/surgery_step/slime/cut_innards/fail_step(mob/living/user, mob/living/carbon/slime/target, target_zone, obj/item/tool)
	user.visible_message(SPAN_WARNING("[user]'s hand slips, tearing [target]'s innards with \the [tool]!"), \
		SPAN_WARNING("Your hand slips, tearing [target]'s innards with \the [tool]!"))

/singleton/surgery_step/slime/saw_core
	name = "Detach Core"
	allowed_tools = list(
	TOOL_SAW = 100, \
	/obj/item/material/hatchet = 75
	)
	base_surgery_time = 5.5 SECONDS
	skill_requirements = alist(XENOBIOLOGY_SKILL_COMPONENT = SKILL_LEVEL_TRAINED)

/singleton/surgery_step/slime/saw_core/can_use(mob/living/user, mob/living/carbon/slime/target, target_zone, obj/item/tool)
	return ..() && (istype(target) && target.core_removal_stage == ORGAN_OPEN_RETRACTED && target.cores > 0) //This is being passed a human as target, unsure why.

/singleton/surgery_step/slime/saw_core/begin_step(mob/user, mob/living/carbon/slime/target, target_zone, obj/item/tool)
	user.visible_message("[user] starts cutting out one of [target]'s cores with \the [tool].", \
		"You start cutting out one of [target]'s cores with \the [tool].")
	..()

/singleton/surgery_step/slime/saw_core/end_step(mob/living/user, mob/living/carbon/slime/target, target_zone, obj/item/tool)
	target.cores--
	user.visible_message(SPAN_NOTICE("[user] cuts out one of [target]'s cores with \the [tool]."),,	\
		SPAN_NOTICE("You cut out one of [target]'s cores with \the [tool]. [target.cores] cores left."))

	if(target.cores >= 0)
		new target.coretype(target.loc)
	if(target.cores < 0)
		target.icon_state = "[target.colour] baby slime dead-nocore"


/singleton/surgery_step/slime/saw_core/fail_step(mob/living/user, mob/living/carbon/slime/target, target_zone, obj/item/tool)
	user.visible_message(SPAN_WARNING("[user]'s hand slips, causing [user.get_pronoun("him")] to miss the core!"), \
		SPAN_WARNING("Your hand slips, causing you to miss the core!"))