mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-08-21 20:20:33 +01:00
Thunder12345andnevimer
20118ad747
## About The Pull Request Converts as many time vars expressed in deciseconds as I could find to use time defines. ## Why It's Good For The Game Makes these values neater and more readable. ## Changelog 🆑 code: Converted a lot of time-based variables to be expressed with time defines. /🆑 # Conflicts: # code/modules/clothing/head/hat.dm # code/modules/clothing/shoes/boots.dm # code/modules/clothing/suits/utility.dm
99 lines
3.8 KiB
Plaintext
99 lines
3.8 KiB
Plaintext
/datum/surgery/hepatectomy
|
|
name = "Hepatectomy"
|
|
surgery_flags = SURGERY_REQUIRE_RESTING | SURGERY_REQUIRE_LIMB | SURGERY_REQUIRES_REAL_LIMB
|
|
organ_to_manipulate = ORGAN_SLOT_LIVER
|
|
possible_locs = list(BODY_ZONE_CHEST)
|
|
steps = list(
|
|
/datum/surgery_step/incise,
|
|
/datum/surgery_step/retract_skin,
|
|
/datum/surgery_step/saw,
|
|
/datum/surgery_step/clamp_bleeders,
|
|
/datum/surgery_step/incise,
|
|
/datum/surgery_step/hepatectomy,
|
|
/datum/surgery_step/close,
|
|
)
|
|
|
|
/datum/surgery/hepatectomy/mechanic
|
|
name = "Impurity Management System Diagnostic"
|
|
requires_bodypart_type = BODYTYPE_ROBOTIC
|
|
steps = list(
|
|
/datum/surgery_step/mechanic_open,
|
|
/datum/surgery_step/open_hatch,
|
|
/datum/surgery_step/mechanic_unwrench,
|
|
/datum/surgery_step/hepatectomy/mechanic,
|
|
/datum/surgery_step/mechanic_wrench,
|
|
/datum/surgery_step/mechanic_close,
|
|
)
|
|
|
|
/datum/surgery/hepatectomy/can_start(mob/user, mob/living/carbon/target)
|
|
var/obj/item/organ/liver/target_liver = target.get_organ_slot(ORGAN_SLOT_LIVER)
|
|
if(isnull(target_liver) || target_liver.damage < 50 || target_liver.operated)
|
|
return FALSE
|
|
return ..()
|
|
|
|
////hepatectomy, removes damaged parts of the liver so that the liver may regenerate properly
|
|
//95% chance of success, not 100 because organs are delicate
|
|
/datum/surgery_step/hepatectomy
|
|
name = "remove damaged liver section (scalpel)"
|
|
implements = list(
|
|
TOOL_SCALPEL = 95,
|
|
/obj/item/melee/energy/sword = 65,
|
|
/obj/item/knife = 45,
|
|
/obj/item/shard = 35)
|
|
time = 5.2 SECONDS
|
|
preop_sound = 'sound/items/handling/surgery/scalpel1.ogg'
|
|
success_sound = 'sound/items/handling/surgery/organ1.ogg'
|
|
failure_sound = 'sound/items/handling/surgery/organ2.ogg'
|
|
surgery_effects_mood = TRUE
|
|
|
|
/datum/surgery_step/hepatectomy/mechanic
|
|
name = "perform maintenance (scalpel or wirecutter)"
|
|
implements = list(
|
|
TOOL_SCALPEL = 95,
|
|
TOOL_WRENCH = 95,
|
|
/obj/item/melee/energy/sword = 65,
|
|
/obj/item/knife = 45,
|
|
/obj/item/shard = 35)
|
|
preop_sound = 'sound/items/tools/ratchet.ogg'
|
|
success_sound = 'sound/machines/airlock/doorclick.ogg'
|
|
|
|
/datum/surgery_step/hepatectomy/preop(mob/user, mob/living/carbon/target, target_zone, obj/item/tool, datum/surgery/surgery)
|
|
display_results(
|
|
user,
|
|
target,
|
|
span_notice("You begin to cut out a damaged piece of [target]'s liver..."),
|
|
span_notice("[user] begins to make an incision in [target]."),
|
|
span_notice("[user] begins to make an incision in [target]."),
|
|
)
|
|
display_pain(target, "Your abdomen burns in horrific stabbing pain!")
|
|
|
|
/datum/surgery_step/hepatectomy/success(mob/user, mob/living/carbon/target, target_zone, obj/item/tool, datum/surgery/surgery, default_display_results = FALSE)
|
|
var/mob/living/carbon/human/human_target = target
|
|
var/obj/item/organ/liver/target_liver = target.get_organ_slot(ORGAN_SLOT_LIVER)
|
|
human_target.setOrganLoss(ORGAN_SLOT_LIVER, 10) //not bad, not great
|
|
if(target_liver)
|
|
target_liver.operated = TRUE
|
|
if(target_liver.organ_flags & ORGAN_EMP) //If our organ is failing due to an EMP, fix that
|
|
target_liver.organ_flags &= ~ORGAN_EMP
|
|
display_results(
|
|
user,
|
|
target,
|
|
span_notice("You successfully remove the damaged part of [target]'s liver."),
|
|
span_notice("[user] successfully removes the damaged part of [target]'s liver."),
|
|
span_notice("[user] successfully removes the damaged part of [target]'s liver."),
|
|
)
|
|
display_pain(target, "The pain receeds slightly.")
|
|
return ..()
|
|
|
|
/datum/surgery_step/hepatectomy/failure(mob/user, mob/living/carbon/target, target_zone, obj/item/tool, datum/surgery)
|
|
var/mob/living/carbon/human/human_target = target
|
|
human_target.adjustOrganLoss(ORGAN_SLOT_LIVER, 15)
|
|
display_results(
|
|
user,
|
|
target,
|
|
span_warning("You cut the wrong part of [target]'s liver!"),
|
|
span_warning("[user] cuts the wrong part of [target]'s liver!"),
|
|
span_warning("[user] cuts the wrong part of [target]'s liver!"),
|
|
)
|
|
display_pain(target, "You feel a sharp stab inside your abdomen!")
|