[NO GBP] Renames mob/camera to mob/eye and makes everything follow suit (#87684)

## Why It's Good For The Game

Clarity and consistency regarding DM's systems. 
Internally, `eye` is used for anything that controls the client's view.

![image](https://github.com/user-attachments/assets/7d1291e1-7a6a-4736-a14b-97834e89846f)
How `eye` is used in DM is consistent with how we use the term, so I
figured this would add clarity.

Being named mob/camera also makes it unclear exactly what it's doing.
The name implies that it would function similar to how mob/camera/ai_eye
does, but most of the time it's only used as... an eye.

My ulterior reason for this PR is that I want to clean up
mob/camera/ai_eye and it's subtypes after this.
## Changelog

🆑
server: mob/camera has been renamed to mob/eye, which may break
downstreams
/🆑

---------

Co-authored-by: Ghom <42542238+Ghommie@users.noreply.github.com>

code/modules/mob/eye/eye.dm

@@ -0,0 +1,54 @@
+// Eye mob, used by cameras and overminds such as blobs.
+/mob/eye
+	name = "eye mob"
+	density = FALSE
+	move_force = INFINITY
+	move_resist = INFINITY
+	mouse_opacity = MOUSE_OPACITY_TRANSPARENT
+	invisibility = INVISIBILITY_ABSTRACT // No one can see us
+	sight = SEE_SELF
+	status_flags = NONE
+	/// Toggles if the camera can move on shuttles
+	var/move_on_shuttle = FALSE
+	/// Toggles if the camera can use emotes
+	var/has_emotes = FALSE
+
+/mob/eye/Initialize(mapload)
+	. = ..()
+	ADD_TRAIT(src, TRAIT_GODMODE, INNATE_TRAIT)
+	SSpoints_of_interest.make_point_of_interest(src)
+	if(!move_on_shuttle)
+		ADD_TRAIT(src, TRAIT_BLOCK_SHUTTLE_MOVEMENT, INNATE_TRAIT)
+
+/mob/eye/experience_pressure_difference()
+	return
+
+/mob/eye/canUseStorage()
+	return FALSE
+
+/mob/eye/up()
+	set name = "Move Upwards"
+	set category = "IC"
+
+	if(zMove(UP, z_move_flags = ZMOVE_FEEDBACK))
+		to_chat(src, span_notice("You move upwards."))
+
+/mob/eye/down()
+	set name = "Move Down"
+	set category = "IC"
+
+	if(zMove(DOWN, z_move_flags = ZMOVE_FEEDBACK))
+		to_chat(src, span_notice("You move down."))
+
+/mob/eye/can_z_move(direction, turf/start, turf/destination, z_move_flags = NONE, mob/living/rider)
+	z_move_flags |= ZMOVE_IGNORE_OBSTACLES  //cameras do not respect these FLOORS you speak so much of
+	return ..()
+
+/mob/eye/emote(act, m_type=1, message = null, intentional = FALSE, force_silence = FALSE)
+	if(has_emotes)
+		return ..()
+	return FALSE
+
+/mob/eye/update_sight()
+	lighting_color_cutoffs = list(lighting_cutoff_red, lighting_cutoff_green, lighting_cutoff_blue)
+	return ..()