mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-07-13 09:05:11 +01:00
Alexis
21b4095dfd
Upstream 04/17/2026 fixes https://github.com/Bubberstation/Bubberstation/issues/5549 --------- Signed-off-by: dependabot[bot] <support@github.com> Co-authored-by: tgstation-ci[bot] <179393467+tgstation-ci[bot]@users.noreply.github.com> Co-authored-by: ArcaneMusic <41715314+ArcaneMusic@users.noreply.github.com> Co-authored-by: MrMelbert <51863163+MrMelbert@users.noreply.github.com> Co-authored-by: Rhials <28870487+Rhials@users.noreply.github.com> Co-authored-by: rageguy505 <54517726+rageguy505@users.noreply.github.com> Co-authored-by: LemonInTheDark <58055496+LemonInTheDark@users.noreply.github.com> Co-authored-by: John Willard <53777086+JohnFulpWillard@users.noreply.github.com> Co-authored-by: Aliceee2ch <160794176+Aliceee2ch@users.noreply.github.com> Co-authored-by: Time-Green <7501474+Time-Green@users.noreply.github.com> Co-authored-by: Tsar-Salat <62388554+Tsar-Salat@users.noreply.github.com> Co-authored-by: SmArtKar <44720187+SmArtKar@users.noreply.github.com> Co-authored-by: Maxipat <108554989+Maxipat112@users.noreply.github.com> Co-authored-by: SyncIt21 <110812394+SyncIt21@users.noreply.github.com> Co-authored-by: deltanedas <39013340+deltanedas@users.noreply.github.com> Co-authored-by: SimplyLogan <47579821+loganuk@users.noreply.github.com> Co-authored-by: loganuk <fakeemail123@aol.com> Co-authored-by: Leland Kemble <70413276+lelandkemble@users.noreply.github.com> Co-authored-by: FalloutFalcon <86381784+FalloutFalcon@users.noreply.github.com> Co-authored-by: Roxy <75404941+TealSeer@users.noreply.github.com> Co-authored-by: Lucy <lucy@absolucy.moe> Co-authored-by: siliconOpossum <138069572+siliconOpossum@users.noreply.github.com> Co-authored-by: Isratosh <Isratosh@hotmail.com> Co-authored-by: TheRyeGuyWhoWillNowDie <70169560+TheRyeGuyWhoWillNowDie@users.noreply.github.com> Co-authored-by: Neocloudy <88008002+Neocloudy@users.noreply.github.com> Co-authored-by: Alexander V. <volas@ya.ru> Co-authored-by: ElGitificador <168473461+ElGitificador@users.noreply.github.com> Co-authored-by: Twaticus <46540570+Twaticus@users.noreply.github.com> Co-authored-by: dependabot[bot] <49699333+dependabot[bot]@users.noreply.github.com> Co-authored-by: Bloop <13398309+vinylspiders@users.noreply.github.com> Co-authored-by: Cameron Lennox <killer65311@gmail.com> Co-authored-by: Tim <timothymtorres@gmail.com> Co-authored-by: Iamgoofball <iamgoofball@gmail.com> Co-authored-by: Layzu666 <121319428+Layzu666@users.noreply.github.com> Co-authored-by: Arturlang <24881678+Arturlang@users.noreply.github.com> Co-authored-by: _0Steven <42909981+00-Steven@users.noreply.github.com> Co-authored-by: mrmanlikesbt <99309552+mrmanlikesbt@users.noreply.github.com> Co-authored-by: Ben10Omintrix <138636438+Ben10Omintrix@users.noreply.github.com> Co-authored-by: John F. Kennedy <54908920+MacaroniCritter@users.noreply.github.com> Co-authored-by: Cursor <102828457+theselfish@users.noreply.github.com> Co-authored-by: Josh <josh.adam.powell@gmail.com> Co-authored-by: Josh Powell <josh.powell@softwire.com> Co-authored-by: Yobrocharlie <Charliemiller5617@gmail.com> Co-authored-by: Hardly3D <66234359+Hardly3D@users.noreply.github.com> Co-authored-by: shayoki <96078776+shayoki@users.noreply.github.com> Co-authored-by: LT3 <83487515+lessthnthree@users.noreply.github.com>
81 lines
3.0 KiB
Plaintext
81 lines
3.0 KiB
Plaintext
///When you have a component accepting multiple connections
|
|
/datum/component/plumbing/multidirectional
|
|
demand_connects = NORTH
|
|
supply_connects = SOUTH | EAST | WEST //SOUTH is straight, EAST is left and WEST is right. We look from the perspective of the insert
|
|
|
|
/**
|
|
* Returns the direction in which this component is connected to an ductnet without the rotation
|
|
* Arguments
|
|
*
|
|
* * datum/ductnet/net - the net we are checking for an connection to
|
|
*/
|
|
/datum/component/plumbing/multidirectional/proc/get_connection(datum/ductnet/net)
|
|
PROTECTED_PROC(TRUE)
|
|
|
|
var/atom/movable/parent_movable = parent
|
|
for(var/A in ducts)
|
|
if(ducts[A] == net)
|
|
return turn(text2num(A), dir2angle(parent_movable.dir) - 180)
|
|
|
|
///Splits reagent amounts along 3 directions
|
|
/datum/component/plumbing/multidirectional/splitter/Initialize(ducting_layer)
|
|
if(!istype(parent, /obj/machinery/plumbing/splitter))
|
|
return COMPONENT_INCOMPATIBLE
|
|
return ..()
|
|
|
|
/datum/component/plumbing/multidirectional/splitter/transfer_to(datum/component/plumbing/target, amount, reagent, datum/ductnet/net, round_robin = TRUE)
|
|
var/obj/machinery/plumbing/splitter/S = parent
|
|
var/limit = INFINITY
|
|
switch(get_connection(net))
|
|
if(SOUTH)
|
|
limit = S.transfer_straight
|
|
if(EAST)
|
|
limit = S.transfer_left
|
|
if(WEST)
|
|
limit = S.transfer_right
|
|
amount = min(amount, limit, reagents.total_volume)
|
|
S.use_energy(S.active_power_usage)
|
|
return ..()
|
|
|
|
///Splits reagents along 3 directions
|
|
/datum/component/plumbing/multidirectional/filter/Initialize(ducting_layer)
|
|
if(!istype(parent, /obj/machinery/plumbing/filter))
|
|
return COMPONENT_INCOMPATIBLE
|
|
return ..()
|
|
|
|
|
|
/**
|
|
* Returns if an reagent can be supplied in an specific direction
|
|
* Arguments
|
|
*
|
|
* * dir - the direction to check
|
|
* * datum/reagent/reagent - the reagent we are checking for
|
|
*/
|
|
/datum/component/plumbing/multidirectional/filter/proc/can_give_in_direction(dir, datum/reagent/reagent)
|
|
PRIVATE_PROC(TRUE)
|
|
|
|
var/obj/machinery/plumbing/filter/F = parent
|
|
switch(dir)
|
|
if(SOUTH) //straight
|
|
return !F.left.Find(reagent) && !F.right.Find(reagent)
|
|
if(EAST) //left
|
|
return F.left.Find(reagent)
|
|
if(WEST) //right
|
|
return F.right.Find(reagent)
|
|
|
|
/datum/component/plumbing/multidirectional/filter/can_give(amount, reagent, datum/ductnet/net)
|
|
return (reagent ? can_give_in_direction(get_connection(net), reagent) : TRUE) && ..()
|
|
|
|
/datum/component/plumbing/multidirectional/filter/transfer_to(datum/component/plumbing/target, amount, reagent, datum/ductnet/net, round_robin = TRUE)
|
|
var/obj/machinery/plumbing/filter/F = parent
|
|
if(reagent)
|
|
reagents.trans_to(target.parent, amount, target_id = reagent, methods = round_robin ? LINEAR : NONE)
|
|
else
|
|
var/direction = get_connection(net)
|
|
var/list/rejected_reagents = list()
|
|
for(var/datum/reagent/R as anything in reagents.reagent_list)
|
|
if(!can_give_in_direction(direction, R.type))
|
|
rejected_reagents += R.type
|
|
reagents.trans_to(target.parent, amount, remove_blacklisted = rejected_reagents, methods = round_robin ? LINEAR : NONE)
|
|
F.use_energy(F.active_power_usage)
|