mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-01-29 10:31:34 +00:00
69827604c4
## About The Pull Request As the title says. Adds a bunch more stat changes to various different items and a somewhat simple way of modifying them whilst minimizing side-effects as much as possible. Added a new negative curse of polymorph suffix that can randomly polymorph you once you pick up the item. Curse of hunger items won't start on items that are not on a turf. Curse of polymorph will only activate when equipped. Bodyparts, two-handed melees, bags, guns and grenades, to name a few, have a bunch of type-specific stat changes depending on their quality. Some items won't gain fantasy suffixes during the RPG loot event, like stacks, chairs and paper, to make gamifying the stats a bit harder. I'm sure there'll still be other ways to game the event, but it's not that big of a deal since these are the easiest ways to game it. High level items also have a cool unusual effect aura ## Why It's Good For The Game Makes the RPG item event cooler. Right now, it's a bit lame since everything only gains force value and wound bonus on attack. This makes the statistic increases more type-based and make it interesting to use It's okay for some items to be powerful since this is a wizard event and a very impactful one too. By making the curse of hunger items not spawn on people, it'll also make it a less painful event too. ## Changelog 🆑 add: Expanded the RPG loot wizard event by giving various different items their own statistic boost. /🆑 --------- Co-authored-by: Watermelon914 <3052169-Watermelon914@users.noreply.gitlab.com>
78 lines
2.9 KiB
Plaintext
78 lines
2.9 KiB
Plaintext
/obj/item/grenade/hypnotic
|
|
name = "flashbang"
|
|
desc = "A modified flashbang which uses hypnotic flashes and mind-altering soundwaves to induce an instant trance upon detonation."
|
|
icon_state = "flashbang"
|
|
inhand_icon_state = "flashbang"
|
|
lefthand_file = 'icons/mob/inhands/equipment/security_lefthand.dmi'
|
|
righthand_file = 'icons/mob/inhands/equipment/security_righthand.dmi'
|
|
var/flashbang_range = 7
|
|
|
|
/obj/item/grenade/hypnotic/apply_grenade_fantasy_bonuses(quality)
|
|
flashbang_range = modify_fantasy_variable("flashbang_range", flashbang_range, quality)
|
|
|
|
/obj/item/grenade/hypnotic/remove_grenade_fantasy_bonuses(quality)
|
|
flashbang_range = reset_fantasy_variable("flashbang_range", flashbang_range)
|
|
|
|
/obj/item/grenade/hypnotic/detonate(mob/living/lanced_by)
|
|
. = ..()
|
|
if(!.)
|
|
return
|
|
|
|
update_mob()
|
|
var/flashbang_turf = get_turf(src)
|
|
if(!flashbang_turf)
|
|
return
|
|
do_sparks(rand(5, 9), FALSE, src)
|
|
playsound(flashbang_turf, 'sound/effects/screech.ogg', 100, TRUE, 8, 0.9)
|
|
new /obj/effect/dummy/lighting_obj (flashbang_turf, flashbang_range + 2, 4, LIGHT_COLOR_PURPLE, 2)
|
|
for(var/mob/living/living_mob in get_hearers_in_view(flashbang_range, flashbang_turf))
|
|
bang(get_turf(living_mob), living_mob)
|
|
qdel(src)
|
|
|
|
/obj/item/grenade/hypnotic/proc/bang(turf/turf, mob/living/living_mob)
|
|
if(living_mob.stat == DEAD) //They're dead!
|
|
return
|
|
var/distance = max(0, get_dist(get_turf(src), turf))
|
|
|
|
//Bang
|
|
var/hypno_sound = FALSE
|
|
|
|
//Hearing protection check
|
|
if(iscarbon(living_mob))
|
|
var/mob/living/carbon/target = living_mob
|
|
var/list/reflist = list(1)
|
|
SEND_SIGNAL(target, COMSIG_CARBON_SOUNDBANG, reflist)
|
|
var/intensity = reflist[1]
|
|
var/ear_safety = target.get_ear_protection()
|
|
var/effect_amount = intensity - ear_safety
|
|
if(effect_amount > 0)
|
|
hypno_sound = TRUE
|
|
|
|
if(!distance || loc == living_mob || loc == living_mob.loc)
|
|
living_mob.Paralyze(10)
|
|
living_mob.Knockdown(100)
|
|
to_chat(living_mob, span_hypnophrase("The sound echoes in your brain..."))
|
|
living_mob.adjust_hallucinations(100 SECONDS)
|
|
|
|
else
|
|
if(distance <= 1)
|
|
living_mob.Paralyze(5)
|
|
living_mob.Knockdown(30)
|
|
if(hypno_sound)
|
|
to_chat(living_mob, span_hypnophrase("The sound echoes in your brain..."))
|
|
living_mob.adjust_hallucinations(100 SECONDS)
|
|
|
|
//Flash
|
|
if(living_mob.flash_act(affect_silicon = 1))
|
|
living_mob.Paralyze(max(10/max(1, distance), 5))
|
|
living_mob.Knockdown(max(100/max(1, distance), 40))
|
|
if(iscarbon(living_mob))
|
|
var/mob/living/carbon/target = living_mob
|
|
if(target.hypnosis_vulnerable()) //The sound causes the necessary conditions unless the target has mindshield or hearing protection
|
|
target.apply_status_effect(/datum/status_effect/trance, 100, TRUE)
|
|
else
|
|
to_chat(target, span_hypnophrase("The light is so pretty..."))
|
|
target.adjust_drowsiness_up_to(20 SECONDS, 40 SECONDS)
|
|
target.adjust_confusion_up_to(10 SECONDS, 20 SECONDS)
|
|
target.adjust_dizzy_up_to(20 SECONDS, 40 SECONDS)
|