mirror of
https://github.com/Aurorastation/Aurora.3.git
synced 2026-07-18 03:21:13 +01:00
FenodyreeAv
cf585ef505
Makes ship combat significantly more destructive (and a bit deadlier), especially with non-explosive projectiles. **Additions:** - A shell that penetrates a solid (dense) structure will cause spalling. This spall does 2-30 damage, depending on range and has a high embed chance. These embedded chunks are large enough to be ripped out by hand. (But you probably shouldn't). The pilot's suit has 30 ballistic armor, so a prepared bridge crew can survive a lot of spall. - Adds a gun that shoots any ship weapon that admins can spawn. Useful for testing, or for adminbus where they don't want to have to spawn a whole overmap ship. - Made several structures destructible, vending machines, computer frames, grilles (these were just bugged) and watertanks (and their children). These structures could just block infinite shots and were common enough to serve as effective armor for the horizon. These now spawn shrapnel (of their material if it's set), in addition to sheets of steel when destroyed. - Added support for negative maim chance. This allows chosen projectiles to be prevented from decapitating. No more accidentally gibbing the bridge crew's heads. (Unless they get hit with something really really big). **Balance:** - All non-explosive anti ship rounds got significant buffs. Typically 2-3x Anti-Material numbers. - Armour piercing anti-ship rounds got massively increased penetration stats. Typically 4-8 from 1-2. - Doors now get destroyed in less hits, if they are hit by anti-material projectiles. Hits to destroy -= Antimaterial / 2 - Francisca frag shells now shoot less fragments but deal more damage. 394 projectiles for every shot was a bit laggy, now it's only 280. **Shields:** Shields now take more power. 13-14 megawatts for a 10 strength shield. Just inside the ship's generation capacity with both the INDRA and Supermatter running. Instead of deleting any projectile they are hit by, shields now have different failure modes. - Firstly, a piercing projectile has it's penetration reduced by the shield strength. Eg A shot that would go through 10 walls, only penetrates 4 after going through a 6 strength shield. - Secondly, a projectile has it's damage multiplied by 1 - shield strength / 10, then has shield strength subtracted from it's damage. Eg. A damage 100 projectile, hitting a 5 strength shield, has it's damaged reduced to 50, (100 * 0.5), then to 45. (50-5) - Thirdly, an explosive projectile (that does not penetrate per the first step) does not explode, but instead deals it's full damage to the shield. Hits to the shield now also damage the field itself, not just the shield tile. As such, a very big hit on the shield can bring the whole thing down, requiring an engineer to reset it. Shields can now be upgraded with research components. Additionally, shield generators can now support more than one capacitor. The roundstart capacitor on the Horizon is only good enough to support a 6 strength shield. The upgrades increase efficiency, strength loss over time and charge speed. **Overmap Targetting** Previously, shells would spawn within 20 tiles of their target and aim directly forwards. This was bugged for shots with burst, which would instead all aim inwards and mostly miss. This is the reason the Grauwolf (in addition to the explosion bug below) and Fransisca felt so useless, only one of every shell in a burst would hit. Shots now spawn at the map edge, based on the orientation of the projectile and ship. Diagonals are now accounted for. Shots are then aimed directly at the target selected on the console, with 3 degrees of dispersion. **Bugfixes:** - Fixes lots of explosions that didn't pass a turf to the explosions subsystem. This caused the explosion not to happen if the thing hit got qdeled before the subsystem could get the turf to spawn the explosion on. - Embedded shrapnel no longer gets the initial projectile name, this prevents it getting named shrapnelshrapnel. - Fixes a bunch of projectile piercing bugs, mostly with grilles and windows. Shots now go past window frames without hitting them. - Fixes shields not having a click delay when attacked. --------- Signed-off-by: FenodyreeAv <fenodyree.av@gmail.com> Co-authored-by: Matt Atlas <mattiathebest2000@hotmail.it>
110 lines
4.8 KiB
Plaintext
110 lines
4.8 KiB
Plaintext
// This is an abstracted energy field to cut down on processing thousands of shields per process tick.
|
|
/datum/energy_field
|
|
/// A gigantic ass fucking list of energy fields.
|
|
var/list/field = list()
|
|
/// The actual strength of the field.
|
|
var/field_strength = 0
|
|
/// Current strengthening rate of a single field.
|
|
var/strengthen_rate = 0.1
|
|
/// Maximum rate by which an energy field can be strengthened. This is set by shield components in RefreshComponents, the initial rate with standard components is 0.5 (2 Manipulators, Rating 1: give 0.1 each)
|
|
var/max_strengthen_rate = 0.3
|
|
/// The percentage of the shield strength that needs to be replaced each second. This is modified by shield components in RefreshComponents, the initial rate with standard components is 0.030. (2 Micro Lasers, Rating 1: subtract 0.003 each)
|
|
var/dissipation_rate = 0.036
|
|
/// An energy field will dissipate by at least this rate in renwicks per field tile (otherwise field would never dissipate completely as dissipation is a percentage)
|
|
var/min_dissipation = 0.01
|
|
/// Our target field strength.
|
|
var/target_field_strength = 10
|
|
/// The maximum field strength we can go to.
|
|
var/max_field_strength = 10
|
|
/// The time passed since the last "fail", AKA losing charge faster than you can replenish it.
|
|
var/time_since_fail = 100
|
|
/// How many renwicks per watt. This is modified by shield components in RefreshComponents, the initial rate with standard components is 0.00005 (2 Capacitors, Rating 1: give 0.00001 each)
|
|
var/energy_conversion_rate = 0.00003
|
|
/// If the field is strong, then the energy field objects will turn dense.
|
|
var/strong_field = FALSE
|
|
|
|
/datum/energy_field/Destroy(force)
|
|
clear_field()
|
|
return ..()
|
|
|
|
/**
|
|
* This proc, called when a shield generator processes, makes the whole thing tick by updating strength and etc.
|
|
* @assumed_charge: the charge that is given to this energy field. You have to get the required energy first, if you want a balanced field.
|
|
*/
|
|
/datum/energy_field/proc/handle_strength(assumed_charge = 0)
|
|
assumed_charge = max(assumed_charge, 0)
|
|
if(length(field))
|
|
time_since_fail++
|
|
//the amount of renwicks that the generator can add this tick, over the entire field
|
|
var/total_renwick_increase = assumed_charge * energy_conversion_rate
|
|
|
|
var/renwick_increase_per_field = total_renwick_increase / length(field) //per field tile
|
|
var/renwick_upkeep_per_field = max(field_strength * dissipation_rate, min_dissipation)
|
|
var/amount_to_strengthen = renwick_increase_per_field - renwick_upkeep_per_field
|
|
field_strength = max(min(field_strength + amount_to_strengthen, max_field_strength), 0)
|
|
|
|
if(field_strength < 1)
|
|
if(strong_field)
|
|
strong_field = FALSE
|
|
SEND_SIGNAL(src, COMSIG_SHIELDS_UPDATE_STRENGTH_STATUS)
|
|
time_since_fail = 0
|
|
else
|
|
if(!strong_field)
|
|
strong_field = TRUE
|
|
SEND_SIGNAL(src, COMSIG_SHIELDS_UPDATE_STRENGTH_STATUS)
|
|
else
|
|
field_strength = 0
|
|
|
|
/**
|
|
* Returns the required energy upkeep for the field.
|
|
*/
|
|
/datum/energy_field/proc/get_required_energy()
|
|
var/required_energy = 0
|
|
if(length(field))
|
|
var/renwick_upkeep_per_field = max(field_strength * dissipation_rate, min_dissipation)
|
|
var/target_renwick_increase = max(min(target_field_strength - field_strength, strengthen_rate) + renwick_upkeep_per_field, 0) //per field tile
|
|
required_energy = length(field) * target_renwick_increase / energy_conversion_rate
|
|
return required_energy
|
|
|
|
/**
|
|
* Clears the field of active field objects.
|
|
*/
|
|
/datum/energy_field/proc/clear_field()
|
|
field_strength = 0
|
|
strong_field = FALSE
|
|
for(var/obj/effect/energy_field/D as anything in field)
|
|
field.Remove(D)
|
|
qdel(D)
|
|
|
|
/**
|
|
* Sets the shielded turfs of the energy field.
|
|
*/
|
|
/datum/energy_field/proc/set_shielded_turfs(list/shielded_turfs)
|
|
if(length(shielded_turfs))
|
|
for(var/turf/T in shielded_turfs)
|
|
var/obj/effect/energy_field/F = new(T, src)
|
|
field += F
|
|
|
|
/**
|
|
* Removes the field from the managed list and deletes it. Called by shield diffusion.
|
|
*/
|
|
/datum/energy_field/proc/remove_individual_field(var/obj/effect/energy_field/field_to_remove)
|
|
field.Remove(field_to_remove)
|
|
qdel(field_to_remove)
|
|
|
|
/**
|
|
* Adds a bunch of UI data for TGUIs with relevant field data.
|
|
*/
|
|
/datum/energy_field/proc/add_field_ui_data(list/data)
|
|
if(!istype(data))
|
|
return
|
|
|
|
data["average_field"] = round(field_strength, 0.01)
|
|
data["progress_field"] = (target_field_strength ? round(100 * field_strength / target_field_strength, 0.1) : "NA")
|
|
data["power_take"] = round(length(field) * max(field_strength * dissipation_rate, min_dissipation) / energy_conversion_rate / 1000) //Divide by 100 to convert to kW
|
|
data["shield_power"] = round(max(length(field) * min(strengthen_rate, target_field_strength - field_strength) / energy_conversion_rate / 1000, 0)) //Divide by 100 to convert to kW
|
|
data["strengthen_rate"] = (strengthen_rate * 10)
|
|
data["max_strengthen_rate"] = (max_strengthen_rate * 10)
|
|
data["target_field_strength"] = target_field_strength
|
|
return data
|