tgui: Stacking Machine Console and Safe UI fix (#55171)

This PR refactors Stacking Machine Console from using html based UI to tgui with some code cleanup and documentation. Also fixes a bug I noticed when using Stacking Machine Console - some materials could get stuck there if they were number subtypes (for example /obj/item/stack/sheet/metal/twenty), because console did not check for their merge_type for releasing like stacking machine itself does when the sheet is put inside. This is fixed now.

Also fixes a small safe UI bug, where some buttons could be hard to press due to the dialer image being too close to the buttons. Bundling this together to prevent merge conflicts with other tgui PRs. Fixes #55169

code/modules/mining/machine_stacking.dm

@@ -7,7 +7,9 @@
 	desc = "Controls a stacking machine... in theory."
 	density = FALSE
 	circuit = /obj/item/circuitboard/machine/stacking_unit_console
+	/// Connected stacking machine
 	var/obj/machinery/mineral/stacking_machine/machine
+	/// Direction for which console looks for stacking machine to connect to
 	var/machinedir = SOUTHEAST
 
 /obj/machinery/mineral/stacking_unit_console/Initialize()
@@ -16,27 +18,6 @@
 	if (machine)
 		machine.CONSOLE = src
 
-/obj/machinery/mineral/stacking_unit_console/ui_interact(mob/user)
-	. = ..()
-
-	if(!machine)
-		to_chat(user, "<span class='notice'>[src] is not linked to a machine!</span>")
-		return
-
-	var/obj/item/stack/sheet/s
-	var/dat
-
-	dat += text("<b>Stacking unit console</b><br><br>")
-
-	for(var/O in machine.stack_list)
-		s = machine.stack_list[O]
-		if(s.amount > 0)
-			dat += text("[capitalize(s.name)]: [s.amount] <A href='?src=[REF(src)];release=[s.type]'>Release</A><br>")
-
-	dat += text("<br>Stacking: [machine.stack_amt]<br><br>")
-
-	user << browse(dat, "window=console_stacking_machine")
-
 /obj/machinery/mineral/stacking_unit_console/multitool_act(mob/living/user, obj/item/I)
 	if(!multitool_check_buffer(user, I))
 		return
@@ -45,22 +26,45 @@
 	to_chat(user, "<span class='notice'>You store linkage information in [I]'s buffer.</span>")
 	return TRUE
 
-/obj/machinery/mineral/stacking_unit_console/Topic(href, href_list)
-	if(..())
+/obj/machinery/mineral/stacking_unit_console/ui_interact(mob/user, datum/tgui/ui)
+	ui = SStgui.try_update_ui(user, src, ui)
+	if(!ui)
+		ui = new(user, src, "StackingConsole", name)
+		ui.open()
+
+/obj/machinery/mineral/stacking_unit_console/ui_data(mob/user)
+	var/list/data = list()
+	data["machine"] = machine ? TRUE : FALSE
+	data["stacking_amount"] = null
+	data["contents"] = list()
+	if(machine)
+		data["stacking_amount"] = machine.stack_amt
+		for(var/stack_type in machine.stack_list)
+			var/obj/item/stack/sheet/stored_sheet = machine.stack_list[stack_type]
+			if(stored_sheet.amount <= 0)
+				continue
+			data["contents"] += list(list(
+				"type" = stored_sheet.type,
+				"name" = capitalize(stored_sheet.name),
+				"amount" = stored_sheet.amount,
+			))
+	return data
+
+/obj/machinery/mineral/stacking_unit_console/ui_act(action, list/params)
+	. = ..()
+	if(.)
 		return
-	usr.set_machine(src)
-	src.add_fingerprint(usr)
-	if(href_list["release"])
-		if(!(text2path(href_list["release"]) in machine.stack_list))
-			return //someone tried to spawn materials by spoofing hrefs
-		var/obj/item/stack/sheet/inp = machine.stack_list[text2path(href_list["release"])]
-		var/obj/item/stack/sheet/out = new inp.type(null, inp.amount)
-		inp.amount = 0
-		machine.unload_mineral(out)
-
-	src.updateUsrDialog()
-	return
 
+	switch(action)
+		if("release")
+			var/obj/item/stack/sheet/released_type = text2path(params["type"])
+			if(!released_type || !(initial(released_type.merge_type) in machine.stack_list))
+				return //someone tried to spawn materials by spoofing hrefs
+			var/obj/item/stack/sheet/inp = machine.stack_list[initial(released_type.merge_type)]
+			var/obj/item/stack/sheet/out = new inp.type(null, inp.amount)
+			inp.amount = 0
+			machine.unload_mineral(out)
+			return TRUE
 
 /**********************Mineral stacking unit**************************/