tgui: Remote Robot Control (#49622)

This PR converts AI's Remote Robot Control from html based interface to tgui with some tweaks and improvements.

code/modules/mob/living/silicon/ai/ai.dm

@@ -98,6 +98,8 @@
 	var/list/cam_hotkeys = new/list(9)
 	var/cam_prev
 
+	var/datum/robot_control/robot_control
+
 /mob/living/silicon/ai/Initialize(mapload, datum/ai_laws/L, mob/target_ai)
 	. = ..()
 	if(!target_ai) //If there is no player/brain inside.
@@ -414,25 +416,6 @@
 		else
 			to_chat(src, "Target is not on or near any active cameras on the station.")
 		return
-	if(href_list["callbot"]) //Command a bot to move to a selected location.
-		if(call_bot_cooldown > world.time)
-			to_chat(src, "<span class='danger'>Error: Your last call bot command is still processing, please wait for the bot to finish calculating a route.</span>")
-			return
-		Bot = locate(href_list["callbot"]) in GLOB.alive_mob_list
-		if(!Bot || Bot.remote_disabled || control_disabled)
-			return //True if there is no bot found, the bot is manually emagged, or the AI is carded with wireless off.
-		waypoint_mode = 1
-		to_chat(src, "<span class='notice'>Set your waypoint by clicking on a valid location free of obstructions.</span>")
-		return
-	if(href_list["interface"]) //Remotely connect to a bot!
-		Bot = locate(href_list["interface"]) in GLOB.alive_mob_list
-		if(!Bot || Bot.remote_disabled || control_disabled)
-			return
-		Bot.attack_ai(src)
-	if(href_list["botrefresh"]) //Refreshes the bot control panel.
-		botcall()
-		return
-
 	if (href_list["ai_take_control"]) //Mech domination
 		var/obj/mecha/M = locate(href_list["ai_take_control"]) in GLOB.mechas_list
 		if (!M)
@@ -478,33 +461,11 @@
 	set category = "AI Commands"
 	set name = "Access Robot Control"
 	set desc = "Wirelessly control various automatic robots."
-	if(incapacitated())
-		return
 
-	if(control_disabled)
-		to_chat(src, "<span class='warning'>Wireless control is disabled.</span>")
-		return
-	var/turf/ai_current_turf = get_turf(src)
-	var/ai_Zlevel = ai_current_turf.z
-	var/d
-	d += "<A HREF=?src=[REF(src)];botrefresh=1>Query network status</A><br>"
-	d += "<table width='100%'><tr><td width='40%'><h3>Name</h3></td><td width='30%'><h3>Status</h3></td><td width='30%'><h3>Location</h3></td><td width='10%'><h3>Control</h3></td></tr>"
+	if(!robot_control)
+		robot_control = new(src)
 
-	for (Bot in GLOB.alive_mob_list)
-		if(Bot.z == ai_Zlevel && !Bot.remote_disabled) //Only non-emagged bots on the same Z-level are detected!
-			var/bot_mode = Bot.get_mode()
-			d += "<tr><td width='30%'>[Bot.hacked ? "<span class='bad'>(!)</span>" : ""] [Bot.name]</A> ([Bot.model])</td>"
-			//If the bot is on, it will display the bot's current mode status. If the bot is not mode, it will just report "Idle". "Inactive if it is not on at all.
-			d += "<td width='30%'>[bot_mode]</td>"
-			d += "<td width='30%'>[get_area_name(Bot, TRUE)]</td>"
-			d += "<td width='10%'><A HREF=?src=[REF(src)];interface=[REF(Bot)]>Interface</A></td>"
-			d += "<td width='10%'><A HREF=?src=[REF(src)];callbot=[REF(Bot)]>Call</A></td>"
-			d += "</tr>"
-			d = format_text(d)
-
-	var/datum/browser/popup = new(src, "botcall", "Remote Robot Control", 700, 400)
-	popup.set_content(d)
-	popup.open()
+	robot_control.ui_interact(src)
 
 /mob/living/silicon/ai/proc/set_waypoint(atom/A)
 	var/turf/turf_check = get_turf(A)
@@ -529,7 +490,6 @@
 	Bot.call_bot(src, waypoint)
 	call_bot_cooldown = 0
 
-
 /mob/living/silicon/ai/triggerAlarm(class, area/A, O, obj/alarmsource)
 	if(alarmsource.z != z)
 		return

code/modules/mob/living/silicon/ai/robot_control.dm

@@ -0,0 +1,74 @@
+/datum/robot_control
+	var/mob/living/silicon/ai/owner
+
+/datum/robot_control/New(mob/living/silicon/ai/new_owner)
+	if(!istype(new_owner))
+		qdel(src)
+	owner = new_owner
+
+/datum/robot_control/proc/is_interactable(mob/user)
+	if(user != owner || owner.incapacitated())
+		return FALSE
+	if(owner.control_disabled)
+		to_chat(user, "<span class='warning'>Wireless control is disabled.</span>")
+		return FALSE
+	return TRUE
+
+/datum/robot_control/ui_status(mob/user)
+	if(is_interactable(user))
+		return ..()
+	return UI_CLOSE
+
+/datum/robot_control/ui_interact(mob/user, ui_key = "main", datum/tgui/ui = null, force_open = FALSE, \
+							datum/tgui/master_ui = null, datum/ui_state/state = GLOB.always_state)
+	ui = SStgui.try_update_ui(user, src, ui_key, ui, force_open)
+	if(!ui)
+		ui = new(user, src, ui_key, "remote_robot_control", "Remote Robot Control", 500, 500, master_ui, state)
+		ui.open()
+
+/datum/robot_control/ui_data(mob/user)
+	if(!owner || user != owner)
+		return
+	var/list/data = list()
+	var/turf/ai_current_turf = get_turf(owner)
+	var/ai_zlevel = ai_current_turf.z
+
+	data["robots"] = list()
+	for(var/mob/living/simple_animal/bot/B in GLOB.bots_list)
+		if(B.z != ai_zlevel || B.remote_disabled) //Only non-emagged bots on the same Z-level are detected!
+			continue
+		var/list/robot_data = list(
+			name = B.name,
+			model = B.model,
+			mode = B.get_mode(),
+			hacked = B.hacked,
+			location = get_area_name(B, TRUE),
+			ref = REF(B)
+		)
+		data["robots"] += list(robot_data)
+
+	return data
+
+/datum/robot_control/ui_act(action, params)
+	if(..())
+		return
+	if(!is_interactable(usr))
+		return
+
+	switch(action)
+		if("callbot") //Command a bot to move to a selected location.
+			if(owner.call_bot_cooldown > world.time)
+				to_chat(usr, "<span class='danger'>Error: Your last call bot command is still processing, please wait for the bot to finish calculating a route.</span>")
+				return
+			owner.Bot = locate(params["ref"]) in GLOB.bots_list
+			if(!owner.Bot || owner.Bot.remote_disabled || owner.control_disabled)
+				return
+			owner.waypoint_mode = TRUE
+			to_chat(usr, "<span class='notice'>Set your waypoint by clicking on a valid location free of obstructions.</span>")
+			. = TRUE
+		if("interface") //Remotely connect to a bot!
+			owner.Bot = locate(params["ref"]) in GLOB.bots_list
+			if(!owner.Bot || owner.Bot.remote_disabled || owner.control_disabled)
+				return
+			owner.Bot.attack_ai(usr)
+			. = TRUE