mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-07-15 10:04:30 +01:00
Jeremiah
c771360e00
## About The Pull Request This defaults every tgui to fancy mode and removes the preference entirely. ## Why It's Good For The Game If you look through the code you'll find comments like these > //some browsers (IE8) have trouble with unsupported css3 elements that break the panel's functionality, so we won't load those if a user is in no frills tgui mode since that's for similar compatability support We're far and away from IE8, therefore our need for compatibility support, so I think it's valid to remove this so called 'no frills tgui mode'. It's tied into the event message system with every backend update, so there's a tad less overhead. ## Changelog 🆑 del: TGUI now defaults to fancy mode, there is only fancy mode. Welcome to the future. /🆑
113 lines
2.8 KiB
Plaintext
113 lines
2.8 KiB
Plaintext
/*!
|
|
* Copyright (c) 2020 Aleksej Komarov
|
|
* SPDX-License-Identifier: MIT
|
|
*/
|
|
|
|
/**
|
|
* tgui_panel datum
|
|
* Hosts tgchat and other nice features.
|
|
*/
|
|
/datum/tgui_panel
|
|
var/client/client
|
|
var/datum/tgui_window/window
|
|
var/broken = FALSE
|
|
var/initialized_at
|
|
/// Each client notifies on protected playback, so this prevents spamming admins.
|
|
var/static/admins_warned = FALSE
|
|
|
|
/datum/tgui_panel/New(client/client, id)
|
|
src.client = client
|
|
window = new(client, id)
|
|
window.subscribe(src, PROC_REF(on_message))
|
|
|
|
/datum/tgui_panel/Del()
|
|
window.unsubscribe(src)
|
|
window.close()
|
|
return ..()
|
|
|
|
/**
|
|
* public
|
|
*
|
|
* TRUE if panel is initialized and ready to receive messages.
|
|
*/
|
|
/datum/tgui_panel/proc/is_ready()
|
|
return !broken && window.is_ready()
|
|
|
|
/**
|
|
* public
|
|
*
|
|
* Initializes tgui panel.
|
|
*/
|
|
/datum/tgui_panel/proc/initialize(force = FALSE)
|
|
set waitfor = FALSE
|
|
// Minimal sleep to defer initialization to after client constructor
|
|
sleep(1 TICKS)
|
|
initialized_at = world.time
|
|
// Perform a clean initialization
|
|
window.initialize(
|
|
strict_mode = TRUE,
|
|
assets = list(
|
|
get_asset_datum(/datum/asset/simple/tgui_panel),
|
|
))
|
|
window.send_asset(get_asset_datum(/datum/asset/simple/namespaced/fontawesome))
|
|
window.send_asset(get_asset_datum(/datum/asset/simple/namespaced/tgfont))
|
|
window.send_asset(get_asset_datum(/datum/asset/spritesheet_batched/chat))
|
|
// Other setup
|
|
request_telemetry()
|
|
addtimer(CALLBACK(src, PROC_REF(on_initialize_timed_out)), 5 SECONDS)
|
|
window.send_message("testTelemetryCommand")
|
|
|
|
/**
|
|
* private
|
|
*
|
|
* Called when initialization has timed out.
|
|
*/
|
|
/datum/tgui_panel/proc/on_initialize_timed_out()
|
|
// Currently does nothing but sending a message to old chat.
|
|
SEND_TEXT(client, span_userdanger("Failed to load fancy chat, click <a href='byond://?src=[REF(src)];reload_tguipanel=1'>HERE</a> to attempt to reload it."))
|
|
|
|
/**
|
|
* private
|
|
*
|
|
* Callback for handling incoming tgui messages.
|
|
*/
|
|
/datum/tgui_panel/proc/on_message(type, payload)
|
|
if(type == "ready")
|
|
broken = FALSE
|
|
window.send_message("update", list(
|
|
"config" = list(
|
|
"client" = list(
|
|
"ckey" = client.ckey,
|
|
"address" = client.address,
|
|
"computer_id" = client.computer_id,
|
|
),
|
|
"window" = list(
|
|
"locked" = FALSE,
|
|
),
|
|
),
|
|
))
|
|
return TRUE
|
|
|
|
if(type == "audio/setAdminMusicVolume")
|
|
client.admin_music_volume = payload["volume"]
|
|
return TRUE
|
|
|
|
if(type == "audio/protected")
|
|
if(!admins_warned)
|
|
message_admins(span_notice("Audio returned a protected playback error, likely due to being copyrighted."))
|
|
admins_warned = TRUE
|
|
addtimer(VARSET_CALLBACK(src, admins_warned, FALSE), 10 SECONDS)
|
|
return TRUE
|
|
|
|
if(type == "telemetry")
|
|
analyze_telemetry(payload)
|
|
return TRUE
|
|
|
|
/**
|
|
* public
|
|
*
|
|
* Sends a round restart notification.
|
|
*/
|
|
/datum/tgui_panel/proc/send_roundrestart()
|
|
window.send_message("roundrestart")
|