mirror of
https://github.com/Aurorastation/Aurora.3.git
synced 2025-12-21 15:42:35 +00:00
d4666caaac
changes:
rscadd: "Ported a new chat system, Goonchat, that allows for cool things like changing font style, size, spacing, highlighting up to 5 strings in the chat, and DARK MODE."
rscadd: "Repeated chat messages can now get compacted. You can disable this in goonchat settings."
rscadd: "You can change icon style to any font on your system."
tweak: "The game window has been altered a bit to adjust for this."
rscdel: "Removed skin style prefs as they are no longer used."
56 lines
1.5 KiB
Plaintext
56 lines
1.5 KiB
Plaintext
/obj/item/mining_scanner
|
|
name = "ore detector"
|
|
desc = "A complex device used to locate ore deep underground."
|
|
icon = 'icons/obj/device.dmi'
|
|
icon_state = "forensic0-old" //GET A BETTER SPRITE.
|
|
item_state = "electronic"
|
|
origin_tech = list(TECH_MAGNET = 1, TECH_ENGINEERING = 1)
|
|
matter = list(DEFAULT_WALL_MATERIAL = 150)
|
|
|
|
/obj/item/mining_scanner/attack_self(mob/user)
|
|
to_chat(user, SPAN_NOTICE("You begin sweeping \the [src] about, scanning for metal deposits."))
|
|
|
|
if(!do_after(user, 50))
|
|
return
|
|
|
|
var/list/metals = list(
|
|
"surface minerals" = 0,
|
|
"precious metals" = 0,
|
|
"nuclear fuel" = 0,
|
|
"exotic matter" = 0
|
|
)
|
|
|
|
for(var/turf/T in range(2, get_turf(user)))
|
|
if(!T.has_resources)
|
|
continue
|
|
|
|
for(var/metal in T.resources)
|
|
var/ore_type
|
|
|
|
switch(metal)
|
|
if("silicates", "carbonaceous rock", "iron")
|
|
ore_type = "surface minerals"
|
|
if("gold", "silver", "diamond")
|
|
ore_type = "precious metals"
|
|
if("uranium")
|
|
ore_type = "nuclear fuel"
|
|
if("phoron", "osmium", "hydrogen")
|
|
ore_type = "exotic matter"
|
|
|
|
if(ore_type)
|
|
metals[ore_type] += T.resources[metal]
|
|
|
|
to_chat(user, "[icon2html(src, user)] [SPAN_NOTICE("The scanner beeps and displays a readout:")]")
|
|
|
|
for(var/ore_type in metals)
|
|
var/result = "no sign"
|
|
|
|
switch(metals[ore_type])
|
|
if(1 to 25)
|
|
result = "trace amounts"
|
|
if(26 to 75)
|
|
result = "significant amounts"
|
|
if(76 to INFINITY)
|
|
result = "huge quantities"
|
|
|
|
to_chat(user, SPAN_NOTICE("- [result] of [ore_type].")) |