mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-07-15 10:04:30 +01:00
Alexis
21b4095dfd
Upstream 04/17/2026 fixes https://github.com/Bubberstation/Bubberstation/issues/5549 --------- Signed-off-by: dependabot[bot] <support@github.com> Co-authored-by: tgstation-ci[bot] <179393467+tgstation-ci[bot]@users.noreply.github.com> Co-authored-by: ArcaneMusic <41715314+ArcaneMusic@users.noreply.github.com> Co-authored-by: MrMelbert <51863163+MrMelbert@users.noreply.github.com> Co-authored-by: Rhials <28870487+Rhials@users.noreply.github.com> Co-authored-by: rageguy505 <54517726+rageguy505@users.noreply.github.com> Co-authored-by: LemonInTheDark <58055496+LemonInTheDark@users.noreply.github.com> Co-authored-by: John Willard <53777086+JohnFulpWillard@users.noreply.github.com> Co-authored-by: Aliceee2ch <160794176+Aliceee2ch@users.noreply.github.com> Co-authored-by: Time-Green <7501474+Time-Green@users.noreply.github.com> Co-authored-by: Tsar-Salat <62388554+Tsar-Salat@users.noreply.github.com> Co-authored-by: SmArtKar <44720187+SmArtKar@users.noreply.github.com> Co-authored-by: Maxipat <108554989+Maxipat112@users.noreply.github.com> Co-authored-by: SyncIt21 <110812394+SyncIt21@users.noreply.github.com> Co-authored-by: deltanedas <39013340+deltanedas@users.noreply.github.com> Co-authored-by: SimplyLogan <47579821+loganuk@users.noreply.github.com> Co-authored-by: loganuk <fakeemail123@aol.com> Co-authored-by: Leland Kemble <70413276+lelandkemble@users.noreply.github.com> Co-authored-by: FalloutFalcon <86381784+FalloutFalcon@users.noreply.github.com> Co-authored-by: Roxy <75404941+TealSeer@users.noreply.github.com> Co-authored-by: Lucy <lucy@absolucy.moe> Co-authored-by: siliconOpossum <138069572+siliconOpossum@users.noreply.github.com> Co-authored-by: Isratosh <Isratosh@hotmail.com> Co-authored-by: TheRyeGuyWhoWillNowDie <70169560+TheRyeGuyWhoWillNowDie@users.noreply.github.com> Co-authored-by: Neocloudy <88008002+Neocloudy@users.noreply.github.com> Co-authored-by: Alexander V. <volas@ya.ru> Co-authored-by: ElGitificador <168473461+ElGitificador@users.noreply.github.com> Co-authored-by: Twaticus <46540570+Twaticus@users.noreply.github.com> Co-authored-by: dependabot[bot] <49699333+dependabot[bot]@users.noreply.github.com> Co-authored-by: Bloop <13398309+vinylspiders@users.noreply.github.com> Co-authored-by: Cameron Lennox <killer65311@gmail.com> Co-authored-by: Tim <timothymtorres@gmail.com> Co-authored-by: Iamgoofball <iamgoofball@gmail.com> Co-authored-by: Layzu666 <121319428+Layzu666@users.noreply.github.com> Co-authored-by: Arturlang <24881678+Arturlang@users.noreply.github.com> Co-authored-by: _0Steven <42909981+00-Steven@users.noreply.github.com> Co-authored-by: mrmanlikesbt <99309552+mrmanlikesbt@users.noreply.github.com> Co-authored-by: Ben10Omintrix <138636438+Ben10Omintrix@users.noreply.github.com> Co-authored-by: John F. Kennedy <54908920+MacaroniCritter@users.noreply.github.com> Co-authored-by: Cursor <102828457+theselfish@users.noreply.github.com> Co-authored-by: Josh <josh.adam.powell@gmail.com> Co-authored-by: Josh Powell <josh.powell@softwire.com> Co-authored-by: Yobrocharlie <Charliemiller5617@gmail.com> Co-authored-by: Hardly3D <66234359+Hardly3D@users.noreply.github.com> Co-authored-by: shayoki <96078776+shayoki@users.noreply.github.com> Co-authored-by: LT3 <83487515+lessthnthree@users.noreply.github.com>
71 lines
2.7 KiB
Plaintext
71 lines
2.7 KiB
Plaintext
/**
|
|
* # Reagent Injector Component
|
|
*
|
|
* Injects reagents into the user.
|
|
* Requires a shell that can be inserted into a mob that reagents can be injected into.
|
|
*/
|
|
|
|
/obj/item/circuit_component/reagent_injector
|
|
display_name = "Reagent Injector"
|
|
desc = "A component that can inject reagents from the circuit's reagent storage."
|
|
category = "Entity"
|
|
//SKYRAT EDIT CHANGE BEGIN - Add container type flag - This is required since we have two reagent components, and the BCI only allows one active
|
|
//circuit_flags = CIRCUIT_NO_DUPLICATES - SKYRAT EDIT - ORIGINAL
|
|
circuit_flags = CIRCUIT_NO_DUPLICATES|CIRCUIT_REAGENT_CONTAINER_TYPE
|
|
//SKYRAT EDIT CHANGE END
|
|
|
|
required_shells = list(/obj/item/organ/cyberimp/bci, /obj/item/implant)
|
|
|
|
var/datum/port/input/inject
|
|
var/datum/port/output/injected
|
|
|
|
var/obj/item/shell_item
|
|
|
|
/obj/item/circuit_component/reagent_injector/Initialize(mapload)
|
|
. = ..()
|
|
create_reagents(15, OPENCONTAINER) //This is mostly used in the case of the shell still having reagents in it when the component is removed.
|
|
|
|
/obj/item/circuit_component/reagent_injector/populate_ports()
|
|
. = ..()
|
|
inject = add_input_port("Inject", PORT_TYPE_SIGNAL, trigger = PROC_REF(trigger_inject))
|
|
injected = add_output_port("Injected", PORT_TYPE_SIGNAL)
|
|
|
|
/obj/item/circuit_component/reagent_injector/proc/get_mob()
|
|
if(istype(shell_item, /obj/item/organ/cyberimp/bci))
|
|
var/obj/item/organ/cyberimp/bci/shell_bci = shell_item
|
|
return shell_bci.owner
|
|
if(istype(shell_item, /obj/item/implant))
|
|
var/obj/item/implant/shell_implant = shell_item
|
|
return shell_implant.imp_in
|
|
|
|
/obj/item/circuit_component/reagent_injector/proc/trigger_inject()
|
|
CIRCUIT_TRIGGER
|
|
var/mob/living/mob_to_inject = get_mob()
|
|
if(!istype(mob_to_inject))
|
|
return
|
|
if(!mob_to_inject.reagents)
|
|
return
|
|
if(mob_to_inject.reagents.total_volume + shell_item.reagents.total_volume > mob_to_inject.reagents.maximum_volume)
|
|
return
|
|
var/contained = shell_item.reagents.get_reagent_log_string()
|
|
var/units = shell_item.reagents.trans_to(mob_to_inject.reagents, shell_item.reagents.total_volume, methods = INJECT)
|
|
if(units)
|
|
injected.set_output(COMPONENT_SIGNAL)
|
|
log_combat(mob_to_inject, mob_to_inject, "injected", shell_item, "which had [contained]")
|
|
|
|
/obj/item/circuit_component/reagent_injector/register_shell(atom/movable/shell)
|
|
. = ..()
|
|
if(is_type_in_list(shell, required_shells))
|
|
shell_item = shell
|
|
shell_item.create_reagents(15, OPENCONTAINER)
|
|
if(reagents.total_volume)
|
|
reagents.trans_to(shell_item, reagents.total_volume)
|
|
|
|
/obj/item/circuit_component/reagent_injector/unregister_shell(atom/movable/shell)
|
|
. = ..()
|
|
if(shell_item?.reagents)
|
|
if(shell_item.reagents.total_volume)
|
|
shell_item.reagents.trans_to(src, shell_item.reagents.total_volume)
|
|
QDEL_NULL(shell_item.reagents)
|
|
shell_item = null
|