mirror of
https://github.com/Aurorastation/Aurora.3.git
synced 2026-01-07 07:52:00 +00:00
cadd19beac
* SDQL2 update * fix that verb * cl * fix that * toworld * this is pointless * update info * siiiiick.. * vv edit update * fix that * fix editing vars * fix VV * Port the /TG/ globals controller. * part 1 * part 2 * oops * part 3 * Hollow Purple * sadas * bsbsdb * muda na agaki ta * ids 1-15 * 16-31 * 41-75 * bring me back to how things used to be before i lost it all * the strength of mayhem * final touches * cl * protect some vars * update sdql2 to use glob * stuff? * forgot that is not defined there * whoops * observ * but it never gets better * a --------- Co-authored-by: Matt Atlas <liermattia@gmail.com>
109 lines
3.5 KiB
Plaintext
109 lines
3.5 KiB
Plaintext
/client/proc/print_random_map()
|
|
set category = "Debug"
|
|
set name = "Display Random Map"
|
|
set desc = "Show the contents of a random map."
|
|
|
|
if(!holder) return
|
|
|
|
var/choice = input("Choose a map to display.") as null|anything in GLOB.random_maps
|
|
if(!choice)
|
|
return
|
|
var/datum/random_map/M = GLOB.random_maps[choice]
|
|
if(istype(M))
|
|
M.display_map(usr)
|
|
|
|
/client/proc/delete_random_map()
|
|
set category = "Debug"
|
|
set name = "Delete Random Map"
|
|
set desc = "Delete a random map."
|
|
|
|
if(!holder) return
|
|
|
|
var/choice = input("Choose a map to delete.") as null|anything in GLOB.random_maps
|
|
if(!choice)
|
|
return
|
|
var/datum/random_map/M = GLOB.random_maps[choice]
|
|
GLOB.random_maps[choice] = null
|
|
if(istype(M))
|
|
message_admins("[key_name_admin(usr)] has deleted [M.name].")
|
|
log_admin("[key_name(usr)] has deleted [M.name].",admin_key=key_name(usr))
|
|
qdel(M)
|
|
|
|
/client/proc/create_random_map()
|
|
set category = "Debug"
|
|
set name = "Create Random Map"
|
|
set desc = "Create a random map."
|
|
|
|
if(!holder) return
|
|
|
|
var/map_datum = input("Choose a map to create.") as null|anything in typesof(/datum/random_map)-/datum/random_map
|
|
if(!map_datum)
|
|
return
|
|
|
|
var/datum/random_map/M
|
|
if(alert("Do you wish to customise the map?",,"Yes","No") == "Yes")
|
|
var/seed = input("Seed? (blank for none)") as text|null
|
|
var/lx = input("X-size? (blank for default)") as num|null
|
|
var/ly = input("Y-size? (blank for default)") as num|null
|
|
M = new map_datum(seed,null,null,null,lx,ly,1)
|
|
else
|
|
M = new map_datum(null,null,null,null,null,null,1)
|
|
|
|
if(M)
|
|
message_admins("[key_name_admin(usr)] has created [M.name].")
|
|
log_admin("[key_name(usr)] has created [M.name].",admin_key=key_name(usr))
|
|
|
|
/client/proc/apply_random_map()
|
|
set category = "Debug"
|
|
set name = "Apply Random Map"
|
|
set desc = "Apply a map to the game world."
|
|
|
|
if(!holder) return
|
|
|
|
var/choice = input("Choose a map to apply.") as null|anything in GLOB.random_maps
|
|
if(!choice)
|
|
return
|
|
var/datum/random_map/M = GLOB.random_maps[choice]
|
|
if(istype(M))
|
|
var/tx = input("X? (default to current turf)") as num|null
|
|
var/ty = input("Y? (default to current turf)") as num|null
|
|
var/tz = input("Z? (default to current turf)") as num|null
|
|
if(isnull(tx) || isnull(ty) || isnull(tz))
|
|
var/turf/T = get_turf(usr)
|
|
tx = !isnull(tx) ? tx : T.x
|
|
ty = !isnull(ty) ? ty : T.y
|
|
tz = !isnull(tz) ? tz : T.z
|
|
message_admins("[key_name_admin(usr)] has applied [M.name] at x[tx],y[ty],z[tz].")
|
|
log_admin("[key_name(usr)] has applied [M.name] at x[tx],y[ty],z[tz].",admin_key=key_name(usr))
|
|
M.set_origins(tx,ty,tz)
|
|
M.apply_to_map()
|
|
|
|
/client/proc/overlay_random_map()
|
|
set category = "Debug"
|
|
set name = "Overlay Random Map"
|
|
set desc = "Apply a map to another map."
|
|
|
|
if(!holder) return
|
|
|
|
var/choice = input("Choose a map as base.") as null|anything in GLOB.random_maps
|
|
if(!choice)
|
|
return
|
|
var/datum/random_map/base_map = GLOB.random_maps[choice]
|
|
|
|
choice = null
|
|
choice = input("Choose a map to overlay.") as null|anything in GLOB.random_maps
|
|
if(!choice)
|
|
return
|
|
|
|
var/datum/random_map/overlay_map = GLOB.random_maps[choice]
|
|
|
|
if(istype(base_map) && istype(overlay_map))
|
|
var/tx = input("X? (default to 1)") as num|null
|
|
var/ty = input("Y? (default to 1)") as num|null
|
|
if(!tx) tx = 1
|
|
if(!ty) ty = 1
|
|
message_admins("[key_name_admin(usr)] has applied [overlay_map.name] to [base_map.name] at x[tx],y[ty].")
|
|
log_admin("[key_name(usr)] has applied [overlay_map.name] to [base_map.name] at x[tx],y[ty].",admin_key=key_name(usr))
|
|
overlay_map.overlay_with(base_map,tx,ty)
|
|
base_map.display_map(usr)
|