mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-07-12 08:36:00 +01:00
Alexis
21b4095dfd
Upstream 04/17/2026 fixes https://github.com/Bubberstation/Bubberstation/issues/5549 --------- Signed-off-by: dependabot[bot] <support@github.com> Co-authored-by: tgstation-ci[bot] <179393467+tgstation-ci[bot]@users.noreply.github.com> Co-authored-by: ArcaneMusic <41715314+ArcaneMusic@users.noreply.github.com> Co-authored-by: MrMelbert <51863163+MrMelbert@users.noreply.github.com> Co-authored-by: Rhials <28870487+Rhials@users.noreply.github.com> Co-authored-by: rageguy505 <54517726+rageguy505@users.noreply.github.com> Co-authored-by: LemonInTheDark <58055496+LemonInTheDark@users.noreply.github.com> Co-authored-by: John Willard <53777086+JohnFulpWillard@users.noreply.github.com> Co-authored-by: Aliceee2ch <160794176+Aliceee2ch@users.noreply.github.com> Co-authored-by: Time-Green <7501474+Time-Green@users.noreply.github.com> Co-authored-by: Tsar-Salat <62388554+Tsar-Salat@users.noreply.github.com> Co-authored-by: SmArtKar <44720187+SmArtKar@users.noreply.github.com> Co-authored-by: Maxipat <108554989+Maxipat112@users.noreply.github.com> Co-authored-by: SyncIt21 <110812394+SyncIt21@users.noreply.github.com> Co-authored-by: deltanedas <39013340+deltanedas@users.noreply.github.com> Co-authored-by: SimplyLogan <47579821+loganuk@users.noreply.github.com> Co-authored-by: loganuk <fakeemail123@aol.com> Co-authored-by: Leland Kemble <70413276+lelandkemble@users.noreply.github.com> Co-authored-by: FalloutFalcon <86381784+FalloutFalcon@users.noreply.github.com> Co-authored-by: Roxy <75404941+TealSeer@users.noreply.github.com> Co-authored-by: Lucy <lucy@absolucy.moe> Co-authored-by: siliconOpossum <138069572+siliconOpossum@users.noreply.github.com> Co-authored-by: Isratosh <Isratosh@hotmail.com> Co-authored-by: TheRyeGuyWhoWillNowDie <70169560+TheRyeGuyWhoWillNowDie@users.noreply.github.com> Co-authored-by: Neocloudy <88008002+Neocloudy@users.noreply.github.com> Co-authored-by: Alexander V. <volas@ya.ru> Co-authored-by: ElGitificador <168473461+ElGitificador@users.noreply.github.com> Co-authored-by: Twaticus <46540570+Twaticus@users.noreply.github.com> Co-authored-by: dependabot[bot] <49699333+dependabot[bot]@users.noreply.github.com> Co-authored-by: Bloop <13398309+vinylspiders@users.noreply.github.com> Co-authored-by: Cameron Lennox <killer65311@gmail.com> Co-authored-by: Tim <timothymtorres@gmail.com> Co-authored-by: Iamgoofball <iamgoofball@gmail.com> Co-authored-by: Layzu666 <121319428+Layzu666@users.noreply.github.com> Co-authored-by: Arturlang <24881678+Arturlang@users.noreply.github.com> Co-authored-by: _0Steven <42909981+00-Steven@users.noreply.github.com> Co-authored-by: mrmanlikesbt <99309552+mrmanlikesbt@users.noreply.github.com> Co-authored-by: Ben10Omintrix <138636438+Ben10Omintrix@users.noreply.github.com> Co-authored-by: John F. Kennedy <54908920+MacaroniCritter@users.noreply.github.com> Co-authored-by: Cursor <102828457+theselfish@users.noreply.github.com> Co-authored-by: Josh <josh.adam.powell@gmail.com> Co-authored-by: Josh Powell <josh.powell@softwire.com> Co-authored-by: Yobrocharlie <Charliemiller5617@gmail.com> Co-authored-by: Hardly3D <66234359+Hardly3D@users.noreply.github.com> Co-authored-by: shayoki <96078776+shayoki@users.noreply.github.com> Co-authored-by: LT3 <83487515+lessthnthree@users.noreply.github.com>
64 lines
2.6 KiB
Plaintext
64 lines
2.6 KiB
Plaintext
///Status effect applied when casting a fishing rod at someone, provided the attached fishing hook allows it.
|
|
/datum/status_effect/grouped/hooked
|
|
id = "hooked"
|
|
duration = STATUS_EFFECT_PERMANENT
|
|
tick_interval = STATUS_EFFECT_NO_TICK
|
|
status_type = STATUS_EFFECT_MULTIPLE
|
|
alert_type = /atom/movable/screen/alert/status_effect/hooked
|
|
|
|
/datum/status_effect/grouped/hooked/proc/try_unhook()
|
|
return do_after(owner, 2 SECONDS, timed_action_flags = IGNORE_USER_LOC_CHANGE, extra_checks = CALLBACK(src, PROC_REF(still_exists)), interaction_key = DOAFTER_SOURCE_REMOVING_HOOK)
|
|
|
|
/datum/status_effect/grouped/hooked/proc/still_exists()
|
|
return !QDELETED(src)
|
|
|
|
/datum/status_effect/grouped/hooked/source_added(datum/beam/fishing_line/source)
|
|
RegisterSignal(source, COMSIG_QDELETING, PROC_REF(on_fishing_line_deleted))
|
|
|
|
/datum/status_effect/grouped/hooked/proc/on_fishing_line_deleted(datum/source)
|
|
SIGNAL_HANDLER
|
|
owner.remove_status_effect(type, source)
|
|
|
|
/atom/movable/screen/alert/status_effect/hooked
|
|
name = "Snagged By Hook"
|
|
desc = "You're being caught like a fish by some asshat! Click to safely remove the hook or move away far enough to snap it off."
|
|
use_user_hud_icon = USER_HUD_STYLE_INHERIT
|
|
overlay_state = "hooked"
|
|
clickable_glow = TRUE
|
|
|
|
/atom/movable/screen/alert/status_effect/hooked/Click()
|
|
. = ..()
|
|
if(!.)
|
|
return
|
|
if(!owner.can_resist())
|
|
return
|
|
owner.balloon_alert(owner, "removing hook...")
|
|
var/datum/status_effect/grouped/hooked/effect = owner.has_status_effect(attached_effect.type)
|
|
if(!effect.try_unhook())
|
|
return
|
|
owner.balloon_alert(owner, "hook removed")
|
|
var/datum/beam/fishing_line/rand_source = pick(effect.sources)
|
|
qdel(rand_source)
|
|
|
|
///Version used by the jawed fishing hook, which also applies slowdown
|
|
/datum/status_effect/grouped/hooked/jaws
|
|
id = "hooked_jaws"
|
|
alert_type = /atom/movable/screen/alert/status_effect/hooked/jaws
|
|
|
|
/datum/status_effect/grouped/hooked/jaws/on_apply()
|
|
. = ..()
|
|
owner.add_movespeed_modifier(/datum/movespeed_modifier/hook_jawed)
|
|
|
|
/datum/status_effect/grouped/hooked/jaws/on_remove()
|
|
. = ..()
|
|
owner.remove_movespeed_modifier(/datum/movespeed_modifier/hook_jawed)
|
|
|
|
/datum/status_effect/grouped/hooked/jaws/try_unhook()
|
|
return do_after(owner, 10 SECONDS, extra_checks = CALLBACK(src, PROC_REF(still_exists)), interaction_key = DOAFTER_SOURCE_REMOVING_HOOK)
|
|
|
|
/atom/movable/screen/alert/status_effect/hooked/jaws
|
|
name = "Snagged By Jaws"
|
|
desc = "You've been snagged by some sort of beartrap-slash-fishing-hook-gizmo! Click to safely remove the hook or move away far enough to snap it off."
|
|
use_user_hud_icon = USER_HUD_STYLE_INHERIT
|
|
overlay_state = "hooked_jaws"
|