mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-07-10 07:41:16 +01:00
Alexis
21b4095dfd
Upstream 04/17/2026 fixes https://github.com/Bubberstation/Bubberstation/issues/5549 --------- Signed-off-by: dependabot[bot] <support@github.com> Co-authored-by: tgstation-ci[bot] <179393467+tgstation-ci[bot]@users.noreply.github.com> Co-authored-by: ArcaneMusic <41715314+ArcaneMusic@users.noreply.github.com> Co-authored-by: MrMelbert <51863163+MrMelbert@users.noreply.github.com> Co-authored-by: Rhials <28870487+Rhials@users.noreply.github.com> Co-authored-by: rageguy505 <54517726+rageguy505@users.noreply.github.com> Co-authored-by: LemonInTheDark <58055496+LemonInTheDark@users.noreply.github.com> Co-authored-by: John Willard <53777086+JohnFulpWillard@users.noreply.github.com> Co-authored-by: Aliceee2ch <160794176+Aliceee2ch@users.noreply.github.com> Co-authored-by: Time-Green <7501474+Time-Green@users.noreply.github.com> Co-authored-by: Tsar-Salat <62388554+Tsar-Salat@users.noreply.github.com> Co-authored-by: SmArtKar <44720187+SmArtKar@users.noreply.github.com> Co-authored-by: Maxipat <108554989+Maxipat112@users.noreply.github.com> Co-authored-by: SyncIt21 <110812394+SyncIt21@users.noreply.github.com> Co-authored-by: deltanedas <39013340+deltanedas@users.noreply.github.com> Co-authored-by: SimplyLogan <47579821+loganuk@users.noreply.github.com> Co-authored-by: loganuk <fakeemail123@aol.com> Co-authored-by: Leland Kemble <70413276+lelandkemble@users.noreply.github.com> Co-authored-by: FalloutFalcon <86381784+FalloutFalcon@users.noreply.github.com> Co-authored-by: Roxy <75404941+TealSeer@users.noreply.github.com> Co-authored-by: Lucy <lucy@absolucy.moe> Co-authored-by: siliconOpossum <138069572+siliconOpossum@users.noreply.github.com> Co-authored-by: Isratosh <Isratosh@hotmail.com> Co-authored-by: TheRyeGuyWhoWillNowDie <70169560+TheRyeGuyWhoWillNowDie@users.noreply.github.com> Co-authored-by: Neocloudy <88008002+Neocloudy@users.noreply.github.com> Co-authored-by: Alexander V. <volas@ya.ru> Co-authored-by: ElGitificador <168473461+ElGitificador@users.noreply.github.com> Co-authored-by: Twaticus <46540570+Twaticus@users.noreply.github.com> Co-authored-by: dependabot[bot] <49699333+dependabot[bot]@users.noreply.github.com> Co-authored-by: Bloop <13398309+vinylspiders@users.noreply.github.com> Co-authored-by: Cameron Lennox <killer65311@gmail.com> Co-authored-by: Tim <timothymtorres@gmail.com> Co-authored-by: Iamgoofball <iamgoofball@gmail.com> Co-authored-by: Layzu666 <121319428+Layzu666@users.noreply.github.com> Co-authored-by: Arturlang <24881678+Arturlang@users.noreply.github.com> Co-authored-by: _0Steven <42909981+00-Steven@users.noreply.github.com> Co-authored-by: mrmanlikesbt <99309552+mrmanlikesbt@users.noreply.github.com> Co-authored-by: Ben10Omintrix <138636438+Ben10Omintrix@users.noreply.github.com> Co-authored-by: John F. Kennedy <54908920+MacaroniCritter@users.noreply.github.com> Co-authored-by: Cursor <102828457+theselfish@users.noreply.github.com> Co-authored-by: Josh <josh.adam.powell@gmail.com> Co-authored-by: Josh Powell <josh.powell@softwire.com> Co-authored-by: Yobrocharlie <Charliemiller5617@gmail.com> Co-authored-by: Hardly3D <66234359+Hardly3D@users.noreply.github.com> Co-authored-by: shayoki <96078776+shayoki@users.noreply.github.com> Co-authored-by: LT3 <83487515+lessthnthree@users.noreply.github.com>
79 lines
2.1 KiB
Plaintext
79 lines
2.1 KiB
Plaintext
SUBSYSTEM_DEF(augury)
|
|
name = "Augury"
|
|
ss_flags = SS_NO_INIT
|
|
runlevels = RUNLEVEL_GAME | RUNLEVEL_POSTGAME
|
|
|
|
var/list/watchers = list()
|
|
var/list/doombringers = list()
|
|
|
|
var/list/observers_given_action = list()
|
|
|
|
/datum/controller/subsystem/augury/stat_entry(msg)
|
|
msg = "W:[watchers.len]|D:[length(doombringers)]"
|
|
return ..()
|
|
|
|
/datum/controller/subsystem/augury/proc/register_doom(atom/A, severity)
|
|
doombringers[A] = severity
|
|
RegisterSignal(A, COMSIG_QDELETING, PROC_REF(unregister_doom))
|
|
|
|
/datum/controller/subsystem/augury/proc/unregister_doom(atom/A)
|
|
SIGNAL_HANDLER
|
|
UnregisterSignal(A, COMSIG_QDELETING)
|
|
doombringers -= A
|
|
|
|
/datum/controller/subsystem/augury/fire()
|
|
var/biggest_doom = null
|
|
var/biggest_threat = null
|
|
|
|
for(var/db in doombringers)
|
|
var/datum/d = db
|
|
if(!d || QDELETED(d))
|
|
doombringers -= d
|
|
continue
|
|
var/threat = doombringers[d]
|
|
if((biggest_threat == null) || (biggest_threat < threat))
|
|
biggest_doom = d
|
|
biggest_threat = threat
|
|
|
|
if(doombringers.len)
|
|
for(var/i in GLOB.player_list)
|
|
if(isobserver(i) && (!(observers_given_action[i])))
|
|
var/datum/action/innate/augury/A = new
|
|
A.Grant(i)
|
|
observers_given_action[i] = TRUE
|
|
else
|
|
for(var/i in observers_given_action)
|
|
if(observers_given_action[i] && isobserver(i))
|
|
var/mob/dead/observer/O = i
|
|
for(var/datum/action/innate/augury/A in O.actions)
|
|
qdel(A)
|
|
observers_given_action -= i
|
|
|
|
for(var/w in watchers)
|
|
if(!w)
|
|
watchers -= w
|
|
continue
|
|
var/mob/dead/observer/O = w
|
|
if(biggest_doom && (!O.orbiting || O.orbiting.parent != biggest_doom))
|
|
O.ManualFollow(biggest_doom)
|
|
|
|
/datum/action/innate/augury
|
|
name = "Auto Follow Debris"
|
|
button_icon = 'icons/obj/meteor.dmi'
|
|
button_icon_state = "flaming"
|
|
|
|
/datum/action/innate/augury/Destroy()
|
|
if(owner)
|
|
SSaugury.watchers -= owner
|
|
return ..()
|
|
|
|
/datum/action/innate/augury/Activate()
|
|
SSaugury.watchers += owner
|
|
to_chat(owner, span_notice("You are now auto-following debris."))
|
|
active = TRUE
|
|
|
|
/datum/action/innate/augury/Deactivate()
|
|
SSaugury.watchers -= owner
|
|
to_chat(owner, span_notice("You are no longer auto-following debris."))
|
|
active = FALSE
|