Heart Attacks are More Violent, and You Can Defib People Repeatedly to Fix Them Like in a Medical Daytime TV Show Drama (#89775)

## About The Pull Request

This overhauls nearly all aspects related to heart attacks, making them
more urgent and threatening. It also enables the use of defibrillators
for quicker, less invasive treatment of heart attacks.

They are now a status effect instead of a virus, with a fixed countdown
of about two and a half minutes before full stoppage. As this timer
counts down, symptoms steadily escalate from audio cues to suffocation
and dizziness. Through treatment, the countdown can be wound back and
eventually cured (or you can just swap the heart like usual. Boring!!).

### Treatment

Replacing the heart is no longer the *only* option for treatment. Now,
heart attacks can be cured with the use of a defib. Each shock will
rewind the countdown (and symptoms) heavily, curing it after 2-4 zaps in
quick succession. In lieu of a defib, most other shock sources will
work, albeit much less effectively.

So, if you're in security and *really* don't feel like going to medical,
you can just have your fellow officers taze you back to health!

![doctor
approved](https://github.com/user-attachments/assets/f633cb08-b7f7-4291-8c18-6fdea4e97c7a)

The emergency penthrite given after the attack has a new icon/message,
and is slightly less forgiving. You can still use it to shock yourself
back to life, still being a very risky move.

The heart attack doesn't manifest on medical HUDs immediately. It only
appears after the victim has reached stage 3 for the first time. At
stage 3, it's pretty apparent to both the victim and anyone around that
they're having a heart attack anyways, but until then it will be on the
victim to identify symptoms. Heart attacks will always be reported on
health analyzer scans, shown as the organ failing due to a myocardial
infarction and a tooltip suggesting defibs/other shocks to treat it.

This also adds two tips, for secoffs and medics, on how to treat a heart
attack.

Defibs also now use up charge for restarting a stopped heart, instead of
only when reviving a corpse.
## Why It's Good For The Game

Making heart attacks more of a threat gives way more weight to something
people should be afraid of, but aren't. Heart attacks fail to emulate
anything resembling a heart attack, to the point that it is lame and
dissapointing. They're an annoyance and a trip to the surgery room for
anyone familiar enough with the game. This iteration may be more
dangerous, but it's also more *exciting* (and can be treated faster).

Broadening the ways to treat a heart attack, or just stave off symptoms,
gives an amount of player agency over this threat. It may be more
urgent, but it doesn't mean it has to be a trip to medbay every time.
You can look for other ways to get zapped (security will help if asked,
I promise) or sandbox up your own solution.

Also, treating heart attacks with defib shocks just makes sense. Why do
we have to trash the whole heart? Usually after a heart attack it still
has like, a year or so of juice left before it quits for good.

More threatening heart attacks also further incentivize synthetic hearts
and working out, or any other clever ways of shielding oneself from an
attack (in case you're paranoid like that).

And lastly, the whole reason I started with this PR in the first place
-- I think it is a bit odd having heart attacks be handled as *diseases*
in the code. Status effects make more sense.
## Changelog
🆑 Rhials
balance: Heart attacks are now more violent and urgent. If you can hear
your own heartbeat and are short of breath, you should probably see a
doctor.
balance: Heart attacks can now be treated and eventually cured with
repeated defibrillation shocks.
balance: Heart attacks can now be treated and eventually cured with
repeated shocks from other sources.
/🆑

code/__DEFINES/dcs/signals/signals_medical.dm

@@ -13,6 +13,9 @@
 #define COMSIG_DEFIBRILLATOR_SUCCESS "defib_success"
 	// #define COMPONENT_DEFIB_STOP (1<<0) // Same return, to stop default defib handling
 
+/// From /obj/item/shockpaddles/proc/do_disarm(), sent to the shock-ee in non-revival scenarios: (obj/item/shockpaddles/source)
+#define COMSIG_HEARTATTACK_DEFIB "heartattack_defib"
+
 /// From /datum/surgery/can_start(): (mob/source, datum/surgery/surgery, mob/living/patient)
 #define COMSIG_SURGERY_STARTING "surgery_starting"
 	#define COMPONENT_CANCEL_SURGERY (1<<0)

code/__DEFINES/traits/declarations.dm

@@ -987,6 +987,8 @@ Remember to update _globalvars/traits.dm if you're adding/removing/renaming trai
 
 /// If present on a [/mob/living/carbon], will make them appear to have a medium level disease on health HUDs.
 #define TRAIT_DISEASELIKE_SEVERITY_MEDIUM "diseaselike_severity_medium"
+/// If present on a [/mob/living/carbon], will make them appear to have a dangerous level disease on health HUDs.
+#define TRAIT_DISEASELIKE_SEVERITY_HIGH "diseaselike_severity_high"
 
 /// trait denoting someone will crawl faster in soft crit
 #define TRAIT_TENACIOUS "tenacious"

code/_globalvars/traits/_traits.dm

@@ -234,6 +234,7 @@ GLOBAL_LIST_INIT(traits_by_type, list(
 		"TRAIT_DIAGNOSTIC_HUD" = TRAIT_DIAGNOSTIC_HUD,
 		"TRAIT_DISCOORDINATED_TOOL_USER" = TRAIT_DISCOORDINATED_TOOL_USER,
 		"TRAIT_DISEASELIKE_SEVERITY_MEDIUM" = TRAIT_DISEASELIKE_SEVERITY_MEDIUM,
+		"TRAIT_DISEASELIKE_SEVERITY_HIGH" = TRAIT_DISEASELIKE_SEVERITY_HIGH,
 		"TRAIT_DISFIGURED" = TRAIT_DISFIGURED,
 		"TRAIT_DISGUISED" = TRAIT_DISGUISED,
 		"TRAIT_DISPLAY_JOB_IN_BINARY" = TRAIT_DISPLAY_JOB_IN_BINARY,

code/datums/components/fearful/effects.dm

@@ -78,9 +78,7 @@
 		span_alert("The shadows begin to creep up from the corners of your vision, and then there is nothing..."),
 		span_hear("You hear something heavy collide with the ground."),
 	)
-	var/datum/disease/heart_failure/heart_attack = new(src)
-	heart_attack.stage_prob = 2 //Advances twice as fast
-	owner.ForceContractDisease(heart_attack)
+	owner.apply_status_effect(/datum/status_effect/heart_attack)
 	owner.Unconscious(20 SECONDS)
 
 /// Low chance to vomit when terrified, increases significantly during panic attacks

code/datums/diseases/heart_failure.dm

@@ -1,70 +0,0 @@
-/datum/disease/heart_failure
-	form = "Condition"
-	name = "Myocardial Infarction"
-	max_stages = 5
-	stage_prob = 1
-	cure_text = "Heart replacement surgery to cure. Defibrillation (or as a last resort, uncontrolled electric shocking) may also be effective after the onset of cardiac arrest. Penthrite can also mitigate cardiac arrest."
-	agent = "Shitty Heart"
-	viable_mobtypes = list(/mob/living/carbon/human)
-	spreading_modifier = 1
-	desc = "If left untreated the subject will die!"
-	severity = "Dangerous!"
-	disease_flags = CAN_CARRY|CAN_RESIST
-	spread_flags = DISEASE_SPREAD_NON_CONTAGIOUS
-	spread_text = "Organ failure"
-	visibility_flags = HIDDEN_PANDEMIC
-	required_organ = ORGAN_SLOT_HEART
-	bypasses_immunity = TRUE // Immunity is based on not having an appendix; this isn't a virus
-	var/sound = FALSE
-
-/datum/disease/heart_failure/Copy()
-	var/datum/disease/heart_failure/D = ..()
-	D.sound = sound
-	return D
-
-
-/datum/disease/heart_failure/stage_act(seconds_per_tick, times_fired)
-	. = ..()
-	if(!.)
-		return
-
-	if(!affected_mob.can_heartattack())
-		cure()
-		return FALSE
-
-	switch(stage)
-		if(1 to 2)
-			if(SPT_PROB(1, seconds_per_tick))
-				to_chat(affected_mob, span_warning("You feel [pick("discomfort", "pressure", "a burning sensation", "pain")] in your chest."))
-			if(SPT_PROB(1, seconds_per_tick))
-				to_chat(affected_mob, span_warning("You feel dizzy."))
-				affected_mob.adjust_confusion(6 SECONDS)
-			if(SPT_PROB(1.5, seconds_per_tick))
-				to_chat(affected_mob, span_warning("You feel [pick("full", "nauseated", "sweaty", "weak", "tired", "short of breath", "uneasy")]."))
-		if(3 to 4)
-			if(!sound)
-				affected_mob.playsound_local(affected_mob, 'sound/effects/health/slowbeat.ogg', 40, FALSE, channel = CHANNEL_HEARTBEAT, use_reverb = FALSE)
-				sound = TRUE
-			if(SPT_PROB(1.5, seconds_per_tick))
-				to_chat(affected_mob, span_danger("You feel a sharp pain in your chest!"))
-				if(prob(25))
-					affected_mob.vomit(VOMIT_CATEGORY_DEFAULT, lost_nutrition = 95)
-				affected_mob.emote("cough")
-				affected_mob.Paralyze(40)
-				affected_mob.losebreath += 4
-			if(SPT_PROB(1.5, seconds_per_tick))
-				to_chat(affected_mob, span_danger("You feel very weak and dizzy..."))
-				affected_mob.adjust_confusion(8 SECONDS)
-				affected_mob.adjustStaminaLoss(40, FALSE)
-				affected_mob.emote("cough")
-		if(5)
-			affected_mob.stop_sound_channel(CHANNEL_HEARTBEAT)
-			affected_mob.playsound_local(affected_mob, 'sound/effects/singlebeat.ogg', 100, FALSE, use_reverb = FALSE)
-			if(affected_mob.stat == CONSCIOUS)
-				affected_mob.visible_message(span_danger("[affected_mob] clutches at [affected_mob.p_their()] chest as if [affected_mob.p_their()] heart is stopping!"), \
-					span_userdanger("You feel a terrible pain in your chest, as if your heart has stopped!"))
-			affected_mob.adjustStaminaLoss(60, FALSE)
-			affected_mob.set_heartattack(TRUE)
-			affected_mob.reagents.add_reagent(/datum/reagent/medicine/c2/penthrite, 3) // To give the victim a final chance to shock their heart before losing consciousness
-			cure()
-			return FALSE

code/datums/status_effects/debuffs/heart_attack.dm

@@ -0,0 +1,191 @@
+///Stage two of the heart attack.
+#define ATTACK_STAGE_TWO 100
+///Stage three of the heart attack.
+#define ATTACK_STAGE_THREE 70
+///Stage four of the heart attack.
+#define ATTACK_STAGE_FOUR 35
+///If we reduce heart damage enough, it will recover on its own.
+#define ATTACK_CURE_THRESHOLD 160
+///What is the max oxyloss we're willing to deal, to prevent people from passing out early.
+#define OXYLOSS_MAXIMUM 40
+
+/datum/status_effect/heart_attack
+	id = "heart_attack"
+	remove_on_fullheal = TRUE
+	alert_type = null
+	///A timer that ticks down until the heart fully stops
+	var/time_until_stoppage = 150
+	///Does this show up on medhuds?
+	var/visible = FALSE
+
+/datum/status_effect/heart_attack/on_apply()
+	var/mob/living/carbon/human/human_owner = owner
+	if(!istype(human_owner) || !human_owner.can_heartattack())
+		return FALSE
+	RegisterSignal(owner, COMSIG_CARBON_LOSE_ORGAN, PROC_REF(on_organ_removed))
+	RegisterSignal(owner, COMSIG_LIVING_MINOR_SHOCK, PROC_REF(minor_shock))
+	RegisterSignal(owner, COMSIG_HEARTATTACK_DEFIB, PROC_REF(defib_shock))
+	RegisterSignal(owner, COMSIG_LIVING_ELECTROCUTE_ACT, PROC_REF(electrocuted))
+	return TRUE
+
+/datum/status_effect/heart_attack/on_remove()
+	UnregisterSignal(owner, list(COMSIG_CARBON_LOSE_ORGAN, COMSIG_LIVING_MINOR_SHOCK, COMSIG_HEARTATTACK_DEFIB, COMSIG_LIVING_ELECTROCUTE_ACT))
+
+/datum/status_effect/heart_attack/tick(seconds_between_ticks)
+	var/mob/living/carbon/human/human_owner = owner
+	if(!istype(human_owner) || !human_owner.can_heartattack())
+		qdel(src) //No heart? No effects.
+		return
+
+	if(time_until_stoppage > ATTACK_CURE_THRESHOLD)
+		owner.visible_message(span_nicegreen("[owner] relaxes [owner.p_their()] body and stops clutching at [owner.p_their()] chest!"), span_nicegreen("The pain in your chest has subsided. You're cured!"))
+		qdel(src)
+		return
+
+	var/oxyloss_sum = 0 //A sum of the oxyloss we will inflict by the end of this cycle.
+
+	if(time_until_stoppage > ATTACK_STAGE_THREE)
+		if(SPT_PROB(5, seconds_between_ticks))
+			owner.playsound_local(owner, 'sound/effects/singlebeat.ogg', 25, FALSE, use_reverb = FALSE)
+			owner.adjustStaminaLoss(5)
+
+	if(time_until_stoppage <= ATTACK_STAGE_TWO && time_until_stoppage > ATTACK_STAGE_THREE)	//This coughing gets replaced with worse coughing, no need to stack it.
+		if(SPT_PROB(10, seconds_between_ticks))
+			owner.emote("cough")
+			owner.adjustStaminaLoss(10)
+			oxyloss_sum += 4
+
+	if(time_until_stoppage <= ATTACK_STAGE_THREE) //At this point, we start with chat messages and make it clear that something is very wrong.
+		if(!visible)
+			ADD_TRAIT(owner, TRAIT_DISEASELIKE_SEVERITY_HIGH, type)
+			owner.med_hud_set_status()
+			visible = TRUE //We do not reset this status until it's fully cured. Once it's been made apparent, there's no reason to hide it again until it is resolved. It will only confuse players.
+		if(SPT_PROB(15, seconds_between_ticks))
+			to_chat(owner, span_danger("You feel a sharp pain in your chest!"))
+			if(SPT_PROB(15, seconds_between_ticks))
+				human_owner.vomit(VOMIT_CATEGORY_DEFAULT, lost_nutrition = 95)
+			owner.emote("cough")
+			oxyloss_sum += 1
+		if(SPT_PROB(8, seconds_between_ticks))
+			to_chat(owner, span_danger("You feel very weak and dizzy..."))
+			owner.adjust_confusion_up_to(6 SECONDS, 10 SECONDS)
+			owner.adjustStaminaLoss(20)
+			owner.emote("cough")
+			oxyloss_sum += 8
+
+	if(time_until_stoppage <= ATTACK_STAGE_FOUR) //And now we compound it with even worse effects.
+
+		if(SPT_PROB(5, seconds_between_ticks))
+			to_chat(owner, span_userdanger("It feels like you're shutting down..."))
+			owner.adjust_dizzy_up_to(4 SECONDS, 10 SECONDS)
+			owner.adjust_eye_blur_up_to(4 SECONDS, 20 SECONDS)
+			owner.adjustStaminaLoss(20)
+
+		if(SPT_PROB(5, seconds_between_ticks))
+			owner.emote("cough")
+			if(SPT_PROB(5, seconds_between_ticks))
+				to_chat(owner, span_userdanger("You cough. Everything goes dark. You're going to die soon."))
+				owner.adjust_temp_blindness(10 SECONDS) //Are you panicking yet? You should be panicking by now.
+			else
+				to_chat(owner, span_userdanger("As you cough, your chest surges in pain and darkness closes in around your sight."))
+				owner.adjust_temp_blindness(2 SECONDS)
+				owner.adjust_eye_blur_up_to(4 SECONDS, 20 SECONDS)
+			oxyloss_sum += 8
+			owner.Paralyze(1 SECONDS)
+		oxyloss_sum += 3
+
+	if(owner.getOxyLoss() < OXYLOSS_MAXIMUM) //A bad enough roll on the verge of passing out might still push you over into unconciousness for a few seconds...?
+		owner.adjustOxyLoss(oxyloss_sum)
+
+	if(time_until_stoppage <= 0)
+		if(owner.stat == CONSCIOUS)
+			to_chat(owner, span_userdanger("You feel a terrible pain in your chest, as if your heart has stopped!"))
+		owner.adjust_eye_blur(20 SECONDS)
+		human_owner.set_heartattack(TRUE)
+		owner.apply_status_effect(/datum/status_effect/heart_desperation) // To give the victim a final chance to shock their heart before losing consciousness
+		var/flash_type = /atom/movable/screen/fullscreen/flash
+		if(owner.client?.prefs?.read_preference(/datum/preference/toggle/darkened_flash))
+			flash_type = /atom/movable/screen/fullscreen/flash/black
+		owner.overlay_fullscreen("flash", flash_type)
+		addtimer(CALLBACK(owner, TYPE_PROC_REF(/mob/living, clear_fullscreen), "flash", 1 SECONDS), 1 SECONDS)
+		qdel(src)
+		return FALSE
+
+	if(time_until_stoppage <= ATTACK_STAGE_TWO)
+		if(time_until_stoppage <= ATTACK_STAGE_FOUR)
+			owner.playsound_local(owner, 'sound/effects/singlebeat.ogg', 100, FALSE, channel = CHANNEL_HEARTBEAT, use_reverb = FALSE)
+		else
+			owner.playsound_local(owner, 'sound/effects/health/slowbeat.ogg', 25, FALSE, channel = CHANNEL_HEARTBEAT, use_reverb = FALSE)
+	else
+		owner.stop_sound_channel(CHANNEL_HEARTBEAT)
+
+	time_until_stoppage--
+
+/datum/status_effect/heart_attack/get_examine_text()
+	if(!time_until_stoppage <= ATTACK_STAGE_THREE)
+		return
+	var/mob/living/carbon/human/human_owner = owner
+	var/cannot_grasp = (human_owner.usable_hands <= 0 || owner.incapacitated & INCAPABLE_RESTRAINTS || HAS_TRAIT(owner, TRAIT_HANDS_BLOCKED))
+	return span_warning("[owner.p_they()] looks to be doubling over" + "[cannot_grasp ? " in pain!" : ", clutching [owner.p_their()] chest in pain!"]")
+
+/datum/status_effect/heart_attack/on_remove()
+	REMOVE_TRAIT(owner, TRAIT_DISEASELIKE_SEVERITY_HIGH, type)
+	owner.med_hud_set_status()
+	return ..()
+
+///End the heart attack due to heart removal.
+/datum/status_effect/heart_attack/proc/on_organ_removed(datum/source, obj/item/organ)
+	SIGNAL_HANDLER
+	if(istype(organ, /obj/item/organ/heart))
+		qdel(src)
+
+///Slightly reduces your timer. Can cure you if you really really want.
+/datum/status_effect/heart_attack/proc/minor_shock(datum/source)
+	SIGNAL_HANDLER
+	time_until_stoppage += 18 //Good for keeping yourself up. Won't be easy to get over the cure threshold by yourself. You're going to need security beating the crap out of you with stunbatons, but it'll work.
+	if(prob(50)) //Also good for crafty solos who want to stunbaton themselves back to health. Timing will be key.
+		to_chat(owner, span_nicegreen("Something about being shocked makes the pain in your chest ease up!"))
+
+///Makes major progress towards curing the attack.
+/datum/status_effect/heart_attack/proc/defib_shock(obj/item/shockpaddles/source)
+	SIGNAL_HANDLER
+	time_until_stoppage += 50 //Three shocks should save pretty much anyone.
+	owner.visible_message(span_nicegreen("[owner] seems to be relieved of their pain as they're shocked by the [source]!"), span_nicegreen("The [source] shocks your heart awake, and you feel the pain in your chest ease up!"))
+
+///Slightly reduces your timer, just like the minor shock signal. Slightly more relief because these use cases are generally more dangerous.
+/datum/status_effect/heart_attack/proc/electrocuted(datum/source, shock_damage)
+	SIGNAL_HANDLER
+	time_until_stoppage += (20 + shock_damage * 1.15)
+	if(prob(50))
+		to_chat(owner, span_nicegreen("Something about being electrocuted makes the pain in your chest ease up!"))
+
+///Alternative to penthrite that keeps you up for a few seconds after having a heart attack. Gives a bit of time to call for help regardless of when/where you've collapsed.
+/datum/status_effect/heart_desperation
+	id = "heart_desperation"
+	duration = (4 SECONDS)
+	alert_type = null
+	/// List of traits to add/remove from our subject when we are in their system
+	var/static/list/subject_traits = list(
+		TRAIT_STABLEHEART,
+		TRAIT_NOHARDCRIT,
+		TRAIT_NOSOFTCRIT,
+		TRAIT_NOCRITDAMAGE,
+	)
+
+/datum/status_effect/heart_desperation/on_apply()
+	owner.add_traits(subject_traits, type)
+	owner.Knockdown(2 SECONDS, 2 SECONDS)
+	return TRUE
+
+/datum/status_effect/heart_desperation/tick(seconds_between_ticks)
+	owner.Knockdown(2 SECONDS, 2 SECONDS)
+	owner.set_silence_if_lower(2 SECONDS)
+
+/datum/status_effect/heart_desperation/on_remove()
+	owner.remove_traits(subject_traits, type)
+
+#undef ATTACK_STAGE_TWO
+#undef ATTACK_STAGE_THREE
+#undef ATTACK_STAGE_FOUR
+#undef ATTACK_CURE_THRESHOLD
+#undef OXYLOSS_MAXIMUM

code/game/data_huds.dm

@@ -101,6 +101,10 @@ Medical HUD! Basic mode needs suit sensors on.
 		severity = DISEASE_SEVERITY_MEDIUM
 		threat = get_disease_severity_value(severity)
 
+	if(HAS_TRAIT(src, TRAIT_DISEASELIKE_SEVERITY_HIGH))
+		severity = DISEASE_SEVERITY_DANGEROUS
+		threat = get_disease_severity_value(severity)
+
 	for(var/thing in diseases)
 		var/datum/disease/D = thing
 		if(!(D.visibility_flags & HIDDEN_MEDHUD)) // BUBBER EDIT CHANGE - DISEASE OUTBREAK UPDATES - Original: HIDDEN_SCANNER

code/game/objects/items/defib.dm

@@ -693,10 +693,15 @@
 				playsound(src, 'sound/machines/defib/defib_zap.ogg', 50, TRUE, -1)
 				if(!(heart.organ_flags & ORGAN_FAILING))
 					H.set_heartattack(FALSE)
+					do_success()
 					user.visible_message(span_notice("[req_defib ? "[defib]" : "[src]"] pings: Patient's heart is now beating again."))
 				else
 					user.visible_message(span_warning("[req_defib ? "[defib]" : "[src]"] buzzes: Resuscitation failed, heart damage detected."))
-
+			else if(H.has_status_effect(/datum/status_effect/heart_attack))
+				user.visible_message(span_notice("[req_defib ? "[defib]" : "[src]"] pings: Patient's heart has stabilized, further applications may be necessary."))
+				SEND_SIGNAL(H, COMSIG_HEARTATTACK_DEFIB)
+				playsound(src, 'sound/machines/defib/defib_zap.ogg', 50, TRUE, -1)
+				do_success()
 			else
 				user.visible_message(span_warning("[req_defib ? "[defib]" : "[src]"] buzzes: Patient is not in a valid state. Operation aborted."))
 				playsound(src, 'sound/machines/defib/defib_failed.ogg', 50, FALSE)

code/modules/events/heart_attack.dm

@@ -30,7 +30,7 @@
 /datum/round_event_control/heart_attack/proc/generate_candidates()
 	heart_attack_candidates.Cut()
 	for(var/mob/living/carbon/human/candidate in shuffle(GLOB.player_list))
-		if(candidate.stat == DEAD || HAS_TRAIT(candidate, TRAIT_CRITICAL_CONDITION) || !candidate.can_heartattack() || (/datum/disease/heart_failure in candidate.diseases) || candidate.undergoing_cardiac_arrest())
+		if(candidate.stat == DEAD || HAS_TRAIT(candidate, TRAIT_CRITICAL_CONDITION) || !candidate.can_heartattack() || (candidate.has_status_effect(/datum/status_effect/heart_attack)) || candidate.undergoing_cardiac_arrest())
 			continue
 		if(!(candidate.mind.assigned_role.job_flags & JOB_CREW_MEMBER))//only crewmembers can get one, a bit unfair for some ghost roles and it wastes the event
 			continue
@@ -78,8 +78,7 @@
 		message_admins("[winner] has just survived a random heart attack!") //time to spawn them a trophy :)
 		victims -= winner
 	else
-		var/datum/disease/heart_disease = new /datum/disease/heart_failure()
-		winner.ForceContractDisease(heart_disease, FALSE, TRUE)
+		winner.apply_status_effect(/datum/status_effect/heart_attack)
 		announce_to_ghosts(winner)
 		victims -= winner
 		return TRUE

code/modules/reagents/chemistry/reagents/cat2_medicine_reagents.dm

@@ -588,7 +588,7 @@
 
 /datum/reagent/medicine/c2/penthrite/on_mob_metabolize(mob/living/user)
 	. = ..()
-	user.throw_alert("penthrite", /atom/movable/screen/alert/penthrite)
+	send_alert(user)
 	user.add_traits(subject_traits, type)
 
 /datum/reagent/medicine/c2/penthrite/on_mob_life(mob/living/carbon/human/affected_mob, seconds_per_tick, times_fired)
@@ -626,7 +626,7 @@
 
 /datum/reagent/medicine/c2/penthrite/on_mob_end_metabolize(mob/living/affected_mob)
 	. = ..()
-	affected_mob.clear_alert("penthrite")
+	remove_alert(affected_mob)
 	affected_mob.remove_traits(subject_traits, type)
 
 /datum/reagent/medicine/c2/penthrite/overdose_process(mob/living/carbon/human/affected_mob, seconds_per_tick, times_fired)
@@ -639,6 +639,11 @@
 	if(need_mob_update)
 		return UPDATE_MOB_HEALTH
 
+/datum/reagent/medicine/c2/penthrite/proc/send_alert(mob/living/affected_mob)
+	affected_mob.throw_alert("penthrite", /atom/movable/screen/alert/penthrite)
+
+/datum/reagent/medicine/c2/penthrite/proc/remove_alert(mob/living/affected_mob)
+	affected_mob.clear_alert("penthrite")
 
 /******NICHE******/
 //todo

code/modules/reagents/chemistry/reagents/drinks/alcohol_reagents.dm

@@ -278,8 +278,7 @@
 		drinker.set_jitter_if_lower(700 SECONDS)
 
 	if(SPT_PROB(0.5, seconds_per_tick) && iscarbon(drinker))
-		var/datum/disease/heart_attack = new /datum/disease/heart_failure
-		drinker.ForceContractDisease(heart_attack)
+		drinker.apply_status_effect(/datum/status_effect/heart_attack)
 		to_chat(drinker, span_userdanger("You're pretty sure you just felt your heart stop for a second there.."))
 		drinker.playsound_local(drinker, 'sound/effects/singlebeat.ogg', 100, 0)
 

code/modules/reagents/chemistry/reagents/medicine_reagents.dm

@@ -600,8 +600,7 @@
 /datum/reagent/medicine/ephedrine/overdose_process(mob/living/affected_mob, seconds_per_tick, times_fired)
 	. = ..()
 	if(SPT_PROB(1 * (1 + (1-normalise_creation_purity())), seconds_per_tick) && iscarbon(affected_mob))
-		var/datum/disease/D = new /datum/disease/heart_failure
-		affected_mob.ForceContractDisease(D)
+		affected_mob.apply_status_effect(/datum/status_effect/heart_attack)
 		to_chat(affected_mob, span_userdanger("You're pretty sure you just felt your heart stop for a second there.."))
 		affected_mob.playsound_local(affected_mob, 'sound/effects/singlebeat.ogg', 100, 0)
 

code/modules/surgery/organs/internal/heart/_heart.dm

@@ -93,8 +93,10 @@
 	return beating
 
 /obj/item/organ/heart/get_status_text(advanced, add_tooltips)
-	if(!beating && !(organ_flags & ORGAN_FAILING) && owner.needs_heart() && owner.stat != DEAD)
-		return conditional_tooltip("<font color='#cc3333'>Cardiac Arrest</font>", "Apply defibrillation immediately. Similar electric shocks may work in emergencies.", add_tooltips)
+	if(owner.has_status_effect(/datum/status_effect/heart_attack))
+		return conditional_tooltip("<font color='#cc3333'>Myocardial Infarction</font>", "Apply defibrillation immediately. Similar electric shocks may work in emergencies.", add_tooltips)
+	if((!beating && !(organ_flags & ORGAN_FAILING) && owner.needs_heart() && owner.stat != DEAD))
+		return conditional_tooltip("<font color='#cc3333'>Cardiac Arrest</font>", "Repair tissue damage and apply defibrillation immediately.", add_tooltips)
 	return ..()
 
 /obj/item/organ/heart/show_on_condensed_scans()

code/modules/surgery/organs/internal/stomach/stomach_ethereal.dm

@@ -113,8 +113,7 @@
 		carbon.visible_message(span_danger("[carbon] violently discharges energy!"), span_warning("You violently discharge energy!"))
 
 		if(prob(10)) //chance of developing heart disease to dissuade overcharging oneself
-			var/datum/disease/D = new /datum/disease/heart_failure
-			carbon.ForceContractDisease(D)
+			carbon.apply_status_effect(/datum/status_effect/heart_attack)
 			to_chat(carbon, span_userdanger("You're pretty sure you just felt your heart stop for a second there.."))
 			carbon.playsound_local(carbon, 'sound/effects/singlebeat.ogg', 100, 0)
 

strings/tips.txt

@@ -74,6 +74,7 @@ As a Medical Doctor, you must target the correct limb and not be in combat mode
 As a Medical Doctor, when messing with viruses, remember that robotic organs can give immunity to disease effects and transmissibility. Make use of the inorganic biology symptom to bypass the protection.
 As a Medical Doctor, while there's an pandemic, you only require small amounts of vaccine to heal a sick patient. Work with the Chemist to distribute your cures more efficiently.
 As a Medical Doctor, try messing with the virology lab sometime! Viruses can range from healing powers so great that you can heal out of critical status, or diseases so dangerous they can kill the entire crew with airborne spontaneous combustion. Experiment!
+As a Medical Doctor, you can cure a heart attack by repeatedly shocking the victim with a defibrillator!
 As a Monkey, you can crawl through air or scrubber vents by alt+left clicking them. You must drop everything you are wearing and holding to do this, however.
 As a Monkey, you can still wear a few human items, such as backpacks, gas masks and hats, and still have two free hands.
 As a Morph, you can talk while disguised, but your words have a chance of being slurred, giving you away!
@@ -110,6 +111,7 @@ As a Security Officer, remember that correlation does not equal causation. Someo
 As a Security Officer, remember that you can attach a sec-lite to your disabler or your helmet!
 As a Security Officer, your sechuds or HUDsunglasses can not only see crewmates' job assignments and criminal status, but also if they are mindshield implanted. You can tell by the flashing blue outline around their job icon. Use this to your advantage in a revolution to definitively tell who is on your side!
 As a Security Officer, you have a special pen in your PDA that you can use to prompt people to surrender. This will stun them without the need to use a baton!
+As a Security Officer, you can treat or even cure a heart attack with repeated blows from a stunbaton. Emphasis on *repeated*.
 As a Service Cyborg, your spray can knocks people down. However, it is blocked by masks and glasses.
 As a Shaft Miner, always have a GPS on you, so a fellow miner or cyborg can come to save you if you die.
 As a Shaft Miner, every monster on Lavaland has a pattern you can exploit to minimize damage from the encounters.

tgstation.dme

@@ -1543,7 +1543,6 @@
 #include "code\datums\diseases\fluspanish.dm"
 #include "code\datums\diseases\gastrolisis.dm"
 #include "code\datums\diseases\gbs.dm"
-#include "code\datums\diseases\heart_failure.dm"
 #include "code\datums\diseases\magnitis.dm"
 #include "code\datums\diseases\parasitic_infection.dm"
 #include "code\datums\diseases\parrotpossession.dm"
@@ -2093,6 +2092,7 @@
 #include "code\datums\status_effects\debuffs\fire_stacks.dm"
 #include "code\datums\status_effects\debuffs\genetic_damage.dm"
 #include "code\datums\status_effects\debuffs\hallucination.dm"
+#include "code\datums\status_effects\debuffs\heart_attack.dm"
 #include "code\datums\status_effects\debuffs\hooked.dm"
 #include "code\datums\status_effects\debuffs\jitteriness.dm"
 #include "code\datums\status_effects\debuffs\pacifism.dm"