mirror of
https://github.com/Aurorastation/Aurora.3.git
synced 2025-12-25 09:31:13 +00:00
1086e1fdb2
This PR removes brain surgery's ability to instantly cure all traumas. Now traumas have been roughly divided into four categories of treatment: 1: Chakra therapy cures traumas that directly affect physical behavior, such as tourettes or paralysis. It is accomplished via the crystal therapy pod available to the psychiatrist. 2: Hypnotic therapy cures traumas that directly affect mental behavior, such as phobias or confusions. It is accomplished via the mesmetron pocketwatch available to the psychiatrist. 3: Isolation therapy cures traumas that cause hallucinations. It is accomplished via the metronome and facilitated by the isolation room available to the psychiatrist. 4: Surgical therapy cures traumas that do not fit into the above categories. It is accomplished via brain surgery. Using the crystal therapy pod's neural scan function will provide the psychiatrist the brain damage the patient suffers from in numerical form. It falls upon the psychiatrist to determine how much of this brain damage is being caused by mental traumas the crystal therapy pod is equipped to deal with. Excessive cycles will cause increasing amounts of radiation damage. The mesmetron pocketwatch requires the patient to believe in hypnosis. It then puts the patient into a slumber, where the psychiatrist can hypnotically suggest new behavior, provided the patient continues to believe in hypnosis. Each suggestion cures a single hypnotic trauma. The isolation room is equipped with a metronome. When active, the metronome will have a chance every ticktock of the metronome to cure an isolation trauma, provided the patient is totally alone. The psychiatry office has been expanded into a complete mental health ward. The only thing it is lacking is beds, as I believe recovering mental health patients still belong in the recovery ward. The chaplain can also cure isolation and chakra traumas by dispelling the demons within with his null rod. Staring at the supermatter unprotected has been known to hypnotize. Electricity applied by any source directly to the head is also known to sometimes cure electroshock trauma.
59 lines
2.2 KiB
Plaintext
59 lines
2.2 KiB
Plaintext
//Brain Traumas are the new actual brain damage. Brain damage itself acts as a way to acquire traumas: every time brain damage is dealt, there's a chance of receiving a trauma.
|
|
//This chance gets higher the higher the mob's brainloss is. Removing traumas is a separate thing from removing brain damage: you can get restored to full brain operativity,
|
|
//but keep the quirks, until repaired by mannitol (for mild/special ones) or brain surgery (for severe ones).
|
|
/datum/brain_trauma
|
|
var/name = "Brain Trauma"
|
|
var/desc = "A trauma caused by brain damage, which causes issues to the patient."
|
|
var/scan_desc = "a generic brain trauma" //description when detected by a health scanner
|
|
var/mob/living/carbon/owner //the poor bastard
|
|
var/obj/item/organ/brain/brain //the poor bastard's brain
|
|
var/gain_text = "<span class='notice'>You feel traumatized.</span>"
|
|
var/lose_text = "<span class='notice'>You no longer feel traumatized.</span>"
|
|
var/can_gain = TRUE //can this be gained through random traumas?
|
|
var/permanent = FALSE //can this be cured?
|
|
var/suppressed = 0 //currently being suppressed
|
|
var/cure_type //type of therapy that cures the trauma
|
|
//current cures:
|
|
//hypnosis - cures traumas that alter behavior
|
|
//solitude - cures traumas that produce hallucination
|
|
//electroshock - cures traumas that have physical effects
|
|
//surgery - cures traumas not covered above
|
|
|
|
/datum/brain_trauma/New(obj/item/organ/brain/B, _permanent)
|
|
brain = B
|
|
owner = B.owner
|
|
permanent = _permanent
|
|
if(owner)
|
|
on_gain()
|
|
|
|
/datum/brain_trauma/Destroy()
|
|
brain.traumas -= src
|
|
if(owner)
|
|
on_lose()
|
|
brain = null
|
|
owner = null
|
|
return ..()
|
|
|
|
//Called on life ticks
|
|
/datum/brain_trauma/proc/on_life()
|
|
if(owner.getBrainLoss() < brain.traumas.len)
|
|
owner.setBrainLoss(brain.traumas.len)
|
|
return
|
|
|
|
//Called when given to a mob
|
|
/datum/brain_trauma/proc/on_gain()
|
|
to_chat(owner, gain_text)
|
|
|
|
//Called when removed from a mob
|
|
/datum/brain_trauma/proc/on_lose(silent)
|
|
if(!silent)
|
|
to_chat(owner, lose_text)
|
|
owner.adjustBrainLoss(-1)
|
|
|
|
//Called when hearing a spoken message
|
|
/datum/brain_trauma/proc/on_hear(message, speaker, message_language, raw_message, radio_freq)
|
|
return message
|
|
|
|
//Called when speaking
|
|
/datum/brain_trauma/proc/on_say(message)
|
|
return message |