mirror of
https://github.com/Aurorastation/Aurora.3.git
synced 2026-08-21 20:11:04 +01:00
e0aa218843
https://www.youtube.com/watch?v=9mPvZ96pHJI A pull request commissioned by the Synthetic Lore Team to comprehensively rework synthetics (read: IPCs) and how they work in Aurora. The objective is to make IPCs as unique as possible from humans, upgrading the robotic feel and atmosphere, while also preserving a good sense of balance in-game. Key features: - A comprehensive expansion of synthetic organs, all of which now fulfill a purpose: hydraulics, cooling units, power systems, actuators, diagnostics units. - Customizable organs with benefits and drawbacks, such as with cooling units and power systems. - Unique ways to repair the organs and more involved steps. - Unique damage mechanics - every organ has wiring and electronics which affect its functioning, and they are defended by plating which provides natural armour. - Improved and immersive diagnostics. - Unique features, benefits, and drawbacks for every IPC frame. - A rework of the positronic brain, which can be either destroyed or shut down, alongside effects caused by low integrity. - A rework of how EMPs affect IPC organs. - Non-binary damage states for each organ. To-do: - [x] Finish the unique features for each frame. - [x] Look into if mechanical synthskin is possible. - [x] Power system. - [x] Posibrain mechanics. - [ ] Passive cooling expansion. - [x] EMP mechanics. - [x] Repair mechanics. - [x] Mob weight mechanics. - [ ] Gurney for heavy mobs. - [x] New augments. - [ ] IPC tag scanning and flashing. --------- Signed-off-by: Werner <1331699+Arrow768@users.noreply.github.com> Co-authored-by: Matt Atlas <liermattia@gmail.com> Co-authored-by: Geeves <22774890+Geevies@users.noreply.github.com> Co-authored-by: Werner <1331699+Arrow768@users.noreply.github.com>
55 lines
1.7 KiB
Plaintext
55 lines
1.7 KiB
Plaintext
// Hydraulics effects are mainly in /datum/species/machine/handle_sprint_cost.
|
|
/obj/item/organ/internal/machine/hydraulics
|
|
name = "hydraulics system"
|
|
desc = "A byzantine system of pumps and other hydraulic components to allow a positronic chassis to stand on both its feet, and do complex tricks such as kicking you in the shins."
|
|
icon = 'icons/obj/organs/ipc_organs.dmi'
|
|
icon_state = "ipc_hydraulics"
|
|
organ_tag = BP_HYDRAULICS
|
|
parent_organ = BP_GROIN
|
|
|
|
max_damage = 40
|
|
relative_size = 70
|
|
|
|
/obj/item/organ/internal/machine/hydraulics/Initialize()
|
|
. = ..()
|
|
RegisterSignal(owner, COMSIG_IPC_HAS_SPRINTED, PROC_REF(handle_hydraulics))
|
|
|
|
/**
|
|
* Handles sprint effects. For example, recharging with the kinetic reactor.
|
|
*/
|
|
/obj/item/organ/internal/machine/hydraulics/proc/handle_hydraulics()
|
|
SIGNAL_HANDLER
|
|
if(!owner)
|
|
return
|
|
|
|
var/obj/item/organ/internal/machine/reactor/reactor = owner.internal_organs_by_name[BP_REACTOR]
|
|
if(!istype(reactor))
|
|
return
|
|
|
|
if(get_integrity() < IPC_INTEGRITY_THRESHOLD_LOW)
|
|
if(prob(10 * (damage / 10)))
|
|
spark(get_turf(owner), rand(1, 5), GLOB.alldirs)
|
|
|
|
if(reactor.power_supply_type & POWER_SUPPLY_KINETIC)
|
|
reactor.generate_power(reactor.base_power_generation)
|
|
|
|
/obj/item/organ/internal/machine/hydraulics/medium_integrity_damage(integrity)
|
|
. = ..()
|
|
if(!.)
|
|
return
|
|
|
|
if(prob(get_integrity_damage_probability()))
|
|
spark(owner, 3, GLOB.alldirs)
|
|
to_chat(owner, SPAN_WARNING("Your hydraulics lock up for a second!"))
|
|
owner.Stun(1)
|
|
|
|
/obj/item/organ/internal/machine/hydraulics/high_integrity_damage(integrity)
|
|
. = ..()
|
|
if(!.)
|
|
return
|
|
|
|
if(prob(get_integrity_damage_probability()))
|
|
spark(owner, 5, GLOB.alldirs)
|
|
to_chat(owner, SPAN_WARNING("Your hydraulics malfunction and you trip!"))
|
|
owner.Weaken(1)
|