Makes railings good (#49171)

About The Pull Request

Makes rails functional in that they can be vaulted from either side, moved, and repaired. Still doesn't add a way to make them.
Why It's Good For The Game

make multiz great

Waiting/working on a few things for the map so I'm just atomizing the few things I'm sitting on so other map makers can take advantage of in the meantime.

code/game/objects/structures/fluff.dm

@@ -178,19 +178,6 @@
 	density = TRUE
 	deconstructible = FALSE
 
-/obj/structure/fluff/railing
-	name = "railing"
-	desc = "Basic railing meant to protect idiots like you from falling."
-	icon = 'icons/obj/fluff.dmi'
-	icon_state = "railing"
-	density = TRUE
-	anchored = TRUE
-	deconstructible = FALSE
-
-/obj/structure/fluff/railing/corner
-	icon_state = "railing_corner"
-	density = FALSE
-
 /obj/structure/fluff/beach_towel
 	name = "beach towel"
 	desc = "A towel decorated in various beach-themed designs."

code/game/objects/structures/railings.dm

@@ -0,0 +1,60 @@
+/obj/structure/railing
+	name = "railing"
+	desc = "Basic railing meant to protect idiots like you from falling."
+	icon = 'icons/obj/fluff.dmi'
+	icon_state = "railing"
+	density = TRUE
+	anchored = TRUE
+	climbable = TRUE
+
+/obj/structure/railing/corner //aesthetic corner sharp edges hurt oof ouch
+	icon_state = "railing_corner"
+	density = FALSE
+	climbable = FALSE
+
+/obj/structure/railing/attackby(obj/item/I, mob/living/user, params)
+	add_fingerprint(user)
+
+	if(I.tool_behaviour == TOOL_WELDER && user.a_intent == INTENT_HELP)
+		if(obj_integrity < max_integrity)
+			if(!I.tool_start_check(user, amount=0))
+				return
+
+			to_chat(user, "<span class='notice'>You begin repairing [src]...</span>")
+			if(I.use_tool(src, user, 40, volume=50))
+				obj_integrity = max_integrity
+				to_chat(user, "<span class='notice'>You repair [src].</span>")
+		else
+			to_chat(user, "<span class='warning'>[src] is already in good condition!</span>")
+		return
+
+	if(!(flags_1&NODECONSTRUCT_1))
+		if(I.tool_behaviour == TOOL_WRENCH)
+			to_chat(user, "<span class='notice'>You begin to [anchored ? "unfasten the railing from":"fasten the railing to"] the floor...</span>")
+			if(I.use_tool(src, user, volume = 75, extra_checks = CALLBACK(src, .proc/check_anchored, anchored)))
+				setAnchored(!anchored)
+				to_chat(user, "<span class='notice'>You [anchored ? "fasten the railing to":"unfasten the railing from"] the floor.</span>")
+			return
+
+/obj/structure/railing/proc/check_anchored(checked_anchored)
+	if(anchored == checked_anchored)
+		return TRUE
+
+/obj/structure/railing/CanPass(atom/movable/mover, turf/target)
+	..()
+	if(get_dir(loc, target) & dir)
+		return !density
+	return TRUE
+
+/obj/structure/railing/corner/CanPass()
+	..()
+	return TRUE
+
+/obj/structure/railing/CheckExit(atom/movable/O, turf/target)
+	..()
+	if(get_dir(loc, target) & dir)
+		return 0
+	return 1
+
+/obj/structure/railing/corner/CheckExit()
+	return 1