mirror of
https://github.com/Aurorastation/Aurora.3.git
synced 2025-12-22 16:12:19 +00:00
bc441ab9d6
changes: Refactored footstep sounds to use less operations & only calculate for human-types. Improved the logging detail of the lighting profiler. Fixed some shuttle corners that weren't correctly working with parallax space. Converted get_turf() into a compiler macro. Solars are now dynamically lit. Silenced warning from lighting overlays pooling themselves when updated on a space tile. Fixed a bug where securing a girder was instant when it was supposed to have a delay.
115 lines
3.6 KiB
Plaintext
115 lines
3.6 KiB
Plaintext
/var/list/all_lighting_overlays = list() // Global list of lighting overlays.
|
|
|
|
/atom/movable/lighting_overlay
|
|
name = ""
|
|
anchored = TRUE
|
|
icon = LIGHTING_ICON
|
|
color = LIGHTING_BASE_MATRIX
|
|
mouse_opacity = 0
|
|
layer = LIGHTING_LAYER
|
|
invisibility = INVISIBILITY_LIGHTING
|
|
simulated = 0
|
|
blend_mode = BLEND_MULTIPLY
|
|
|
|
var/needs_update = FALSE
|
|
|
|
#if WORLD_ICON_SIZE != 32
|
|
transform = matrix(WORLD_ICON_SIZE / 32, 0, (WORLD_ICON_SIZE - 32) / 2, 0, WORLD_ICON_SIZE / 32, (WORLD_ICON_SIZE - 32) / 2)
|
|
#endif
|
|
|
|
/atom/movable/lighting_overlay/New(var/atom/loc, var/no_update = FALSE)
|
|
. = ..()
|
|
verbs.Cut()
|
|
global.all_lighting_overlays += src
|
|
|
|
var/turf/T = loc // If this runtimes atleast we'll know what's creating overlays in things that aren't turfs.
|
|
T.lighting_overlay = src
|
|
T.luminosity = 0
|
|
|
|
if (no_update)
|
|
return
|
|
|
|
update_overlay()
|
|
|
|
/atom/movable/lighting_overlay/Destroy()
|
|
L_PROF(loc, "overlay_destroy")
|
|
global.all_lighting_overlays -= src
|
|
global.lighting_update_overlays -= src
|
|
lighting_process.curr_overlays -= src
|
|
|
|
var/turf/T = loc
|
|
if (istype(T))
|
|
T.lighting_overlay = null
|
|
T.luminosity = 1
|
|
|
|
..()
|
|
|
|
/atom/movable/lighting_overlay/proc/update_overlay()
|
|
var/turf/T = loc
|
|
if (!istype(T)) // Erm...
|
|
if (loc)
|
|
warning("A lighting overlay realised its loc was NOT a turf (actual loc: [loc], [loc.type]) in update_overlay() and got pooled!")
|
|
|
|
else
|
|
warning("A lighting overlay realised it was in nullspace in update_overlay() and got pooled!")
|
|
|
|
returnToPool(src)
|
|
return
|
|
|
|
if (istype(T, /turf/space))
|
|
// I mean, this happens often and doesn't do any harm. Might as well silence the warning.
|
|
//warning("A lighting overlay realised it was attached to a space tile and got pooled!")
|
|
returnToPool(src)
|
|
return
|
|
|
|
// To the future coder who sees this and thinks
|
|
// "Why didn't he just use a loop?"
|
|
// Well my man, it's because the loop performed like shit.
|
|
// And there's no way to improve it because
|
|
// without a loop you can make the list all at once which is the fastest you're gonna get.
|
|
// Oh it's also shorter line wise.
|
|
// Including with these comments.
|
|
|
|
// See LIGHTING_CORNER_DIAGONAL in lighting_corner.dm for why these values are what they are.
|
|
// No I seriously cannot think of a more efficient method, fuck off Comic.
|
|
var/datum/lighting_corner/cr = T.corners[3] || dummy_lighting_corner
|
|
var/datum/lighting_corner/cg = T.corners[2] || dummy_lighting_corner
|
|
var/datum/lighting_corner/cb = T.corners[4] || dummy_lighting_corner
|
|
var/datum/lighting_corner/ca = T.corners[1] || dummy_lighting_corner
|
|
|
|
var/max = max(cr.cache_mx, cg.cache_mx, cb.cache_mx, ca.cache_mx)
|
|
|
|
color = list(
|
|
cr.cache_r, cr.cache_g, cr.cache_b, 0,
|
|
cg.cache_r, cg.cache_g, cg.cache_b, 0,
|
|
cb.cache_r, cb.cache_g, cb.cache_b, 0,
|
|
ca.cache_r, ca.cache_g, ca.cache_b, 0,
|
|
0, 0, 0, 1
|
|
)
|
|
luminosity = max > LIGHTING_SOFT_THRESHOLD
|
|
|
|
// Variety of overrides so the overlays don't get affected by weird things.
|
|
|
|
/atom/movable/lighting_overlay/ex_act(severity)
|
|
return 0
|
|
|
|
/atom/movable/lighting_overlay/singularity_act()
|
|
return
|
|
|
|
/atom/movable/lighting_overlay/singularity_pull()
|
|
return
|
|
|
|
/atom/movable/lighting_overlay/singuloCanEat()
|
|
return FALSE
|
|
|
|
// Override here to prevent things accidentally moving around overlays.
|
|
/atom/movable/lighting_overlay/forceMove(atom/destination, var/no_tp=FALSE, var/harderforce = FALSE)
|
|
if(harderforce)
|
|
L_PROF(loc, "overlay_forcemove")
|
|
. = ..()
|
|
|
|
/atom/movable/lighting_overlay/resetVariables(...)
|
|
color = LIGHTING_BASE_MATRIX
|
|
|
|
return ..("color")
|