mirror of
https://github.com/Aurorastation/Aurora.3.git
synced 2025-12-21 15:42:35 +00:00
63eafb3643
In this PR: Destroy() fixes backported from PR #1783. JaniPDA fixes & improvements. Chickens no longer consume their own eggs. Language adding in setup is now 100% more sane. Chemical dispensers now actually check that the user is still alive before renaming. Ghosts are now marked as non-simulated atoms. Non-simulated atoms no longer trigger proximity listeners. Vendors no longer accept synthetic tools as stocking options. Fixes #812. Fixes #1877, Fixes #1929. Fixes #1930. Fixes #1152, Fixes #1917. Fixes #1902. Fixes #1165.
84 lines
3.6 KiB
Plaintext
84 lines
3.6 KiB
Plaintext
/datum/category_item/player_setup_item/general/language
|
|
name = "Language"
|
|
sort_order = 2
|
|
|
|
/datum/category_item/player_setup_item/general/language/load_character(var/savefile/S)
|
|
S["language"] >> pref.alternate_languages
|
|
|
|
/datum/category_item/player_setup_item/general/language/save_character(var/savefile/S)
|
|
S["language"] << pref.alternate_languages
|
|
|
|
/datum/category_item/player_setup_item/general/language/gather_load_query()
|
|
return list("ss13_characters" = list("vars" = list("language" = "alternate_languages"), "args" = list("id")))
|
|
|
|
/datum/category_item/player_setup_item/general/language/gather_load_parameters()
|
|
return list(":id" = pref.current_character)
|
|
|
|
/datum/category_item/player_setup_item/general/language/gather_save_query()
|
|
return list("ss13_characters" = list("id" = 1,
|
|
"ckey" = 1,
|
|
"language"))
|
|
|
|
/datum/category_item/player_setup_item/general/language/gather_save_parameters()
|
|
return list(":language" = list2params(pref.alternate_languages),
|
|
":id" = pref.current_character,
|
|
":ckey" = pref.client.ckey)
|
|
|
|
/datum/category_item/player_setup_item/general/language/sanitize_character(var/sql_load = 0)
|
|
if (sql_load)
|
|
pref.alternate_languages = params2list(pref.alternate_languages)
|
|
|
|
if(!islist(pref.alternate_languages))
|
|
pref.alternate_languages = list()
|
|
|
|
/datum/category_item/player_setup_item/general/language/content()
|
|
. += "<b>Languages</b><br>"
|
|
var/datum/species/S = all_species[pref.species]
|
|
if(S.language)
|
|
. += "- [S.language]<br>"
|
|
if(S.default_language && S.default_language != S.language)
|
|
. += "- [S.default_language]<br>"
|
|
if(S.num_alternate_languages)
|
|
if(pref.alternate_languages.len)
|
|
for(var/i = 1 to pref.alternate_languages.len)
|
|
var/lang = pref.alternate_languages[i]
|
|
. += "- [lang] - <a href='?src=\ref[src];remove_language=[i]'>remove</a><br>"
|
|
|
|
if(pref.alternate_languages.len < S.num_alternate_languages)
|
|
. += "- <a href='?src=\ref[src];add_language=1'>add</a> ([S.num_alternate_languages - pref.alternate_languages.len] remaining)<br>"
|
|
else
|
|
. += "- [pref.species] cannot choose secondary languages.<br>"
|
|
|
|
/datum/category_item/player_setup_item/general/language/OnTopic(var/href,var/list/href_list, var/mob/user)
|
|
if(href_list["remove_language"])
|
|
var/index = text2num(href_list["remove_language"])
|
|
pref.alternate_languages.Cut(index, index+1)
|
|
return TOPIC_REFRESH
|
|
else if(href_list["add_language"])
|
|
var/datum/species/S = all_species[pref.species]
|
|
if(pref.alternate_languages.len >= S.num_alternate_languages)
|
|
alert(user, "You have already selected the maximum number of alternate languages for this species!")
|
|
else
|
|
var/list/available_languages = S.secondary_langs.Copy()
|
|
for(var/L in all_languages)
|
|
var/datum/language/lang = all_languages[L]
|
|
if(!(lang.flags & RESTRICTED) && (!config.usealienwhitelist || is_alien_whitelisted(user, L) || !(lang.flags & WHITELISTED)))
|
|
available_languages |= L
|
|
|
|
// make sure we don't let them waste slots on the default languages
|
|
available_languages -= S.language
|
|
available_languages -= S.default_language
|
|
available_languages -= pref.alternate_languages
|
|
|
|
if(!available_languages.len)
|
|
alert(user, "There are no additional languages available to select.")
|
|
else
|
|
var/new_lang = input(user, "Select an additional language", "Character Generation", null) as null|anything in available_languages
|
|
if(new_lang)
|
|
if (pref.alternate_languages.len >= S.num_alternate_languages)
|
|
alert(user, "You have already selected the maximum number of alternate languages for this species!")
|
|
else
|
|
pref.alternate_languages |= new_lang
|
|
return TOPIC_REFRESH
|
|
return ..()
|