mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-07-14 17:45:02 +01:00
John Willard
751bfc08bb
## About The Pull Request Removes the IC tab in its entirety - Some mobs (Blob Minion & Lightgeist) had manually removed the "pull" verb, this replaces it with taking away their pull force. - Lightgeist had their "Me" verb manually removed, this is replaced by giving them Emotemute trait (the same that mime's bane gives) - Floor Changer: You can now RMB the arrow buttons to look in a direction w/o moving. Added a tip to help with this. - Exit Hivemind: Already an action button and was removed without further edits ### Removed entirely Rest Resist Look Up/Down Move Upwards/Down Activate Held Object Open Language Menu Memories View Skills ### Moved to command bar (secret verb ooh) because I am biased Sleep Navigate ### Martial Arts Martial Arts had a button to see your current skills & the ability to cycle between artstyles. This was replaced with 1 action button that does both of these. <img width="317" height="148" alt="image" src="https://github.com/user-attachments/assets/afed910f-b6b6-441d-86cb-dade0e253044" /> Name auto-updates as you swap artstyle to whatever help verb the current style uses. Mention of RMB in the name is only there if you have more than 1 martial art, but the desc will remain just so players can see it even if they only have one, for future reference. ## Why It's Good For The Game Brings greater visibility to Martial Art stuff, and especially since the stat panel is being made optional we should not be hiding ANYTHING in there. This also helps me with my project listed in https://hackmd.io/443_dE5lRWeEAp9bjGcKYw?view And also fixes some sorta-removed features due to removing verbs not matching people's actual powers due to new features like "Custom Me" and "Ctrl Clicking". ## Changelog 🆑 SirNightKnight (sprites), JohnFulpWillard del: Deleted the "IC" tab of the stat panel. fix: Lightgeists can't emote or pull as intended. fix: Blob minions can't pull again. qol: Martial Art users now have an action button for their artstyle-related businesses, rather than it being in the stat panel. qol: You can now right-click the move up/down UI buttons to look in the direction without moving. /🆑
109 lines
3.7 KiB
Plaintext
109 lines
3.7 KiB
Plaintext
/**
|
|
* ## Lightgeists
|
|
*
|
|
* Small critters meant to heal other living mobs and unable to interact with almost everything else.
|
|
*
|
|
*/
|
|
/mob/living/basic/lightgeist
|
|
name = "lightgeist"
|
|
desc = "This small floating creature is a completely unknown form of life... being near it fills you with a sense of tranquility."
|
|
icon_state = "lightgeist"
|
|
icon_living = "lightgeist"
|
|
icon_dead = "butterfly_dead"
|
|
response_help_continuous = "waves away"
|
|
response_help_simple = "wave away"
|
|
response_disarm_continuous = "brushes aside"
|
|
response_disarm_simple = "brush aside"
|
|
response_harm_continuous = "disrupts"
|
|
response_harm_simple = "disrupt"
|
|
speak_emote = list("oscillates")
|
|
maxHealth = 2
|
|
health = 2
|
|
melee_damage_lower = 5
|
|
melee_damage_upper = 5
|
|
melee_attack_cooldown = 5 SECONDS
|
|
friendly_verb_continuous = "taps"
|
|
friendly_verb_simple = "tap"
|
|
density = FALSE
|
|
basic_mob_flags = DEL_ON_DEATH
|
|
pass_flags = PASSTABLE | PASSGRILLE | PASSMOB
|
|
mob_size = MOB_SIZE_TINY
|
|
gold_core_spawnable = HOSTILE_SPAWN
|
|
verb_say = "warps"
|
|
verb_ask = "floats inquisitively"
|
|
verb_exclaim = "zaps"
|
|
verb_yell = "bangs"
|
|
initial_language_holder = /datum/language_holder/lightbringer
|
|
damage_coeff = list(BRUTE = 1, BURN = 1, TOX = 0, STAMINA = 1, OXY = 0)
|
|
light_range = 4
|
|
faction = list(FACTION_NEUTRAL)
|
|
unsuitable_atmos_damage = 0
|
|
minimum_survivable_temperature = 0
|
|
maximum_survivable_temperature = 1500
|
|
obj_damage = 0
|
|
pull_force = 0
|
|
environment_smash = ENVIRONMENT_SMASH_NONE
|
|
|
|
ai_controller = /datum/ai_controller/basic_controller/lightgeist
|
|
|
|
/mob/living/basic/lightgeist/Initialize(mapload)
|
|
. = ..()
|
|
add_traits(list(TRAIT_VENTCRAWLER_ALWAYS, TRAIT_MEDICAL_HUD, TRAIT_EMOTEMUTE), INNATE_TRAIT)
|
|
AddElement(/datum/element/simple_flying)
|
|
AddComponent(\
|
|
/datum/component/healing_touch,\
|
|
heal_brute = melee_damage_upper,\
|
|
heal_burn = melee_damage_upper,\
|
|
heal_time = 0,\
|
|
valid_targets_typecache = typecacheof(list(/mob/living)),\
|
|
action_text = "%SOURCE% begins mending the wounds of %TARGET%",\
|
|
complete_text = "%TARGET%'s wounds mend together.",\
|
|
)
|
|
|
|
/mob/living/basic/lightgeist/melee_attack(atom/target, list/modifiers, ignore_cooldown = FALSE)
|
|
. = ..()
|
|
if (. && isliving(target))
|
|
add_ally(target) // Anyone we heal will treat us as a friend
|
|
|
|
/mob/living/basic/lightgeist/ghost()
|
|
. = ..()
|
|
if(.)
|
|
death()
|
|
|
|
/datum/ai_controller/basic_controller/lightgeist
|
|
blackboard = list(
|
|
BB_TARGETING_STRATEGY = /datum/targeting_strategy/lightgeist,
|
|
)
|
|
|
|
ai_traits = PASSIVE_AI_FLAGS
|
|
ai_movement = /datum/ai_movement/basic_avoidance
|
|
idle_behavior = /datum/idle_behavior/idle_random_walk/less_walking
|
|
|
|
planning_subtrees = list(
|
|
/datum/ai_planning_subtree/simple_find_target,
|
|
/datum/ai_planning_subtree/basic_melee_attack_subtree, // We heal things by attacking them
|
|
)
|
|
|
|
/// Attack only mobs who have damage that we can heal, I think this is specific enough not to be a generic type
|
|
/datum/targeting_strategy/lightgeist
|
|
/// Types of mobs we can heal, not in a blackboard key because there is no point changing this at runtime because the component will already exist
|
|
var/heal_biotypes = MOB_ORGANIC | MOB_MINERAL
|
|
/// Type of limb we can heal
|
|
var/required_bodytype = BODYTYPE_ORGANIC
|
|
|
|
/datum/targeting_strategy/lightgeist/can_attack(mob/living/living_mob, mob/living/target, vision_range)
|
|
if (!isliving(target) || target.stat == DEAD)
|
|
return FALSE
|
|
if (!(heal_biotypes & target.mob_biotypes))
|
|
return FALSE
|
|
if (!iscarbon(target))
|
|
return target.get_brute_loss() > 0 || target.get_fire_loss() > 0
|
|
var/mob/living/carbon/carbon_target = target
|
|
for (var/obj/item/bodypart/part in carbon_target.get_bodyparts())
|
|
if (!part.brute_dam && !part.burn_dam)
|
|
continue
|
|
if (!(part.bodytype & required_bodytype))
|
|
continue
|
|
return TRUE
|
|
return FALSE
|