mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-07-13 09:05:11 +01:00
SyncIt21
3c5749f862
## About The Pull Request The overall behaviour of everything should stay the same but the memory & speed of these components has been slightly improved and when you scale that across large plumbing factories you get a substantial improvement. Here's a list of the most noticeable changes along with many others that aren't worth mentioning - Removed vars `use_overlays`, `turn_connects`, `recipient_reagents_holder` - `active` var is now replaced with a proc which simply returns is the machine wrenched or not - `turn_connects` has been removed because all machines have their pipes rotate when the machine is rotated. This also removed all the static icon states ending with `-s` from the `dmi` file thus reducing that file size as well - `extend_pipe_to_edge` var is directly integrated into `cut_overlays()` because it's use cases were limited such for showers & sinks - Simplified `Initialize()` a lot. Removed params `start`, `turn_connects`, `custom_receiver`, `extend_pipe_to_edge`. We now only pass `bolt_layer` making that proc faster & less convoluted - Replaced `set_recipient_reagents_holder()` proc with `recipient_reagents_holder()` which returns the reagent holder for holding reagents instead of storing it in the component. This removes the need to hook a qdel signal on the holder & we don't need to keep track of it - Merged a ton of procs to reduce overhead & reduce file size - Plumbing ducts creating the network at mapload is faster without using recursion and the timer subsystem - Deconstructing plumbing ducts is faster in reconstructing the network without using recursion and the timer subsystem This makes managing plumbing code less convoluted & overall better for the foreseeable future. See the lines of code removed vs added and still preserves behaviour ## Changelog 🆑 qol: added examines & screentips for ducts & stack of ducts qol: you can wrench a stack of ducts on the ground to create a pipe refactor: plumbing code has been improved overall. Report bugs on github sprite: removed unused static(does not rotate with machine) icon states for plumbing connections /🆑 --------- Co-authored-by: Time-Green <7501474+Time-Green@users.noreply.github.com>
49 lines
1.6 KiB
Plaintext
49 lines
1.6 KiB
Plaintext
///We handle the unity part of plumbing. We track who is connected to who.
|
|
/datum/ductnet
|
|
///All the ducts that make this network
|
|
var/list/obj/machinery/duct/ducts
|
|
///Stuff that can supply chems used by machines to retrive chems
|
|
var/list/datum/component/plumbing/suppliers
|
|
///Stuff that demands chems keep track of components that need their ducts updated as this net evolves
|
|
var/list/datum/component/plumbing/demanders
|
|
|
|
/datum/ductnet/New(obj/machinery/duct/parent)
|
|
ducts = parent ? list(parent) : list()
|
|
suppliers = list()
|
|
demanders = list()
|
|
return ..()
|
|
|
|
/datum/ductnet/Destroy(force)
|
|
ducts.Cut()
|
|
for(var/datum/component/plumbing/plumbing as anything in suppliers + demanders)
|
|
remove_plumber(plumbing)
|
|
suppliers.Cut()
|
|
demanders.Cut()
|
|
return ..()
|
|
|
|
///add a plumbing object to either demanders or suppliers
|
|
/datum/ductnet/proc/add_plumber(datum/component/plumbing/plumbing, dir)
|
|
var/dirtext = num2text(dir)
|
|
if(plumbing.ducts[dirtext] == src)
|
|
return FALSE
|
|
plumbing.ducts[dirtext] = src
|
|
if(dir & plumbing.supply_connects)
|
|
suppliers += plumbing
|
|
if(dir & plumbing.demand_connects)
|
|
demanders += plumbing
|
|
return TRUE
|
|
|
|
///remove a plumber. we don't delete ourselves because ductnets don't persist through plumbing objects.
|
|
/datum/ductnet/proc/remove_plumber(datum/component/plumbing/plumbing)
|
|
for(var/dir in plumbing.ducts)
|
|
if(plumbing.ducts[dir] == src)
|
|
plumbing.ducts -= dir
|
|
dir = text2num(dir)
|
|
if(dir & plumbing.supply_connects)
|
|
suppliers -= plumbing
|
|
if(dir & plumbing.demand_connects)
|
|
demanders -= plumbing
|
|
|
|
//return if this net has no ducts like when 2 machines are connected
|
|
return ducts.len == 0
|