mirror of
https://github.com/Aurorastation/Aurora.3.git
synced 2026-07-22 21:38:47 +01:00
Batrachophreno
8111a8489b
Many, many, many items have inhand sprites in their .dmis but for whatever reasons do not display them in-game. This PR: 1. Updates many item definitions to point to their already-existing inhands correctly. This consists largely of held tools, but also gas tanks and jetpacks mounted in the suit storage slot. 2. Adds a few codersprites made by me for objects with either missing inhands or poorly matching mishands (IE, the tape recorder, which has a black case, reused the white inhand sprites of the health analyzer). The new sprites are modified or recolored variations of other inhand sprites from our repo, except for circuitboards which are new. <img width="444" height="400" alt="image" src="https://github.com/user-attachments/assets/7f107b9a-fe24-4e31-8f16-4d34768ee117" /> 3. Adds inhand sprites for Inflatables and Inflatable Boxes made by Tomixcomics. <img width="424" height="101" alt="image" src="https://github.com/user-attachments/assets/434107c4-8577-49a2-a58e-d6b014c03933" /> 4. Ports inhand sprites for the Hydraulic Rescue Tool from tg's Jaws of Life. <img width="224" height="94" alt="Screenshot 2026-02-07 172931" src="https://github.com/user-attachments/assets/070c7956-f6a8-4fb5-870f-10c64afcc8b3" /> 5. Some additional cleanup while in the area. The 'analyzer' has been renamed the 'gas analyzer' to be consistent with the other analyzer objects, standardized icon_state naming conventions where I saw oddballs, updated code docs to use DMDocs when in the area, etc. ### Asset Licenses The following assets that **have not** been created by myself are included in this PR: | Path | Original Author | License | | --- | --- | --- | | icons/obj/item/hydraulic_rescue_tool.dmi | [SomeAngryMiner (bee station)](https://github.com/BeeStation/BeeStation-Hornet/pull/2487), [maxymax (/tg/station)](https://github.com/tgstation/tgstation/pull/58616) | CC-BY-SA | | icons/obj/item/inflatables.dmi | [Tomixcomics](https://github.com/tomixcomics) | CC-BY-SA |
76 lines
2.6 KiB
Plaintext
76 lines
2.6 KiB
Plaintext
//Shuttle controller computer for shuttles going between sectors
|
|
/obj/machinery/computer/shuttle_control/explore
|
|
name = "general shuttle control console"
|
|
ui_template = "ShuttleControlConsoleMultiExplore"
|
|
var/obj/effect/overmap/visitable/ship/connected //Ship we're connected to
|
|
|
|
/obj/machinery/computer/shuttle_control/explore/Initialize()
|
|
. = ..()
|
|
if(istype(linked, /obj/effect/overmap/visitable/ship))
|
|
connected = linked
|
|
|
|
/obj/machinery/computer/shuttle_control/explore/attempt_hook_up(var/obj/effect/overmap/visitable/sector)
|
|
. = ..()
|
|
|
|
if(.)
|
|
connected = linked
|
|
LAZYSET(connected.consoles, src, TRUE)
|
|
|
|
/obj/machinery/computer/shuttle_control/explore/Destroy()
|
|
if(connected)
|
|
LAZYREMOVE(connected.consoles, src)
|
|
. = ..()
|
|
|
|
/obj/machinery/computer/shuttle_control/explore/ui_data(mob/user)
|
|
. = ..()
|
|
|
|
var/datum/shuttle/autodock/overmap/shuttle = SSshuttle.shuttles[shuttle_tag]
|
|
if(istype(shuttle))
|
|
var/total_gas = 0
|
|
for(var/obj/structure/fuel_port/FP in shuttle.fuel_ports) //loop through fuel ports
|
|
var/obj/item/tank/fuel_tank = locate() in FP
|
|
if(fuel_tank)
|
|
total_gas += fuel_tank.air_contents.total_moles
|
|
|
|
var/fuel_span = "good"
|
|
if(total_gas < shuttle.fuel_consumption * 2)
|
|
fuel_span = "bad"
|
|
|
|
. += list(
|
|
"destination_name" = shuttle.get_destination_name(),
|
|
"destination_map_image" = shuttle.next_location ? SSholomap.minimaps_scan_base64[shuttle.next_location.z] : null,
|
|
"destination_x" = shuttle.next_location?.x,
|
|
"destination_y" = shuttle.next_location?.y,
|
|
"can_pick" = shuttle.moving_status == SHUTTLE_IDLE,
|
|
"fuel_usage" = shuttle.fuel_consumption * 100,
|
|
"remaining_fuel" = round(total_gas, 0.01) * 100,
|
|
"fuel_span" = fuel_span
|
|
)
|
|
|
|
/obj/machinery/computer/shuttle_control/explore/handle_topic_href(var/mob/user, var/datum/shuttle/autodock/overmap/shuttle, var/action, var/list/params)
|
|
. = ..()
|
|
if(. != null)
|
|
return
|
|
|
|
if(action == "pick")
|
|
var/list/possible_d = shuttle.get_possible_destinations()
|
|
var/D
|
|
if(length(possible_d))
|
|
D = tgui_input_list(usr, "Choose shuttle destination.", "Shuttle Destination", possible_d)
|
|
else
|
|
to_chat(usr, SPAN_WARNING("No valid landing sites in range."))
|
|
if(CanInteract(user, GLOB.physical_state) && (D in possible_d))
|
|
shuttle.set_destination(possible_d[D])
|
|
return TRUE
|
|
|
|
/obj/machinery/computer/shuttle_control/explore/terminal
|
|
name = "shuttle control terminal"
|
|
icon = 'icons/obj/modular_computers/modular_terminal.dmi'
|
|
icon_screen = "helm"
|
|
icon_keyboard = "tech_key"
|
|
icon_keyboard_emis = "tech_key_mask"
|
|
is_connected = TRUE
|
|
has_off_keyboards = TRUE
|
|
can_pass_under = FALSE
|
|
light_power_on = 1
|