mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-08-29 08:08:49 +01:00
60d2d2ee1a
* Optimizes some gas_mixture procs, Optimizes pipeline processing significantly by 33% (#74233) ## About The Pull Request It is faster to operate on a gas list, especially if cached, then it is to operate on a datum. Doing this cause I'm seeing cost in merge() post #74230 Hits on a few other important places too. self_breakdown and such. Worth it IMO Could in theory go further by caching the global list. I'm tempted I admit but it needs profiling first and it's late EDIT: I have not slept, and have gone tooo far [Micros /gas_mixture/copy and copy_from, adds a new proc to handle copying with a ratio, copy_from_ratio](https://github.com/tgstation/tgstation/pull/74233/commits/91da0003daa9485962525d3e6bc9170a4c09876b) [91da000](https://github.com/tgstation/tgstation/pull/74233/commits/91da0003daa9485962525d3e6bc9170a4c09876b) The ADD_GAS sidestep saves us 0.1 seconds of init (used to at least. Ensuring we don't break archive is gonna have a cost. I don't want to profile this so I'll estimate maybe 0.05 seconds). The faster version of copy_from is just well, better, and helps to avoid stupid [Optimizes pipeline processing](https://github.com/tgstation/tgstation/pull/74233/commits/bf5a2d2d60554da2ce5fa1ac5f6c4179f6208cb2) [bf5a2d2](https://github.com/tgstation/tgstation/pull/74233/commits/bf5a2d2d60554da2ce5fa1ac5f6c4179f6208cb2) I haven't slept in 36 hours. Have some atmos optimizations Pipelines now keep track of components that require custom reconciliation as a seperate list. This avoids the overhead of filtering all connected atmos machinery. Rather then relying on |= to avoid duplicate gas_mixtures, we instead use a cycle var stored on the mix itself, which is compared with a static unique id from reconcile_air() This fully prevents double processing of gas, and should (hopefully) prevent stupid dupe issues in future Rather then summing volume on the gas mixture itself, we sum it in a local var. This avoids datum var accesses, and saves a slight bit of time Instead of running THERMAL_ENERGY() (and thus heat_capacity(), which iterates all gases in the mix AGAIN) when processing gas, we instead just hook into the existing heat capacity calculation done inside the giver gases loop This saves a significant amount of time, somewhere around 30% of the proc, I think? This doesn't tackle the big headache here, which is the copy_from loop at the base of the proc. I think the solution is to convert pipelines to a sort of polling model. Atmos components don't "own" their mix, they instead have to request a copy of it from the pipeline datum. This would work based off a mutually agreed upon volume amount for that component in that process cycle. We'd use an archived system to figure out what gases to give to components, while removing from the real MOLES list. We could then push gas consumption requests to the pipeline, which would handle them, alongside volume changes, on the next process. Not sure how I'd handle connected pipelines... Merging post reconcile maybe? This is a problem for tomorrow though, I need to go to bed. Saves about 30% of pipeline costs. Profiles taken on kilo, until each reconcile_air hits 5000 calls [old.txt](https://github.com/tgstation/tgstation/files/11075118/Profile.results.total.time.txt) [new.txt](https://github.com/tgstation/tgstation/files/11075133/profiler.txt) * Optimizes some gas_mixture procs, Optimizes pipeline processing significantly by 33% --------- Co-authored-by: LemonInTheDark <58055496+LemonInTheDark@users.noreply.github.com>
94 lines
2.8 KiB
Plaintext
94 lines
2.8 KiB
Plaintext
//"immutable" gas mixture used for immutable calculations
|
|
//it can be changed, but any changes will ultimately be undone before they can have any effect
|
|
|
|
/datum/gas_mixture/immutable
|
|
var/initial_temperature
|
|
gc_share = TRUE
|
|
|
|
/datum/gas_mixture/immutable/New()
|
|
..()
|
|
garbage_collect()
|
|
|
|
/datum/gas_mixture/immutable/garbage_collect()
|
|
temperature = initial_temperature
|
|
temperature_archived = initial_temperature
|
|
gases.Cut()
|
|
|
|
/datum/gas_mixture/immutable/archive()
|
|
return TRUE //nothing changes, so we do nothing and the archive is successful
|
|
|
|
/datum/gas_mixture/immutable/merge()
|
|
return FALSE //we're immutable.
|
|
|
|
/datum/gas_mixture/immutable/share(datum/gas_mixture/sharer, our_coeff, sharer_coeff)
|
|
. = ..()
|
|
sharer.temperature = initial_temperature
|
|
garbage_collect()
|
|
|
|
/datum/gas_mixture/immutable/react()
|
|
return FALSE //we're immutable.
|
|
|
|
/datum/gas_mixture/immutable/copy()
|
|
return new type //we're immutable, so we can just return a new instance.
|
|
|
|
/datum/gas_mixture/immutable/copy_from()
|
|
return FALSE //we're immutable.
|
|
|
|
/datum/gas_mixture/immutable/copy_from_ratio()
|
|
return FALSE //we're immutable.
|
|
|
|
/datum/gas_mixture/immutable/temperature_share(datum/gas_mixture/sharer, conduction_coefficient, sharer_temperature, sharer_heat_capacity)
|
|
. = ..()
|
|
temperature = initial_temperature
|
|
|
|
//used by space tiles
|
|
/datum/gas_mixture/immutable/space
|
|
initial_temperature = TCMB
|
|
|
|
/datum/gas_mixture/immutable/space/heat_capacity()
|
|
return HEAT_CAPACITY_VACUUM
|
|
|
|
/datum/gas_mixture/immutable/space/remove()
|
|
return copy() //we're always empty, so we can just return a copy.
|
|
|
|
/datum/gas_mixture/immutable/space/remove_ratio()
|
|
return copy() //we're always empty, so we can just return a copy.
|
|
|
|
//planet side stuff
|
|
/datum/gas_mixture/immutable/planetary
|
|
var/list/initial_gas = list()
|
|
|
|
/datum/gas_mixture/immutable/planetary/garbage_collect()
|
|
..()
|
|
gases.Cut()
|
|
for(var/id in initial_gas)
|
|
ADD_GAS(id, gases)
|
|
gases[id][MOLES] = initial_gas[id][MOLES]
|
|
gases[id][ARCHIVE] = initial_gas[id][ARCHIVE]
|
|
|
|
/datum/gas_mixture/immutable/planetary/proc/parse_string_immutable(gas_string) //I know I know, I need this tho
|
|
gas_string = SSair.preprocess_gas_string(gas_string)
|
|
|
|
var/list/mix = initial_gas
|
|
var/list/gas = params2list(gas_string)
|
|
if(gas["TEMP"])
|
|
initial_temperature = text2num(gas["TEMP"])
|
|
temperature_archived = initial_temperature
|
|
temperature = initial_temperature
|
|
gas -= "TEMP"
|
|
mix.Cut()
|
|
for(var/id in gas)
|
|
var/path = id
|
|
if(!ispath(path))
|
|
path = gas_id2path(path) //a lot of these strings can't have embedded expressions (especially for mappers), so support for IDs needs to stick around
|
|
ADD_GAS(path, mix)
|
|
mix[path][MOLES] = text2num(gas[id])
|
|
mix[path][ARCHIVE] = mix[path][MOLES]
|
|
|
|
for(var/id in mix)
|
|
ADD_GAS(id, gases)
|
|
gases[id][MOLES] = mix[id][MOLES]
|
|
gases[id][ARCHIVE] = mix[id][MOLES]
|
|
|
|
|