mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-07-18 11:36:24 +01:00
Alexis
21b4095dfd
Upstream 04/17/2026 fixes https://github.com/Bubberstation/Bubberstation/issues/5549 --------- Signed-off-by: dependabot[bot] <support@github.com> Co-authored-by: tgstation-ci[bot] <179393467+tgstation-ci[bot]@users.noreply.github.com> Co-authored-by: ArcaneMusic <41715314+ArcaneMusic@users.noreply.github.com> Co-authored-by: MrMelbert <51863163+MrMelbert@users.noreply.github.com> Co-authored-by: Rhials <28870487+Rhials@users.noreply.github.com> Co-authored-by: rageguy505 <54517726+rageguy505@users.noreply.github.com> Co-authored-by: LemonInTheDark <58055496+LemonInTheDark@users.noreply.github.com> Co-authored-by: John Willard <53777086+JohnFulpWillard@users.noreply.github.com> Co-authored-by: Aliceee2ch <160794176+Aliceee2ch@users.noreply.github.com> Co-authored-by: Time-Green <7501474+Time-Green@users.noreply.github.com> Co-authored-by: Tsar-Salat <62388554+Tsar-Salat@users.noreply.github.com> Co-authored-by: SmArtKar <44720187+SmArtKar@users.noreply.github.com> Co-authored-by: Maxipat <108554989+Maxipat112@users.noreply.github.com> Co-authored-by: SyncIt21 <110812394+SyncIt21@users.noreply.github.com> Co-authored-by: deltanedas <39013340+deltanedas@users.noreply.github.com> Co-authored-by: SimplyLogan <47579821+loganuk@users.noreply.github.com> Co-authored-by: loganuk <fakeemail123@aol.com> Co-authored-by: Leland Kemble <70413276+lelandkemble@users.noreply.github.com> Co-authored-by: FalloutFalcon <86381784+FalloutFalcon@users.noreply.github.com> Co-authored-by: Roxy <75404941+TealSeer@users.noreply.github.com> Co-authored-by: Lucy <lucy@absolucy.moe> Co-authored-by: siliconOpossum <138069572+siliconOpossum@users.noreply.github.com> Co-authored-by: Isratosh <Isratosh@hotmail.com> Co-authored-by: TheRyeGuyWhoWillNowDie <70169560+TheRyeGuyWhoWillNowDie@users.noreply.github.com> Co-authored-by: Neocloudy <88008002+Neocloudy@users.noreply.github.com> Co-authored-by: Alexander V. <volas@ya.ru> Co-authored-by: ElGitificador <168473461+ElGitificador@users.noreply.github.com> Co-authored-by: Twaticus <46540570+Twaticus@users.noreply.github.com> Co-authored-by: dependabot[bot] <49699333+dependabot[bot]@users.noreply.github.com> Co-authored-by: Bloop <13398309+vinylspiders@users.noreply.github.com> Co-authored-by: Cameron Lennox <killer65311@gmail.com> Co-authored-by: Tim <timothymtorres@gmail.com> Co-authored-by: Iamgoofball <iamgoofball@gmail.com> Co-authored-by: Layzu666 <121319428+Layzu666@users.noreply.github.com> Co-authored-by: Arturlang <24881678+Arturlang@users.noreply.github.com> Co-authored-by: _0Steven <42909981+00-Steven@users.noreply.github.com> Co-authored-by: mrmanlikesbt <99309552+mrmanlikesbt@users.noreply.github.com> Co-authored-by: Ben10Omintrix <138636438+Ben10Omintrix@users.noreply.github.com> Co-authored-by: John F. Kennedy <54908920+MacaroniCritter@users.noreply.github.com> Co-authored-by: Cursor <102828457+theselfish@users.noreply.github.com> Co-authored-by: Josh <josh.adam.powell@gmail.com> Co-authored-by: Josh Powell <josh.powell@softwire.com> Co-authored-by: Yobrocharlie <Charliemiller5617@gmail.com> Co-authored-by: Hardly3D <66234359+Hardly3D@users.noreply.github.com> Co-authored-by: shayoki <96078776+shayoki@users.noreply.github.com> Co-authored-by: LT3 <83487515+lessthnthree@users.noreply.github.com>
55 lines
2.2 KiB
Plaintext
55 lines
2.2 KiB
Plaintext
/datum/preference/choiced/vampire_status
|
|
savefile_key = "feature_vampire_status"
|
|
savefile_identifier = PREFERENCE_CHARACTER
|
|
category = PREFERENCE_CATEGORY_FEATURES
|
|
priority = PREFERENCE_PRIORITY_NAME_MODIFICATIONS //this will be overwritten by names otherwise
|
|
main_feature_name = "Vampire status"
|
|
should_generate_icons = TRUE
|
|
relevant_inherent_trait = TRAIT_BLOOD_CLANS
|
|
should_update_preview = FALSE
|
|
|
|
/datum/preference/choiced/vampire_status/create_default_value()
|
|
return "Inoculated" //eh, have em try out the mechanic first
|
|
|
|
/datum/preference/choiced/vampire_status/init_possible_values()
|
|
return list("Inoculated", "Outcast")
|
|
|
|
/datum/preference/choiced/vampire_status/icon_for(value)
|
|
switch (value)
|
|
if ("Inoculated")
|
|
return uni_icon('icons/obj/drinks/drinks.dmi', "bloodglass")
|
|
if ("Outcast")
|
|
return uni_icon('icons/obj/medical/bloodpack.dmi', "generic_bloodpack")
|
|
|
|
///list that stores a vampire house name for each department
|
|
GLOBAL_LIST_EMPTY(vampire_houses)
|
|
|
|
/datum/preference/choiced/vampire_status/apply_to_human(mob/living/carbon/human/target, value)
|
|
if(!HAS_TRAIT(target, TRAIT_BLOOD_CLANS))
|
|
return
|
|
|
|
if(value != "Inoculated")
|
|
return
|
|
|
|
//find and setup the house (department) this vampire is joining
|
|
var/datum/job_department/vampire_house
|
|
var/datum/job/vampire_job = SSjob.get_job(target.job)
|
|
if(!vampire_job) //no job or no mind LOSERS
|
|
return
|
|
var/list/valid_departments = (SSjob.joinable_departments.Copy()) - list(/datum/job_department/silicon, /datum/job_department/undefined)
|
|
for(var/datum/job_department/potential_house as anything in valid_departments)
|
|
if(vampire_job in potential_house.department_jobs)
|
|
vampire_house = potential_house
|
|
break
|
|
if(!vampire_house) //sillycones
|
|
return
|
|
if(!GLOB.vampire_houses[vampire_house.department_name])
|
|
GLOB.vampire_houses[vampire_house.department_name] = pick(GLOB.vampire_house_names)
|
|
var/house_name = GLOB.vampire_houses[vampire_house.department_name]
|
|
|
|
//modify name (Platos Syrup > Platos de Lioncourt)
|
|
var/first_space_index = findtextEx(target.real_name, " ")
|
|
var/new_name = copytext(target.real_name, 1, first_space_index + 1)
|
|
new_name += house_name
|
|
target.fully_replace_character_name(target.real_name, new_name)
|