mirror of
https://github.com/Aurorastation/Aurora.3.git
synced 2026-07-21 21:10:30 +01:00
Batrachophreno
8111a8489b
Many, many, many items have inhand sprites in their .dmis but for whatever reasons do not display them in-game. This PR: 1. Updates many item definitions to point to their already-existing inhands correctly. This consists largely of held tools, but also gas tanks and jetpacks mounted in the suit storage slot. 2. Adds a few codersprites made by me for objects with either missing inhands or poorly matching mishands (IE, the tape recorder, which has a black case, reused the white inhand sprites of the health analyzer). The new sprites are modified or recolored variations of other inhand sprites from our repo, except for circuitboards which are new. <img width="444" height="400" alt="image" src="https://github.com/user-attachments/assets/7f107b9a-fe24-4e31-8f16-4d34768ee117" /> 3. Adds inhand sprites for Inflatables and Inflatable Boxes made by Tomixcomics. <img width="424" height="101" alt="image" src="https://github.com/user-attachments/assets/434107c4-8577-49a2-a58e-d6b014c03933" /> 4. Ports inhand sprites for the Hydraulic Rescue Tool from tg's Jaws of Life. <img width="224" height="94" alt="Screenshot 2026-02-07 172931" src="https://github.com/user-attachments/assets/070c7956-f6a8-4fb5-870f-10c64afcc8b3" /> 5. Some additional cleanup while in the area. The 'analyzer' has been renamed the 'gas analyzer' to be consistent with the other analyzer objects, standardized icon_state naming conventions where I saw oddballs, updated code docs to use DMDocs when in the area, etc. ### Asset Licenses The following assets that **have not** been created by myself are included in this PR: | Path | Original Author | License | | --- | --- | --- | | icons/obj/item/hydraulic_rescue_tool.dmi | [SomeAngryMiner (bee station)](https://github.com/BeeStation/BeeStation-Hornet/pull/2487), [maxymax (/tg/station)](https://github.com/tgstation/tgstation/pull/58616) | CC-BY-SA | | icons/obj/item/inflatables.dmi | [Tomixcomics](https://github.com/tomixcomics) | CC-BY-SA |
60 lines
2.4 KiB
Plaintext
60 lines
2.4 KiB
Plaintext
/obj/item/ipc_tag_scanner
|
|
name = "IPC tag scanner"
|
|
desc = "A hand-held IPC tag scanner, that, when used to analyze the info of an IPC, will output its tag status and information."
|
|
icon = 'icons/obj/item/scanner.dmi'
|
|
icon_state = "ipc_tag_scanner"
|
|
item_state = "ipc_tag_scanner"
|
|
contained_sprite = TRUE
|
|
obj_flags = OBJ_FLAG_CONDUCTABLE
|
|
slot_flags = SLOT_BELT
|
|
throwforce = 3
|
|
w_class = WEIGHT_CLASS_SMALL
|
|
|
|
// Wiring
|
|
var/datum/wires/tag_scanner/wires
|
|
var/wires_exposed = FALSE
|
|
var/powered = TRUE
|
|
var/hacked = FALSE
|
|
|
|
throw_speed = 5
|
|
throw_range = 10
|
|
origin_tech = list(TECH_MAGNET = 2, TECH_BIO = 1, TECH_ENGINEERING = 2)
|
|
matter = list(DEFAULT_WALL_MATERIAL = 500, MATERIAL_GLASS = 200)
|
|
|
|
/obj/item/ipc_tag_scanner/Initialize(mapload, ...)
|
|
. = ..()
|
|
wires = new /datum/wires/tag_scanner(src)
|
|
|
|
/obj/item/ipc_tag_scanner/Destroy()
|
|
QDEL_NULL(wires)
|
|
return ..()
|
|
|
|
/obj/item/ipc_tag_scanner/attack(mob/living/target_mob, mob/living/user, target_zone)
|
|
add_fingerprint(user)
|
|
if(!powered)
|
|
to_chat(user, SPAN_WARNING("\The [src] reads, \"Scanning failure, please submit scanner for repairs.\""))
|
|
return
|
|
user.visible_message(SPAN_NOTICE("\The [user] starts analyzing \the [target_mob] with \the [src]..."), SPAN_NOTICE("You start analyzing \the [target_mob] with \the [src]..."))
|
|
if(do_after(user, 5 SECONDS, src, DO_UNIQUE))
|
|
if(!isipc(target_mob))
|
|
to_chat(user, SPAN_WARNING("You analyze \the [target_mob], but find that they're not an IPC at all!"))
|
|
return
|
|
var/mob/living/carbon/human/IPC = target_mob
|
|
var/obj/item/organ/internal/machine/ipc_tag/tag = IPC.internal_organs_by_name[BP_IPCTAG]
|
|
if(isnull(tag) || !tag)
|
|
to_chat(user, SPAN_WARNING("Error: Serial Identification Missing."))
|
|
return
|
|
to_chat(user, SPAN_NOTICE("[capitalize_first_letters(tag.name)]:"))
|
|
to_chat(user, SPAN_NOTICE("<b>Serial Number:</b> [tag.serial_number]"))
|
|
to_chat(user, SPAN_NOTICE("<b>Ownership Status:</b> [tag.ownership_info]"))
|
|
to_chat(user, SPAN_NOTICE("<b>Citizenship Info:</b> [tag.citizenship_info]"))
|
|
|
|
/obj/item/ipc_tag_scanner/attackby(obj/item/attacking_item, mob/user)
|
|
if(attacking_item.tool_behaviour == TOOL_SCREWDRIVER)
|
|
wires_exposed = !wires_exposed
|
|
user.visible_message(SPAN_WARNING("\The [user] [wires_exposed ? "exposes the wiring" : "closes the panel"] on \the [src]."), SPAN_WARNING("You [wires_exposed ? "expose the wiring" : "close the panel"] on \the [src]."), 3)
|
|
else if(wires_exposed)
|
|
wires.interact(user)
|
|
else
|
|
..()
|