mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-08-22 04:30:44 +01:00
[MIRROR] BCI overlays and click interception (#7319)
* BCI overlays and click interception (#60503) * BCI overlays and click interception Co-authored-by: SmArtKar <44720187+SmArtKar@users.noreply.github.com>
This commit is contained in:
SkyratBot
@@ -0,0 +1,60 @@
|
||||
/**
|
||||
* # Bar Overlay Component
|
||||
*
|
||||
* Basically an advanced verion of object overlay component that shows a horizontal/vertical bar.
|
||||
* Requires a BCI shell.
|
||||
*/
|
||||
|
||||
#define BAR_OVERLAY_LIMIT 10
|
||||
|
||||
/obj/item/circuit_component/object_overlay/bar
|
||||
display_name = "Bar Overlay"
|
||||
desc = "Requires a BCI shell. A component that shows a bar overlay ontop of an object from a range of 0 to 100."
|
||||
|
||||
var/datum/port/input/bar_number
|
||||
|
||||
/obj/item/circuit_component/object_overlay/bar/Initialize()
|
||||
. = ..()
|
||||
bar_number = add_input_port("Number", PORT_TYPE_NUMBER)
|
||||
|
||||
/obj/item/circuit_component/object_overlay/bar/populate_options()
|
||||
var/static/component_options_bar = list(
|
||||
"Vertical",
|
||||
"Horizontal"
|
||||
)
|
||||
options = component_options_bar
|
||||
|
||||
var/static/options_to_icons_bar = list(
|
||||
"Vertical" = "barvert",
|
||||
"Horizontal" = "barhoriz"
|
||||
)
|
||||
options_map = options_to_icons_bar
|
||||
|
||||
/obj/item/circuit_component/object_overlay/bar/show_to_owner(atom/target_atom, mob/living/owner)
|
||||
if(LAZYLEN(active_overlays) >= BAR_OVERLAY_LIMIT)
|
||||
return
|
||||
|
||||
if(active_overlays[target_atom])
|
||||
QDEL_NULL(active_overlays[target_atom])
|
||||
|
||||
var/number_clear = clamp(bar_number.input_value, 0, 100)
|
||||
if(current_option == "Horizontal")
|
||||
number_clear = round(number_clear / 6.25) * 6.25
|
||||
else if(current_option == "Vertical")
|
||||
number_clear = round(number_clear / 10) * 10
|
||||
var/image/cool_overlay = image(icon = 'icons/hud/screen_bci.dmi', loc = target_atom, icon_state = "[options_map[current_option]][number_clear]", layer = RIPPLE_LAYER)
|
||||
|
||||
if(image_pixel_x.input_value)
|
||||
cool_overlay.pixel_x = image_pixel_x.input_value
|
||||
|
||||
if(image_pixel_y.input_value)
|
||||
cool_overlay.pixel_y = image_pixel_y.input_value
|
||||
|
||||
active_overlays[target_atom] = WEAKREF(target_atom.add_alt_appearance(
|
||||
/datum/atom_hud/alternate_appearance/basic/one_person,
|
||||
"bar_overlay_[REF(src)]",
|
||||
cool_overlay,
|
||||
owner,
|
||||
))
|
||||
|
||||
#undef BAR_OVERLAY_LIMIT
|
||||
@@ -0,0 +1,102 @@
|
||||
/**
|
||||
* # Counter Overlay Component
|
||||
*
|
||||
* Shows an counter overlay.
|
||||
* Requires a BCI shell.
|
||||
*/
|
||||
|
||||
/obj/item/circuit_component/counter_overlay
|
||||
display_name = "Counter Overlay"
|
||||
desc = "A component that shows an three digit counter. Requires a BCI shell."
|
||||
|
||||
required_shells = list(/obj/item/organ/cyberimp/bci)
|
||||
|
||||
var/datum/port/input/counter_number
|
||||
|
||||
var/datum/port/input/image_pixel_x
|
||||
var/datum/port/input/image_pixel_y
|
||||
|
||||
var/datum/port/input/signal_update
|
||||
|
||||
var/obj/item/organ/cyberimp/bci/bci
|
||||
var/list/numbers = list()
|
||||
var/counter_appearance
|
||||
|
||||
/obj/item/circuit_component/counter_overlay/Initialize()
|
||||
. = ..()
|
||||
counter_number = add_input_port("Displayed Number", PORT_TYPE_NUMBER)
|
||||
|
||||
signal_update = add_input_port("Update Overlay", PORT_TYPE_SIGNAL)
|
||||
|
||||
image_pixel_x = add_input_port("X-Axis Shift", PORT_TYPE_NUMBER)
|
||||
image_pixel_y = add_input_port("Y-Axis Shift", PORT_TYPE_NUMBER)
|
||||
|
||||
/obj/item/circuit_component/counter_overlay/register_shell(atom/movable/shell)
|
||||
bci = shell
|
||||
RegisterSignal(shell, COMSIG_ORGAN_REMOVED, .proc/on_organ_removed)
|
||||
|
||||
/obj/item/circuit_component/counter_overlay/unregister_shell(atom/movable/shell)
|
||||
bci = null
|
||||
QDEL_NULL(counter_appearance)
|
||||
for(var/number in numbers)
|
||||
QDEL_NULL(number)
|
||||
UnregisterSignal(shell, COMSIG_ORGAN_REMOVED)
|
||||
|
||||
/obj/item/circuit_component/counter_overlay/input_received(datum/port/input/port)
|
||||
. = ..()
|
||||
|
||||
if(. || !bci)
|
||||
return
|
||||
|
||||
var/mob/living/owner = bci.owner
|
||||
|
||||
if(!owner || !istype(owner) || !owner.client)
|
||||
return
|
||||
|
||||
for(var/number in numbers)
|
||||
QDEL_NULL(number)
|
||||
numbers = list()
|
||||
|
||||
QDEL_NULL(counter_appearance)
|
||||
var/image/counter = image(icon = 'icons/hud/screen_bci.dmi', icon_state = "hud_numbers", loc = owner)
|
||||
if(image_pixel_x.input_value)
|
||||
counter.pixel_x = image_pixel_x.input_value
|
||||
if(image_pixel_y.input_value)
|
||||
counter.pixel_y = image_pixel_y.input_value
|
||||
|
||||
counter_appearance = WEAKREF(owner.add_alt_appearance(
|
||||
/datum/atom_hud/alternate_appearance/basic/one_person,
|
||||
"counter_overlay_[REF(src)]",
|
||||
counter,
|
||||
owner,
|
||||
))
|
||||
|
||||
var/cleared_number = clamp(round(counter_number.input_value), 0, 999)
|
||||
|
||||
for(var/i = 1 to 3)
|
||||
var/cur_num = round(cleared_number / (10 ** (3 - i))) % 10
|
||||
var/image/number = image(icon = 'icons/hud/screen_bci.dmi', icon_state = "hud_number_[cur_num]", loc = owner)
|
||||
|
||||
if(image_pixel_x.input_value)
|
||||
number.pixel_x = image_pixel_x.input_value + (i - 1) * 9
|
||||
if(image_pixel_y.input_value)
|
||||
number.pixel_y = image_pixel_y.input_value
|
||||
|
||||
numbers.Add(WEAKREF(owner.add_alt_appearance(
|
||||
/datum/atom_hud/alternate_appearance/basic/one_person,
|
||||
"counter_overlay_[REF(src)]_[i]",
|
||||
number,
|
||||
owner,
|
||||
)))
|
||||
|
||||
/obj/item/circuit_component/counter_overlay/proc/on_organ_removed(datum/source, mob/living/carbon/owner)
|
||||
SIGNAL_HANDLER
|
||||
QDEL_NULL(counter_appearance)
|
||||
for(var/number in numbers)
|
||||
QDEL_NULL(number)
|
||||
|
||||
/obj/item/circuit_component/counter_overlay/Destroy()
|
||||
QDEL_NULL(counter_appearance)
|
||||
for(var/number in numbers)
|
||||
QDEL_NULL(number)
|
||||
return ..()
|
||||
@@ -0,0 +1,132 @@
|
||||
/**
|
||||
* # Object Overlay Component
|
||||
*
|
||||
* Shows an overlay ontop of an object. Toggleable.
|
||||
* Requires a BCI shell.
|
||||
*/
|
||||
|
||||
#define OBJECT_OVERLAY_LIMIT 10
|
||||
|
||||
/obj/item/circuit_component/object_overlay
|
||||
display_name = "Object Overlay"
|
||||
desc = "Requires a BCI shell. A component that shows an overlay on top of an object."
|
||||
|
||||
required_shells = list(/obj/item/organ/cyberimp/bci)
|
||||
|
||||
/// Target atom
|
||||
var/datum/port/input/target
|
||||
|
||||
var/datum/port/input/image_pixel_x
|
||||
var/datum/port/input/image_pixel_y
|
||||
|
||||
/// On/Off signals
|
||||
var/datum/port/input/signal_on
|
||||
var/datum/port/input/signal_off
|
||||
|
||||
var/obj/item/organ/cyberimp/bci/bci
|
||||
var/list/active_overlays = list()
|
||||
var/list/options_map
|
||||
|
||||
/obj/item/circuit_component/object_overlay/Initialize()
|
||||
. = ..()
|
||||
target = add_input_port("Target", PORT_TYPE_ATOM)
|
||||
|
||||
signal_on = add_input_port("Create Overlay", PORT_TYPE_SIGNAL)
|
||||
signal_off = add_input_port("Remove Overlay", PORT_TYPE_SIGNAL)
|
||||
|
||||
image_pixel_x = add_input_port("X-Axis Shift", PORT_TYPE_NUMBER)
|
||||
image_pixel_y = add_input_port("Y-Axis Shift", PORT_TYPE_NUMBER)
|
||||
|
||||
/obj/item/circuit_component/object_overlay/Destroy()
|
||||
for(var/active_overlay in active_overlays)
|
||||
QDEL_NULL(active_overlay)
|
||||
return ..()
|
||||
|
||||
/obj/item/circuit_component/object_overlay/populate_options()
|
||||
var/static/component_options = list(
|
||||
"Corners (Blue)",
|
||||
"Corners (Red)",
|
||||
"Circle (Blue)",
|
||||
"Circle (Red)",
|
||||
"Small Corners (Blue)",
|
||||
"Small Corners (Red)",
|
||||
"Triangle (Blue)",
|
||||
"Triangle (Red)",
|
||||
"HUD mark (Blue)",
|
||||
"HUD mark (Red)"
|
||||
)
|
||||
options = component_options
|
||||
|
||||
var/static/options_to_icons = list(
|
||||
"Corners (Blue)" = "hud_corners",
|
||||
"Corners (Red)" = "hud_corners_red",
|
||||
"Circle (Blue)" = "hud_circle",
|
||||
"Circle (Red)" = "hud_circle_red",
|
||||
"Small Corners (Blue)" = "hud_corners_small",
|
||||
"Small Corners (Red)" = "hud_corners_small_red",
|
||||
"Triangle (Blue)" = "hud_triangle",
|
||||
"Triangle (Red)" = "hud_triangle_red",
|
||||
"HUD mark (Blue)" = "hud_mark",
|
||||
"HUD mark (Red)" = "hud_mark_red"
|
||||
)
|
||||
options_map = options_to_icons
|
||||
|
||||
/obj/item/circuit_component/object_overlay/register_shell(atom/movable/shell)
|
||||
bci = shell
|
||||
RegisterSignal(shell, COMSIG_ORGAN_REMOVED, .proc/on_organ_removed)
|
||||
|
||||
/obj/item/circuit_component/object_overlay/unregister_shell(atom/movable/shell)
|
||||
bci = null
|
||||
UnregisterSignal(shell, COMSIG_ORGAN_REMOVED)
|
||||
|
||||
/obj/item/circuit_component/object_overlay/input_received(datum/port/input/port)
|
||||
. = ..()
|
||||
|
||||
if(. || !bci)
|
||||
return
|
||||
|
||||
var/mob/living/owner = bci.owner
|
||||
var/atom/target_atom = target.input_value
|
||||
|
||||
if(!owner || !istype(owner) || !owner.client || !target_atom)
|
||||
return
|
||||
|
||||
if(COMPONENT_TRIGGERED_BY(signal_on, port))
|
||||
show_to_owner(target_atom, owner)
|
||||
|
||||
if(COMPONENT_TRIGGERED_BY(signal_off, port) && (target_atom in active_overlays))
|
||||
QDEL_NULL(active_overlays[target_atom])
|
||||
active_overlays.Remove(target_atom)
|
||||
|
||||
/obj/item/circuit_component/object_overlay/proc/show_to_owner(atom/target_atom, mob/living/owner)
|
||||
if(LAZYLEN(active_overlays) >= OBJECT_OVERLAY_LIMIT)
|
||||
return
|
||||
|
||||
if(active_overlays[target_atom])
|
||||
QDEL_NULL(active_overlays[target_atom])
|
||||
|
||||
var/image/cool_overlay = image(icon = 'icons/hud/screen_bci.dmi', loc = target_atom, icon_state = options_map[current_option], layer = RIPPLE_LAYER)
|
||||
|
||||
if(image_pixel_x.input_value)
|
||||
cool_overlay.pixel_x = image_pixel_x.input_value
|
||||
|
||||
if(image_pixel_y.input_value)
|
||||
cool_overlay.pixel_y = image_pixel_y.input_value
|
||||
|
||||
var/alt_appearance = WEAKREF(target_atom.add_alt_appearance(
|
||||
/datum/atom_hud/alternate_appearance/basic/one_person,
|
||||
"object_overlay_[REF(src)]",
|
||||
cool_overlay,
|
||||
owner,
|
||||
))
|
||||
|
||||
active_overlays[target_atom] = alt_appearance
|
||||
|
||||
/obj/item/circuit_component/object_overlay/proc/on_organ_removed(datum/source, mob/living/carbon/owner)
|
||||
SIGNAL_HANDLER
|
||||
|
||||
for(var/atom/target_atom in active_overlays)
|
||||
QDEL_NULL(active_overlays[target_atom])
|
||||
active_overlays.Remove(target_atom)
|
||||
|
||||
#undef OBJECT_OVERLAY_LIMIT
|
||||
@@ -0,0 +1,64 @@
|
||||
/**
|
||||
* # Target Intercept Component
|
||||
*
|
||||
* When activated intercepts next click and outputs clicked atom.
|
||||
* Requires a BCI shell.
|
||||
*/
|
||||
|
||||
/obj/item/circuit_component/target_intercept
|
||||
display_name = "Target Intercept"
|
||||
desc = "Requires a BCI shell. When activated, this component will allow user to target an object using their brain and will output the reference to said object."
|
||||
|
||||
required_shells = list(/obj/item/organ/cyberimp/bci)
|
||||
|
||||
var/datum/port/output/clicked_atom
|
||||
|
||||
var/obj/item/organ/cyberimp/bci/bci
|
||||
var/intercept_cooldown = 1 SECONDS
|
||||
|
||||
/obj/item/circuit_component/target_intercept/Initialize()
|
||||
. = ..()
|
||||
trigger_input = add_input_port("Activate", PORT_TYPE_SIGNAL)
|
||||
trigger_output = add_output_port("Triggered", PORT_TYPE_SIGNAL)
|
||||
clicked_atom = add_output_port("Targeted Object", PORT_TYPE_ATOM)
|
||||
|
||||
/obj/item/circuit_component/target_intercept/register_shell(atom/movable/shell)
|
||||
bci = shell
|
||||
RegisterSignal(shell, COMSIG_ORGAN_REMOVED, .proc/on_organ_removed)
|
||||
|
||||
/obj/item/circuit_component/target_intercept/unregister_shell(atom/movable/shell)
|
||||
bci = null
|
||||
UnregisterSignal(shell, COMSIG_ORGAN_REMOVED)
|
||||
|
||||
/obj/item/circuit_component/target_intercept/input_received(datum/port/input/port)
|
||||
. = ..()
|
||||
|
||||
if(. || !bci)
|
||||
return
|
||||
|
||||
var/mob/living/owner = bci.owner
|
||||
if(!owner || !istype(owner) || !owner.client)
|
||||
return
|
||||
|
||||
if(TIMER_COOLDOWN_CHECK(parent, COOLDOWN_CIRCUIT_TARGET_INTERCEPT))
|
||||
return
|
||||
|
||||
to_chat(owner, "<B>Left-click to trigger target interceptor!</B>")
|
||||
owner.client.click_intercept = src
|
||||
|
||||
/obj/item/circuit_component/target_intercept/proc/on_organ_removed(datum/source, mob/living/carbon/owner)
|
||||
SIGNAL_HANDLER
|
||||
|
||||
if(owner.client && owner.client.click_intercept == src)
|
||||
owner.client.click_intercept = null
|
||||
|
||||
/obj/item/circuit_component/target_intercept/proc/InterceptClickOn(mob/user, params, atom/object)
|
||||
user.client.click_intercept = null
|
||||
clicked_atom.set_output(object)
|
||||
trigger_output.set_output(COMPONENT_SIGNAL)
|
||||
TIMER_COOLDOWN_START(parent, COOLDOWN_CIRCUIT_TARGET_INTERCEPT, intercept_cooldown)
|
||||
|
||||
/obj/item/circuit_component/target_intercept/get_ui_notices()
|
||||
. = ..()
|
||||
. += create_ui_notice("Target Interception Cooldown: [DisplayTimeText(intercept_cooldown)]", "orange", "stopwatch")
|
||||
. += create_ui_notice("Only usable in BCI circuits", "orange", "info")
|
||||
Reference in New Issue
Block a user