mirror of
https://github.com/Aurorastation/Aurora.3.git
synced 2025-12-20 15:12:19 +00:00
76b743a986
* Base work for the unathi robot subspecies. * Adds metabolism species, kidney vars, and the robot unathi organs. * Moves some action buttons to organs, pretty much a bay port right now. Todo: the unathi and alien stuff should also go here. * First autakh implant power. * Fixes the organs action button this time. * Finishes more implants, and interactions with flashs and vaurca. * Prepare for great changes. * Drops the real bomb, boss. * He who fights with monsters. * Far more work into augments and limb removing powers. * Limb verbs should be good now. * A LOT of work into the assited organ, allowing it to bleed and etc, as well adding a new chem that will stop bleeding in their case. * Probably the last work on implants. * Some extra touches. * Some tweaks to the species. * More fixes and adds kyre's sprites. * More runtime fixes. * Fixes the species name too. * Fixes travis. * Updates this file too to work with the new tools procs. * Adds changelog * Fixed changelog. * Unathi hair and lore description. * Some tweaks to this too. * Locks away them for now, they will be released after we got all the events and etc done. * Changes this chemical. * Fixes an airlock runtime. * Adds the non scan flag to the autakh, mostly due to some bizzare interactions with changelings and cloning. * Organs removal changes; can't take out the organ if it is too damage. * Restricts them back again. * Robotic organs now have the proper icons and names. * Adds sprites for their organs and some extra tweaks. * Fixes this missing icon. * emp should also now hurt assited organs. * Tweaks more organ related things. * Fixes the head not being properly set as well. * Fixes their flags. * fixes the flag for real this time. * Poze's review. * Changes the au'takh organ buttons to don't be animated. * Helps with adminbus or something. * Fowl's requested changes. * Fixes a typo. * Robotic limb's brute and burn mods are now controlled by the limb model. * Fowl's changes once more. * Stops some spam. * More grammar. * No eal. * Skull's review.
89 lines
3.4 KiB
Plaintext
89 lines
3.4 KiB
Plaintext
/obj/item/weapon/computer_hardware/
|
|
name = "Hardware"
|
|
desc = "Unknown Hardware."
|
|
icon = 'icons/obj/modular_components.dmi'
|
|
var/obj/item/modular_computer/holder2 = null
|
|
var/power_usage = 0 // If the hardware uses extra power, change this.
|
|
var/enabled = 1 // If the hardware is turned off set this to 0.
|
|
var/critical = 1 // Prevent disabling for important component, like the HDD.
|
|
var/hardware_size = 1 // Limits which devices can contain this component. 1: Tablets/Laptops/Consoles, 2: Laptops/Consoles, 3: Consoles only
|
|
var/damage = 0 // Current damage level
|
|
var/max_damage = 100 // Maximal damage level.
|
|
var/damage_malfunction = 20 // "Malfunction" threshold. When damage exceeds this value the hardware piece will semi-randomly fail and do !!FUN!! things
|
|
var/damage_failure = 50 // "Failure" threshold. When damage exceeds this value the hardware piece will not work at all.
|
|
var/malfunction_probability = 10// Chance of malfunction when the component is damaged
|
|
|
|
/obj/item/weapon/computer_hardware/attackby(var/obj/item/W as obj, var/mob/living/user as mob)
|
|
// Multitool. Runs diagnostics
|
|
if(W.ismultitool())
|
|
to_chat(user, "***** DIAGNOSTICS REPORT *****")
|
|
diagnostics(user)
|
|
to_chat(user, "******************************")
|
|
return 1
|
|
// Nanopaste. Repair all damage if present for a single unit.
|
|
var/obj/item/stack/S = W
|
|
if(istype(S, /obj/item/stack/nanopaste))
|
|
if(!damage)
|
|
to_chat(user, "\The [src] doesn't seem to require repairs.")
|
|
return 1
|
|
if(S.use(1))
|
|
to_chat(user, "You apply a bit of \the [W] to \the [src]. It immediately repairs all damage.")
|
|
damage = 0
|
|
return 1
|
|
// Cable coil. Works as repair method, but will probably require multiple applications and more cable.
|
|
if(S.iscoil())
|
|
if(!damage)
|
|
to_chat(user, "\The [src] doesn't seem to require repairs.")
|
|
return 1
|
|
if(S.use(1))
|
|
to_chat(user, "You patch up \the [src] with a bit of \the [W].")
|
|
take_damage(-10)
|
|
return 1
|
|
return ..()
|
|
|
|
|
|
// Called on multitool click, prints diagnostic information to the user.
|
|
/obj/item/weapon/computer_hardware/proc/diagnostics(var/mob/user)
|
|
to_chat(user, "Hardware Integrity Test... (Corruption: [damage]/[max_damage]) [damage > damage_failure ? "FAIL" : damage > damage_malfunction ? "WARN" : "PASS"]")
|
|
|
|
/obj/item/weapon/computer_hardware/Initialize()
|
|
. = ..()
|
|
w_class = hardware_size
|
|
if(istype(loc, /obj/item/modular_computer))
|
|
holder2 = loc
|
|
return .
|
|
|
|
/obj/item/weapon/computer_hardware/Destroy()
|
|
holder2 = null
|
|
return ..()
|
|
|
|
// Handles damage checks
|
|
/obj/item/weapon/computer_hardware/proc/check_functionality()
|
|
// Turned off
|
|
if(!enabled)
|
|
return 0
|
|
// Too damaged to work at all.
|
|
if(damage > damage_failure)
|
|
return 0
|
|
// Still working. Well, sometimes...
|
|
if(damage > damage_malfunction)
|
|
if(prob(malfunction_probability))
|
|
return 0
|
|
// Good to go.
|
|
return 1
|
|
|
|
/obj/item/weapon/computer_hardware/examine(var/mob/user)
|
|
. = ..()
|
|
if(damage > damage_failure)
|
|
to_chat(user, "<span class='danger'>It seems to be severely damaged!</span>")
|
|
else if(damage > damage_malfunction)
|
|
to_chat(user, "<span class='notice'>It seems to be damaged!</span>")
|
|
else if(damage)
|
|
to_chat(user, "It seems to be slightly damaged.")
|
|
|
|
// Damages the component. Contains necessary checks. Negative damage "heals" the component.
|
|
/obj/item/weapon/computer_hardware/proc/take_damage(var/amount)
|
|
damage += round(amount) // We want nice rounded numbers here.
|
|
damage = between(0, damage, max_damage) // Clamp the value.
|
|
|