[MIRROR] More circuit components. Restructures the circuit components folder to be more organised. (#6142)

* More circuit components. Restructures the circuit components folder to be more organised.

* Mirror!

Co-authored-by: Watermelon914 <37270891+Watermelon914@users.noreply.github.com>
Co-authored-by: Funce <funce.973@gmail.com>

code/modules/wiremod/components/string/concat.dm

@@ -0,0 +1,45 @@
+/**
+ * # Concatenate Component
+ *
+ * General string concatenation component. Puts strings together.
+ */
+/obj/item/circuit_component/concat
+	display_name = "Concatenate"
+
+	/// The amount of input ports to have
+	var/input_port_amount = 4
+
+	/// The result from the output
+	var/datum/port/output/output
+	circuit_flags = CIRCUIT_FLAG_INPUT_SIGNAL|CIRCUIT_FLAG_OUTPUT_SIGNAL
+
+/obj/item/circuit_component/concat/Initialize()
+	. = ..()
+	for(var/port_id in 1 to input_port_amount)
+		var/letter = ascii2text(text2ascii("A") + (port_id-1))
+		add_input_port(letter, PORT_TYPE_STRING)
+
+	output = add_output_port("Output", PORT_TYPE_STRING)
+
+/obj/item/circuit_component/concat/Destroy()
+	output = null
+	return ..()
+
+/obj/item/circuit_component/concat/input_received(datum/port/input/port)
+	. = ..()
+	if(.)
+		return
+
+	var/result = ""
+	var/list/ports = input_ports.Copy()
+	ports -= trigger_input
+
+	for(var/datum/port/input/input_port as anything in ports)
+		var/value = input_port.input_value
+		if(isnull(value))
+			continue
+
+		result += "[value]"
+
+	output.set_output(result)
+

code/modules/wiremod/components/string/contains.dm

@@ -0,0 +1,34 @@
+/**
+ * # String Contains Component
+ *
+ * Checks if a string contains a word/letter
+ */
+/obj/item/circuit_component/compare/contains
+	display_name = "String Contains"
+
+	input_port_amount = 0
+
+	var/datum/port/input/needle
+	var/datum/port/input/haystack
+
+/obj/item/circuit_component/compare/contains/load_custom_ports()
+	needle = add_input_port("Needle", PORT_TYPE_STRING)
+	haystack = add_input_port("Haystack", PORT_TYPE_STRING)
+
+/obj/item/circuit_component/compare/contains/Destroy()
+	needle = null
+	haystack = null
+	return ..()
+
+
+/obj/item/circuit_component/compare/contains/do_comparisons(list/ports)
+	if(length(ports) < input_port_amount)
+		return
+
+	var/to_find = needle.input_value
+	var/to_search = haystack.input_value
+
+	if(!to_find || !to_search)
+		return
+
+	return findtext(to_search, to_find)

code/modules/wiremod/components/string/textcase.dm

@@ -0,0 +1,50 @@
+/**
+ * # Text Component
+ *
+ * Either makes the text upper case or lower case.
+ */
+/obj/item/circuit_component/textcase
+	display_name = "Text Case"
+
+	/// The input port
+	var/datum/port/input/input_port
+
+	/// The result of the text operation
+	var/datum/port/output/output
+
+	circuit_flags = CIRCUIT_FLAG_INPUT_SIGNAL|CIRCUIT_FLAG_OUTPUT_SIGNAL
+
+GLOBAL_LIST_INIT(comp_text_operations, list(
+	COMP_TEXT_LOWER,
+	COMP_TEXT_UPPER
+))
+
+/obj/item/circuit_component/textcase/Initialize()
+	options = GLOB.comp_text_operations
+	. = ..()
+	input_port = add_input_port("Input", PORT_TYPE_STRING)
+	output = add_output_port("Output", PORT_TYPE_STRING)
+
+/obj/item/circuit_component/textcase/Destroy()
+	input_port = null
+	output = null
+	return ..()
+
+/obj/item/circuit_component/textcase/input_received(datum/port/input/port)
+	. = ..()
+	if(.)
+		return
+
+	var/value = input_port.input_value
+	if(isnull(value))
+		return
+
+	var/result
+	switch(current_option)
+		if(COMP_TEXT_LOWER)
+			result = lowertext(value)
+		if(COMP_TEXT_UPPER)
+			result = uppertext(value)
+
+	output.set_output(result)
+

code/modules/wiremod/components/string/tostring.dm

@@ -0,0 +1,44 @@
+/**
+ * # To String Component
+ *
+ * Converts any value into a string
+ */
+/obj/item/circuit_component/tostring
+	display_name = "To String"
+
+	/// The input port
+	var/datum/port/input/input_port
+
+	/// The result from the output
+	var/datum/port/output/output
+
+	circuit_flags = CIRCUIT_FLAG_INPUT_SIGNAL|CIRCUIT_FLAG_OUTPUT_SIGNAL
+
+	var/max_range = 5
+
+/obj/item/circuit_component/tostring/Initialize()
+	. = ..()
+	input_port = add_input_port("Input", PORT_TYPE_ANY)
+
+	output = add_output_port("Output", PORT_TYPE_STRING)
+
+/obj/item/circuit_component/tostring/Destroy()
+	input_port = null
+	output = null
+	return ..()
+
+/obj/item/circuit_component/tostring/input_received(datum/port/input/port)
+	. = ..()
+	if(.)
+		return
+
+	var/input_value = input_port.input_value
+	if(isatom(input_value))
+		var/turf/location = get_turf(src)
+		var/atom/object = input_value
+		if(object.z != location.z || get_dist(location, object) > max_range)
+			output.set_output(PORT_TYPE_ATOM)
+			return
+
+	output.set_output("[input_value]")
+