mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-08-22 04:30:44 +01:00
ff006aa4a5
## About The Pull Request just macro-izes all the usages of verbs in the codebase as a pre-requisite to my follow up pr that serializes all the verbs arguments so we can tgui-ify the command bar, so we can then put it on the onscreen map. this also basically does the same as #94487 so can easily be integrated into the verb queueing stuff... but does not actually do any verb queueing by itself. basically im just trying to be https://github.com/tgstation/tgstation/labels/Atomic ## Why It's Good For The Game it doesn't really do anything by itself but it does let us do more stuff ## Changelog 🆑 code: the backend to all verbs in the game has been played with, please report any issues to github /🆑 --------- Co-authored-by: harryob <55142896+harryob@users.noreply.github.com>
134 lines
3.8 KiB
Plaintext
134 lines
3.8 KiB
Plaintext
/**
|
|
* A generic background object.
|
|
* It is also implicitly used to allocate a rectangle on the map, which will
|
|
* be used for auto-scaling the map.
|
|
*/
|
|
/atom/movable/screen/background
|
|
name = "background"
|
|
icon = 'icons/hud/map_backgrounds.dmi'
|
|
icon_state = "clear"
|
|
layer = GAME_PLANE
|
|
plane = GAME_PLANE
|
|
|
|
/**
|
|
* Sets screen_loc of this screen object, in form of point coordinates,
|
|
* with optional pixel offset (px, py).
|
|
*
|
|
* If applicable, "assigned_map" has to be assigned before this proc call.
|
|
*/
|
|
/atom/movable/screen/proc/set_position(x, y, px = 0, py = 0)
|
|
if(assigned_map)
|
|
screen_loc = "[assigned_map]:[x]:[px],[y]:[py]"
|
|
else
|
|
screen_loc = "[x]:[px],[y]:[py]"
|
|
|
|
/**
|
|
* Sets screen_loc to fill a rectangular area of the map.
|
|
*
|
|
* If applicable, "assigned_map" has to be assigned before this proc call.
|
|
*/
|
|
/atom/movable/screen/proc/fill_rect(x1, y1, x2, y2)
|
|
if(assigned_map)
|
|
screen_loc = "[assigned_map]:[x1],[y1] to [x2],[y2]"
|
|
else
|
|
screen_loc = "[x1],[y1] to [x2],[y2]"
|
|
|
|
/**
|
|
* Registers screen obj with the client, which makes it visible on the
|
|
* assigned map, and becomes a part of the assigned map's lifecycle.
|
|
*/
|
|
/client/proc/register_map_obj(atom/movable/screen/screen_obj)
|
|
if(!screen_obj.assigned_map)
|
|
CRASH("Can't register [screen_obj] without 'assigned_map' property.")
|
|
if(!screen_maps[screen_obj.assigned_map])
|
|
screen_maps[screen_obj.assigned_map] = list()
|
|
// NOTE: Possibly an expensive operation
|
|
var/list/screen_map = screen_maps[screen_obj.assigned_map]
|
|
screen_map |= screen_obj
|
|
screen |= screen_obj
|
|
|
|
/**
|
|
* Clears the map of registered screen objects.
|
|
*/
|
|
/client/proc/clear_map(map_name)
|
|
if(!map_name || !screen_maps[map_name])
|
|
return FALSE
|
|
for(var/atom/movable/screen/screen_obj in screen_maps[map_name])
|
|
screen_maps[map_name] -= screen_obj
|
|
screen -= screen_obj
|
|
if(screen_obj.del_on_map_removal)
|
|
qdel(screen_obj)
|
|
screen_maps -= map_name
|
|
|
|
/**
|
|
* Clears all the maps of registered screen objects.
|
|
*/
|
|
/client/proc/clear_all_maps()
|
|
for(var/map_name in screen_maps)
|
|
clear_map(map_name)
|
|
|
|
/**
|
|
* Creates a popup window with a basic map element in it, without any
|
|
* further initialization.
|
|
*
|
|
* Ratio is how many pixels by how many pixels (keep it simple).
|
|
*
|
|
* Returns a map name.
|
|
*/
|
|
/client/proc/create_popup(name, title, ratiox = 100, ratioy = 100)
|
|
winclone(src, "popupwindow", name)
|
|
var/list/winparams = list()
|
|
winparams["title"] = title
|
|
winparams["size"] = "[ratiox]x[ratioy]"
|
|
winparams["on-close"] = "handle-popup-close [name]"
|
|
winset(src, "[name]", list2params(winparams))
|
|
winshow(src, "[name]", 1)
|
|
|
|
var/list/params = list()
|
|
params["parent"] = "[name]"
|
|
params["type"] = "map"
|
|
params["size"] = "[ratiox]x[ratioy]"
|
|
params["anchor1"] = "0,0"
|
|
params["anchor2"] = "[ratiox],[ratioy]"
|
|
winset(src, "[name]_map", list2params(params))
|
|
|
|
return "[name]_map"
|
|
|
|
/**
|
|
* Create the popup, and get it ready for generic use by giving
|
|
* it a background.
|
|
*
|
|
* Width and height are multiplied by 64 by default.
|
|
*/
|
|
/client/proc/setup_popup(popup_name, width = 9, height = 9, \
|
|
tilesize = 2, title, bg_icon)
|
|
if(!popup_name)
|
|
return
|
|
clear_map("[popup_name]_map")
|
|
var/x_value = ICON_SIZE_X * tilesize * width
|
|
var/y_value = ICON_SIZE_Y * tilesize * height
|
|
var/map_name = create_popup(popup_name, title, x_value, y_value)
|
|
|
|
var/atom/movable/screen/background/background = new
|
|
background.assigned_map = map_name
|
|
background.fill_rect(1, 1, width, height)
|
|
if(bg_icon)
|
|
background.icon_state = bg_icon
|
|
register_map_obj(background)
|
|
|
|
return map_name
|
|
|
|
/**
|
|
* Closes a popup.
|
|
*/
|
|
/client/proc/close_popup(popup)
|
|
winshow(src, popup, 0)
|
|
handle_popup_close(popup)
|
|
|
|
/**
|
|
* When the popup closes in any way (player or proc call) it calls this.
|
|
*/
|
|
GAME_VERB_HIDDEN(/client, handle_popup_close, "handle popup close", window_id as text)
|
|
clear_map("[window_id]_map")
|
|
SEND_SIGNAL(src, COMSIG_POPUP_CLEARED, window_id)
|