mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-07-10 07:41:16 +01:00
Ghom
0b0c5ea91e
## About The Pull Request Extends the part of the crafting unit test that ensures consistency between the total mats of the components of a recipe (or rather, the result of said recipe) and a generic instance of the same type as its result, previously only implemented on food recipes. ## Why It's Good For The Game This ensures a degree of consistency with the material composition of various objects in the game. I couldn't do it in the original PR as that one was too big already and it took months to get it merged, and have the relative bugs fixed. Currently a WIP as I slowly deal with the unit test reports. ## Changelog 🆑 refactor: Follow-up to the crafting/material refactor from months ago. All objects crafted with stacks now inherit their mat composition (not necessarily the effects and color) by default, while previously only a few things like chair, sinks and toilets did. Report any object looking or behaving weirdly as a result. fix: The material composition of ammo boxes is no longer a 1/10 of what it's supposed to be. It was a shitty hack to make it harder to recycle empty ammo boxes. Instead, they lose materials as they're emptied now. /🆑
57 lines
2.3 KiB
Plaintext
57 lines
2.3 KiB
Plaintext
/**
|
|
* # Experi-Scanner
|
|
*
|
|
* Handheld scanning unit to perform scanning experiments
|
|
*/
|
|
/obj/item/experi_scanner
|
|
name = "Experi-Scanner"
|
|
desc = "A handheld scanner used for completing the many experiments of modern science."
|
|
w_class = WEIGHT_CLASS_SMALL
|
|
icon = 'icons/obj/devices/scanner.dmi'
|
|
icon_state = "experiscanner"
|
|
lefthand_file = 'icons/mob/inhands/items/devices_lefthand.dmi'
|
|
righthand_file = 'icons/mob/inhands/items/devices_righthand.dmi'
|
|
sound_vary = TRUE
|
|
pickup_sound = SFX_GENERIC_DEVICE_PICKUP
|
|
drop_sound = SFX_GENERIC_DEVICE_DROP
|
|
|
|
/obj/item/experi_scanner/Initialize(mapload)
|
|
..()
|
|
return INITIALIZE_HINT_LATELOAD
|
|
|
|
// Late initialize to allow for the rnd servers to initialize first
|
|
/obj/item/experi_scanner/LateInitialize()
|
|
var/static/list/handheld_signals = list(
|
|
COMSIG_ITEM_PRE_ATTACK = TYPE_PROC_REF(/datum/component/experiment_handler, try_run_handheld_experiment),
|
|
COMSIG_ITEM_AFTERATTACK = TYPE_PROC_REF(/datum/component/experiment_handler, ignored_handheld_experiment_attempt),
|
|
)
|
|
AddComponent(/datum/component/experiment_handler, \
|
|
allowed_experiments = list(/datum/experiment/scanning, /datum/experiment/physical), \
|
|
disallowed_traits = EXPERIMENT_TRAIT_DESTRUCTIVE, \
|
|
config_flags = EXPERIMENT_CONFIG_ALWAYS_ANNOUNCE, \
|
|
experiment_signals = handheld_signals, \
|
|
)
|
|
|
|
/obj/item/experi_scanner/suicide_act(mob/living/carbon/user)
|
|
user.visible_message(span_suicide("[user] is giving in to the Great Toilet Beyond! It looks like [user.p_theyre()] trying to commit suicide!"))
|
|
|
|
forceMove(drop_location())
|
|
user.forceMove(src)
|
|
user.AddComponent(/datum/component/itembound, src) //basically a bread smite but with a bloody finale
|
|
icon_state = "experiscanner_closed"
|
|
add_atom_colour(COLOR_RED, ADMIN_COLOUR_PRIORITY)
|
|
|
|
playsound(src, 'sound/effects/pope_entry.ogg', 60, TRUE)
|
|
playsound(src, 'sound/machines/destructive_scanner/ScanDangerous.ogg', 40)
|
|
user.emote("scream")
|
|
|
|
addtimer(CALLBACK(src, PROC_REF(make_meat_toilet), user), 5 SECONDS)
|
|
return MANUAL_SUICIDE
|
|
|
|
/obj/item/experi_scanner/proc/make_meat_toilet(mob/living/carbon/user)
|
|
///The toilet we're about to unleash unto this cursed plane of existence
|
|
new /obj/structure/toilet/greyscale/flesh (drop_location(), user) //the toilet's Initialize proc will handle the rest from here.
|
|
|
|
icon_state = "experiscanner"
|
|
remove_atom_colour(ADMIN_COLOUR_PRIORITY, COLOR_RED)
|