mirror of
https://github.com/Aurorastation/Aurora.3.git
synced 2025-12-20 15:12:19 +00:00
44f22c2128
Okay. You can read the entire theory over in this issue: #1365 But basically. All objects to be initialized are now added to a list in their New() proc on world/New(). This is substantially smaller than the entire world. This allows game_controller/setup_objects() to crawl a much larger list, and speeds it up by 6 seconds (from 9.5 to 3.5 seconds). The impact on world/New() is, on average, under 1 second. Also fixes #1365 and #1363 as a result of reworking the initialization call logic in atoms_movable.dm. initialize() is now more secure, and can handle recursive calls at any point in time.
91 lines
2.8 KiB
Plaintext
91 lines
2.8 KiB
Plaintext
//simplified MC that is designed to fail when procs 'break'. When it fails it's just replaced with a new one.
|
|
//It ensures master_controller.process() is never doubled up by killing the MC (hence terminating any of its sleeping procs)
|
|
//WIP, needs lots of work still
|
|
|
|
var/global/datum/controller/game_controller/master_controller //Set in world.New()
|
|
|
|
var/global/controller_iteration = 0
|
|
var/global/last_tick_duration = 0
|
|
|
|
var/global/air_processing_killed = 0
|
|
var/global/pipe_processing_killed = 0
|
|
|
|
datum/controller/game_controller
|
|
var/list/shuttle_list // For debugging and VV
|
|
|
|
datum/controller/game_controller/New()
|
|
//There can be only one master_controller. Out with the old and in with the new.
|
|
if(master_controller != src)
|
|
log_debug("Rebuilding Master Controller")
|
|
if(istype(master_controller))
|
|
qdel(master_controller)
|
|
master_controller = src
|
|
|
|
if(!job_master)
|
|
job_master = new /datum/controller/occupations()
|
|
job_master.SetupOccupations()
|
|
job_master.LoadJobs("config/jobs.txt")
|
|
admin_notice("<span class='danger'>Job setup complete</span>", R_DEBUG)
|
|
|
|
if(!syndicate_code_phrase) syndicate_code_phrase = generate_code_phrase()
|
|
if(!syndicate_code_response) syndicate_code_response = generate_code_phrase()
|
|
|
|
datum/controller/game_controller/proc/setup()
|
|
world.tick_lag = config.Ticklag
|
|
|
|
spawn(20)
|
|
createRandomZlevel()
|
|
|
|
setup_objects()
|
|
setupgenetics()
|
|
SetupXenoarch()
|
|
|
|
transfer_controller = new
|
|
|
|
|
|
datum/controller/game_controller/proc/setup_objects()
|
|
admin_notice("<span class='danger'>Initializing objects</span>", R_DEBUG)
|
|
sleep(-1)
|
|
objects_initialized = 1
|
|
for(var/A in objects_init_list)
|
|
var/atom/movable/object = A
|
|
if(isnull(object.gcDestroyed))
|
|
object.initialize()
|
|
|
|
objects_init_list.Cut()
|
|
|
|
admin_notice("<span class='danger'>Initializing areas</span>", R_DEBUG)
|
|
sleep(-1)
|
|
for(var/A in all_areas)
|
|
var/area/area = A
|
|
area.initialize()
|
|
|
|
admin_notice("<span class='danger'>Initializing pipe networks</span>", R_DEBUG)
|
|
sleep(-1)
|
|
for(var/obj/machinery/atmospherics/machine in machines)
|
|
machine.build_network()
|
|
|
|
admin_notice("<span class='danger'>Initializing atmos machinery.</span>", R_DEBUG)
|
|
sleep(-1)
|
|
for(var/obj/machinery/atmospherics/unary/U in machines)
|
|
if(istype(U, /obj/machinery/atmospherics/unary/vent_pump))
|
|
var/obj/machinery/atmospherics/unary/vent_pump/T = U
|
|
T.broadcast_status()
|
|
else if(istype(U, /obj/machinery/atmospherics/unary/vent_scrubber))
|
|
var/obj/machinery/atmospherics/unary/vent_scrubber/T = U
|
|
T.broadcast_status()
|
|
|
|
|
|
//Spawn the contents of the cargo warehouse
|
|
sleep(-1)
|
|
spawn_cargo_stock()
|
|
|
|
// Set up antagonists.
|
|
populate_antag_type_list()
|
|
|
|
//Set up spawn points.
|
|
populate_spawn_points()
|
|
|
|
admin_notice("<span class='danger'>Initializations complete.</span>", R_DEBUG)
|
|
sleep(-1)
|