mirror of
https://github.com/Aurorastation/Aurora.3.git
synced 2026-08-29 16:10:02 +01:00
BatrachophrenoandGitHub
1c8c0c2221
Fixes several runtimes from the past few weeks, some additional material repath regressions, and the fact that if I shoot you with a stream of ionized deuterium particles, it doesn't riddle you with cancer. changes: - bugfix: "Fixes emergency shields runtiming when hit by thrown objects." - bugfix: "Fixes several stale global list runtimes." - bugfix: "Fixes several health percentage checks that could use unset initial health values." - bugfix: "Fixes additional materials regressions in INDRA code." - bugfix: "Fixes invalid fuel injector depletion math." - bugfix: "Makes accelerated particles apply radiation damage to living mobs they pass through."
46 lines
1.6 KiB
Plaintext
46 lines
1.6 KiB
Plaintext
/obj/effect/overlay/burnt_wall
|
|
name = "burnt wall"
|
|
desc = "A wall that had a hole burnt into it. Nasty."
|
|
icon = 'icons/turf/flooring/plating.dmi'
|
|
icon_state = "wall_thermite"
|
|
var/singleton/material/material
|
|
var/singleton/material/reinf_material
|
|
|
|
/obj/effect/overlay/burnt_wall/Initialize(mapload, new_name, new_mat, new_reinf_mat)
|
|
. = ..()
|
|
name = "burnt [new_name]"
|
|
material = SSmaterials.get_material_by_id(new_mat)
|
|
if(new_reinf_mat)
|
|
reinf_material = SSmaterials.get_material_by_id(new_reinf_mat)
|
|
color = material.icon_colour
|
|
if(material.opacity < 0.5)
|
|
alpha = 125
|
|
|
|
/obj/effect/overlay/burnt_wall/attackby(obj/item/attacking_item, mob/user)
|
|
if(attacking_item.tool_behaviour == TOOL_WELDER)
|
|
var/obj/item/weldingtool/WT = attacking_item
|
|
if(!WT.isOn())
|
|
return TRUE
|
|
if(WT.use(0,user))
|
|
user.visible_message("<b>[user]</b> starts slicing \the [src] apart.", SPAN_NOTICE("You start slicing \the [src] apart."))
|
|
playsound(src, 'sound/items/Welder.ogg', 100, 1)
|
|
var/slice_time = reinf_material ? 100 : 30
|
|
if(WT.use_tool(src, user, slice_time, volume = 50))
|
|
user.visible_message("<b>[user]</b> slices \the [src] apart.", SPAN_NOTICE("You slice \the [src] apart."))
|
|
material.place_sheet(get_turf(src))
|
|
if(reinf_material)
|
|
reinf_material.place_sheet(get_turf(src))
|
|
qdel(src)
|
|
return TRUE
|
|
return ..()
|
|
|
|
/obj/effect/overlay/thermite
|
|
name = "blazing heat"
|
|
desc = "It's blazing wall of heat!"
|
|
icon = 'icons/effects/fire.dmi'
|
|
icon_state = "2"
|
|
anchored = TRUE
|
|
|
|
/obj/effect/overlay/burnt_wall/steel/Initialize(mapload)
|
|
. = ..(mapload, "wall", MATERIAL_STEEL)
|