mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-07-12 00:27:31 +01:00
Nick
834245ecdb
## About The Pull Request Hello hello the evil folder mover goat is back, i will destroy years worth of muscle memory. Items is an folder alot of stuff that really didn't get a spefific location. Items/Weaponry Contains Shields.dm Items/Weaponry/Melee Contains (Most of the extra dm files come from me splitting misc/weaponry.dm into its own categories killing offf weaponry.dm in its whole) baseball_bat.dm, baton.dm, chainofcommand.dm, chainsaw.dm, claymore.dm, dualsaber.dm, energy.dm fireaxe.dm, high_frequency_blade.dm, his_grace.dm, katana.dm, knives.dm, misc.dm, powerfist.dm, sabre.dm soulscythe.dm, spear.dm, supermatter_sword.dm. Items/weaponry/ranged Contains flamethrower.dm, pnuematic_cannon.dm, throwing_star.dm items/tools Contains control_wand.dm, extinguisher.dm, inducer.dm, spess_knife.dm, theft_tools.dm items/tools/engineering Contains airlock_painter.dm, decal_painter.dm, paintable_decals.dm, crowbar.dm, screwdriver.dm, weldingtool.dm wirebbrush.dm, wirecutters.dm, wrench.dm items/tools/janitorial Contains broom.dm, janitor_key.dm items/tools/medical Contains bodybag.dm, cane.dm, defib.dm, reflex_hammer.dm boxcutter.dm is merged into knives.dm Kitchen.dm renamed into kitchen utensils and moved into food and drinks module surgery_tray.dm moved into surgery module banhammer/extendo hand moved from weaponry into toys.dm balloon mallet moved into clown_items.dm ectoplasm moved from weaponry.dm into soulstone.dm (since thats the resulting residue when a shade dies, and not really a weapon) ## Why It's Good For The Game So things are way easier to navigate ## Changelog
115 lines
3.8 KiB
Plaintext
115 lines
3.8 KiB
Plaintext
GLOBAL_DATUM(bridge_axe, /obj/item/fireaxe)
|
|
|
|
/*
|
|
* Fireaxe
|
|
*/
|
|
/obj/item/fireaxe // DEM AXES MAN, marker -Agouri
|
|
name = "fire axe"
|
|
desc = "Truly, the weapon of a madman. Who would think to fight fire with an axe?"
|
|
icon = 'icons/obj/weapons/fireaxe.dmi'
|
|
icon_state = "fireaxe0"
|
|
base_icon_state = "fireaxe"
|
|
lefthand_file = 'icons/mob/inhands/weapons/axes_lefthand.dmi'
|
|
righthand_file = 'icons/mob/inhands/weapons/axes_righthand.dmi'
|
|
force = 5
|
|
throwforce = 15
|
|
demolition_mod = 1.25
|
|
w_class = WEIGHT_CLASS_BULKY
|
|
obj_flags = CONDUCTS_ELECTRICITY
|
|
slot_flags = ITEM_SLOT_BACK
|
|
attack_verb_continuous = list("attacks", "chops", "cleaves", "tears", "lacerates", "cuts")
|
|
attack_verb_simple = list("attack", "chop", "cleave", "tear", "lacerate", "cut")
|
|
hitsound = 'sound/items/weapons/bladeslice.ogg'
|
|
sharpness = SHARP_EDGED
|
|
armor_type = /datum/armor/item_fireaxe
|
|
resistance_flags = FIRE_PROOF
|
|
wound_bonus = -15
|
|
exposed_wound_bonus = 20
|
|
/// How much damage to do unwielded
|
|
var/force_unwielded = 5
|
|
/// How much damage to do wielded
|
|
var/force_wielded = 24
|
|
|
|
/datum/armor/item_fireaxe
|
|
fire = 100
|
|
acid = 30
|
|
|
|
/obj/item/fireaxe/Initialize(mapload)
|
|
. = ..()
|
|
if(!GLOB.bridge_axe && istype(get_area(src), /area/station/command))
|
|
GLOB.bridge_axe = src
|
|
|
|
AddComponent(/datum/component/butchering, \
|
|
speed = 10 SECONDS, \
|
|
effectiveness = 80, \
|
|
bonus_modifier = 0 , \
|
|
butcher_sound = hitsound, \
|
|
)
|
|
//axes are not known for being precision butchering tools
|
|
AddComponent(/datum/component/two_handed, force_unwielded=force_unwielded, force_wielded=force_wielded, icon_wielded="[base_icon_state]1")
|
|
|
|
/obj/item/fireaxe/Destroy()
|
|
if(GLOB.bridge_axe == src)
|
|
GLOB.bridge_axe = null
|
|
return ..()
|
|
|
|
/obj/item/fireaxe/get_demolition_modifier(obj/target)
|
|
return HAS_TRAIT(src, TRAIT_WIELDED) ? demolition_mod : 0.8
|
|
|
|
/obj/item/fireaxe/update_icon_state()
|
|
icon_state = "[base_icon_state]0"
|
|
return ..()
|
|
|
|
/obj/item/fireaxe/suicide_act(mob/living/user)
|
|
user.visible_message(span_suicide("[user] axes [user.p_them()]self from head to toe! It looks like [user.p_theyre()] trying to commit suicide!"))
|
|
return BRUTELOSS
|
|
|
|
/obj/item/fireaxe/afterattack(atom/target, mob/user, list/modifiers, list/attack_modifiers)
|
|
if(!HAS_TRAIT(src, TRAIT_WIELDED)) //destroys windows and grilles in one hit
|
|
return
|
|
if(target.resistance_flags & INDESTRUCTIBLE)
|
|
return
|
|
if(QDELETED(target))
|
|
return
|
|
if(istype(target, /obj/structure/window) || istype(target, /obj/structure/grille))
|
|
target.atom_destruction("fireaxe")
|
|
|
|
/*
|
|
* Bone Axe
|
|
*/
|
|
/obj/item/fireaxe/boneaxe // Blatant imitation of the fireaxe, but made out of bone.
|
|
name = "bone axe"
|
|
desc = "A large, vicious axe crafted out of several sharpened bone plates and crudely tied together. Made of monsters, by killing monsters, for killing monsters."
|
|
icon_state = "bone_axe0"
|
|
base_icon_state = "bone_axe"
|
|
icon_angle = 180
|
|
force_unwielded = 5
|
|
force_wielded = 23
|
|
custom_materials = list(/datum/material/bone = SHEET_MATERIAL_AMOUNT * 6)
|
|
|
|
/*
|
|
* Metal Hydrogen Axe
|
|
*/
|
|
/obj/item/fireaxe/metal_h2_axe
|
|
name = "metallic hydrogen axe"
|
|
desc = "A lightweight crowbar with an extreme sharp fire axe head attached. It trades its heft as a weapon by making it easier to carry around when holstered to suits without having to sacrifice your backpack."
|
|
icon_state = "metalh2_axe0"
|
|
base_icon_state = "metalh2_axe"
|
|
icon_angle = -45
|
|
force_unwielded = 5
|
|
force_wielded = 15
|
|
demolition_mod = 2
|
|
tool_behaviour = TOOL_CROWBAR
|
|
toolspeed = 1
|
|
usesound = 'sound/items/tools/crowbar.ogg'
|
|
|
|
//boarding axe
|
|
/obj/item/fireaxe/boardingaxe
|
|
name = "boarding axe"
|
|
desc = "A hulking cleaver that feels like a burden just looking at it. Seems excellent at halving obstacles like windows, airlocks, barricades and people."
|
|
icon_state = "boarding_axe0"
|
|
base_icon_state = "boarding_axe"
|
|
force_unwielded = 5
|
|
force_wielded = 30
|
|
demolition_mod = 3
|