mirror of
https://github.com/Aurorastation/Aurora.3.git
synced 2026-07-21 12:56:10 +01:00
Batrachophreno
8111a8489b
Many, many, many items have inhand sprites in their .dmis but for whatever reasons do not display them in-game. This PR: 1. Updates many item definitions to point to their already-existing inhands correctly. This consists largely of held tools, but also gas tanks and jetpacks mounted in the suit storage slot. 2. Adds a few codersprites made by me for objects with either missing inhands or poorly matching mishands (IE, the tape recorder, which has a black case, reused the white inhand sprites of the health analyzer). The new sprites are modified or recolored variations of other inhand sprites from our repo, except for circuitboards which are new. <img width="444" height="400" alt="image" src="https://github.com/user-attachments/assets/7f107b9a-fe24-4e31-8f16-4d34768ee117" /> 3. Adds inhand sprites for Inflatables and Inflatable Boxes made by Tomixcomics. <img width="424" height="101" alt="image" src="https://github.com/user-attachments/assets/434107c4-8577-49a2-a58e-d6b014c03933" /> 4. Ports inhand sprites for the Hydraulic Rescue Tool from tg's Jaws of Life. <img width="224" height="94" alt="Screenshot 2026-02-07 172931" src="https://github.com/user-attachments/assets/070c7956-f6a8-4fb5-870f-10c64afcc8b3" /> 5. Some additional cleanup while in the area. The 'analyzer' has been renamed the 'gas analyzer' to be consistent with the other analyzer objects, standardized icon_state naming conventions where I saw oddballs, updated code docs to use DMDocs when in the area, etc. ### Asset Licenses The following assets that **have not** been created by myself are included in this PR: | Path | Original Author | License | | --- | --- | --- | | icons/obj/item/hydraulic_rescue_tool.dmi | [SomeAngryMiner (bee station)](https://github.com/BeeStation/BeeStation-Hornet/pull/2487), [maxymax (/tg/station)](https://github.com/tgstation/tgstation/pull/58616) | CC-BY-SA | | icons/obj/item/inflatables.dmi | [Tomixcomics](https://github.com/tomixcomics) | CC-BY-SA |
80 lines
2.6 KiB
Plaintext
80 lines
2.6 KiB
Plaintext
GLOBAL_LIST_INIT_TYPED(doppler_arrays, /obj/machinery/doppler_array, list())
|
|
|
|
/obj/machinery/doppler_array
|
|
name = "tachyon-doppler array"
|
|
desc = "A highly precise sensor array which measures the release of quants from decaying tachyons. The doppler shifting of the mirror-image formed by these quants can reveal the size, location and temporal affects of energetic disturbances within a large radius ahead of the array."
|
|
icon = 'icons/obj/modular_computers/modular_console.dmi'
|
|
icon_state = "computer"
|
|
|
|
anchored = TRUE
|
|
density = TRUE
|
|
var/active = TRUE
|
|
|
|
/obj/machinery/doppler_array/feedback_hints(mob/user, distance, is_adjacent)
|
|
. += ..()
|
|
. += SPAN_NOTICE("\The [src] is [active ? "listening for explosions" : "inactive"].")
|
|
|
|
/obj/machinery/doppler_array/Initialize()
|
|
. = ..()
|
|
GLOB.doppler_arrays += src
|
|
update_icon()
|
|
|
|
/obj/machinery/doppler_array/Destroy()
|
|
GLOB.doppler_arrays -= src
|
|
return ..()
|
|
|
|
/obj/machinery/doppler_array/attack_hand(mob/user)
|
|
active = !active
|
|
to_chat(user, SPAN_NOTICE("\The [src] is now [active ? "listening for explosions" : "[SPAN_WARNING("inactive")]"]."))
|
|
|
|
/obj/machinery/doppler_array/update_icon()
|
|
icon_state = initial(icon_state)
|
|
set_light(0)
|
|
if(stat & BROKEN)
|
|
icon_state = "broken"
|
|
else
|
|
ClearOverlays()
|
|
if(!(stat & NOPOWER))
|
|
set_light(2, 1, COLOR_CYAN)
|
|
AddOverlays(image(icon, src, "teleport"))
|
|
|
|
/obj/machinery/doppler_array/proc/sense_explosion(var/x0,var/y0,var/z0,var/devastation_range,var/heavy_impact_range,var/light_impact_range)
|
|
if(!active)
|
|
return
|
|
if(stat & NOPOWER)
|
|
return
|
|
if(z != z0)
|
|
return
|
|
|
|
var/dx = abs(x0-x)
|
|
var/dy = abs(y0-y)
|
|
var/distance
|
|
|
|
if(dx > dy)
|
|
distance = dx
|
|
else
|
|
distance = dy
|
|
|
|
if(distance > 100)
|
|
return
|
|
|
|
var/message = "Explosive disturbance detected - Epicenter at: grid ([x0],[y0],[z0]). Epicenter radius: [devastation_range]. Outer radius: [heavy_impact_range]. Shockwave radius: [light_impact_range]."
|
|
GLOB.global_announcer.autosay(message, "Tachyon-Doppler Array", "Science")
|
|
|
|
var/list/gained_tech
|
|
switch(devastation_range)
|
|
if(-INFINITY to 1) // minimum
|
|
gained_tech = list(TECH_BLUESPACE = 1, TECH_COMBAT = 2, TECH_MATERIAL = 2)
|
|
if(1 to 2) // starter bombs
|
|
gained_tech = list(TECH_BLUESPACE = 2, TECH_PHORON = 2, TECH_COMBAT = 3, TECH_MATERIAL = 3)
|
|
if(2 to 4) // max toxins can get
|
|
gained_tech = list(TECH_BLUESPACE = 3, TECH_PHORON = 3, TECH_COMBAT = 3, TECH_MATERIAL = 3, TECH_ENGINEERING = 3)
|
|
else
|
|
gained_tech = list(TECH_BLUESPACE = 4, TECH_PHORON = 4, TECH_COMBAT = 4, TECH_MATERIAL = 4, TECH_ENGINEERING = 4)
|
|
|
|
new /obj/item/research_slip(get_turf(src), gained_tech)
|
|
|
|
/obj/machinery/doppler_array/power_change()
|
|
..()
|
|
update_icon()
|