//Beam Datum and effect
/datum/beam
	var/atom/origin = null
	var/atom/target = null
	var/list/elements = list()
	var/icon/base_icon = null
	var/icon
	var/icon_state = "" //icon state of the main segments of the beam
	var/max_distance = 0
	var/curr_distance = 0
	var/sleep_time = 3
	var/finished = 0
	var/turf/target_oldloc = null
	var/turf/origin_oldloc = null
	var/static_beam = 0
	var/beam_type = /obj/effect/ebeam //must be subtype
	var/timing_id = null
	var/recalculating = FALSE

/datum/beam/New(beam_origin,beam_target,beam_icon='icons/effects/beam.dmi',beam_icon_state="b_beam",time=50,maxdistance=10,btype = /obj/effect/ebeam,beam_sleep_time=3)
	origin = beam_origin
	origin_oldloc = get_turf(origin)
	target = beam_target
	target_oldloc = get_turf(target)
	sleep_time = beam_sleep_time
	if(origin_oldloc == origin && target_oldloc == target)
		static_beam = TRUE
	max_distance = maxdistance
	curr_distance = get_dist(origin_oldloc, target_oldloc)
	base_icon = new(beam_icon,beam_icon_state)
	icon = beam_icon
	icon_state = beam_icon_state
	beam_type = btype
	if(time != -1)
		addtimer(CALLBACK(src,.proc/End), time)

/datum/beam/proc/Start()
	Draw()
	recalculate_in(sleep_time)

/datum/beam/proc/recalculate()
	if(recalculating)
		recalculate_in(sleep_time)
		return
	recalculating = TRUE
	timing_id = null
	var/turf/origin_turf = get_turf(origin)
	var/turf/target_turf = get_turf(target)
	curr_distance = get_dist(origin_turf, target_turf)
	if(origin_turf && target_turf && curr_distance < max_distance && origin_turf.z == target_turf.z)
		if(!static_beam && (origin_turf != origin_oldloc || target_turf != target_oldloc))
			origin_oldloc = origin_turf //so we don't keep checking against their initial positions, leading to endless Reset()+Draw() calls
			target_oldloc = target_turf
			Reset()
			Draw()
		after_calculate()
		recalculating = FALSE
	else
		End()

/datum/beam/proc/afterDraw()
	return

/datum/beam/proc/recalculate_in(time)
	timing_id = addtimer(CALLBACK(src, .proc/recalculate), time, TIMER_STOPPABLE | TIMER_UNIQUE | TIMER_NO_HASH_WAIT | TIMER_OVERRIDE)

/datum/beam/proc/after_calculate()
	if((sleep_time == null) || finished)	//Does not automatically recalculate.
		return
	timing_id = addtimer(CALLBACK(src, .proc/recalculate), sleep_time, TIMER_STOPPABLE | TIMER_UNIQUE | TIMER_NO_HASH_WAIT)

/datum/beam/proc/End(destroy_self = TRUE)
	finished = TRUE
	if(timing_id)
		deltimer(timing_id)
	if(!QDELING(src) && destroy_self)
		qdel(src)

/datum/beam/proc/Reset()
	for(var/obj/effect/ebeam/B in elements)
		qdel(B)
	elements.Cut()

/datum/beam/Destroy()
	Reset()
	target = null
	origin = null
	return ..()

/datum/beam/proc/Draw()
	var/Angle = round(Get_Angle(get_turf(origin), get_turf(target)))
	var/matrix/rot_matrix = matrix()
	rot_matrix.Turn(Angle)

	//Translation vector for origin and target
	var/DX = get_x_translation_vector()
	var/DY = get_y_translation_vector()
	var/N = 0
	var/length = round(sqrt((DX)**2+(DY)**2)) //hypotenuse of the triangle formed by target and origin's displacement

	for(N in 0 to length-1 step world.icon_size)//-1 as we want < not <=, but we want the speed of X in Y to Z and step X
		var/obj/effect/ebeam/X = new beam_type(origin_oldloc)
		X.owner = src
		elements += X

		//Assign icon, for main segments it's base_icon, for the end, it's icon+icon_state
		//cropped by a transparent box of length-N pixel size
		if(N+world.icon_size>length)
			var/icon/II = new(icon, icon_state)
			II.DrawBox(null,1,(length-N),world.icon_size,world.icon_size)
			X.icon = II
		else
			X.icon = base_icon
		X.transform = rot_matrix

		//Calculate pixel offsets (If necessary)
		var/Pixel_x
		var/Pixel_y
		if(DX == 0)
			Pixel_x = 0
		else
			Pixel_x = round(sin(Angle)+world.icon_size*sin(Angle)*(N+16)/world.icon_size)
		if(DY == 0)
			Pixel_y = 0
		else
			Pixel_y = round(cos(Angle)+world.icon_size*cos(Angle)*(N+16)/world.icon_size)

		//Position the effect so the beam is one continous line
		var/a
		if(abs(Pixel_x)>world.icon_size)
			a = Pixel_x > 0 ? round(Pixel_x/world.icon_size) : Ceiling(Pixel_x/world.icon_size)
			X.x += a
			Pixel_x %= world.icon_size
		if(abs(Pixel_y)>world.icon_size)
			a = Pixel_y > 0 ? round(Pixel_y/world.icon_size) : Ceiling(Pixel_y/world.icon_size)
			X.y += a
			Pixel_y %= world.icon_size

		X.pixel_x = Pixel_x
		X.pixel_y = Pixel_y
		CHECK_TICK
	afterDraw()

/datum/beam/proc/get_x_translation_vector()
	return (world.icon_size*target.x+target.pixel_x)-(world.icon_size*origin.x+origin.pixel_x)

/datum/beam/proc/get_y_translation_vector()
	return (world.icon_size*target.y+target.pixel_y)-(world.icon_size*origin.y+origin.pixel_y)

/datum/beam/exploration
	var/obj/item/tethering_device/owner

/datum/beam/exploration/End()
	owner.active_beams -= target
	owner.untether(target, FALSE)
	return ..()

/datum/beam/exploration/get_x_translation_vector()
	return (world.icon_size * target_oldloc.x) - (world.icon_size * origin_oldloc.x)

/datum/beam/exploration/get_y_translation_vector()
	return (world.icon_size * target_oldloc.y) - (world.icon_size * origin_oldloc.y)

/datum/beam/exploration/afterDraw()
	var/distance = curr_distance / max_distance
	var/set_color = COLOR_GREEN
	if(distance >= 0.8)
		set_color = COLOR_MAROON
	else if(distance >= 0.3)
		set_color = COLOR_BLUE
	else
		set_color = COLOR_GREEN
	for(var/beam in elements)
		var/obj/effect/ebeam/B = beam
		B.color = set_color

/obj/effect/ebeam
	mouse_opacity = 0
	anchored = 1
	layer = EFFECTS_ABOVE_LIGHTING_LAYER
	blend_mode = BLEND_ADD
	var/datum/beam/owner

/obj/effect/ebeam/tesla_act()
	return

/obj/effect/ebeam/Destroy()
	owner = null
	return ..()

/atom/proc/Beam(atom/BeamTarget,icon_state="b_beam",icon='icons/effects/beam.dmi',time=50, maxdistance=10,beam_type=/obj/effect/ebeam,beam_sleep_time = 3)
	if(time >= INFINITY)
		crash_with("Tried to create beam with infinite time!")
		return null
	var/datum/beam/newbeam = new(src,BeamTarget,icon,icon_state,time,maxdistance,beam_type,beam_sleep_time)
	INVOKE_ASYNC(newbeam, /datum/beam/.proc/Start)
	return newbeam