mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-07-13 09:05:11 +01:00
Alexis
21b4095dfd
Upstream 04/17/2026 fixes https://github.com/Bubberstation/Bubberstation/issues/5549 --------- Signed-off-by: dependabot[bot] <support@github.com> Co-authored-by: tgstation-ci[bot] <179393467+tgstation-ci[bot]@users.noreply.github.com> Co-authored-by: ArcaneMusic <41715314+ArcaneMusic@users.noreply.github.com> Co-authored-by: MrMelbert <51863163+MrMelbert@users.noreply.github.com> Co-authored-by: Rhials <28870487+Rhials@users.noreply.github.com> Co-authored-by: rageguy505 <54517726+rageguy505@users.noreply.github.com> Co-authored-by: LemonInTheDark <58055496+LemonInTheDark@users.noreply.github.com> Co-authored-by: John Willard <53777086+JohnFulpWillard@users.noreply.github.com> Co-authored-by: Aliceee2ch <160794176+Aliceee2ch@users.noreply.github.com> Co-authored-by: Time-Green <7501474+Time-Green@users.noreply.github.com> Co-authored-by: Tsar-Salat <62388554+Tsar-Salat@users.noreply.github.com> Co-authored-by: SmArtKar <44720187+SmArtKar@users.noreply.github.com> Co-authored-by: Maxipat <108554989+Maxipat112@users.noreply.github.com> Co-authored-by: SyncIt21 <110812394+SyncIt21@users.noreply.github.com> Co-authored-by: deltanedas <39013340+deltanedas@users.noreply.github.com> Co-authored-by: SimplyLogan <47579821+loganuk@users.noreply.github.com> Co-authored-by: loganuk <fakeemail123@aol.com> Co-authored-by: Leland Kemble <70413276+lelandkemble@users.noreply.github.com> Co-authored-by: FalloutFalcon <86381784+FalloutFalcon@users.noreply.github.com> Co-authored-by: Roxy <75404941+TealSeer@users.noreply.github.com> Co-authored-by: Lucy <lucy@absolucy.moe> Co-authored-by: siliconOpossum <138069572+siliconOpossum@users.noreply.github.com> Co-authored-by: Isratosh <Isratosh@hotmail.com> Co-authored-by: TheRyeGuyWhoWillNowDie <70169560+TheRyeGuyWhoWillNowDie@users.noreply.github.com> Co-authored-by: Neocloudy <88008002+Neocloudy@users.noreply.github.com> Co-authored-by: Alexander V. <volas@ya.ru> Co-authored-by: ElGitificador <168473461+ElGitificador@users.noreply.github.com> Co-authored-by: Twaticus <46540570+Twaticus@users.noreply.github.com> Co-authored-by: dependabot[bot] <49699333+dependabot[bot]@users.noreply.github.com> Co-authored-by: Bloop <13398309+vinylspiders@users.noreply.github.com> Co-authored-by: Cameron Lennox <killer65311@gmail.com> Co-authored-by: Tim <timothymtorres@gmail.com> Co-authored-by: Iamgoofball <iamgoofball@gmail.com> Co-authored-by: Layzu666 <121319428+Layzu666@users.noreply.github.com> Co-authored-by: Arturlang <24881678+Arturlang@users.noreply.github.com> Co-authored-by: _0Steven <42909981+00-Steven@users.noreply.github.com> Co-authored-by: mrmanlikesbt <99309552+mrmanlikesbt@users.noreply.github.com> Co-authored-by: Ben10Omintrix <138636438+Ben10Omintrix@users.noreply.github.com> Co-authored-by: John F. Kennedy <54908920+MacaroniCritter@users.noreply.github.com> Co-authored-by: Cursor <102828457+theselfish@users.noreply.github.com> Co-authored-by: Josh <josh.adam.powell@gmail.com> Co-authored-by: Josh Powell <josh.powell@softwire.com> Co-authored-by: Yobrocharlie <Charliemiller5617@gmail.com> Co-authored-by: Hardly3D <66234359+Hardly3D@users.noreply.github.com> Co-authored-by: shayoki <96078776+shayoki@users.noreply.github.com> Co-authored-by: LT3 <83487515+lessthnthree@users.noreply.github.com>
70 lines
2.0 KiB
Plaintext
70 lines
2.0 KiB
Plaintext
#define BASE_HEAL 4
|
|
|
|
/datum/component/netpod_healing
|
|
|
|
/datum/component/netpod_healing/Initialize(obj/machinery/netpod/pod)
|
|
if (!iscarbon(parent))
|
|
return COMPONENT_INCOMPATIBLE
|
|
|
|
RegisterSignals(
|
|
pod,
|
|
list(COMSIG_MACHINERY_BROKEN, COMSIG_QDELETING, COMSIG_BITRUNNER_NETPOD_OPENED),
|
|
PROC_REF(on_remove),
|
|
)
|
|
|
|
RegisterSignal(parent, COMSIG_MOVABLE_MOVED, PROC_REF(on_remove))
|
|
|
|
var/mob/living/carbon/player = parent
|
|
player.apply_status_effect(/datum/status_effect/embryonic, STASIS_NETPOD_EFFECT)
|
|
|
|
START_PROCESSING(SSmachines, src)
|
|
|
|
/datum/component/netpod_healing/Destroy(force)
|
|
STOP_PROCESSING(SSmachines, src)
|
|
|
|
var/mob/living/carbon/player = parent
|
|
player.remove_status_effect(/datum/status_effect/embryonic)
|
|
|
|
return ..()
|
|
|
|
/datum/component/netpod_healing/process(seconds_per_tick)
|
|
var/mob/living/carbon/owner = parent
|
|
if(isnull(owner))
|
|
qdel(src)
|
|
return
|
|
|
|
var/need_mob_update = FALSE
|
|
need_mob_update += owner.adjust_brute_loss(-BASE_HEAL * seconds_per_tick, updating_health = FALSE)
|
|
need_mob_update += owner.adjust_fire_loss(-BASE_HEAL * seconds_per_tick, updating_health = FALSE)
|
|
need_mob_update += owner.adjust_tox_loss(-BASE_HEAL * seconds_per_tick, updating_health = FALSE, forced = TRUE)
|
|
|
|
owner.adjust_blood_volume(BASE_HEAL * seconds_per_tick, maximum = BLOOD_VOLUME_NORMAL)
|
|
|
|
if(need_mob_update)
|
|
owner.updatehealth()
|
|
|
|
/// Deletes itself when the machine was opened
|
|
/datum/component/netpod_healing/proc/on_remove()
|
|
SIGNAL_HANDLER
|
|
|
|
qdel(src)
|
|
|
|
/datum/status_effect/embryonic
|
|
id = "embryonic"
|
|
alert_type = /atom/movable/screen/alert/status_effect/embryonic
|
|
|
|
/datum/status_effect/embryonic/on_apply()
|
|
ADD_TRAIT(owner, TRAIT_STASIS, TRAIT_STATUS_EFFECT(id))
|
|
return TRUE
|
|
|
|
/datum/status_effect/embryonic/on_remove()
|
|
REMOVE_TRAIT(owner, TRAIT_STASIS, TRAIT_STATUS_EFFECT(id))
|
|
|
|
/atom/movable/screen/alert/status_effect/embryonic
|
|
name = "Embryonic Stasis"
|
|
use_user_hud_icon = USER_HUD_STYLE_INHERIT
|
|
overlay_state = "netpod_stasis"
|
|
desc = "You feel like you're in a dream."
|
|
|
|
#undef BASE_HEAL
|