Adds Datum Tagging for admins (#62982)

code/modules/admin/admin_verbs.dm

@@ -17,6 +17,7 @@ GLOBAL_PROTECT(admin_verbs_default)
 	/client/proc/cmd_admin_pm_panel, /*admin-pm list*/
 	/client/proc/stop_sounds,
 	/client/proc/mark_datum_mapview,
+	/client/proc/tag_datum_mapview,
 	/client/proc/debugstatpanel,
 	/client/proc/fix_air, /*resets air in designated radius to its default atmos composition*/
 	/client/proc/requests
@@ -77,6 +78,7 @@ GLOBAL_PROTECT(admin_verbs_admin)
 	/datum/admins/proc/view_all_sdql_spells,
 	/datum/admins/proc/known_alts_panel,
 	/datum/admins/proc/paintings_manager,
+	/datum/admins/proc/display_tags,
 	)
 GLOBAL_LIST_INIT(admin_verbs_ban, list(/client/proc/unban_panel, /client/proc/ban_panel, /client/proc/stickybanpanel))
 GLOBAL_PROTECT(admin_verbs_ban)

code/modules/admin/holder2.dm

@@ -39,6 +39,9 @@ GLOBAL_PROTECT(href_token)
 	/// Whether or not this user can bypass 2FA
 	var/bypass_2fa = FALSE
 
+	/// A lazylist of tagged datums, for quick reference with the View Tags verb
+	var/list/tagged_datums
+
 /datum/admins/New(datum/admin_rank/R, ckey, force_active = FALSE, protected)
 	if(IsAdminAdvancedProcCall())
 		var/msg = " has tried to elevate permissions!"

code/modules/admin/tag.dm

@@ -0,0 +1,108 @@
+/**
+ * Inserts the target_datum into [/datum/admins/var/tagged_datums], for later reference.
+ *
+ * Arguments:
+ * * target_datum - The datum you want to create a tag for
+ */
+/datum/admins/proc/add_tagged_datum(datum/target_datum)
+	if(LAZYFIND(tagged_datums, target_datum))
+		to_chat(owner, span_warning("[target_datum] is already tagged!"))
+		return
+
+	LAZYADD(tagged_datums, target_datum)
+	RegisterSignal(target_datum, COMSIG_PARENT_QDELETING, .proc/handle_tagged_del, override = TRUE)
+	to_chat(owner, span_notice("[target_datum] has been tagged."))
+
+/// Get ahead of the curve with deleting
+/datum/admins/proc/handle_tagged_del(datum/source)
+	SIGNAL_HANDLER
+
+	if(owner)
+		to_chat(owner, span_boldnotice("Tagged datum [source] ([source.type]) has been deleted."))
+	remove_tagged_datum(source, silent = TRUE)
+
+/**
+ * Attempts to remove the specified datum from [/datum/admins/var/tagged_datums] if it exists
+ *
+ * Arguments:
+ * * target_datum - The datum you want to remove from the tagged_datums list
+ * * silent - If TRUE, won't print messages to the owner's chat
+ */
+/datum/admins/proc/remove_tagged_datum(datum/target_datum, silent=FALSE)
+	if(!istype(target_datum))
+		return
+
+	if(LAZYFIND(tagged_datums, target_datum))
+		LAZYREMOVE(tagged_datums, target_datum)
+		if(!silent)
+			to_chat(owner, span_notice("[target_datum] has been untagged."))
+	else if(!silent)
+		to_chat(owner, span_warning("[target_datum] was not already tagged."))
+
+/// Quick define for readability
+#define TAG_DEL(X) "<b>(<A href='?src=[REF(src)];[HrefToken(TRUE)];del_tag=[REF(X)]'>UNTAG</a>)</b>"
+#define TAG_MARK(X) "<b>(<A href='?src=[REF(src)];[HrefToken(TRUE)];mark_datum=[REF(X)]'>MARK</a>)</b>"
+#define TAG_SIMPLE_HEALTH(X) "<font color='#ff0000'><b>Health: [X.health]</b></font>"
+#define TAG_CARBON_HEALTH(X) "<font color='#ff0000'><b>Health: [X.health]</b></font> (\
+					<font color='#ff3333'>[X.getBruteLoss()]</font> \
+					<font color='#ff9933'>[X.getFireLoss()]</font> \
+					<font color='#00cc66'>[X.getToxLoss()]</font> \
+					<font color='#00cccc'>[X.getOxyLoss()]</font>\
+					[X.getCloneLoss() ? " <font color='#1c3ac4'>[X.getCloneLoss()]</font>" : ""])"
+
+/// Display all of the tagged datums
+/datum/admins/proc/display_tags()
+	set category = "Admin.Game"
+	set name = "View Tags"
+
+	if (!istype(src, /datum/admins))
+		src = usr.client.holder
+	if (!istype(src, /datum/admins))
+		to_chat(usr, "Error: you are not an admin!", confidential = TRUE)
+		return
+
+	var/index = 0
+	var/list/dat = list("<center><B>Tag Menu</B></center><hr>")
+
+	dat += "<br><A href='?src=[REF(src)];[HrefToken(TRUE)];show_tags=1'>Refresh</a><br>"
+	if(LAZYLEN(tagged_datums))
+		for(var/datum/iter_datum as anything in tagged_datums)
+			index++
+			var/specific_info
+
+			if(isnull(iter_datum))
+				dat += "\t[index]: Null reference - Check runtime logs!"
+				stack_trace("Null datum found in tagged datum menu! User: [usr]")
+				continue
+			else if(iscarbon(iter_datum))
+				var/mob/living/carbon/resolved_carbon = iter_datum
+				specific_info = "[TAG_CARBON_HEALTH(resolved_carbon)] | [AREACOORD(resolved_carbon)] [ADMIN_PP(iter_datum)] [ADMIN_FLW(iter_datum)]"
+			else if(isliving(iter_datum))
+				var/mob/living/resolved_living = iter_datum
+				specific_info = "[TAG_SIMPLE_HEALTH(resolved_living)] | [AREACOORD(resolved_living)] [ADMIN_PP(iter_datum)] [ADMIN_FLW(iter_datum)]"
+			else if(ismob(iter_datum))
+				var/atom/resolved_atom = iter_datum // needed for ADMIN_JMP
+				specific_info = "[AREACOORD(resolved_atom)] [ADMIN_PP(iter_datum)] [ADMIN_FLW(iter_datum)]"
+			else if(ismovable(iter_datum))
+				var/atom/resolved_atom = iter_datum // needed for ADMIN_JMP
+				specific_info = "[AREACOORD(resolved_atom)] [ADMIN_FLW(iter_datum)]"
+			else if(isatom(iter_datum))
+				var/atom/resolved_atom = iter_datum // needed for ADMIN_JMP
+				specific_info = "[AREACOORD(resolved_atom)] [ADMIN_JMP(resolved_atom)]"
+			else if(istype(iter_datum, /datum/controller/subsystem))
+				var/datum/controller/subsystem/resolved_subsystem = iter_datum
+				specific_info = "[resolved_subsystem.stat_entry()]"
+			// else, it's just a /datum
+
+			dat += "\t[index]: [iter_datum] | [specific_info] | [ADMIN_VV(iter_datum)]| [TAG_DEL(iter_datum)] | [iter_datum == marked_datum ? "<b>Marked</b>" : TAG_MARK(iter_datum)] "
+			dat += "\t(<b><font size='2'>[iter_datum.type])</font></b>"
+	else
+		dat += "No datums tagged :("
+
+	dat = dat.Join("<br>")
+	usr << browse(dat, "window=tag;size=800x480")
+
+#undef TAG_DEL
+#undef TAG_MARK
+#undef TAG_SIMPLE_HEALTH
+#undef TAG_CARBON_HEALTH

code/modules/admin/topic.dm

@@ -1926,3 +1926,24 @@
 		if(!check_rights(R_ADMIN))
 			return
 		GLOB.interviews.ui_interact(usr)
+
+	else if(href_list["del_tag"])
+		if(!check_rights(R_ADMIN))
+			return
+		var/datum/datum_to_remove = locate(href_list["del_tag"])
+		if(!datum_to_remove)
+			return
+		return remove_tagged_datum(datum_to_remove)
+
+	else if(href_list["show_tags"])
+		if(!check_rights(R_ADMIN))
+			return
+		return display_tags()
+
+	else if(href_list["mark_datum"])
+		if(!check_rights(R_ADMIN))
+			return
+		var/datum/datum_to_mark = locate(href_list["mark_datum"])
+		if(!datum_to_mark)
+			return
+		return usr.client?.mark_datum(datum_to_mark)

code/modules/admin/view_variables/get_variables.dm

@@ -85,6 +85,15 @@
 			markstring = "[VV_MARKED_DATUM] (CURRENT: [(istype(holder) && istype(holder.marked_datum))? holder.marked_datum.type : "NULL"])"
 			classes += markstring
 
+		var/list/tagstrings = new
+		if(!(VV_TAGGED_DATUM in restricted_classes) && holder && LAZYLEN(holder.tagged_datums))
+			var/i = 0
+			for(var/datum/iter_tagged_datum as anything in holder.tagged_datums)
+				i++
+				var/new_tagstring = "[VV_TAGGED_DATUM] #[i]: [iter_tagged_datum.type])"
+				tagstrings[new_tagstring] = iter_tagged_datum
+				classes += new_tagstring
+
 		if(restricted_classes)
 			classes -= restricted_classes
 
@@ -95,6 +104,12 @@
 		if(holder && holder.marked_datum && .["class"] == markstring)
 			.["class"] = VV_MARKED_DATUM
 
+		if(holder && tagstrings[.["class"]])
+			var/datum/chosen_datum = tagstrings[.["class"]]
+			.["value"] = chosen_datum
+			.["class"] = VV_TAGGED_DATUM
+
+
 	switch(.["class"])
 		if(VV_TEXT)
 			.["value"] = input("Enter new text:", "Text", current_value) as null|text
@@ -210,6 +225,11 @@
 				.["class"] = null
 				return
 
+		if(VV_TAGGED_DATUM)
+			if(.["value"] == null)
+				.["class"] = null
+				return
+
 		if(VV_PROCCALL_RETVAL)
 			var/list/get_retval = list()
 			callproc_blocking(get_retval)

code/modules/admin/view_variables/tag_datum.dm

@@ -0,0 +1,18 @@
+/client/proc/tag_datum(datum/target_datum)
+	if(!holder || QDELETED(target_datum))
+		return
+	holder.add_tagged_datum(target_datum)
+
+/client/proc/toggle_tag_datum(datum/target_datum)
+	if(!holder || !target_datum)
+		return
+
+	if(LAZYFIND(holder.tagged_datums, target_datum))
+		holder.remove_tagged_datum(target_datum)
+	else
+		holder.add_tagged_datum(target_datum)
+
+/client/proc/tag_datum_mapview(datum/target_datum as mob|obj|turf|area in view(view))
+	set category = "Debug"
+	set name = "Tag Datum"
+	tag_datum(target_datum)

code/modules/admin/view_variables/topic_basic.dm

@@ -50,6 +50,8 @@
 
 	if(href_list[VV_HK_MARK])
 		usr.client.mark_datum(target)
+	if(href_list[VV_HK_TAG])
+		usr.client.tag_datum(target)
 	if(href_list[VV_HK_ADDCOMPONENT])
 		if(!check_rights(NONE))
 			return