mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-07-13 09:05:11 +01:00
Bloop
183c5af2e4
## About The Pull Request Fixes https://github.com/tgstation/tgstation/issues/90641 Fixes https://github.com/tgstation/tgstation/issues/88366 Eliminates worries over virtualspace currency being sent to real accounts. When I was looking into why there were no flags for bitrunning areas. Then I saw this mess: <img width="929" height="889" alt="Code_2we2QjDyFp" src="https://github.com/user-attachments/assets/8a807bfe-b566-4057-a8ea-2b306325687d" /> Not having enough space / being too lazy to refactor this is a silly reason to not include flags for something like these virtual areas where it can be quite helpful. Fortunately I am not too lazy ~~in this moment~~ so here we go: It was fairly logical to move over some of these to a separate flag, which I've called `area_flags_mapping` since they pertain to maploading things and terrain generation mostly. `area_flags` stays reserved for general properties and now has more room than it did before for you people to fill it with. In doing this it's also neatened up the code quit a bit, as UNIQUE_AREA was kind of everywhere and now that it's implied by default less areas need to have it defined (or explicitly un-defined). <details> <summary> Working as intended </summary> <img width="787" height="448" alt="dreamseeker_p0Qts36tG1" src="https://github.com/user-attachments/assets/25056f34-8d43-4be2-a293-e53df7a7d1db" /> <img width="383" height="59" alt="dreamseeker_Ek7TXCcpbA" src="https://github.com/user-attachments/assets/89622974-9467-4cdb-8345-d684f7c9004b" /> </details> ## Why It's Good For The Game Fixes an exploit, improves the area flags situation slightly. ## Changelog 🆑 fix: you can no longer send money from virtualspace to a real account code: adds a flag for virtual areas so they can easily be checked, as well as an easy helper proc, 'is_area_virtual(your_area)' /🆑
76 lines
2.2 KiB
Plaintext
76 lines
2.2 KiB
Plaintext
/// Turf type that appears to be a world border, completely impassable and non-interactable to all physical (alive) entities.
|
|
/turf/cordon
|
|
name = "cordon"
|
|
icon = 'icons/turf/walls.dmi'
|
|
icon_state = "cordon"
|
|
invisibility = INVISIBILITY_ABSTRACT
|
|
mouse_opacity = MOUSE_OPACITY_TRANSPARENT
|
|
explosive_resistance = INFINITY
|
|
rad_insulation = RAD_FULL_INSULATION
|
|
opacity = TRUE
|
|
density = TRUE
|
|
blocks_air = TRUE
|
|
init_air = FALSE
|
|
space_lit = TRUE
|
|
bullet_bounce_sound = null
|
|
turf_flags = NOJAUNT
|
|
baseturfs = /turf/cordon
|
|
|
|
/turf/cordon/AfterChange()
|
|
. = ..()
|
|
SSair.high_pressure_delta -= src
|
|
|
|
/turf/cordon/rust_heretic_act()
|
|
return FALSE
|
|
|
|
/turf/cordon/acid_act(acidpwr, acid_volume, acid_id)
|
|
return FALSE
|
|
|
|
/turf/cordon/Melt()
|
|
to_be_destroyed = FALSE
|
|
return src
|
|
|
|
/turf/cordon/singularity_act()
|
|
return FALSE
|
|
|
|
/turf/cordon/ScrapeAway(amount, flags)
|
|
return src // :devilcat:
|
|
|
|
/turf/cordon/TerraformTurf(path, list/new_baseturfs, flags)
|
|
return
|
|
|
|
/turf/cordon/bullet_act(obj/projectile/hitting_projectile, def_zone, piercing_hit)
|
|
SHOULD_CALL_PARENT(FALSE) // Fuck you
|
|
return BULLET_ACT_BLOCK
|
|
|
|
/turf/cordon/Adjacent(atom/neighbor, atom/target, atom/movable/mover)
|
|
return FALSE
|
|
|
|
/turf/cordon/Bumped(atom/movable/bumped_atom)
|
|
. = ..()
|
|
|
|
if(HAS_TRAIT(bumped_atom, TRAIT_FREE_HYPERSPACE_SOFTCORDON_MOVEMENT)) //we could feasibly reach the border, so just don't
|
|
dump_in_space(bumped_atom)
|
|
|
|
/// Area used in conjunction with the cordon turf to create a fully functioning world border.
|
|
/area/misc/cordon
|
|
name = "CORDON"
|
|
icon_state = "cordon"
|
|
static_lighting = FALSE
|
|
base_lighting_alpha = 255
|
|
area_flags = NOTELEPORT|HIDDEN_AREA
|
|
requires_power = FALSE
|
|
|
|
/area/misc/cordon/Entered(atom/movable/arrived, area/old_area)
|
|
. = ..()
|
|
for(var/mob/living/enterer as anything in arrived.get_all_contents_type(/mob/living))
|
|
to_chat(enterer, span_userdanger("This was a bad idea..."))
|
|
enterer.dust(TRUE, FALSE, TRUE)
|
|
|
|
/// This type of cordon will block ghosts from passing through it. Useful for stuff like Away Missions, where you feasibly want to block ghosts from entering to keep a certain map section a secret.
|
|
/turf/cordon/secret
|
|
name = "secret cordon (ghost blocking)"
|
|
|
|
/turf/cordon/secret/attack_ghost(mob/dead/observer/user)
|
|
return FALSE
|