mirror of
https://github.com/Aurorastation/Aurora.3.git
synced 2026-07-20 12:29:23 +01:00
Matt Atlas
e0aa218843
https://www.youtube.com/watch?v=9mPvZ96pHJI A pull request commissioned by the Synthetic Lore Team to comprehensively rework synthetics (read: IPCs) and how they work in Aurora. The objective is to make IPCs as unique as possible from humans, upgrading the robotic feel and atmosphere, while also preserving a good sense of balance in-game. Key features: - A comprehensive expansion of synthetic organs, all of which now fulfill a purpose: hydraulics, cooling units, power systems, actuators, diagnostics units. - Customizable organs with benefits and drawbacks, such as with cooling units and power systems. - Unique ways to repair the organs and more involved steps. - Unique damage mechanics - every organ has wiring and electronics which affect its functioning, and they are defended by plating which provides natural armour. - Improved and immersive diagnostics. - Unique features, benefits, and drawbacks for every IPC frame. - A rework of the positronic brain, which can be either destroyed or shut down, alongside effects caused by low integrity. - A rework of how EMPs affect IPC organs. - Non-binary damage states for each organ. To-do: - [x] Finish the unique features for each frame. - [x] Look into if mechanical synthskin is possible. - [x] Power system. - [x] Posibrain mechanics. - [ ] Passive cooling expansion. - [x] EMP mechanics. - [x] Repair mechanics. - [x] Mob weight mechanics. - [ ] Gurney for heavy mobs. - [x] New augments. - [ ] IPC tag scanning and flashing. --------- Signed-off-by: Werner <1331699+Arrow768@users.noreply.github.com> Co-authored-by: Matt Atlas <liermattia@gmail.com> Co-authored-by: Geeves <22774890+Geevies@users.noreply.github.com> Co-authored-by: Werner <1331699+Arrow768@users.noreply.github.com>
78 lines
2.7 KiB
Plaintext
78 lines
2.7 KiB
Plaintext
/*!
|
|
* Copyright (c) 2020 Aleksej Komarov
|
|
* SPDX-License-Identifier: MIT
|
|
*/
|
|
|
|
/**
|
|
* tgui state: default_state
|
|
*
|
|
* Checks a number of things -- mostly physical distance for humans
|
|
* and view for robots.
|
|
*/
|
|
|
|
GLOBAL_DATUM_INIT(default_state, /datum/ui_state/default, new)
|
|
|
|
/datum/ui_state/default/can_use_topic(src_object, mob/user)
|
|
return user.default_can_use_topic(src_object) // Call the individual mob-overridden procs.
|
|
|
|
/mob/proc/default_can_use_topic(src_object)
|
|
return UI_CLOSE // Don't allow interaction by default.
|
|
|
|
/mob/living/default_can_use_topic(src_object)
|
|
. = shared_ui_interaction(src_object)
|
|
if(. > UI_CLOSE && loc) //must not be in nullspace.
|
|
. = min(., shared_living_ui_distance(src_object)) // Check the distance...
|
|
if(. == UI_INTERACTIVE && !src.IsAdvancedToolUser()) // unhandy living mobs can only look, not touch.
|
|
return UI_UPDATE
|
|
|
|
/mob/living/silicon/robot/default_can_use_topic(src_object)
|
|
. = shared_ui_interaction(src_object)
|
|
if(. <= UI_DISABLED)
|
|
return
|
|
|
|
// Robots can interact with anything they can see.
|
|
var/list/clientviewlist = getviewsize(client.view)
|
|
if(get_dist(src, src_object) <= min(clientviewlist[1],clientviewlist[2]))
|
|
return UI_INTERACTIVE
|
|
return UI_DISABLED // Otherwise they can keep the UI open.
|
|
|
|
/mob/living/silicon/ai/default_can_use_topic(src_object)
|
|
. = shared_ui_interaction(src_object)
|
|
if(. < UI_INTERACTIVE)
|
|
return
|
|
|
|
// The AI can interact with anything it can see nearby, or with cameras while wireless control is enabled.
|
|
if(!control_disabled)
|
|
return UI_INTERACTIVE
|
|
return UI_CLOSE
|
|
|
|
/mob/living/silicon/pai/default_can_use_topic(src_object)
|
|
// pAIs can use themselves, the owner's radio, and any computer they're inserted into. Limited by synced ID for certain programs.
|
|
if((src_object == src || src_object == radio) && !stat)
|
|
return UI_INTERACTIVE
|
|
else if(src_object == src.parent_computer)
|
|
if(istype(src_object, /obj/item/modular_computer))
|
|
var/obj/item/modular_computer/PDA = src_object
|
|
if(PDA.pAI_lock == FALSE)
|
|
return UI_INTERACTIVE
|
|
else
|
|
to_chat(src, SPAN_WARNING("Access denied."))
|
|
|
|
return min(..(), UI_UPDATE)
|
|
|
|
/mob/living/simple_animal/spiderbot/default_can_use_topic(src_object)
|
|
if(ismech(src_object))
|
|
return UI_INTERACTIVE
|
|
return ..()
|
|
|
|
/mob/living/carbon/human/default_can_use_topic(src_object)
|
|
. = ..()
|
|
|
|
var/obj/item/organ/internal/machine/wireless_access/access_point = internal_organs_by_name[BP_WIRELESS_ACCESS]
|
|
if(istype(access_point))
|
|
// Just like robots, these IPCs can interact with anything they can see.
|
|
var/list/clientviewlist = getviewsize(client.view)
|
|
if(get_dist(src, src_object) <= min(clientviewlist[1], clientviewlist[2]))
|
|
return UI_INTERACTIVE
|
|
return UI_DISABLED // Otherwise they can keep the UI open.
|